New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/2014/dev_CNRS_2014/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2014/dev_CNRS_2014/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 4896

Last change on this file since 4896 was 4896, checked in by cetlod, 9 years ago

2014/dev_CNRS_2014 : merge the 1st branch onto dev_CNRS_2014, see ticket #1415
  • Property svn:keywords set to Id
File size: 11.3 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! surface boundary condition: ocean fields
17   USE sbcapr          ! surface boundary condition: atmospheric pressure
18   USE eosbn2          ! equation of state and related derivatives
19   !
20   USE in_out_manager  ! I/O manager
21   USE prtctl          ! Print control
22   USE iom             ! IOM library
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   sbc_ssm         ! routine called by step.F90
28   PUBLIC   sbc_ssm_init    ! routine called by sbcmod.F90
29
30   LOGICAL, SAVE  ::   l_ssm_mean = .FALSE.       ! keep track of whether means have been read
31                                                  ! from restart file
32   
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE sbc_ssm( kt )
43      !!---------------------------------------------------------------------
44      !!                     ***  ROUTINE sbc_oce  ***
45      !!                     
46      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
47      !!                condition computation
48      !!               
49      !! ** Method  :   compute mean surface velocity (2 components at U and
50      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
51      !!      the periode (kt - nn_fsbc) to kt
52      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
53      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
54      !!---------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kt   ! ocean time step
56      !
57      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
58      !!---------------------------------------------------------------------
59      !                                                   ! ---------------------------------------- !
60      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
61         !                                                ! ---------------------------------------- !
62         ssu_m(:,:) = ub(:,:,1)
63         ssv_m(:,:) = vb(:,:,1)
64         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
65         ELSE                    ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
66         ENDIF
67         sss_m(:,:) = tsn(:,:,1,jp_sal)
68         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
69         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
70         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
71         ENDIF
72         !
73         IF( lk_vvl )   fse3t_m(:,:) = fse3t_n(:,:,1)
74         !
75      ELSE
76         !                                                ! ----------------------------------------------- !
77         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
78            !                                             ! ----------------------------------------------- !
79            IF(lwp) WRITE(numout,*)
80            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
81            zcoef = REAL( nn_fsbc - 1, wp )
82            ssu_m(:,:) = zcoef * ub(:,:,1)
83            ssv_m(:,:) = zcoef * vb(:,:,1)
84            IF( ln_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
85            ELSE                    ;   sst_m(:,:) = zcoef * tsn(:,:,1,jp_tem)
86            ENDIF
87            sss_m(:,:) = zcoef * tsn(:,:,1,jp_sal)
88            !                          ! removed inverse barometer ssh when Patm forcing is used
89            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
90            ELSE                    ;   ssh_m(:,:) = zcoef *   sshn(:,:)
91            ENDIF
92            IF( lk_vvl )   fse3t_m(:,:) = zcoef * fse3t_n(:,:,1)
93            !                                             ! ---------------------------------------- !
94         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
95            !                                             ! ---------------------------------------- !
96            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
97            ssv_m(:,:) = 0.e0
98            sst_m(:,:) = 0.e0
99            sss_m(:,:) = 0.e0
100            ssh_m(:,:) = 0.e0
101            IF( lk_vvl )   fse3t_m(:,:) = 0.e0
102         ENDIF
103         !                                                ! ---------------------------------------- !
104         !                                                !        Cumulate at each time step        !
105         !                                                ! ---------------------------------------- !
106         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
107         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
108         IF( ln_useCT )  THEN    ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
109         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + tsn(:,:,1,jp_tem)
110         ENDIF
111         sss_m(:,:) = sss_m(:,:) + tsn(:,:,1,jp_sal)
112         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
113         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 *  ( ssh_ib(:,:) + ssh_ibb(:,:) )
114         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
115         ENDIF
116         IF( lk_vvl )   fse3t_m(:,:) = fse3t_m(:,:) + fse3t_n(:,:,1)
117
118         !                                                ! ---------------------------------------- !
119         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
120            !                                             ! ---------------------------------------- !
121            zcoef = 1. / REAL( nn_fsbc, wp )
122            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
123            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
124            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
125            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
126            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
127            IF( lk_vvl )   fse3t_m(:,:) = fse3t_m(:,:) * zcoef   ! mean vertical scale factor [m]
128            !
129         ENDIF
130         !                                                ! ---------------------------------------- !
131         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
132            !                                             ! ---------------------------------------- !
133            IF(lwp) WRITE(numout,*)
134            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
135               &                    'at it= ', kt,' date= ', ndastp
136            IF(lwp) WRITE(numout,*) '~~~~~~~'
137            zf_sbc = REAL( nn_fsbc, wp )
138            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
139            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
140            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
141            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
142            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
143            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
144            IF( lk_vvl ) THEN
145               CALL iom_rstput( kt, nitrst, numrow, 'fse3t_m'  , fse3t_m(:,:)  )
146            END IF
147            !
148         ENDIF
149         !
150      ENDIF
151      !
152   END SUBROUTINE sbc_ssm
153
154   SUBROUTINE sbc_ssm_init
155      !!----------------------------------------------------------------------
156      !!                  ***  ROUTINE sbc_ssm_init  ***
157      !!
158      !! ** Purpose :   Initialisation of the sbc data
159      !!
160      !! ** Action  : - read parameters
161      !!----------------------------------------------------------------------
162      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
163      !!----------------------------------------------------------------------
164
165      IF( nn_fsbc == 1 ) THEN
166         !
167         IF(lwp) WRITE(numout,*)
168         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
169         IF(lwp) WRITE(numout,*) '~~~~~~~ '
170         !
171      ELSE
172         !               
173         IF(lwp) WRITE(numout,*)
174         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
175         IF(lwp) WRITE(numout,*) '~~~~~~~ '
176         !
177         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
178            l_ssm_mean = .TRUE.
179            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
180            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
181            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
182            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
183            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
184            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
185            IF( lk_vvl ) CALL iom_get( numror, jpdom_autoglo, 'fse3t_m', fse3t_m(:,:) )
186            !
187            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
188               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
189                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
190               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
191               ssu_m(:,:) = zcoef * ssu_m(:,:) 
192               ssv_m(:,:) = zcoef * ssv_m(:,:)
193               sst_m(:,:) = zcoef * sst_m(:,:)
194               sss_m(:,:) = zcoef * sss_m(:,:)
195               ssh_m(:,:) = zcoef * ssh_m(:,:)
196               IF( lk_vvl ) fse3t_m(:,:) = zcoef * fse3t_m(:,:)
197            ELSE
198               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
199            ENDIF
200         ENDIF
201      ENDIF
202      !
203   END SUBROUTINE sbc_ssm_init
204
205   !!======================================================================
206END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.