New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcrnf.F90 in branches/2014/dev_MERGE_2014/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2014/dev_MERGE_2014/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 4955

Last change on this file since 4955 was 4666, checked in by mathiot, 10 years ago
#1331 : add ISOMIP config files + ice shelf code
Property svn:keywords set to `Id`
File size: 26.9 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE sbcisf ! PM we could remove it I think
22	USE closea ! closed seas
23	USE fldread ! read input field at current time step
24	USE in_out_manager ! I/O manager
25	USE iom ! I/O module
26	USE lib_mpp ! MPP library
27	USE eosbn2
28	USE wrk_nemo ! Memory allocation
29
30	IMPLICIT NONE
31	PRIVATE
32
33	PUBLIC sbc_rnf ! routine call in sbcmod module
34	PUBLIC sbc_rnf_div ! routine called in sshwzv module
35	PUBLIC sbc_rnf_alloc ! routine call in sbcmod module
36	PUBLIC sbc_rnf_init ! (PUBLIC for TAM)
37	! !!* namsbc_rnf namelist *
38	CHARACTER(len=100), PUBLIC :: cn_dir !: Root directory for location of ssr files
39	LOGICAL , PUBLIC :: ln_rnf_depth !: depth river runoffs attribute specified in a file
40	LOGICAL , PUBLIC :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
41	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
42	LOGICAL , PUBLIC :: ln_rnf_emp !: runoffs into a file to be read or already into precipitation
43	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
44	TYPE(FLD_N) , PUBLIC :: sn_cnf !: information about the runoff mouth file to be read
45	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
46	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
47	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
48	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
49	REAL(wp) , PUBLIC :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
50	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
51	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
52
53	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
54	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
55	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
56	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
57	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
58	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s]
59
60	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
61	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
62	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
63
64	!! * Substitutions
65	# include "domzgr_substitute.h90"
66	!!----------------------------------------------------------------------
67	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
68	!! $Id$
69	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
70	!!----------------------------------------------------------------------
71	CONTAINS
72
73	INTEGER FUNCTION sbc_rnf_alloc()
74	!!----------------------------------------------------------------------
75	!! * ROUTINE sbc_rnf_alloc *
76	!!----------------------------------------------------------------------
77	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
78	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
79	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
80	!
81	IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc )
82	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
83	END FUNCTION sbc_rnf_alloc
84
85
86	SUBROUTINE sbc_rnf( kt )
87	!!----------------------------------------------------------------------
88	!! * ROUTINE sbc_rnf *
89	!!
90	!! ** Purpose : Introduce a climatological run off forcing
91	!!
92	!! ** Method : Set each river mouth with a monthly climatology
93	!! provided from different data.
94	!! CAUTION : upward water flux, runoff forced to be < 0
95	!!
96	!! ** Action : runoff updated runoff field at time-step kt
97	!!----------------------------------------------------------------------
98	INTEGER, INTENT(in) :: kt ! ocean time step
99	!
100	INTEGER :: ji, jj ! dummy loop indices
101	INTEGER :: z_err = 0 ! dummy integer for error handling
102	!!----------------------------------------------------------------------
103	REAL(wp), DIMENSION(:,:), POINTER :: ztfrz ! freezing point used for temperature correction
104	!
105	CALL wrk_alloc( jpi,jpj, ztfrz)
106
107	!
108	IF( kt == nit000 ) CALL sbc_rnf_init ! Read namelist and allocate structures
109
110	! ! ---------------------------------------- !
111	IF( kt /= nit000 ) THEN ! Swap of forcing fields !
112	! ! ---------------------------------------- !
113	rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000
114	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine
115	!
116	ENDIF
117
118	! !-------------------!
119	IF( .NOT. ln_rnf_emp ) THEN ! Update runoff !
120	! !-------------------!
121	!
122	CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
123	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
124	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
125	!
126	! Runoff reduction only associated to the ORCA2_LIM configuration
127	! when reading the NetCDF file runoff_1m_nomask.nc
128	IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN
129	WHERE( 40._wp < gphit(:,:) .AND. gphit(:,:) < 65._wp )
130	sf_rnf(1)%fnow(:,:,1) = 0.85 * sf_rnf(1)%fnow(:,:,1)
131	END WHERE
132	ENDIF
133	!
134	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
135	!
136	rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) ! updated runoff value at time step kt
137	!
138	! ! set temperature & salinity content of runoffs
139	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
140	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
141	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
142	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
143	END WHERE
144	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp ) ! where fwf comes from melting of ice shelves or iceberg
145	ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
146	rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
147	END WHERE
148	ELSE ! use SST as runoffs temperature
149	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
150	ENDIF
151	! ! use runoffs salinity data
152	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
153	! ! else use S=0 for runoffs (done one for all in the init)
154	IF ( ANY( rnf(:,:) < 0._wp ) ) z_err=1
155	IF(lk_mpp) CALL mpp_sum(z_err)
156	IF( z_err > 0 ) CALL ctl_stop( 'sbc_rnf : negative runnoff values exist' )
157	!
158	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
159	ENDIF
160	!
161	ENDIF
162	!
163	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
164	! ! ---------------------------------------- !
165	IF( ln_rstart .AND. & !* Restart: read in restart file
166	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
167	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
168	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
169	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
170	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
171	ELSE !* no restart: set from nit000 values
172	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
173	rnf_b (:,: ) = rnf (:,: )
174	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
175	ENDIF
176	ENDIF
177	! ! ---------------------------------------- !
178	IF( lrst_oce ) THEN ! Write in the ocean restart file !
179	! ! ---------------------------------------- !
180	IF(lwp) WRITE(numout,*)
181	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
182	& 'at it= ', kt,' date= ', ndastp
183	IF(lwp) WRITE(numout,*) '~~~~'
184	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
185	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
186	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
187	ENDIF
188	!
189	END SUBROUTINE sbc_rnf
190
191
192	SUBROUTINE sbc_rnf_div( phdivn )
193	!!----------------------------------------------------------------------
194	!! * ROUTINE sbc_rnf *
195	!!
196	!! ** Purpose : update the horizontal divergence with the runoff inflow
197	!!
198	!! ** Method :
199	!! CAUTION : rnf is positive (inflow) decreasing the
200	!! divergence and expressed in m/s
201	!!
202	!! ** Action : phdivn decreased by the runoff inflow
203	!!----------------------------------------------------------------------
204	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
205	!!
206	INTEGER :: ji, jj, jk ! dummy loop indices
207	REAL(wp) :: zfact ! local scalar
208	!!----------------------------------------------------------------------
209	!
210	zfact = 0.5_wp
211	!
212	IF( ln_rnf_depth ) THEN !== runoff distributed over several levels ==!
213	IF( lk_vvl ) THEN ! variable volume case
214	DO jj = 1, jpj ! update the depth over which runoffs are distributed
215	DO ji = 1, jpi
216	h_rnf(ji,jj) = 0._wp
217	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
218	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
219	END DO
220	! ! apply the runoff input flow
221	DO jk = 1, nk_rnf(ji,jj)
222	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
223	END DO
224	END DO
225	END DO
226	ELSE ! constant volume case : just apply the runoff input flow
227	DO jj = 1, jpj
228	DO ji = 1, jpi
229	DO jk = 1, nk_rnf(ji,jj)
230	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
231	END DO
232	END DO
233	END DO
234	ENDIF
235	ELSE !== runoff put only at the surface ==!
236	IF( lk_vvl ) THEN ! variable volume case
237	h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box
238	ENDIF
239	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
240	ENDIF
241	!
242	END SUBROUTINE sbc_rnf_div
243
244
245	SUBROUTINE sbc_rnf_init
246	!!----------------------------------------------------------------------
247	!! * ROUTINE sbc_rnf_init *
248	!!
249	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
250	!!
251	!! ** Method : - read the runoff namsbc_rnf namelist
252	!!
253	!! ** Action : - read parameters
254	!!----------------------------------------------------------------------
255	CHARACTER(len=32) :: rn_dep_file ! runoff file name
256	INTEGER :: ji, jj, jk ! dummy loop indices
257	INTEGER :: ierror, inum ! temporary integer
258	INTEGER :: ios ! Local integer output status for namelist read
259	!
260	NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
261	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
262	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact
263	!!----------------------------------------------------------------------
264	!
265	! ! ============
266	! ! Namelist
267	! ! ============
268	!
269	REWIND( numnam_ref ) ! Namelist namsbc_rnf in reference namelist : Runoffs
270	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
271	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
272
273	REWIND( numnam_cfg ) ! Namelist namsbc_rnf in configuration namelist : Runoffs
274	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
275	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
276	IF(lwm) WRITE ( numond, namsbc_rnf )
277	!
278	! ! Control print
279	IF(lwp) THEN
280	WRITE(numout,*)
281	WRITE(numout,*) 'sbc_rnf : runoff '
282	WRITE(numout,*) '~~~~~~~ '
283	WRITE(numout,*) ' Namelist namsbc_rnf'
284	WRITE(numout,*) ' runoff in a file to be read ln_rnf_emp = ', ln_rnf_emp
285	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
286	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
287	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
288	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
289	ENDIF
290	!
291	! ! ==================
292	! ! Type of runoff
293	! ! ==================
294	! !== allocate runoff arrays
295	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
296	!
297	IF( ln_rnf_emp ) THEN !== runoffs directly provided in the precipitations ==!
298	IF(lwp) WRITE(numout,*)
299	IF(lwp) WRITE(numout,*) ' runoffs directly provided in the precipitations'
300	IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN
301	CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' )
302	ln_rnf_depth = .FALSE. ; ln_rnf_tem = .FALSE. ; ln_rnf_sal = .FALSE.
303	ENDIF
304	!
305	ELSE !== runoffs read in a file : set sf_rnf structure ==!
306	!
307	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
308	IF(lwp) WRITE(numout,*)
309	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
310	IF( ierror > 0 ) THEN
311	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
312	ENDIF
313	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
314	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
315	! ! fill sf_rnf with the namelist (sn_rnf) and control print
316	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
317	!
318	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
319	IF(lwp) WRITE(numout,*)
320	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
321	ALLOCATE( sf_t_rnf(1), STAT=ierror )
322	IF( ierror > 0 ) THEN
323	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
324	ENDIF
325	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
326	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
327	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
328	ENDIF
329	!
330	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
331	IF(lwp) WRITE(numout,*)
332	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
333	ALLOCATE( sf_s_rnf(1), STAT=ierror )
334	IF( ierror > 0 ) THEN
335	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
336	ENDIF
337	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
338	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
339	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
340	ENDIF
341	!
342	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
343	IF(lwp) WRITE(numout,*)
344	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
345	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
346	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
347	IF( sn_dep_rnf%cltype == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
348	ENDIF
349	CALL iom_open ( rn_dep_file, inum ) ! open file
350	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
351	CALL iom_close( inum ) ! close file
352	!
353	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
354	DO jj = 1, jpj
355	DO ji = 1, jpi
356	IF( h_rnf(ji,jj) > 0._wp ) THEN
357	jk = 2
358	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; END DO
359	nk_rnf(ji,jj) = jk
360	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
361	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
362	ELSE
363	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
364	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
365	ENDIF
366	END DO
367	END DO
368	DO jj = 1, jpj ! set the associated depth
369	DO ji = 1, jpi
370	h_rnf(ji,jj) = 0._wp
371	DO jk = 1, nk_rnf(ji,jj)
372	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
373	END DO
374	END DO
375	END DO
376	ELSE ! runoffs applied at the surface
377	nk_rnf(:,:) = 1
378	h_rnf (:,:) = fse3t(:,:,1)
379	ENDIF
380	!
381	ENDIF
382	!
383	rnf(:,:) = 0._wp ! runoff initialisation
384	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
385	!
386	! ! ========================
387	! ! River mouth vicinity
388	! ! ========================
389	!
390	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
391	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
392	! ! - set to zero SSS damping (ln_ssr=T)
393	! ! - mixed upstream-centered (ln_traadv_cen2=T)
394	!
395	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
396	& 'be spread through depth by ln_rnf_depth' )
397	!
398	nkrnf = 0 ! Number of level over which Kz increase
399	IF( rn_hrnf > 0._wp ) THEN
400	nkrnf = 2
401	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1 ; END DO
402	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
403	ENDIF
404	IF(lwp) WRITE(numout,*)
405	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
406	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
407	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
408	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
409	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
410	!
411	CALL rnf_mouth ! set river mouth mask
412	!
413	ELSE ! No treatment at river mouths
414	IF(lwp) WRITE(numout,*)
415	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
416	rnfmsk (:,:) = 0._wp
417	rnfmsk_z(:) = 0._wp
418	nkrnf = 0
419	ENDIF
420	!
421	END SUBROUTINE sbc_rnf_init
422
423
424	SUBROUTINE rnf_mouth
425	!!----------------------------------------------------------------------
426	!! * ROUTINE rnf_mouth *
427	!!
428	!! ** Purpose : define the river mouths mask
429	!!
430	!! ** Method : read the river mouth mask (=0/1) in the river runoff
431	!! climatological file. Defined a given vertical structure.
432	!! CAUTION, the vertical structure is hard coded on the
433	!! first 5 levels.
434	!! This fields can be used to:
435	!! - set an upstream advection scheme
436	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
437	!! - increase vertical on the top nn_krnf vertical levels
438	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
439	!! - set to zero SSS restoring flux at river mouth grid points
440	!!
441	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
442	!! rnfmsk_z vertical structure
443	!!----------------------------------------------------------------------
444	INTEGER :: inum ! temporary integers
445	CHARACTER(len=140) :: cl_rnfile ! runoff file name
446	!!----------------------------------------------------------------------
447	!
448	IF(lwp) WRITE(numout,*)
449	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
450	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
451	!
452	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
453	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
454	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
455	ENDIF
456	!
457	! horizontal mask (read in NetCDF file)
458	CALL iom_open ( cl_rnfile, inum ) ! open file
459	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
460	CALL iom_close( inum ) ! close file
461	!
462	IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
463	!
464	rnfmsk_z(:) = 0._wp ! vertical structure
465	rnfmsk_z(1) = 1.0
466	rnfmsk_z(2) = 1.0 ! **********
467	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
468	rnfmsk_z(4) = 0.25 ! **********
469	rnfmsk_z(5) = 0.125
470	!
471	END SUBROUTINE rnf_mouth
472
473	!!======================================================================
474	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

Download in other formats: