| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! sbc_init : read namsbc namelist |
|---|
| 19 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce ! ocean dynamics and tracers |
|---|
| 22 | USE dom_oce ! ocean space and time domain |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 25 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 26 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 27 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 28 | USE sbcapr ! surface boundary condition: atmospheric pressure |
|---|
| 29 | USE sbcana ! surface boundary condition: analytical formulation |
|---|
| 30 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 31 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 32 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 33 | USE sbcblk_mfs ! surface boundary condition: bulk formulation : MFS |
|---|
| 34 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 35 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 36 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 37 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 38 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 39 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 40 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 41 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 42 | USE closea ! closed sea |
|---|
| 43 | USE icbstp ! Icebergs! |
|---|
| 44 | |
|---|
| 45 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 46 | USE iom ! IOM library |
|---|
| 47 | USE in_out_manager ! I/O manager |
|---|
| 48 | USE lib_mpp ! MPP library |
|---|
| 49 | USE timing ! Timing |
|---|
| 50 | USE sbcwave ! Wave module |
|---|
| 51 | |
|---|
| 52 | IMPLICIT NONE |
|---|
| 53 | PRIVATE |
|---|
| 54 | |
|---|
| 55 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 56 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 57 | |
|---|
| 58 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 59 | |
|---|
| 60 | !! * Substitutions |
|---|
| 61 | # include "domzgr_substitute.h90" |
|---|
| 62 | !!---------------------------------------------------------------------- |
|---|
| 63 | !! NEMO/OPA 4.0 , NEMO-consortium (2011) |
|---|
| 64 | !! $Id$ |
|---|
| 65 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 66 | !!---------------------------------------------------------------------- |
|---|
| 67 | CONTAINS |
|---|
| 68 | |
|---|
| 69 | SUBROUTINE sbc_init |
|---|
| 70 | !!--------------------------------------------------------------------- |
|---|
| 71 | !! *** ROUTINE sbc_init *** |
|---|
| 72 | !! |
|---|
| 73 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 74 | !! |
|---|
| 75 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 76 | !! Call init routines for all other SBC modules that have one |
|---|
| 77 | !! |
|---|
| 78 | !! ** Action : - read namsbc parameters |
|---|
| 79 | !! - nsbc: type of sbc |
|---|
| 80 | !!---------------------------------------------------------------------- |
|---|
| 81 | INTEGER :: icpt ! local integer |
|---|
| 82 | !! |
|---|
| 83 | NAMELIST/namsbc/ nn_fsbc , ln_ana , ln_flx, ln_blk_clio, ln_blk_core, & |
|---|
| 84 | & ln_blk_mfs, ln_apr_dyn, nn_ice, nn_ice_embd, ln_dm2dc , ln_rnf, & |
|---|
| 85 | & ln_ssr , nn_fwb , ln_cdgw , ln_wave , ln_sdw, nn_lsm, nn_limflx |
|---|
| 86 | INTEGER :: ios |
|---|
| 87 | !!---------------------------------------------------------------------- |
|---|
| 88 | |
|---|
| 89 | IF(lwp) THEN |
|---|
| 90 | WRITE(numout,*) |
|---|
| 91 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 92 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 93 | ENDIF |
|---|
| 94 | |
|---|
| 95 | REWIND( numnam_ref ) ! Namelist namsbc in reference namelist : Surface boundary |
|---|
| 96 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 97 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp ) |
|---|
| 98 | |
|---|
| 99 | REWIND( numnam_cfg ) ! Namelist namsbc in configuration namelist : Parameters of the run |
|---|
| 100 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 101 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp ) |
|---|
| 102 | IF(lwm) WRITE ( numond, namsbc ) |
|---|
| 103 | |
|---|
| 104 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 105 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 106 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 107 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 108 | IF( lk_cice ) nn_ice = 4 |
|---|
| 109 | ENDIF |
|---|
| 110 | IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration |
|---|
| 111 | ln_ana = .TRUE. |
|---|
| 112 | nn_ice = 0 |
|---|
| 113 | ENDIF |
|---|
| 114 | |
|---|
| 115 | IF(lwp) THEN ! Control print |
|---|
| 116 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 117 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 118 | WRITE(numout,*) ' Type of sbc : ' |
|---|
| 119 | WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana |
|---|
| 120 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 121 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 122 | WRITE(numout,*) ' CORE bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 123 | WRITE(numout,*) ' MFS bulk formulation ln_blk_mfs = ', ln_blk_mfs |
|---|
| 124 | WRITE(numout,*) ' coupled formulation (T if key_oasis3) lk_cpl = ', lk_cpl |
|---|
| 125 | WRITE(numout,*) ' Multicategory heat flux formulation (LIM3) nn_limflx = ', nn_limflx |
|---|
| 126 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 127 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 128 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 129 | WRITE(numout,*) ' ice-ocean embedded/levitating (=0/1/2) nn_ice_embd = ', nn_ice_embd |
|---|
| 130 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 131 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 132 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 133 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 134 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 135 | WRITE(numout,*) ' n. of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 136 | ENDIF |
|---|
| 137 | |
|---|
| 138 | ! LIM3 Multi-category heat flux formulation |
|---|
| 139 | SELECT CASE ( nn_limflx) |
|---|
| 140 | CASE ( -1 ) |
|---|
| 141 | IF(lwp) WRITE(numout,*) ' Use of per-category fluxes (nn_limflx = -1) ' |
|---|
| 142 | CASE ( 0 ) |
|---|
| 143 | IF(lwp) WRITE(numout,*) ' Average per-category fluxes (nn_limflx = 0) ' |
|---|
| 144 | CASE ( 1 ) |
|---|
| 145 | IF(lwp) WRITE(numout,*) ' Average then redistribute per-category fluxes (nn_limflx = 1) ' |
|---|
| 146 | CASE ( 2 ) |
|---|
| 147 | IF(lwp) WRITE(numout,*) ' Redistribute a single flux over categories (nn_limflx = 2) ' |
|---|
| 148 | END SELECT |
|---|
| 149 | ! |
|---|
| 150 | #if defined key_top && ! defined key_offline |
|---|
| 151 | ltrcdm2dc = (ln_dm2dc .AND. ln_blk_core .AND. nn_ice==2) |
|---|
| 152 | IF( ltrcdm2dc )THEN |
|---|
| 153 | IF(lwp)THEN |
|---|
| 154 | WRITE(numout,*)"analytical diurnal cycle, core bulk formulation and LIM2 use: " |
|---|
| 155 | WRITE(numout,*)"Diurnal cycle on physics but not in passive tracers" |
|---|
| 156 | ENDIF |
|---|
| 157 | ENDIF |
|---|
| 158 | #else |
|---|
| 159 | ltrcdm2dc = .FALSE. |
|---|
| 160 | #endif |
|---|
| 161 | |
|---|
| 162 | ! |
|---|
| 163 | ! ! allocate sbc arrays |
|---|
| 164 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 165 | |
|---|
| 166 | ! ! Checks: |
|---|
| 167 | IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths |
|---|
| 168 | ln_rnf_mouth = .false. |
|---|
| 169 | IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' ) |
|---|
| 170 | nkrnf = 0 |
|---|
| 171 | rnf (:,:) = 0.0_wp |
|---|
| 172 | rnf_b (:,:) = 0.0_wp |
|---|
| 173 | rnfmsk (:,:) = 0.0_wp |
|---|
| 174 | rnfmsk_z(:) = 0.0_wp |
|---|
| 175 | ENDIF |
|---|
| 176 | IF( nn_ice == 0 ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero |
|---|
| 177 | |
|---|
| 178 | sfx(:,:) = 0.0_wp ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero) |
|---|
| 179 | ! only if sea-ice is present |
|---|
| 180 | |
|---|
| 181 | fmmflx(:,:) = 0.0_wp ! freezing-melting array initialisation |
|---|
| 182 | |
|---|
| 183 | taum(:,:) = 0.0_wp ! Initialise taum for use in gls in case of reduced restart |
|---|
| 184 | |
|---|
| 185 | ! ! restartability |
|---|
| 186 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 187 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 188 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 189 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 190 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 191 | ENDIF |
|---|
| 192 | ! |
|---|
| 193 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 194 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 195 | ! |
|---|
| 196 | IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 197 | & CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 198 | IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 199 | & CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' ) |
|---|
| 200 | IF( nn_ice == 4 .AND. lk_agrif ) & |
|---|
| 201 | & CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 202 | IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 ) & |
|---|
| 203 | & CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' ) |
|---|
| 204 | IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) ) & |
|---|
| 205 | & WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3' |
|---|
| 206 | IF( ( nn_ice == 3 ) .AND. ( lk_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) ) & |
|---|
| 207 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' ) |
|---|
| 208 | IF( ( nn_ice == 3 ) .AND. ( .NOT. lk_cpl ) .AND. ( nn_limflx == 2 ) ) & |
|---|
| 209 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' ) |
|---|
| 210 | |
|---|
| 211 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 212 | |
|---|
| 213 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) ) & |
|---|
| 214 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 215 | |
|---|
| 216 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 217 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 218 | |
|---|
| 219 | IF ( ln_wave ) THEN |
|---|
| 220 | !Activated wave module but neither drag nor stokes drift activated |
|---|
| 221 | IF ( .NOT.(ln_cdgw .OR. ln_sdw) ) THEN |
|---|
| 222 | CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' ) |
|---|
| 223 | !drag coefficient read from wave model definable only with mfs bulk formulae and core |
|---|
| 224 | ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) ) THEN |
|---|
| 225 | CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core') |
|---|
| 226 | ENDIF |
|---|
| 227 | ELSE |
|---|
| 228 | IF ( ln_cdgw .OR. ln_sdw ) & |
|---|
| 229 | & CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but & |
|---|
| 230 | & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ') |
|---|
| 231 | ENDIF |
|---|
| 232 | |
|---|
| 233 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 234 | icpt = 0 |
|---|
| 235 | IF( ln_ana ) THEN ; nsbc = jp_ana ; icpt = icpt + 1 ; ENDIF ! analytical formulation |
|---|
| 236 | IF( ln_flx ) THEN ; nsbc = jp_flx ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 237 | IF( ln_blk_clio ) THEN ; nsbc = jp_clio ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 238 | IF( ln_blk_core ) THEN ; nsbc = jp_core ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 239 | IF( ln_blk_mfs ) THEN ; nsbc = jp_mfs ; icpt = icpt + 1 ; ENDIF ! MFS bulk formulation |
|---|
| 240 | IF( lk_cpl ) THEN ; nsbc = jp_cpl ; icpt = icpt + 1 ; ENDIF ! Coupled formulation |
|---|
| 241 | IF( cp_cfg == 'gyre') THEN ; nsbc = jp_gyre ; ENDIF ! GYRE analytical formulation |
|---|
| 242 | IF( lk_esopa ) nsbc = jp_esopa ! esopa test, ALL formulations |
|---|
| 243 | ! |
|---|
| 244 | IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN |
|---|
| 245 | WRITE(numout,*) |
|---|
| 246 | WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option ' |
|---|
| 247 | WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)' |
|---|
| 248 | WRITE(numout,*) ' We stop' |
|---|
| 249 | nstop = nstop + 1 |
|---|
| 250 | ENDIF |
|---|
| 251 | IF(lwp) THEN |
|---|
| 252 | WRITE(numout,*) |
|---|
| 253 | IF( nsbc == jp_esopa ) WRITE(numout,*) ' ESOPA test All surface boundary conditions' |
|---|
| 254 | IF( nsbc == jp_gyre ) WRITE(numout,*) ' GYRE analytical formulation' |
|---|
| 255 | IF( nsbc == jp_ana ) WRITE(numout,*) ' analytical formulation' |
|---|
| 256 | IF( nsbc == jp_flx ) WRITE(numout,*) ' flux formulation' |
|---|
| 257 | IF( nsbc == jp_clio ) WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 258 | IF( nsbc == jp_core ) WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 259 | IF( nsbc == jp_cpl ) WRITE(numout,*) ' coupled formulation' |
|---|
| 260 | IF( nsbc == jp_mfs ) WRITE(numout,*) ' MFS Bulk formulation' |
|---|
| 261 | ENDIF |
|---|
| 262 | ! |
|---|
| 263 | CALL sbc_ssm_init ! Sea-surface mean fields initialisation |
|---|
| 264 | ! |
|---|
| 265 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialisation |
|---|
| 266 | ! |
|---|
| 267 | IF( nn_ice == 4 ) CALL cice_sbc_init( nsbc ) ! CICE initialisation |
|---|
| 268 | ! |
|---|
| 269 | IF( nsbc == jp_cpl ) CALL sbc_cpl_init (nn_ice) ! OASIS initialisation. must be done before first time step |
|---|
| 270 | |
|---|
| 271 | END SUBROUTINE sbc_init |
|---|
| 272 | |
|---|
| 273 | |
|---|
| 274 | SUBROUTINE sbc( kt ) |
|---|
| 275 | !!--------------------------------------------------------------------- |
|---|
| 276 | !! *** ROUTINE sbc *** |
|---|
| 277 | !! |
|---|
| 278 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 279 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 280 | !! |
|---|
| 281 | !! ** Method : blah blah to be written ????????? |
|---|
| 282 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 283 | !! |
|---|
| 284 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 285 | !! time step, i.e. |
|---|
| 286 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 287 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 288 | !! - updte the ice fraction : fr_i |
|---|
| 289 | !!---------------------------------------------------------------------- |
|---|
| 290 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 291 | !!--------------------------------------------------------------------- |
|---|
| 292 | ! |
|---|
| 293 | IF( nn_timing == 1 ) CALL timing_start('sbc') |
|---|
| 294 | ! |
|---|
| 295 | ! ! ---------------------------------------- ! |
|---|
| 296 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 297 | ! ! ---------------------------------------- ! |
|---|
| 298 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 299 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 300 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 301 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 302 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 303 | emp_b(:,:) = emp(:,:) |
|---|
| 304 | sfx_b(:,:) = sfx(:,:) |
|---|
| 305 | ENDIF |
|---|
| 306 | ! ! ---------------------------------------- ! |
|---|
| 307 | ! ! forcing field computation ! |
|---|
| 308 | ! ! ---------------------------------------- ! |
|---|
| 309 | ! |
|---|
| 310 | IF( ln_apr_dyn ) CALL sbc_apr( kt ) ! atmospheric pressure provided at kt+0.5*nn_fsbc |
|---|
| 311 | ! (caution called before sbc_ssm) |
|---|
| 312 | ! |
|---|
| 313 | CALL sbc_ssm( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 314 | ! ! averaged over nf_sbc time-step |
|---|
| 315 | |
|---|
| 316 | IF (ln_wave) CALL sbc_wave( kt ) |
|---|
| 317 | !== sbc formulation ==! |
|---|
| 318 | |
|---|
| 319 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 320 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 321 | CASE( jp_gyre ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration |
|---|
| 322 | CASE( jp_ana ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc |
|---|
| 323 | CASE( jp_flx ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 324 | CASE( jp_clio ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 325 | CASE( jp_core ) ; CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 326 | CASE( jp_cpl ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! coupled formulation |
|---|
| 327 | CASE( jp_mfs ) ; CALL sbc_blk_mfs ( kt ) ! bulk formulation : MFS for the ocean |
|---|
| 328 | CASE( jp_esopa ) |
|---|
| 329 | CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations |
|---|
| 330 | CALL sbc_gyre ( kt ) ! |
|---|
| 331 | CALL sbc_flx ( kt ) ! |
|---|
| 332 | CALL sbc_blk_clio( kt ) ! |
|---|
| 333 | CALL sbc_blk_core( kt ) ! |
|---|
| 334 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! |
|---|
| 335 | END SELECT |
|---|
| 336 | |
|---|
| 337 | ! !== Misc. Options ==! |
|---|
| 338 | |
|---|
| 339 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 340 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 341 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 342 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 343 | CASE( 4 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 344 | END SELECT |
|---|
| 345 | |
|---|
| 346 | IF( ln_icebergs ) CALL icb_stp( kt ) ! compute icebergs |
|---|
| 347 | |
|---|
| 348 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 349 | |
|---|
| 350 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 351 | |
|---|
| 352 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 353 | |
|---|
| 354 | IF( nn_closea == 1 ) CALL sbc_clo( kt ) ! treatment of closed sea in the model domain |
|---|
| 355 | ! ! (update freshwater fluxes) |
|---|
| 356 | !RBbug do not understand why see ticket 667 |
|---|
| 357 | !clem-bugsal CALL lbc_lnk( emp, 'T', 1. ) |
|---|
| 358 | ! |
|---|
| 359 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 360 | ! ! ---------------------------------------- ! |
|---|
| 361 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 362 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 363 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 364 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 365 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 366 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 367 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 368 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 369 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b ) ! before freshwater flux (T-point) |
|---|
| 370 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 371 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 372 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b ) ! before salt flux (T-point) |
|---|
| 373 | ELSE |
|---|
| 374 | sfx_b (:,:) = sfx(:,:) |
|---|
| 375 | ENDIF |
|---|
| 376 | ELSE !* no restart: set from nit000 values |
|---|
| 377 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 378 | utau_b(:,:) = utau(:,:) |
|---|
| 379 | vtau_b(:,:) = vtau(:,:) |
|---|
| 380 | qns_b (:,:) = qns (:,:) |
|---|
| 381 | emp_b (:,:) = emp(:,:) |
|---|
| 382 | sfx_b (:,:) = sfx(:,:) |
|---|
| 383 | ENDIF |
|---|
| 384 | ENDIF |
|---|
| 385 | ! ! ---------------------------------------- ! |
|---|
| 386 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 387 | ! ! ---------------------------------------- ! |
|---|
| 388 | IF(lwp) WRITE(numout,*) |
|---|
| 389 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 390 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 391 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 392 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 393 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 394 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 395 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 396 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 397 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 398 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx ) |
|---|
| 399 | ENDIF |
|---|
| 400 | |
|---|
| 401 | ! ! ---------------------------------------- ! |
|---|
| 402 | ! ! Outputs and control print ! |
|---|
| 403 | ! ! ---------------------------------------- ! |
|---|
| 404 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 405 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 406 | CALL iom_put( "saltflx", sfx ) ! downward salt flux |
|---|
| 407 | ! (includes virtual salt flux beneath ice |
|---|
| 408 | ! in linear free surface case) |
|---|
| 409 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 410 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 411 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 412 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 413 | IF( nn_ice > 0 ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 414 | CALL iom_put( "taum" , taum ) ! wind stress module |
|---|
| 415 | CALL iom_put( "wspd" , wndm ) ! wind speed module over free ocean or leads in presence of sea-ice |
|---|
| 416 | ENDIF |
|---|
| 417 | ! |
|---|
| 418 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 419 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 420 | ! |
|---|
| 421 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 422 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 423 | CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 424 | CALL prt_ctl(tab2d_1=(sfx-rnf) , clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 425 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 426 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 427 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 428 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 429 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 430 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 431 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 432 | ENDIF |
|---|
| 433 | |
|---|
| 434 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 435 | ! |
|---|
| 436 | IF( nn_timing == 1 ) CALL timing_stop('sbc') |
|---|
| 437 | ! |
|---|
| 438 | END SUBROUTINE sbc |
|---|
| 439 | |
|---|
| 440 | |
|---|
| 441 | SUBROUTINE sbc_final |
|---|
| 442 | !!--------------------------------------------------------------------- |
|---|
| 443 | !! *** ROUTINE sbc_final *** |
|---|
| 444 | !! |
|---|
| 445 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 446 | !!--------------------------------------------------------------------- |
|---|
| 447 | ! |
|---|
| 448 | IF( nn_ice == 4 ) CALL cice_sbc_final |
|---|
| 449 | ! |
|---|
| 450 | END SUBROUTINE sbc_final |
|---|
| 451 | |
|---|
| 452 | !!====================================================================== |
|---|
| 453 | END MODULE sbcmod |
|---|
