New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/2014/dev_MERGE_2014/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2014/dev_MERGE_2014/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 4944

Last change on this file since 4944 was 4666, checked in by mathiot, 10 years ago

#1331 : add ISOMIP config files + ice shelf code
  • Property svn:keywords set to Id
File size: 11.5 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! Surface boundary condition: ocean fields
17   USE sbc_oce         ! surface boundary condition: ocean fields
18   USE sbcapr          ! surface boundary condition: atmospheric pressure
19   USE prtctl          ! Print control                    (prt_ctl routine)
20   USE iom
21   USE in_out_manager  ! I/O manager
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   sbc_ssm         ! routine called by step.F90
27   PUBLIC   sbc_ssm_init    ! routine called by sbcmod.F90
28
29   LOGICAL, SAVE  ::   l_ssm_mean = .FALSE.       ! keep track of whether means have been read
30                                                  ! from restart file
31   
32   !! * Substitutions
33#  include "domzgr_substitute.h90"
34   !!----------------------------------------------------------------------
35   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
36   !! $Id$
37   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE sbc_ssm( kt )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE sbc_oce  ***
44      !!                     
45      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
46      !!                condition computation
47      !!               
48      !! ** Method  :   compute mean surface velocity (2 components at U and
49      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
50      !!      the periode (kt - nn_fsbc) to kt
51      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
52      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT(in) ::   kt   ! ocean time step
55      !
56      INTEGER  ::   ji,jj               ! loop index
57      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
58      !!---------------------------------------------------------------------
59      !                                                   ! ---------------------------------------- !
60      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
61         !                                                ! ---------------------------------------- !
62         DO jj = 1, jpj
63            DO ji = 1, jpi
64               ssu_m(ji,jj) = ub(ji,jj,miku(ji,jj))
65               ssv_m(ji,jj) = vb(ji,jj,mikv(ji,jj))
66               sst_m(ji,jj) = tsn(ji,jj,mikt(ji,jj),jp_tem)
67               sss_m(ji,jj) = tsn(ji,jj,mikt(ji,jj),jp_sal)
68               IF( lk_vvl )   fse3t_m(ji,jj) = fse3t_n(ji,jj,mikt(ji,jj))
69            END DO
70         END DO
71         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
72         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
73         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
74         ENDIF
75         !
76      ELSE
77         !                                                ! ----------------------------------------------- !
78         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
79            !                                             ! ----------------------------------------------- !
80            IF(lwp) WRITE(numout,*)
81            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
82            zcoef = REAL( nn_fsbc - 1, wp )
83            DO jj = 1, jpj
84               DO ji = 1, jpi
85                  ssu_m(ji,jj) = zcoef * ub(ji,jj,miku(ji,jj))
86                  ssv_m(ji,jj) = zcoef * vb(ji,jj,mikv(ji,jj))
87                  sst_m(ji,jj) = zcoef * tsn(ji,jj,mikt(ji,jj),jp_tem)
88                  sss_m(ji,jj) = zcoef * tsn(ji,jj,mikt(ji,jj),jp_sal)
89                  IF( lk_vvl )   fse3t_m(ji,jj) = zcoef * fse3t_n(ji,jj,mikt(ji,jj))
90               END DO
91            END DO
92            !                          ! removed inverse barometer ssh when Patm forcing is used
93            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
94            ELSE                    ;   ssh_m(:,:) = zcoef *   sshn(:,:)
95            ENDIF
96            !                                             ! ---------------------------------------- !
97         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
98            !                                             ! ---------------------------------------- !
99            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
100            ssv_m(:,:) = 0.e0
101            sst_m(:,:) = 0.e0
102            sss_m(:,:) = 0.e0
103            ssh_m(:,:) = 0.e0
104            IF( lk_vvl )   fse3t_m(:,:) = 0.e0
105         ENDIF
106         !                                                ! ---------------------------------------- !
107         !                                                !        Cumulate at each time step        !
108         !                                                ! ---------------------------------------- !
109         DO jj = 1, jpj
110            DO ji = 1, jpi
111               ssu_m(ji,jj) = ssu_m(ji,jj) + ub(ji,jj,miku(ji,jj))
112               ssv_m(ji,jj) = ssv_m(ji,jj) + vb(ji,jj,mikv(ji,jj))
113               sst_m(ji,jj) = sst_m(ji,jj) + tsn(ji,jj,mikt(ji,jj),jp_tem)
114               sss_m(ji,jj) = sss_m(ji,jj) + tsn(ji,jj,mikt(ji,jj),jp_sal)
115               IF( lk_vvl )   fse3t_m(ji,jj) = fse3t_m(ji,jj) + fse3t_n(ji,jj,mikt(ji,jj))
116            END DO
117         END DO
118!                                   ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
119         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 *  ( ssh_ib(:,:) + ssh_ibb(:,:) )
120         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
121         ENDIF
122
123         !                                                ! ---------------------------------------- !
124         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
125            !                                             ! ---------------------------------------- !
126            zcoef = 1. / REAL( nn_fsbc, wp )
127            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
128            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
129            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
130            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
131            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
132            IF( lk_vvl )   fse3t_m(:,:) = fse3t_m(:,:) * zcoef   ! mean vertical scale factor [m]
133            !
134         ENDIF
135         !                                                ! ---------------------------------------- !
136         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
137            !                                             ! ---------------------------------------- !
138            IF(lwp) WRITE(numout,*)
139            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
140               &                    'at it= ', kt,' date= ', ndastp
141            IF(lwp) WRITE(numout,*) '~~~~~~~'
142            zf_sbc = REAL( nn_fsbc, wp )
143            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
144            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
145            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
146            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
147            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
148            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
149            IF( lk_vvl ) THEN
150               CALL iom_rstput( kt, nitrst, numrow, 'fse3t_m'  , fse3t_m(:,:)  )
151            END IF
152            !
153         ENDIF
154         !
155      ENDIF
156      !
157   END SUBROUTINE sbc_ssm
158
159   SUBROUTINE sbc_ssm_init
160      !!----------------------------------------------------------------------
161      !!                  ***  ROUTINE sbc_ssm_init  ***
162      !!
163      !! ** Purpose :   Initialisation of the sbc data
164      !!
165      !! ** Action  : - read parameters
166      !!----------------------------------------------------------------------
167      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
168      !!----------------------------------------------------------------------
169
170      IF( nn_fsbc == 1 ) THEN
171         !
172         IF(lwp) WRITE(numout,*)
173         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
174         IF(lwp) WRITE(numout,*) '~~~~~~~ '
175         !
176      ELSE
177         !               
178         IF(lwp) WRITE(numout,*)
179         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
180         IF(lwp) WRITE(numout,*) '~~~~~~~ '
181         !
182         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
183            l_ssm_mean = .TRUE.
184            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
185            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
186            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
187            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
188            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
189            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
190            IF( lk_vvl ) CALL iom_get( numror, jpdom_autoglo, 'fse3t_m', fse3t_m(:,:) )
191            !
192            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
193               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
194                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
195               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
196               ssu_m(:,:) = zcoef * ssu_m(:,:) 
197               ssv_m(:,:) = zcoef * ssv_m(:,:)
198               sst_m(:,:) = zcoef * sst_m(:,:)
199               sss_m(:,:) = zcoef * sss_m(:,:)
200               ssh_m(:,:) = zcoef * ssh_m(:,:)
201               IF( lk_vvl ) fse3t_m(:,:) = zcoef * fse3t_m(:,:)
202            ELSE
203               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
204            ENDIF
205         ENDIF
206      ENDIF
207      !
208   END SUBROUTINE sbc_ssm_init
209
210   !!======================================================================
211END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.