New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/2014/dev_MERGE_2014/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2014/dev_MERGE_2014/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 4944

Last change on this file since 4944 was 4934, checked in by acc, 10 years ago

Branch dev_r4879_UKMO_NOC_MERGE, Check in merged changes from NOC_ZTS branch; all conflicts resolved
  • Property svn:keywords set to Id
File size: 32.0 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trdmod_oce     ! tracers trends
25   USE trdtra         ! tracers trends
26   USE in_out_manager ! I/O manager
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE lib_mpp        ! MPP library
29   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
30   USE diaptr         ! poleward transport diagnostics
31   USE trc_oce        ! share passive tracers/Ocean variables
32   USE wrk_nemo       ! Memory Allocation
33   USE timing         ! Timing
34   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_tvd        ! routine called by traadv.F90
40   PUBLIC   tra_adv_tvd_zts    ! routine called by traadv.F90
41
42   LOGICAL ::   l_trd   ! flag to compute trends
43
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
55      &                                       ptb, ptn, pta, kjpt )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE tra_adv_tvd  ***
58      !!
59      !! **  Purpose :   Compute the now trend due to total advection of
60      !!       tracers and add it to the general trend of tracer equations
61      !!
62      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
63      !!       corrected flux (monotonic correction)
64      !!       note: - this advection scheme needs a leap-frog time scheme
65      !!
66      !! ** Action : - update (pta) with the now advective tracer trends
67      !!             - save the trends
68      !!----------------------------------------------------------------------
69      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
70      !
71      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
72      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
73      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
74      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
75      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
76      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
79      !
80      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices
81      INTEGER  ::   ik 
82      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
83      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
84      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
90      !
91      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
92      !
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
96         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
97      ENDIF
98      !
99      l_trd = .FALSE.
100      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
101      !
102      IF( l_trd )  THEN
103         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
104         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
105      ENDIF
106      !
107      zwi(:,:,:) = 0.e0 ; zwz(:,:,:) = 0.e0
108      !
109      !                                                          ! ===========
110      DO jn = 1, kjpt                                            ! tracer loop
111         !                                                       ! ===========
112         ! 1. Bottom value : flux set to zero
113         ! ----------------------------------
114         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
115         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
116
117         ! 2. upstream advection with initial mass fluxes & intermediate update
118         ! --------------------------------------------------------------------
119         ! upstream tracer flux in the i and j direction
120         DO jk = 1, jpkm1
121            DO jj = 1, jpjm1
122               DO ji = 1, fs_jpim1   ! vector opt.
123                  ! upstream scheme
124                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
125                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
126                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
127                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
128                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
129                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
130               END DO
131            END DO
132         END DO
133
134         ! upstream tracer flux in the k direction
135         ! Surface value
136         IF( lk_vvl ) THEN   
137            DO jj = 1, jpj
138               DO ji = 1, jpi
139                  zwz(ji,jj, mikt(ji,jj) ) = 0.e0                         ! volume variable
140               END DO
141            END DO
142         ELSE               
143            DO jj = 1, jpj
144               DO ji = 1, jpi
145                  zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
146               END DO
147            END DO   
148         ENDIF
149         ! Interior value
150         DO jj = 1, jpj
151            DO ji = 1, jpi
152               DO jk = mikt(ji,jj)+1, jpkm1
153                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
154                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
155                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
156               END DO
157            END DO
158         END DO
159
160         ! total advective trend
161         DO jk = 1, jpkm1
162            z2dtt = p2dt(jk)
163            DO jj = 2, jpjm1
164               DO ji = fs_2, fs_jpim1   ! vector opt.
165                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
166                  ! total intermediate advective trends
167                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
168                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
169                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
170                  ! update and guess with monotonic sheme
171                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra   * tmask(ji,jj,jk)
172                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
173               END DO
174            END DO
175         END DO
176         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
177         CALL lbc_lnk( zwi, 'T', 1. ) 
178
179         !                                 ! trend diagnostics (contribution of upstream fluxes)
180         IF( l_trd )  THEN 
181            ! store intermediate advective trends
182            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
183         END IF
184         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
185         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
186           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
187           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
188         ENDIF
189
190         ! 3. antidiffusive flux : high order minus low order
191         ! --------------------------------------------------
192         ! antidiffusive flux on i and j
193         DO jk = 1, jpkm1
194            DO jj = 1, jpjm1
195               DO ji = 1, fs_jpim1   ! vector opt.
196                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
197                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
198               END DO
199            END DO
200         END DO
201     
202         ! antidiffusive flux on k
203         zwz(:,:,1) = 0.e0         ! Surface value
204         !
205         DO jj = 1, jpj
206            DO ji = 1, jpi
207               ik=mikt(ji,jj)
208               ! surface value
209               zwz(ji,jj,1:ik) = 0.e0
210               ! Interior value
211               DO jk = mikt(ji,jj)+1, jpkm1                   
212                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
213               END DO
214            END DO
215         END DO
216         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
217         CALL lbc_lnk( zwz, 'W',  1. )
218
219         ! 4. monotonicity algorithm
220         ! -------------------------
221         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
222
223
224         ! 5. final trend with corrected fluxes
225         ! ------------------------------------
226         DO jk = 1, jpkm1
227            DO jj = 2, jpjm1
228               DO ji = fs_2, fs_jpim1   ! vector opt. 
229                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
230                  ! total advective trends
231                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
232                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
233                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
234                  ! add them to the general tracer trends
235                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra * tmask(ji,jj,jk)
236               END DO
237            END DO
238         END DO
239
240         !                                 ! trend diagnostics (contribution of upstream fluxes)
241         IF( l_trd )  THEN
242            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
243            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
244            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
245           
246            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
247            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
248            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
249         END IF
250         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
251         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
252           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
253           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
254         ENDIF
255         !
256      END DO
257      !
258                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
259      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
260      !
261      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
262      !
263   END SUBROUTINE tra_adv_tvd
264
265   SUBROUTINE tra_adv_tvd_zts ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
266      &                                       ptb, ptn, pta, kjpt )
267      !!----------------------------------------------------------------------
268      !!                  ***  ROUTINE tra_adv_tvd_zts  ***
269      !!
270      !! **  Purpose :   Compute the now trend due to total advection of
271      !!       tracers and add it to the general trend of tracer equations
272      !!
273      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
274      !!       corrected flux (monotonic correction). This version use sub-
275      !!       timestepping for the vertical advection which increases stability
276      !!       when vertical metrics are small.
277      !!       note: - this advection scheme needs a leap-frog time scheme
278      !!
279      !! ** Action : - update (pta) with the now advective tracer trends
280      !!             - save the trends
281      !!----------------------------------------------------------------------
282      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
283      !
284      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
285      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
286      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
287      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
288      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
289      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
290      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
291      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
292      !
293      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
294      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
295      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
296      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
297      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
298      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
299      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
300      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
301      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
302      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
303      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwx_sav , zwy_sav
304      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz, zhdiv, zwz_sav, zwzts
305      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
306      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrs
307      !!----------------------------------------------------------------------
308      !
309      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd_zts')
310      !
311      CALL wrk_alloc( jpi, jpj, zwx_sav, zwy_sav )
312      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zhdiv, zwz_sav, zwzts )
313      CALL wrk_alloc( jpi, jpj, jpk, 3, ztrs )
314      !
315      IF( kt == kit000 )  THEN
316         IF(lwp) WRITE(numout,*)
317         IF(lwp) WRITE(numout,*) 'tra_adv_tvd_zts : TVD ZTS advection scheme on ', cdtype
318         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
319      ENDIF
320      !
321      l_trd = .FALSE.
322      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
323      !
324      IF( l_trd )  THEN
325         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
326         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
327      ENDIF
328      !
329      zwi(:,:,:) = 0._wp
330      z_rzts = 1._wp / REAL( jnzts, wp )
331      zr_p2dt(:) = 1._wp / p2dt(:)
332      !
333      !                                                          ! ===========
334      DO jn = 1, kjpt                                            ! tracer loop
335         !                                                       ! ===========
336         ! 1. Bottom value : flux set to zero
337         ! ----------------------------------
338         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
339         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
340
341         ! 2. upstream advection with initial mass fluxes & intermediate update
342         ! --------------------------------------------------------------------
343         ! upstream tracer flux in the i and j direction
344         DO jk = 1, jpkm1
345            DO jj = 1, jpjm1
346               DO ji = 1, fs_jpim1   ! vector opt.
347                  ! upstream scheme
348                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
349                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
350                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
351                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
352                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
353                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
354               END DO
355            END DO
356         END DO
357
358         ! upstream tracer flux in the k direction
359         ! Surface value
360         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0._wp                        ! volume variable
361         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
362         ENDIF
363         ! Interior value
364         DO jk = 2, jpkm1
365            DO jj = 1, jpj
366               DO ji = 1, jpi
367                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
368                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
369                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
370               END DO
371            END DO
372         END DO
373
374         ! total advective trend
375         DO jk = 1, jpkm1
376            z2dtt = p2dt(jk)
377            DO jj = 2, jpjm1
378               DO ji = fs_2, fs_jpim1   ! vector opt.
379                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
380                  ! total intermediate advective trends
381                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
382                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
383                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
384                  ! update and guess with monotonic sheme
385                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
386                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
387               END DO
388            END DO
389         END DO
390         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
391         CALL lbc_lnk( zwi, 'T', 1. ) 
392
393         !                                 ! trend diagnostics (contribution of upstream fluxes)
394         IF( l_trd )  THEN 
395            ! store intermediate advective trends
396            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
397         END IF
398         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
399         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
400           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
401           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
402         ENDIF
403
404         ! 3. antidiffusive flux : high order minus low order
405         ! --------------------------------------------------
406         ! antidiffusive flux on i and j
407
408
409         DO jk = 1, jpkm1
410
411            DO jj = 1, jpjm1
412               DO ji = 1, fs_jpim1   ! vector opt.
413                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
414                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
415
416                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
417                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
418               END DO
419            END DO
420
421            DO jj = 2, jpjm1         ! partial horizontal divergence
422               DO ji = fs_2, fs_jpim1
423                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
424                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
425               END DO
426            END DO
427
428            DO jj = 1, jpjm1
429               DO ji = 1, fs_jpim1   ! vector opt.
430                  zwx(ji,jj,jk) = zwx(ji,jj,jk)  - zwx_sav(ji,jj)
431                  zwy(ji,jj,jk) = zwy(ji,jj,jk)  - zwy_sav(ji,jj)
432               END DO
433            END DO
434         END DO
435     
436         ! antidiffusive flux on k
437         zwz(:,:,1) = 0._wp        ! Surface value
438         zwz_sav(:,:,:) = zwz(:,:,:)
439         !
440         ztrs(:,:,:,1) = ptb(:,:,:,jn)
441         zwzts(:,:,:) = 0._wp
442
443         DO jl = 1, jnzts                   ! Start of sub timestepping loop
444
445            IF( jl == 1 ) THEN              ! Euler forward to kick things off
446              jtb = 1   ;   jtn = 1   ;   jta = 2
447              zts(:) = p2dt(:) * z_rzts
448              jtaken = MOD( jnzts + 1 , 2)  ! Toggle to collect every second flux
449                                            ! starting at jl =1 if jnzts is odd;
450                                            ! starting at jl =2 otherwise
451            ELSEIF( jl == 2 ) THEN          ! First leapfrog step
452              jtb = 1   ;   jtn = 2   ;   jta = 3
453              zts(:) = 2._wp * p2dt(:) * z_rzts
454            ELSE                            ! Shuffle pointers for subsequent leapfrog steps
455              jtb = MOD(jtb,3) + 1
456              jtn = MOD(jtn,3) + 1
457              jta = MOD(jta,3) + 1
458            ENDIF
459            DO jk = 2, jpkm1          ! Interior value
460               DO jj = 2, jpjm1
461                  DO ji = fs_2, fs_jpim1
462                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) )
463                     IF( jtaken == 0 ) zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk)*zts(jk)           ! Accumulate time-weighted vertcal flux
464                  END DO
465               END DO
466            END DO
467
468            jtaken = MOD( jtaken + 1 , 2 )
469
470            DO jk = 2, jpkm1          ! Interior value
471               DO jj = 2, jpjm1
472                  DO ji = fs_2, fs_jpim1
473                     zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
474                     ! total advective trends
475                     ztra = - zbtr * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
476                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb) + zts(jk) * ztra
477                  END DO
478               END DO
479            END DO
480
481         END DO
482
483         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
484            DO jj = 2, jpjm1
485               DO ji = fs_2, fs_jpim1
486                  zwz(ji,jj,jk) = zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk)
487               END DO
488            END DO
489         END DO
490         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
491         CALL lbc_lnk( zwz, 'W',  1. )
492
493         ! 4. monotonicity algorithm
494         ! -------------------------
495         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
496
497
498         ! 5. final trend with corrected fluxes
499         ! ------------------------------------
500         DO jk = 1, jpkm1
501            DO jj = 2, jpjm1
502               DO ji = fs_2, fs_jpim1   ! vector opt. 
503                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
504                  ! total advective trends
505                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
506                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
507                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
508                  ! add them to the general tracer trends
509                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
510               END DO
511            END DO
512         END DO
513
514         !                                 ! trend diagnostics (contribution of upstream fluxes)
515         IF( l_trd )  THEN
516            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
517            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
518            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
519           
520            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
521            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
522            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
523         END IF
524         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
525         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
526           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
527           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
528         ENDIF
529         !
530      END DO
531      !
532                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz, zhdiv, zwz_sav, zwzts )
533                   CALL wrk_dealloc( jpi, jpj, jpk, 3, ztrs )
534                   CALL wrk_dealloc( jpi, jpj, zwx_sav, zwy_sav )
535      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
536      !
537      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd_zts')
538      !
539   END SUBROUTINE tra_adv_tvd_zts
540
541   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
542      !!---------------------------------------------------------------------
543      !!                    ***  ROUTINE nonosc  ***
544      !!     
545      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
546      !!       scheme and the before field by a nonoscillatory algorithm
547      !!
548      !! **  Method  :   ... ???
549      !!       warning : pbef and paft must be masked, but the boundaries
550      !!       conditions on the fluxes are not necessary zalezak (1979)
551      !!       drange (1995) multi-dimensional forward-in-time and upstream-
552      !!       in-space based differencing for fluid
553      !!----------------------------------------------------------------------
554      !
555      !!----------------------------------------------------------------------
556      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
557      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
558      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
559      !
560      INTEGER ::   ji, jj, jk   ! dummy loop indices
561      INTEGER ::   ikm1         ! local integer
562      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
563      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
564      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
565      !!----------------------------------------------------------------------
566      !
567      IF( nn_timing == 1 )  CALL timing_start('nonosc')
568      !
569      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
570      !
571
572      zbig  = 1.e+40_wp
573      zrtrn = 1.e-15_wp
574      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
575
576
577      ! Search local extrema
578      ! --------------------
579      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
580      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
581         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
582      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
583         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
584
585      DO jj = 2, jpjm1
586         DO ji = fs_2, fs_jpim1   ! vector opt.
587            DO jk = mikt(ji,jj), jpkm1
588               ikm1 = MAX(jk-1,mikt(ji,jj))
589               z2dtt = p2dt(jk)
590               
591               ! search maximum in neighbourhood
592               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
593                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
594                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
595                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
596
597               ! search minimum in neighbourhood
598               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
599                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
600                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
601                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
602
603               ! positive part of the flux
604               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
605                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
606                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
607
608               ! negative part of the flux
609               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
610                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
611                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
612
613               ! up & down beta terms
614               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
615               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
616               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
617            END DO
618         END DO
619      END DO
620      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
621
622      ! 3. monotonic flux in the i & j direction (paa & pbb)
623      ! ----------------------------------------
624      DO jk = 1, jpkm1
625         DO jj = 2, jpjm1
626            DO ji = fs_2, fs_jpim1   ! vector opt.
627               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
628               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
629               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
630               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
631
632               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
633               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
634               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
635               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
636
637      ! monotonic flux in the k direction, i.e. pcc
638      ! -------------------------------------------
639               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
640               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
641               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
642               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
643            END DO
644         END DO
645      END DO
646      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
647      !
648      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
649      !
650      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
651      !
652   END SUBROUTINE nonosc
653
654   !!======================================================================
655END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.