1 | MODULE iceini |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE iceini *** |
---|
4 | !! Sea-ice model : LIM Sea ice model Initialization |
---|
5 | !!====================================================================== |
---|
6 | !! History : 3.0 ! 2008-03 (M. Vancoppenolle) LIM-3 original code |
---|
7 | !! 3.3 ! 2010-12 (G. Madec) add call to lim_thd_init and lim_thd_sal_init |
---|
8 | !! 4.0 ! 2011-02 (G. Madec) dynamical allocation |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | #if defined key_lim3 |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! 'key_lim3' LIM sea-ice model |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! ice_init : sea-ice model initialization |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | USE phycst ! physical constants |
---|
17 | USE dom_oce ! ocean domain |
---|
18 | USE sbc_oce ! Surface boundary condition: ocean fields |
---|
19 | USE sbc_ice ! Surface boundary condition: ice fields |
---|
20 | USE ice ! LIM variables |
---|
21 | USE par_ice ! LIM parameters |
---|
22 | USE dom_ice ! LIM domain |
---|
23 | USE thd_ice ! LIM thermodynamical variables |
---|
24 | USE limitd_me ! LIM ice thickness distribution |
---|
25 | USE limmsh ! LIM mesh |
---|
26 | USE limistate ! LIM initial state |
---|
27 | USE limrst ! LIM restart |
---|
28 | USE limthd ! LIM ice thermodynamics |
---|
29 | USE limthd_sal ! LIM ice thermodynamics: salinity |
---|
30 | USE limvar ! LIM variables |
---|
31 | USE limsbc ! LIM surface boundary condition |
---|
32 | USE in_out_manager ! I/O manager |
---|
33 | USE lib_mpp ! MPP library |
---|
34 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
35 | |
---|
36 | IMPLICIT NONE |
---|
37 | PRIVATE |
---|
38 | |
---|
39 | PUBLIC ice_init ! called by sbcice_lim.F90 |
---|
40 | |
---|
41 | !!---------------------------------------------------------------------- |
---|
42 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
---|
43 | !! $Id$ |
---|
44 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
45 | !!---------------------------------------------------------------------- |
---|
46 | CONTAINS |
---|
47 | |
---|
48 | SUBROUTINE ice_init |
---|
49 | !!---------------------------------------------------------------------- |
---|
50 | !! *** ROUTINE ice_init *** |
---|
51 | !! |
---|
52 | !! ** purpose : Allocate all the dynamic arrays of the LIM-3 modules |
---|
53 | !!---------------------------------------------------------------------- |
---|
54 | INTEGER :: ierr |
---|
55 | !!---------------------------------------------------------------------- |
---|
56 | |
---|
57 | ! ! Allocate the ice arrays |
---|
58 | ierr = ice_alloc () ! ice variables |
---|
59 | ierr = ierr + dom_ice_alloc () ! domain |
---|
60 | ierr = ierr + sbc_ice_alloc () ! surface forcing |
---|
61 | ierr = ierr + thd_ice_alloc () ! thermodynamics |
---|
62 | ierr = ierr + lim_itd_me_alloc () ! ice thickness distribution - mechanics |
---|
63 | ! |
---|
64 | IF( lk_mpp ) CALL mpp_sum( ierr ) |
---|
65 | IF( ierr /= 0 ) CALL ctl_stop('STOP', 'ice_init : unable to allocate ice arrays') |
---|
66 | ! |
---|
67 | ! ! adequation jpk versus ice/snow layers/categories |
---|
68 | IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk ) & |
---|
69 | & CALL ctl_stop( 'STOP', & |
---|
70 | & 'ice_init: the 3rd dimension of workspace arrays is too small.', & |
---|
71 | & 'use more ocean levels or less ice/snow layers/categories.' ) |
---|
72 | |
---|
73 | ! Open the reference and configuration namelist files and namelist output file |
---|
74 | CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp ) |
---|
75 | CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp ) |
---|
76 | IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 ) |
---|
77 | ! |
---|
78 | CALL ice_run ! set some ice run parameters |
---|
79 | ! |
---|
80 | CALL lim_thd_init ! set ice thermodynics parameters |
---|
81 | ! |
---|
82 | CALL lim_thd_sal_init ! set ice salinity parameters |
---|
83 | ! |
---|
84 | rdt_ice = nn_fsbc * rdttra(1) ! sea-ice timestep |
---|
85 | r1_rdtice = 1._wp / rdt_ice ! sea-ice timestep inverse |
---|
86 | ! |
---|
87 | CALL lim_msh ! ice mesh initialization |
---|
88 | ! |
---|
89 | CALL lim_itd_ini ! ice thickness distribution initialization |
---|
90 | ! |
---|
91 | CALL lim_itd_me_init ! ice thickness distribution initialization |
---|
92 | ! ! Initial sea-ice state |
---|
93 | IF( .NOT. ln_rstart ) THEN ! start from rest |
---|
94 | numit = 0 |
---|
95 | numit = nit000 - 1 |
---|
96 | CALL lim_istate ! start from rest: sea-ice deduced from sst |
---|
97 | CALL lim_var_agg(1) ! aggregate category variables in bulk variables |
---|
98 | CALL lim_var_glo2eqv ! convert global variables in equivalent variables |
---|
99 | ELSE ! start from a restart file |
---|
100 | CALL lim_rst_read ! read the restart file |
---|
101 | numit = nit000 - 1 |
---|
102 | CALL lim_var_agg(1) ! aggregate ice variables |
---|
103 | CALL lim_var_glo2eqv ! convert global var in equivalent variables |
---|
104 | ENDIF |
---|
105 | ! |
---|
106 | hi_max(jpl) = 99._wp ! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl) |
---|
107 | ! |
---|
108 | CALL lim_sbc_init ! ice surface boundary condition |
---|
109 | ! |
---|
110 | fr_i(:,:) = at_i(:,:) ! initialisation of sea-ice fraction |
---|
111 | tn_ice(:,:,:) = t_su(:,:,:) ! initialisation of surface temp for coupled simu |
---|
112 | ! |
---|
113 | nstart = numit + nn_fsbc |
---|
114 | nitrun = nitend - nit000 + 1 |
---|
115 | nlast = numit + nitrun |
---|
116 | ! |
---|
117 | IF( nstock == 0 ) nstock = nlast + 1 |
---|
118 | ! |
---|
119 | END SUBROUTINE ice_init |
---|
120 | |
---|
121 | |
---|
122 | SUBROUTINE ice_run |
---|
123 | !!------------------------------------------------------------------- |
---|
124 | !! *** ROUTINE ice_run *** |
---|
125 | !! |
---|
126 | !! ** Purpose : Definition some run parameter for ice model |
---|
127 | !! |
---|
128 | !! ** Method : Read the namicerun namelist and check the parameter |
---|
129 | !! values called at the first timestep (nit000) |
---|
130 | !! |
---|
131 | !! ** input : Namelist namicerun |
---|
132 | !!------------------------------------------------------------------- |
---|
133 | NAMELIST/namicerun/ cn_icerst_in, cn_icerst_out, ln_limdyn, amax, cai, cao, ln_nicep, ln_limdiahsb, ln_limdiaout |
---|
134 | INTEGER :: ios ! Local integer output status for namelist read |
---|
135 | !!------------------------------------------------------------------- |
---|
136 | ! |
---|
137 | REWIND( numnam_ice_ref ) ! Namelist namicerun in reference namelist : Parameters for ice |
---|
138 | READ ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901) |
---|
139 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp ) |
---|
140 | |
---|
141 | REWIND( numnam_ice_cfg ) ! Namelist namicerun in configuration namelist : Parameters for ice |
---|
142 | READ ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 ) |
---|
143 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp ) |
---|
144 | IF(lwm) WRITE ( numoni, namicerun ) |
---|
145 | ! |
---|
146 | !IF( lk_mpp .AND. ln_nicep ) THEN |
---|
147 | ! ln_nicep = .FALSE. |
---|
148 | ! CALL ctl_warn( 'ice_run : specific control print for LIM3 desactivated with MPI' ) |
---|
149 | !ENDIF |
---|
150 | ! |
---|
151 | IF(lwp) THEN ! control print |
---|
152 | WRITE(numout,*) |
---|
153 | WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice' |
---|
154 | WRITE(numout,*) ' ~~~~~~' |
---|
155 | WRITE(numout,*) ' switch for ice dynamics (1) or not (0) ln_limdyn = ', ln_limdyn |
---|
156 | WRITE(numout,*) ' maximum ice concentration = ', amax |
---|
157 | WRITE(numout,*) ' atmospheric drag over sea ice = ', cai |
---|
158 | WRITE(numout,*) ' atmospheric drag over ocean = ', cao |
---|
159 | WRITE(numout,*) ' Several ice points in the ice or not in ocean.output = ', ln_nicep |
---|
160 | WRITE(numout,*) ' Diagnose heat/salt budget or not ln_limdiahsb = ', ln_limdiahsb |
---|
161 | WRITE(numout,*) ' Output heat/salt budget or not ln_limdiaout = ', ln_limdiaout |
---|
162 | ENDIF |
---|
163 | ! |
---|
164 | END SUBROUTINE ice_run |
---|
165 | |
---|
166 | |
---|
167 | SUBROUTINE lim_itd_ini |
---|
168 | !!------------------------------------------------------------------ |
---|
169 | !! *** ROUTINE lim_itd_ini *** |
---|
170 | !! |
---|
171 | !! ** Purpose : Initializes the ice thickness distribution |
---|
172 | !! ** Method : ... |
---|
173 | !! Note : hi_max(jpl) is here set up to a value close to 7 m for |
---|
174 | !! limistate (only) and is changed to 99 m in ice_init |
---|
175 | !!------------------------------------------------------------------ |
---|
176 | INTEGER :: jl ! dummy loop index |
---|
177 | REAL(wp) :: zc1, zc2, zc3, zx1 ! local scalars |
---|
178 | !!------------------------------------------------------------------ |
---|
179 | |
---|
180 | IF(lwp) WRITE(numout,*) |
---|
181 | IF(lwp) WRITE(numout,*) 'lim_itd_ini : Initialization of ice thickness distribution ' |
---|
182 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~' |
---|
183 | |
---|
184 | !------------------------------------------------------------------------------! |
---|
185 | ! 1) Ice thickness distribution parameters initialization |
---|
186 | !------------------------------------------------------------------------------! |
---|
187 | IF(lwp) THEN |
---|
188 | WRITE(numout,*) ' Number of ice categories jpl = ', jpl |
---|
189 | ENDIF |
---|
190 | |
---|
191 | !- Thickness categories boundaries |
---|
192 | !---------------------------------- |
---|
193 | hi_max(:) = 0._wp |
---|
194 | |
---|
195 | zc1 = 3._wp / REAL( jpl, wp ) |
---|
196 | zc2 = 10._wp * zc1 |
---|
197 | zc3 = 3._wp |
---|
198 | |
---|
199 | DO jl = 1, jpl |
---|
200 | zx1 = REAL( jl-1, wp ) / REAL( jpl, wp ) |
---|
201 | hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) ) |
---|
202 | END DO |
---|
203 | |
---|
204 | IF(lwp) WRITE(numout,*) ' Thickness category boundaries ' |
---|
205 | IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl) |
---|
206 | |
---|
207 | ! |
---|
208 | DO jl = 1, jpl |
---|
209 | hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp |
---|
210 | END DO |
---|
211 | ! |
---|
212 | ! |
---|
213 | END SUBROUTINE lim_itd_ini |
---|
214 | |
---|
215 | #else |
---|
216 | !!---------------------------------------------------------------------- |
---|
217 | !! Default option : Empty module NO LIM sea-ice model |
---|
218 | !!---------------------------------------------------------------------- |
---|
219 | CONTAINS |
---|
220 | SUBROUTINE ice_init ! Empty routine |
---|
221 | END SUBROUTINE ice_init |
---|
222 | #endif |
---|
223 | |
---|
224 | !!====================================================================== |
---|
225 | END MODULE iceini |
---|