| 1 | MODULE sbcice_lim_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcice_lim_2 *** |
|---|
| 4 | !! Surface module : update surface ocean boundary condition over ice covered area using LIM sea-ice model |
|---|
| 5 | !! Sea-Ice model : LIM-2 Sea ice model time-stepping |
|---|
| 6 | !!====================================================================== |
|---|
| 7 | !! History : 1.0 ! 06-2006 (G. Madec) from icestp_2.F90 |
|---|
| 8 | !! 3.0 ! 08-2008 (S. Masson, E. .... ) coupled interface |
|---|
| 9 | !! 3.3 ! 05-2009 (G.Garric) addition of the lim2_evp case |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | #if defined key_lim2 |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! 'key_lim2' : LIM-2 sea-ice model |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! sbc_ice_lim_2 : sea-ice model time-stepping and update ocean sbc over ice-covered area |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers |
|---|
| 18 | USE dom_oce ! ocean space and time domain |
|---|
| 19 | USE ice_2 |
|---|
| 20 | USE par_ice_2 |
|---|
| 21 | USE iceini_2 |
|---|
| 22 | USE dom_ice_2 |
|---|
| 23 | |
|---|
| 24 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 25 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 26 | USE sbcblk_core ! Surface boundary condition: CORE bulk |
|---|
| 27 | USE sbcblk_clio ! Surface boundary condition: CLIO bulk |
|---|
| 28 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 29 | USE albedo |
|---|
| 30 | |
|---|
| 31 | USE phycst ! Define parameters for the routines |
|---|
| 32 | USE eosbn2 ! equation of state |
|---|
| 33 | USE limdyn_2 |
|---|
| 34 | USE limtrp_2 |
|---|
| 35 | USE limdmp_2 |
|---|
| 36 | USE limthd_2 |
|---|
| 37 | USE limsbc_2 ! sea surface boundary condition |
|---|
| 38 | USE limdia_2 |
|---|
| 39 | USE limwri_2 |
|---|
| 40 | USE limrst_2 |
|---|
| 41 | |
|---|
| 42 | USE c1d ! 1D vertical configuration |
|---|
| 43 | |
|---|
| 44 | USE lbclnk ! lateral boundary condition - MPP link |
|---|
| 45 | USE lib_mpp ! MPP library |
|---|
| 46 | USE wrk_nemo ! work arrays |
|---|
| 47 | USE iom ! I/O manager library |
|---|
| 48 | USE in_out_manager ! I/O manager |
|---|
| 49 | USE prtctl ! Print control |
|---|
| 50 | |
|---|
| 51 | # if defined key_agrif |
|---|
| 52 | USE agrif_ice |
|---|
| 53 | USE agrif_lim2_update |
|---|
| 54 | # endif |
|---|
| 55 | |
|---|
| 56 | IMPLICIT NONE |
|---|
| 57 | PRIVATE |
|---|
| 58 | |
|---|
| 59 | PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90 |
|---|
| 60 | |
|---|
| 61 | !! * Substitutions |
|---|
| 62 | # include "domzgr_substitute.h90" |
|---|
| 63 | # include "vectopt_loop_substitute.h90" |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 66 | !! $Id$ |
|---|
| 67 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | CONTAINS |
|---|
| 70 | |
|---|
| 71 | SUBROUTINE sbc_ice_lim_2( kt, ksbc ) |
|---|
| 72 | !!--------------------------------------------------------------------- |
|---|
| 73 | !! *** ROUTINE sbc_ice_lim_2 *** |
|---|
| 74 | !! |
|---|
| 75 | !! ** Purpose : update the ocean surface boundary condition via the |
|---|
| 76 | !! Louvain la Neuve Sea Ice Model time stepping |
|---|
| 77 | !! |
|---|
| 78 | !! ** Method : ice model time stepping |
|---|
| 79 | !! - call the ice dynamics routine |
|---|
| 80 | !! - call the ice advection/diffusion routine |
|---|
| 81 | !! - call the ice thermodynamics routine |
|---|
| 82 | !! - call the routine that computes mass and |
|---|
| 83 | !! heat fluxes at the ice/ocean interface |
|---|
| 84 | !! - save the outputs |
|---|
| 85 | !! - save the outputs for restart when necessary |
|---|
| 86 | !! |
|---|
| 87 | !! ** Action : - time evolution of the LIM sea-ice model |
|---|
| 88 | !! - update all sbc variables below sea-ice: |
|---|
| 89 | !! utau, vtau, taum, wndm, qns , qsr, emp , sfx |
|---|
| 90 | !!--------------------------------------------------------------------- |
|---|
| 91 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 92 | INTEGER, INTENT(in) :: ksbc ! type of sbc ( =3 CLIO bulk ; =4 CORE bulk ; =5 coupled ) |
|---|
| 93 | !! |
|---|
| 94 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 95 | REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_os ! ice albedo under overcast sky |
|---|
| 96 | REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_cs ! ice albedo under clear sky |
|---|
| 97 | REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_ice ! mean ice albedo |
|---|
| 98 | REAL(wp), DIMENSION(:,:,:), POINTER :: zsist ! ice surface temperature (K) |
|---|
| 99 | !!---------------------------------------------------------------------- |
|---|
| 100 | |
|---|
| 101 | CALL wrk_alloc( jpi,jpj,1, zalb_os, zalb_cs, zalb_ice, zsist ) |
|---|
| 102 | |
|---|
| 103 | IF( kt == nit000 ) THEN |
|---|
| 104 | IF(lwp) WRITE(numout,*) |
|---|
| 105 | IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' |
|---|
| 106 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM) time stepping' |
|---|
| 107 | ! |
|---|
| 108 | CALL ice_init_2 |
|---|
| 109 | ! |
|---|
| 110 | # if defined key_agrif |
|---|
| 111 | IF( .NOT. Agrif_Root() ) CALL Agrif_InitValues_cont_lim2 ! AGRIF: set the meshes |
|---|
| 112 | # endif |
|---|
| 113 | ENDIF |
|---|
| 114 | |
|---|
| 115 | ! !----------------------! |
|---|
| 116 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! Ice time-step only ! |
|---|
| 117 | ! !----------------------! |
|---|
| 118 | # if defined key_agrif |
|---|
| 119 | IF( .NOT. Agrif_Root() ) lim_nbstep = MOD(lim_nbstep,Agrif_rhot()& |
|---|
| 120 | &*Agrif_PArent(nn_fsbc)/REAL(nn_fsbc)) + 1 |
|---|
| 121 | # endif |
|---|
| 122 | ! Bulk Formulea ! |
|---|
| 123 | !----------------! |
|---|
| 124 | ! ... mean surface ocean current at ice dynamics point |
|---|
| 125 | SELECT CASE( cp_ice_msh ) |
|---|
| 126 | CASE( 'I' ) !== B-grid ice dynamics : I-point (i.e. F-point with sea-ice indexation) |
|---|
| 127 | DO jj = 2, jpj |
|---|
| 128 | DO ji = 2, jpi ! NO vector opt. possible |
|---|
| 129 | u_oce(ji,jj) = 0.5_wp * ( ssu_m(ji-1,jj ) + ssu_m(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 130 | v_oce(ji,jj) = 0.5_wp * ( ssv_m(ji ,jj-1) + ssv_m(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 131 | END DO |
|---|
| 132 | END DO |
|---|
| 133 | CALL lbc_lnk( u_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 134 | CALL lbc_lnk( v_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 135 | ! |
|---|
| 136 | CASE( 'C' ) !== C-grid ice dynamics : U & V-points (same as ocean) |
|---|
| 137 | u_oce(:,:) = ssu_m(:,:) ! mean surface ocean current at ice velocity point |
|---|
| 138 | v_oce(:,:) = ssv_m(:,:) |
|---|
| 139 | ! |
|---|
| 140 | END SELECT |
|---|
| 141 | |
|---|
| 142 | ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land) |
|---|
| 143 | tfu(:,:) = eos_fzp( sss_m ) + rt0 |
|---|
| 144 | |
|---|
| 145 | zsist (:,:,1) = sist (:,:) + rt0 * ( 1. - tmask(:,:,1) ) |
|---|
| 146 | |
|---|
| 147 | ! Ice albedo |
|---|
| 148 | |
|---|
| 149 | CALL albedo_ice( zsist, reshape( hicif, (/jpi,jpj,1/) ), & |
|---|
| 150 | reshape( hsnif, (/jpi,jpj,1/) ), & |
|---|
| 151 | zalb_cs, zalb_os ) |
|---|
| 152 | |
|---|
| 153 | SELECT CASE( ksbc ) |
|---|
| 154 | CASE( jp_core , jp_cpl ) ! CORE and COUPLED bulk formulations |
|---|
| 155 | |
|---|
| 156 | ! albedo depends on cloud fraction because of non-linear spectral effects |
|---|
| 157 | zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 158 | ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo |
|---|
| 159 | ! (zalb_ice) is computed within the bulk routine |
|---|
| 160 | |
|---|
| 161 | END SELECT |
|---|
| 162 | |
|---|
| 163 | ! ... Sea-ice surface boundary conditions output from bulk formulae : |
|---|
| 164 | ! - utau_ice ! surface ice stress i-component (I-point) [N/m2] |
|---|
| 165 | ! - vtau_ice ! surface ice stress j-component (I-point) [N/m2] |
|---|
| 166 | ! - qns_ice ! non solar heat flux over ice (T-point) [W/m2] |
|---|
| 167 | ! - qsr_ice ! solar heat flux over ice (T-point) [W/m2] |
|---|
| 168 | ! - qla_ice ! latent heat flux over ice (T-point) [W/m2] |
|---|
| 169 | ! - dqns_ice ! non solar heat sensistivity (T-point) [W/m2] |
|---|
| 170 | ! - dqla_ice ! latent heat sensistivity (T-point) [W/m2] |
|---|
| 171 | ! - tprecip ! total precipitation (T-point) [Kg/m2/s] |
|---|
| 172 | ! - sprecip ! solid precipitation (T-point) [Kg/m2/s] |
|---|
| 173 | ! - fr1_i0 ! 1sr fraction of qsr penetration in ice [%] |
|---|
| 174 | ! - fr2_i0 ! 2nd fraction of qsr penetration in ice [%] |
|---|
| 175 | ! |
|---|
| 176 | SELECT CASE( ksbc ) |
|---|
| 177 | CASE( jp_clio ) ! CLIO bulk formulation |
|---|
| 178 | CALL blk_ice_clio( zsist, zalb_cs , zalb_os , zalb_ice , & |
|---|
| 179 | & utau_ice , vtau_ice , qns_ice , qsr_ice, & |
|---|
| 180 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 181 | & tprecip , sprecip , & |
|---|
| 182 | & fr1_i0 , fr2_i0 , cp_ice_msh , jpl ) |
|---|
| 183 | |
|---|
| 184 | CASE( jp_core ) ! CORE bulk formulation |
|---|
| 185 | CALL blk_ice_core( zsist, u_ice , v_ice , zalb_ice , & |
|---|
| 186 | & utau_ice , vtau_ice , qns_ice , qsr_ice, & |
|---|
| 187 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 188 | & tprecip , sprecip , & |
|---|
| 189 | & fr1_i0 , fr2_i0 , cp_ice_msh , jpl ) |
|---|
| 190 | IF( ltrcdm2dc_ice ) CALL blk_ice_meanqsr( zalb_ice, qsr_ice_mean, jpl ) |
|---|
| 191 | |
|---|
| 192 | CASE( jp_cpl ) ! Coupled formulation : atmosphere-ice stress only (fluxes provided after ice dynamics) |
|---|
| 193 | CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) |
|---|
| 194 | END SELECT |
|---|
| 195 | |
|---|
| 196 | CALL iom_put( 'utau_ice', utau_ice ) ! Wind stress over ice along i-axis at I-point |
|---|
| 197 | CALL iom_put( 'vtau_ice', vtau_ice ) ! Wind stress over ice along j-axis at I-point |
|---|
| 198 | |
|---|
| 199 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 200 | CALL prt_ctl_info( 'Ice Forcings ' ) |
|---|
| 201 | CALL prt_ctl( tab2d_1=tprecip ,clinfo1=' sbc_ice_lim: precip : ', tab2d_2=sprecip , clinfo2=' Snow : ' ) |
|---|
| 202 | CALL prt_ctl( tab2d_1=utau_ice,clinfo1=' sbc_ice_lim: utau_ice: ', tab2d_2=vtau_ice, clinfo2=' vtau_ice: ' ) |
|---|
| 203 | CALL prt_ctl( tab2d_1=sst_m ,clinfo1=' sbc_ice_lim: sst : ', tab2d_2=sss_m , clinfo2=' sss : ' ) |
|---|
| 204 | CALL prt_ctl( tab2d_1=u_oce ,clinfo1=' sbc_ice_lim: u_io : ', tab2d_2=v_oce , clinfo2=' v_io : ' ) |
|---|
| 205 | CALL prt_ctl( tab2d_1=hsnif ,clinfo1=' sbc_ice_lim: hsnif 1: ', tab2d_2=hicif , clinfo2=' hicif : ' ) |
|---|
| 206 | CALL prt_ctl( tab2d_1=frld ,clinfo1=' sbc_ice_lim: frld 1: ', tab2d_2=sist , clinfo2=' sist : ' ) |
|---|
| 207 | ENDIF |
|---|
| 208 | |
|---|
| 209 | ! ---------------- ! |
|---|
| 210 | ! Ice model step ! |
|---|
| 211 | ! ---------------- ! |
|---|
| 212 | numit = numit + nn_fsbc ! Ice model time step |
|---|
| 213 | |
|---|
| 214 | CALL lim_rst_opn_2 ( kt ) ! Open Ice restart file |
|---|
| 215 | IF( .NOT. lk_c1d ) THEN ! Ice dynamics & transport (except in 1D case) |
|---|
| 216 | CALL lim_dyn_2 ( kt ) ! Ice dynamics ( rheology/dynamics ) |
|---|
| 217 | CALL lim_trp_2 ( kt ) ! Ice transport ( Advection/diffusion ) |
|---|
| 218 | IF( ln_limdmp ) CALL lim_dmp_2 ( kt ) ! Ice damping |
|---|
| 219 | END IF |
|---|
| 220 | ! ! Ice surface fluxes in coupled mode |
|---|
| 221 | IF( ksbc == jp_cpl ) THEN |
|---|
| 222 | a_i(:,:,1)=fr_i |
|---|
| 223 | CALL sbc_cpl_ice_flx( frld, & |
|---|
| 224 | ! optional arguments, used only in 'mixed oce-ice' case |
|---|
| 225 | & palbi = zalb_ice, psst = sst_m, pist = zsist ) |
|---|
| 226 | sprecip(:,:) = - emp_ice(:,:) ! Ugly patch, WARNING, in coupled mode, sublimation included in snow (parsub = 0.) |
|---|
| 227 | ENDIF |
|---|
| 228 | CALL lim_thd_2 ( kt ) ! Ice thermodynamics |
|---|
| 229 | CALL lim_sbc_flx_2 ( kt ) ! update surface ocean mass, heat & salt fluxes |
|---|
| 230 | #if defined key_top |
|---|
| 231 | IF( ltrcdm2dc_ice )CALL lim_bio_meanqsr_2 |
|---|
| 232 | #endif |
|---|
| 233 | |
|---|
| 234 | IF( .NOT. lk_mpp )THEN |
|---|
| 235 | IF( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 ) & |
|---|
| 236 | & CALL lim_dia_2 ( kt ) ! Ice Diagnostics |
|---|
| 237 | ENDIF |
|---|
| 238 | # if ! defined key_iomput |
|---|
| 239 | CALL lim_wri_2 ( kt ) ! Ice outputs |
|---|
| 240 | # endif |
|---|
| 241 | IF( lrst_ice ) CALL lim_rst_write_2( kt ) ! Ice restart file |
|---|
| 242 | ! |
|---|
| 243 | # if defined key_agrif && defined key_lim2 |
|---|
| 244 | IF( .NOT. Agrif_Root() ) CALL agrif_update_lim2( kt ) |
|---|
| 245 | # endif |
|---|
| 246 | ! |
|---|
| 247 | ENDIF ! End sea-ice time step only |
|---|
| 248 | ! |
|---|
| 249 | ! !--------------------------! |
|---|
| 250 | ! ! at all ocean time step ! |
|---|
| 251 | ! !--------------------------! |
|---|
| 252 | ! |
|---|
| 253 | ! ! Update surface ocean stresses (only in ice-dynamic case) |
|---|
| 254 | ! ! otherwise the atm.-ocean stresses are used everywhere |
|---|
| 255 | IF( ln_limdyn ) CALL lim_sbc_tau_2( kt, ub(:,:,1), vb(:,:,1) ) ! using before instantaneous surf. currents |
|---|
| 256 | ! |
|---|
| 257 | CALL wrk_dealloc( jpi,jpj,1, zalb_os, zalb_cs, zalb_ice, zsist ) |
|---|
| 258 | ! |
|---|
| 259 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 260 | |
|---|
| 261 | #else |
|---|
| 262 | !!---------------------------------------------------------------------- |
|---|
| 263 | !! Default option Dummy module NO LIM 2.0 sea-ice model |
|---|
| 264 | !!---------------------------------------------------------------------- |
|---|
| 265 | CONTAINS |
|---|
| 266 | SUBROUTINE sbc_ice_lim_2 ( kt, ksbc ) ! Dummy routine |
|---|
| 267 | INTEGER, INTENT(in) :: kt, ksbc |
|---|
| 268 | WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, ksbc |
|---|
| 269 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 270 | #endif |
|---|
| 271 | |
|---|
| 272 | !!====================================================================== |
|---|
| 273 | END MODULE sbcice_lim_2 |
|---|
