New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2014/dev_CNRS_2014/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2014/dev_CNRS_2014/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 4896

Last change on this file since 4896 was 4896, checked in by cetlod, 9 years ago

2014/dev_CNRS_2014 : merge the 1st branch onto dev_CNRS_2014, see ticket #1415
  • Property svn:keywords set to Id
File size: 52.0 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   dyn_hpg      : update the momentum trend with the now horizontal
22   !!                  gradient of the hydrostatic pressure
23   !!   dyn_hpg_init : initialisation and control of options
24   !!       hpg_zco  : z-coordinate scheme
25   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
26   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
27   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
28   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE dom_oce         ! ocean space and time domain
32   USE phycst          ! physical constants
33   USE trd_oce         ! trends: ocean variables
34   USE trddyn          ! trend manager: dynamics
35   !
36   USE in_out_manager  ! I/O manager
37   USE prtctl          ! Print control
38   USE lbclnk          ! lateral boundary condition
39   USE lib_mpp         ! MPP library
40   USE wrk_nemo        ! Memory Allocation
41   USE timing          ! Timing
42
43   IMPLICIT NONE
44   PRIVATE
45
46   PUBLIC   dyn_hpg        ! routine called by step module
47   PUBLIC   dyn_hpg_init   ! routine called by opa module
48
49   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
50   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
51   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
52   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
53   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
54   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
55   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
56
57   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
58
59   !! * Substitutions
60#  include "domzgr_substitute.h90"
61#  include "vectopt_loop_substitute.h90"
62   !!----------------------------------------------------------------------
63   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
64   !! $Id$
65   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
66   !!----------------------------------------------------------------------
67CONTAINS
68
69   SUBROUTINE dyn_hpg( kt )
70      !!---------------------------------------------------------------------
71      !!                  ***  ROUTINE dyn_hpg  ***
72      !!
73      !! ** Method  :   Call the hydrostatic pressure gradient routine
74      !!              using the scheme defined in the namelist
75      !!
76      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
77      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
78      !!----------------------------------------------------------------------
79      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
80      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
81      !!----------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
84      !
85      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
86         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
87         ztrdu(:,:,:) = ua(:,:,:)
88         ztrdv(:,:,:) = va(:,:,:)
89      ENDIF
90      !
91      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
92      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
93      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
94      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
95      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
96      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
97      END SELECT
98      !
99      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
100         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
101         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
102         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
103         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
104      ENDIF
105      !
106      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
107         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
108      !
109      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
110      !
111   END SUBROUTINE dyn_hpg
112
113
114   SUBROUTINE dyn_hpg_init
115      !!----------------------------------------------------------------------
116      !!                 ***  ROUTINE dyn_hpg_init  ***
117      !!
118      !! ** Purpose :   initializations for the hydrostatic pressure gradient
119      !!              computation and consistency control
120      !!
121      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
122      !!      with the type of vertical coordinate used (zco, zps, sco)
123      !!----------------------------------------------------------------------
124      INTEGER ::   ioptio = 0      ! temporary integer
125      INTEGER ::   ios             ! Local integer output status for namelist read
126      !!
127      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
128         &                 ln_hpg_djc, ln_hpg_prj, ln_dynhpg_imp
129      !!----------------------------------------------------------------------
130      !
131      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
132      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
133901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
134
135      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
136      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
137902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
138      WRITE ( numond, namdyn_hpg )
139      !
140      IF(lwp) THEN                   ! Control print
141         WRITE(numout,*)
142         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
143         WRITE(numout,*) '~~~~~~~~~~~~'
144         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
145         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
146         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
147         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
148         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
149         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
150         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
151      ENDIF
152      !
153      IF( ln_hpg_djc )   &
154         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
155                           & currently disabled (bugs under investigation). Please select &
156                           & either  ln_hpg_sco or  ln_hpg_prj instead')
157      !
158      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj) )   &
159         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
160                           & the standard jacobian formulation hpg_sco or &
161                           & the pressure jacobian formulation hpg_prj')
162      !
163      !                               ! Set nhpg from ln_hpg_... flags
164      IF( ln_hpg_zco )   nhpg = 0
165      IF( ln_hpg_zps )   nhpg = 1
166      IF( ln_hpg_sco )   nhpg = 2
167      IF( ln_hpg_djc )   nhpg = 3
168      IF( ln_hpg_prj )   nhpg = 4
169      !
170      !                               ! Consistency check
171      ioptio = 0
172      IF( ln_hpg_zco )   ioptio = ioptio + 1
173      IF( ln_hpg_zps )   ioptio = ioptio + 1
174      IF( ln_hpg_sco )   ioptio = ioptio + 1
175      IF( ln_hpg_djc )   ioptio = ioptio + 1
176      IF( ln_hpg_prj )   ioptio = ioptio + 1
177      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
178      !
179   END SUBROUTINE dyn_hpg_init
180
181
182   SUBROUTINE hpg_zco( kt )
183      !!---------------------------------------------------------------------
184      !!                  ***  ROUTINE hpg_zco  ***
185      !!
186      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
187      !!      The now hydrostatic pressure gradient at a given level, jk,
188      !!      is computed by taking the vertical integral of the in-situ
189      !!      density gradient along the model level from the suface to that
190      !!      level:    zhpi = grav .....
191      !!                zhpj = grav .....
192      !!      add it to the general momentum trend (ua,va).
193      !!            ua = ua - 1/e1u * zhpi
194      !!            va = va - 1/e2v * zhpj
195      !!
196      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
197      !!----------------------------------------------------------------------
198      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
199      !!
200      INTEGER  ::   ji, jj, jk       ! dummy loop indices
201      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
202      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
203      !!----------------------------------------------------------------------
204      !
205      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
206      !
207      IF( kt == nit000 ) THEN
208         IF(lwp) WRITE(numout,*)
209         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
210         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
211      ENDIF
212
213      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
214
215      ! Surface value
216      DO jj = 2, jpjm1
217         DO ji = fs_2, fs_jpim1   ! vector opt.
218            zcoef1 = zcoef0 * fse3w(ji,jj,1)
219            ! hydrostatic pressure gradient
220            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
221            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
222            ! add to the general momentum trend
223            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
224            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
225         END DO
226      END DO
227
228      !
229      ! interior value (2=<jk=<jpkm1)
230      DO jk = 2, jpkm1
231         DO jj = 2, jpjm1
232            DO ji = fs_2, fs_jpim1   ! vector opt.
233               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
234               ! hydrostatic pressure gradient
235               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
236                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
237                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
238
239               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
240                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
241                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
242               ! add to the general momentum trend
243               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
244               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
245            END DO
246         END DO
247      END DO
248      !
249      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
250      !
251   END SUBROUTINE hpg_zco
252
253
254   SUBROUTINE hpg_zps( kt )
255      !!---------------------------------------------------------------------
256      !!                 ***  ROUTINE hpg_zps  ***
257      !!
258      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
259      !!
260      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
261      !!----------------------------------------------------------------------
262      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
263      !!
264      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
265      INTEGER  ::   iku, ikv                         ! temporary integers
266      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
267      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
268      !!----------------------------------------------------------------------
269      !
270      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
271      !
272      IF( kt == nit000 ) THEN
273         IF(lwp) WRITE(numout,*)
274         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
275         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
276      ENDIF
277
278
279      ! Local constant initialization
280      zcoef0 = - grav * 0.5_wp
281
282      !  Surface value (also valid in partial step case)
283      DO jj = 2, jpjm1
284         DO ji = fs_2, fs_jpim1   ! vector opt.
285            zcoef1 = zcoef0 * fse3w(ji,jj,1)
286            ! hydrostatic pressure gradient
287            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
288            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
289            ! add to the general momentum trend
290            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
291            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
292         END DO
293      END DO
294
295
296      ! interior value (2=<jk=<jpkm1)
297      DO jk = 2, jpkm1
298         DO jj = 2, jpjm1
299            DO ji = fs_2, fs_jpim1   ! vector opt.
300               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
301               ! hydrostatic pressure gradient
302               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
303                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
304                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
305
306               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
307                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
308                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
309               ! add to the general momentum trend
310               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
311               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
312            END DO
313         END DO
314      END DO
315
316
317      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
318      DO jj = 2, jpjm1
319         DO ji = 2, jpim1
320            iku = mbku(ji,jj)
321            ikv = mbkv(ji,jj)
322            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
323            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
324            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
325               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
326               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
327                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
328               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
329            ENDIF
330            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
331               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
332               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
333                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
334               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
335            ENDIF
336         END DO
337      END DO
338      !
339      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
340      !
341   END SUBROUTINE hpg_zps
342
343
344   SUBROUTINE hpg_sco( kt )
345      !!---------------------------------------------------------------------
346      !!                  ***  ROUTINE hpg_sco  ***
347      !!
348      !! ** Method  :   s-coordinate case. Jacobian scheme.
349      !!      The now hydrostatic pressure gradient at a given level, jk,
350      !!      is computed by taking the vertical integral of the in-situ
351      !!      density gradient along the model level from the suface to that
352      !!      level. s-coordinates (ln_sco): a corrective term is added
353      !!      to the horizontal pressure gradient :
354      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
355      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
356      !!      add it to the general momentum trend (ua,va).
357      !!         ua = ua - 1/e1u * zhpi
358      !!         va = va - 1/e2v * zhpj
359      !!
360      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
361      !!----------------------------------------------------------------------
362      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
363      !!
364      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
365      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
366      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
367      !!----------------------------------------------------------------------
368      !
369      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
370      !
371      IF( kt == nit000 ) THEN
372         IF(lwp) WRITE(numout,*)
373         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
374         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
375      ENDIF
376
377      ! Local constant initialization
378      zcoef0 = - grav * 0.5_wp
379      ! To use density and not density anomaly
380      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
381      ELSE                 ;     znad = 0._wp         ! Fixed volume
382      ENDIF
383
384      ! Surface value
385      DO jj = 2, jpjm1
386         DO ji = fs_2, fs_jpim1   ! vector opt.
387            ! hydrostatic pressure gradient along s-surfaces
388            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
389               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
390            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
391               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
392            ! s-coordinate pressure gradient correction
393            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
394               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
395            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
396               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
397            ! add to the general momentum trend
398            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
399            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
400         END DO
401      END DO
402
403      ! interior value (2=<jk=<jpkm1)
404      DO jk = 2, jpkm1
405         DO jj = 2, jpjm1
406            DO ji = fs_2, fs_jpim1   ! vector opt.
407               ! hydrostatic pressure gradient along s-surfaces
408               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
409                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
410                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
411               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
412                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
413                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
414               ! s-coordinate pressure gradient correction
415               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
416                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
417               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
418                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
419               ! add to the general momentum trend
420               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
421               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
422            END DO
423         END DO
424      END DO
425      !
426      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
427      !
428   END SUBROUTINE hpg_sco
429
430
431   SUBROUTINE hpg_djc( kt )
432      !!---------------------------------------------------------------------
433      !!                  ***  ROUTINE hpg_djc  ***
434      !!
435      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
436      !!
437      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
438      !!----------------------------------------------------------------------
439      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
440      !!
441      INTEGER  ::   ji, jj, jk          ! dummy loop indices
442      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
443      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
444      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
445      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
446      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
447      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
448      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
449      !!----------------------------------------------------------------------
450      !
451      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
452      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
453      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
454      !
455
456      IF( kt == nit000 ) THEN
457         IF(lwp) WRITE(numout,*)
458         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
459         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
460      ENDIF
461
462      ! Local constant initialization
463      zcoef0 = - grav * 0.5_wp
464      z1_10  = 1._wp / 10._wp
465      z1_12  = 1._wp / 12._wp
466
467      !----------------------------------------------------------------------------------------
468      !  compute and store in provisional arrays elementary vertical and horizontal differences
469      !----------------------------------------------------------------------------------------
470
471!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
472
473      DO jk = 2, jpkm1
474         DO jj = 2, jpjm1
475            DO ji = fs_2, fs_jpim1   ! vector opt.
476               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
477               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
478               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
479               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
480               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
481               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
482            END DO
483         END DO
484      END DO
485
486      !-------------------------------------------------------------------------
487      ! compute harmonic averages using eq. 5.18
488      !-------------------------------------------------------------------------
489      zep = 1.e-15
490
491!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
492!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
493
494      DO jk = 2, jpkm1
495         DO jj = 2, jpjm1
496            DO ji = fs_2, fs_jpim1   ! vector opt.
497               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
498
499               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
500               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
501
502               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
503               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
504
505               IF( cffw > zep) THEN
506                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
507                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
508               ELSE
509                  drhow(ji,jj,jk) = 0._wp
510               ENDIF
511
512               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
513                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
514
515               IF( cffu > zep ) THEN
516                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
517                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
518               ELSE
519                  drhou(ji,jj,jk ) = 0._wp
520               ENDIF
521
522               IF( cffx > zep ) THEN
523                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
524                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
525               ELSE
526                  dzu(ji,jj,jk) = 0._wp
527               ENDIF
528
529               IF( cffv > zep ) THEN
530                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
531                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
532               ELSE
533                  drhov(ji,jj,jk) = 0._wp
534               ENDIF
535
536               IF( cffy > zep ) THEN
537                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
538                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
539               ELSE
540                  dzv(ji,jj,jk) = 0._wp
541               ENDIF
542
543            END DO
544         END DO
545      END DO
546
547      !----------------------------------------------------------------------------------
548      ! apply boundary conditions at top and bottom using 5.36-5.37
549      !----------------------------------------------------------------------------------
550      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
551      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
552      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
553
554      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
555      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
556      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
557
558
559      !--------------------------------------------------------------
560      ! Upper half of top-most grid box, compute and store
561      !-------------------------------------------------------------
562
563!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
564!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
565
566      DO jj = 2, jpjm1
567         DO ji = fs_2, fs_jpim1   ! vector opt.
568            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
569               &                   * (  rhd(ji,jj,1)                                    &
570               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
571               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
572               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
573         END DO
574      END DO
575
576!!bug gm    : here also, simplification is possible
577!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
578
579      DO jk = 2, jpkm1
580         DO jj = 2, jpjm1
581            DO ji = fs_2, fs_jpim1   ! vector opt.
582
583               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
584                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
585                  &            - grav * z1_10 * (                                                                     &
586                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
587                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
588                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
589                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
590                  &                             )
591
592               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
593                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
594                  &            - grav* z1_10 * (                                                                      &
595                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
596                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
597                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
598                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
599                  &                            )
600
601               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
602                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
603                  &            - grav* z1_10 * (                                                                      &
604                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
605                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
606                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
607                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
608                  &                            )
609
610            END DO
611         END DO
612      END DO
613      CALL lbc_lnk(rho_k,'W',1.)
614      CALL lbc_lnk(rho_i,'U',1.)
615      CALL lbc_lnk(rho_j,'V',1.)
616
617
618      ! ---------------
619      !  Surface value
620      ! ---------------
621      DO jj = 2, jpjm1
622         DO ji = fs_2, fs_jpim1   ! vector opt.
623            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
624            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
625            ! add to the general momentum trend
626            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
627            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
628         END DO
629      END DO
630
631      ! ----------------
632      !  interior value   (2=<jk=<jpkm1)
633      ! ----------------
634      DO jk = 2, jpkm1
635         DO jj = 2, jpjm1
636            DO ji = fs_2, fs_jpim1   ! vector opt.
637               ! hydrostatic pressure gradient along s-surfaces
638               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
639                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
640                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
641               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
642                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
643                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
644               ! add to the general momentum trend
645               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
646               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
647            END DO
648         END DO
649      END DO
650      !
651      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
652      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
653      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
654      !
655   END SUBROUTINE hpg_djc
656
657
658   SUBROUTINE hpg_prj( kt )
659      !!---------------------------------------------------------------------
660      !!                  ***  ROUTINE hpg_prj  ***
661      !!
662      !! ** Method  :   s-coordinate case.
663      !!      A Pressure-Jacobian horizontal pressure gradient method
664      !!      based on the constrained cubic-spline interpolation for
665      !!      all vertical coordinate systems
666      !!
667      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
668      !!----------------------------------------------------------------------
669      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
670      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
671      !!
672      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
673      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
674      !!
675      !! The local variables for the correction term
676      INTEGER  :: jk1, jis, jid, jjs, jjd
677      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
678      REAL(wp) :: zrhdt1
679      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
680      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
681      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
682      !!----------------------------------------------------------------------
683      !
684      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
685      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
686      !
687      IF( kt == nit000 ) THEN
688         IF(lwp) WRITE(numout,*)
689         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
690         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
691      ENDIF
692
693      !!----------------------------------------------------------------------
694      ! Local constant initialization
695      zcoef0 = - grav
696      znad = 0.0_wp
697      IF( lk_vvl ) znad = 1._wp
698
699      ! Clean 3-D work arrays
700      zhpi(:,:,:) = 0._wp
701      zrhh(:,:,:) = rhd(:,:,:)
702
703      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
704      DO jj = 1, jpj
705        DO ji = 1, jpi
706          jk = mbathy(ji,jj)
707          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
708          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
709          ELSE IF(jk < jpkm1) THEN
710             DO jkk = jk+1, jpk
711                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
712                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
713             END DO
714          ENDIF
715        END DO
716      END DO
717
718      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
719      DO jj = 1, jpj
720         DO ji = 1, jpi
721            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
722         END DO
723      END DO
724
725      DO jk = 2, jpk
726         DO jj = 1, jpj
727            DO ji = 1, jpi
728               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
729            END DO
730         END DO
731      END DO
732
733      fsp(:,:,:) = zrhh (:,:,:)
734      xsp(:,:,:) = zdept(:,:,:)
735
736      ! Construct the vertical density profile with the
737      ! constrained cubic spline interpolation
738      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
739      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
740
741      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
742      DO jj = 2, jpj
743        DO ji = 2, jpi
744          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
745                                         bsp(ji,jj,1),   csp(ji,jj,1), &
746                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
747
748          ! assuming linear profile across the top half surface layer
749          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
750        END DO
751      END DO
752
753      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
754      DO jk = 2, jpkm1
755        DO jj = 2, jpj
756          DO ji = 2, jpi
757            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
758                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
759                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
760                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
761          END DO
762        END DO
763      END DO
764
765      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
766      DO jj = 2, jpjm1
767        DO ji = 2, jpim1
768          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshu_n for ztilde compilation
769          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshv_n for ztilde compilation
770        END DO
771      END DO
772
773      DO jk = 2, jpkm1
774        DO jj = 2, jpjm1
775          DO ji = 2, jpim1
776            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
777            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
778          END DO
779        END DO
780      END DO
781
782      DO jk = 1, jpkm1
783        DO jj = 2, jpjm1
784          DO ji = 2, jpim1
785            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
786            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
787          END DO
788        END DO
789      END DO
790
791      DO jk = 1, jpkm1
792        DO jj = 2, jpjm1
793          DO ji = 2, jpim1
794            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
795            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
796            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
797            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
798          END DO
799        END DO
800      END DO
801
802
803      DO jk = 1, jpkm1
804        DO jj = 2, jpjm1
805          DO ji = 2, jpim1
806            zpwes = 0._wp; zpwed = 0._wp
807            zpnss = 0._wp; zpnsd = 0._wp
808            zuijk = zu(ji,jj,jk)
809            zvijk = zv(ji,jj,jk)
810
811            !!!!!     for u equation
812            IF( jk <= mbku(ji,jj) ) THEN
813               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
814                 jis = ji + 1; jid = ji
815               ELSE
816                 jis = ji;     jid = ji +1
817               ENDIF
818
819               ! integrate the pressure on the shallow side
820               jk1 = jk
821               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
822                 IF( jk1 == mbku(ji,jj) ) THEN
823                   zuijk = -zdept(jis,jj,jk1)
824                   EXIT
825                 ENDIF
826                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
827                 zpwes = zpwes +                                    &
828                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
829                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
830                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
831                 jk1 = jk1 + 1
832               END DO
833
834               ! integrate the pressure on the deep side
835               jk1 = jk
836               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
837                 IF( jk1 == 1 ) THEN
838                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
839                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
840                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
841                                                     dsp(jid,jj,1)) * zdeps
842                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
843                   EXIT
844                 ENDIF
845                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
846                 zpwed = zpwed +                                        &
847                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
848                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
849                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
850                 jk1 = jk1 - 1
851               END DO
852
853               ! update the momentum trends in u direction
854
855               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
856               IF( lk_vvl ) THEN
857                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
858                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
859                ELSE
860                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
861               ENDIF
862
863               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
864               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
865            ENDIF
866
867            !!!!!     for v equation
868            IF( jk <= mbkv(ji,jj) ) THEN
869               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
870                 jjs = jj + 1; jjd = jj
871               ELSE
872                 jjs = jj    ; jjd = jj + 1
873               ENDIF
874
875               ! integrate the pressure on the shallow side
876               jk1 = jk
877               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
878                 IF( jk1 == mbkv(ji,jj) ) THEN
879                   zvijk = -zdept(ji,jjs,jk1)
880                   EXIT
881                 ENDIF
882                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
883                 zpnss = zpnss +                                      &
884                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
885                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
886                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
887                 jk1 = jk1 + 1
888               END DO
889
890               ! integrate the pressure on the deep side
891               jk1 = jk
892               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
893                 IF( jk1 == 1 ) THEN
894                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
895                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
896                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
897                                                     dsp(ji,jjd,1) ) * zdeps
898                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
899                   EXIT
900                 ENDIF
901                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
902                 zpnsd = zpnsd +                                        &
903                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
904                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
905                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
906                 jk1 = jk1 - 1
907               END DO
908
909
910               ! update the momentum trends in v direction
911
912               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
913               IF( lk_vvl ) THEN
914                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
915                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
916               ELSE
917                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
918               ENDIF
919
920               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
921               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
922            ENDIF
923
924
925           END DO
926        END DO
927      END DO
928      !
929      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
930      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
931      !
932   END SUBROUTINE hpg_prj
933
934
935   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
936      !!----------------------------------------------------------------------
937      !!                 ***  ROUTINE cspline  ***
938      !!
939      !! ** Purpose :   constrained cubic spline interpolation
940      !!
941      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
942      !!
943      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
944      !!----------------------------------------------------------------------
945      IMPLICIT NONE
946      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
947      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
948                                                                    ! the interpoated function
949      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
950                                                                    ! 2: Linear
951      !
952      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
953      INTEGER  ::   jpi, jpj, jpkm1
954      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
955      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
956      REAL(wp) ::   zdf(size(fsp,3))
957      !!----------------------------------------------------------------------
958
959      jpi   = size(fsp,1)
960      jpj   = size(fsp,2)
961      jpkm1 = size(fsp,3) - 1
962
963
964      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
965         DO ji = 1, jpi
966            DO jj = 1, jpj
967           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
968           !    DO jk = 2, jpkm1-1
969           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
970           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
971           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
972           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
973           !
974           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
975           !
976           !       IF(zdf1 * zdf2 <= 0._wp) THEN
977           !           zdf(jk) = 0._wp
978           !       ELSE
979           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
980           !       ENDIF
981           !    END DO
982
983           !!Simply geometric average
984               DO jk = 2, jpkm1-1
985                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
986                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
987
988                  IF(zdf1 * zdf2 <= 0._wp) THEN
989                     zdf(jk) = 0._wp
990                  ELSE
991                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
992                  ENDIF
993               END DO
994
995               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
996                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
997               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
998                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
999                          & 0.5_wp * zdf(jpkm1 - 1)
1000
1001               DO jk = 1, jpkm1 - 1
1002                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1003                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1004                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1005                 zddf1  = -2._wp * ztmp1 + ztmp2
1006                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1007                 zddf2  =  2._wp * ztmp1 - ztmp2
1008
1009                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1010                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1011                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1012                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1013                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1014                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1015                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1016                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1017                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1018               END DO
1019            END DO
1020         END DO
1021
1022      ELSE IF (polynomial_type == 2) THEN     ! Linear
1023         DO ji = 1, jpi
1024            DO jj = 1, jpj
1025               DO jk = 1, jpkm1-1
1026                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1027                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1028
1029                  dsp(ji,jj,jk) = 0._wp
1030                  csp(ji,jj,jk) = 0._wp
1031                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1032                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1033               END DO
1034            END DO
1035         END DO
1036
1037      ELSE
1038           CALL ctl_stop( 'invalid polynomial type in cspline' )
1039      ENDIF
1040
1041   END SUBROUTINE cspline
1042
1043
1044   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1045      !!----------------------------------------------------------------------
1046      !!                 ***  ROUTINE interp1  ***
1047      !!
1048      !! ** Purpose :   1-d linear interpolation
1049      !!
1050      !! ** Method  :   interpolation is straight forward
1051      !!                extrapolation is also permitted (no value limit)
1052      !!----------------------------------------------------------------------
1053      IMPLICIT NONE
1054      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1055      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1056      REAL(wp)             ::  zdeltx
1057      !!----------------------------------------------------------------------
1058
1059      zdeltx = xr - xl
1060      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1061        f = 0.5_wp * (fl + fr)
1062      ELSE
1063        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1064      ENDIF
1065
1066   END FUNCTION interp1
1067
1068
1069   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1070      !!----------------------------------------------------------------------
1071      !!                 ***  ROUTINE interp1  ***
1072      !!
1073      !! ** Purpose :   1-d constrained cubic spline interpolation
1074      !!
1075      !! ** Method  :  cubic spline interpolation
1076      !!
1077      !!----------------------------------------------------------------------
1078      IMPLICIT NONE
1079      REAL(wp), INTENT(in) ::  x, a, b, c, d
1080      REAL(wp)             ::  f ! value from the interpolation
1081      !!----------------------------------------------------------------------
1082
1083      f = a + x* ( b + x * ( c + d * x ) )
1084
1085   END FUNCTION interp2
1086
1087
1088   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1089      !!----------------------------------------------------------------------
1090      !!                 ***  ROUTINE interp1  ***
1091      !!
1092      !! ** Purpose :   Calculate the first order of deriavtive of
1093      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1094      !!
1095      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1096      !!
1097      !!----------------------------------------------------------------------
1098      IMPLICIT NONE
1099      REAL(wp), INTENT(in) ::  x, a, b, c, d
1100      REAL(wp)             ::  f ! value from the interpolation
1101      !!----------------------------------------------------------------------
1102
1103      f = b + x * ( 2._wp * c + 3._wp * d * x)
1104
1105   END FUNCTION interp3
1106
1107
1108   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1109      !!----------------------------------------------------------------------
1110      !!                 ***  ROUTINE interp1  ***
1111      !!
1112      !! ** Purpose :   1-d constrained cubic spline integration
1113      !!
1114      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1115      !!
1116      !!----------------------------------------------------------------------
1117      IMPLICIT NONE
1118      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1119      REAL(wp)             ::  za1, za2, za3
1120      REAL(wp)             ::  f                   ! integration result
1121      !!----------------------------------------------------------------------
1122
1123      za1 = 0.5_wp * b
1124      za2 = c / 3.0_wp
1125      za3 = 0.25_wp * d
1126
1127      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1128         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1129
1130   END FUNCTION integ_spline
1131
1132   !!======================================================================
1133END MODULE dynhpg
1134
Note: See TracBrowser for help on using the repository browser.