| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! sbc_init : read namsbc namelist |
|---|
| 19 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce ! ocean dynamics and tracers |
|---|
| 22 | USE dom_oce ! ocean space and time domain |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 25 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 26 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 27 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 28 | USE sbcapr ! surface boundary condition: atmospheric pressure |
|---|
| 29 | USE sbcana ! surface boundary condition: analytical formulation |
|---|
| 30 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 31 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 32 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 33 | USE sbcblk_mfs ! surface boundary condition: bulk formulation : MFS |
|---|
| 34 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 35 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 36 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 37 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 38 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 39 | USE cpl_oasis3, ONLY:lk_cpl ! are we in coupled mode? |
|---|
| 40 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 41 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 42 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 43 | USE closea ! closed sea |
|---|
| 44 | USE icbstp ! Icebergs! |
|---|
| 45 | |
|---|
| 46 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 47 | USE iom ! IOM library |
|---|
| 48 | USE in_out_manager ! I/O manager |
|---|
| 49 | USE lib_mpp ! MPP library |
|---|
| 50 | USE timing ! Timing |
|---|
| 51 | USE sbcwave ! Wave module |
|---|
| 52 | USE sbcwave_ecmwf ! ECMWF wave module |
|---|
| 53 | |
|---|
| 54 | IMPLICIT NONE |
|---|
| 55 | PRIVATE |
|---|
| 56 | |
|---|
| 57 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 58 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 59 | |
|---|
| 60 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 61 | |
|---|
| 62 | !! * Substitutions |
|---|
| 63 | # include "domzgr_substitute.h90" |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | !! NEMO/OPA 4.0 , NEMO-consortium (2011) |
|---|
| 66 | !! $Id$ |
|---|
| 67 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | CONTAINS |
|---|
| 70 | |
|---|
| 71 | SUBROUTINE sbc_init |
|---|
| 72 | !!--------------------------------------------------------------------- |
|---|
| 73 | !! *** ROUTINE sbc_init *** |
|---|
| 74 | !! |
|---|
| 75 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 76 | !! |
|---|
| 77 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 78 | !! Call init routines for all other SBC modules that have one |
|---|
| 79 | !! |
|---|
| 80 | !! ** Action : - read namsbc parameters |
|---|
| 81 | !! - nsbc: type of sbc |
|---|
| 82 | !!---------------------------------------------------------------------- |
|---|
| 83 | INTEGER :: icpt ! local integer |
|---|
| 84 | !! |
|---|
| 85 | NAMELIST/namsbc/ nn_fsbc , ln_ana , ln_flx , ln_blk_clio, ln_blk_core, ln_cpl, & |
|---|
| 86 | & ln_blk_mfs, ln_apr_dyn, nn_ice , nn_ice_embd, ln_dm2dc , ln_rnf, & |
|---|
| 87 | & ln_ssr , nn_fwb , ln_cdgw , ln_wave , ln_sdw , nn_lsm, & |
|---|
| 88 | & cn_iceflx , ln_stcor , ln_tauoc, ln_wavetke |
|---|
| 89 | INTEGER :: ios |
|---|
| 90 | !!---------------------------------------------------------------------- |
|---|
| 91 | |
|---|
| 92 | IF(lwp) THEN |
|---|
| 93 | WRITE(numout,*) |
|---|
| 94 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 95 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 96 | ENDIF |
|---|
| 97 | |
|---|
| 98 | REWIND( numnam_ref ) ! Namelist namsbc in reference namelist : Surface boundary |
|---|
| 99 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 100 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp ) |
|---|
| 101 | |
|---|
| 102 | REWIND( numnam_cfg ) ! Namelist namsbc in configuration namelist : Parameters of the run |
|---|
| 103 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 104 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp ) |
|---|
| 105 | IF(lwm) WRITE ( numond, namsbc ) |
|---|
| 106 | |
|---|
| 107 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 108 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 109 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 110 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 111 | IF( lk_cice ) nn_ice = 4 |
|---|
| 112 | ENDIF |
|---|
| 113 | IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration |
|---|
| 114 | ln_ana = .TRUE. |
|---|
| 115 | nn_ice = 0 |
|---|
| 116 | ENDIF |
|---|
| 117 | |
|---|
| 118 | IF(lwp) THEN ! Control print |
|---|
| 119 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 120 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 121 | WRITE(numout,*) ' Type of sbc : ' |
|---|
| 122 | WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana |
|---|
| 123 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 124 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 125 | WRITE(numout,*) ' CORE bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 126 | WRITE(numout,*) ' MFS bulk formulation ln_blk_mfs = ', ln_blk_mfs |
|---|
| 127 | WRITE(numout,*) ' coupled formulation (T if key_sbc_cpl) ln_cpl = ', ln_cpl |
|---|
| 128 | WRITE(numout,*) ' Flux handling over ice categories cn_iceflx = ', TRIM (cn_iceflx) |
|---|
| 129 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 130 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 131 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 132 | WRITE(numout,*) ' ice-ocean embedded/levitating (=0/1/2) nn_ice_embd = ', nn_ice_embd |
|---|
| 133 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 134 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 135 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 136 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 137 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 138 | WRITE(numout,*) ' n. of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 139 | WRITE(numout,*) ' Drag coefficient from wave model ln_cdgw = ', ln_cdgw |
|---|
| 140 | WRITE(numout,*) ' Stokes-Coriolis forcing from wave model ln_stcor = ', ln_stcor |
|---|
| 141 | WRITE(numout,*) ' TKE wave breaking BC from wave model ln_wavetke = ', ln_wavetke |
|---|
| 142 | WRITE(numout,*) ' Wave-modified stress from wave model ln_tauoc = ', ln_tauoc |
|---|
| 143 | ENDIF |
|---|
| 144 | |
|---|
| 145 | ! Flux handling over ice categories |
|---|
| 146 | #if defined key_coupled |
|---|
| 147 | SELECT CASE ( TRIM (cn_iceflx)) |
|---|
| 148 | CASE ('ave') |
|---|
| 149 | ln_iceflx_ave = .TRUE. |
|---|
| 150 | ln_iceflx_linear = .FALSE. |
|---|
| 151 | CASE ('linear') |
|---|
| 152 | ln_iceflx_ave = .FALSE. |
|---|
| 153 | ln_iceflx_linear = .TRUE. |
|---|
| 154 | CASE default |
|---|
| 155 | ln_iceflx_ave = .FALSE. |
|---|
| 156 | ln_iceflx_linear = .FALSE. |
|---|
| 157 | END SELECT |
|---|
| 158 | IF(lwp) WRITE(numout,*) ' Fluxes averaged over all ice categories ln_iceflx_ave = ', ln_iceflx_ave |
|---|
| 159 | IF(lwp) WRITE(numout,*) ' Fluxes distributed linearly over ice categories ln_iceflx_linear = ', ln_iceflx_linear |
|---|
| 160 | #endif |
|---|
| 161 | ! |
|---|
| 162 | #if defined key_top && ! defined key_offline |
|---|
| 163 | ltrcdm2dc = (ln_dm2dc .AND. ln_blk_core .AND. nn_ice==2) |
|---|
| 164 | IF( ltrcdm2dc )THEN |
|---|
| 165 | IF(lwp)THEN |
|---|
| 166 | WRITE(numout,*)"analytical diurnal cycle, core bulk formulation and LIM2 use: " |
|---|
| 167 | WRITE(numout,*)"Diurnal cycle on physics but not in passive tracers" |
|---|
| 168 | ENDIF |
|---|
| 169 | ENDIF |
|---|
| 170 | #else |
|---|
| 171 | ltrcdm2dc = .FALSE. |
|---|
| 172 | #endif |
|---|
| 173 | |
|---|
| 174 | ! |
|---|
| 175 | ! ! allocate sbc arrays |
|---|
| 176 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 177 | |
|---|
| 178 | ! ! Checks: |
|---|
| 179 | IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths |
|---|
| 180 | ln_rnf_mouth = .false. |
|---|
| 181 | IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' ) |
|---|
| 182 | nkrnf = 0 |
|---|
| 183 | rnf (:,:) = 0.0_wp |
|---|
| 184 | rnf_b (:,:) = 0.0_wp |
|---|
| 185 | rnfmsk (:,:) = 0.0_wp |
|---|
| 186 | rnfmsk_z(:) = 0.0_wp |
|---|
| 187 | ENDIF |
|---|
| 188 | IF( nn_ice == 0 ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero |
|---|
| 189 | |
|---|
| 190 | sfx(:,:) = 0.0_wp ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero) |
|---|
| 191 | ! only if sea-ice is present |
|---|
| 192 | |
|---|
| 193 | fmmflx(:,:) = 0.0_wp ! freezing-melting array initialisation |
|---|
| 194 | |
|---|
| 195 | ! ! restartability |
|---|
| 196 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 197 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 198 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 199 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 200 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 201 | ENDIF |
|---|
| 202 | ! |
|---|
| 203 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 204 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 205 | ! |
|---|
| 206 | IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 207 | & CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 208 | IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 209 | & CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' ) |
|---|
| 210 | IF( nn_ice == 4 .AND. lk_agrif ) & |
|---|
| 211 | & CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 212 | IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 ) & |
|---|
| 213 | & CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' ) |
|---|
| 214 | #if defined key_coupled |
|---|
| 215 | IF( ln_iceflx_ave .AND. ln_iceflx_linear ) & |
|---|
| 216 | & CALL ctl_stop( ' ln_iceflx_ave and ln_iceflx_linear options are not compatible' ) |
|---|
| 217 | IF( ( nn_ice ==3 .AND. lk_cpl) .AND. .NOT. ( ln_iceflx_ave .OR. ln_iceflx_linear ) ) & |
|---|
| 218 | & CALL ctl_stop( ' With lim3 coupled, either ln_iceflx_ave or ln_iceflx_linear must be set to .TRUE.' ) |
|---|
| 219 | #endif |
|---|
| 220 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 221 | |
|---|
| 222 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) ) & |
|---|
| 223 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 224 | |
|---|
| 225 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 226 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 227 | |
|---|
| 228 | IF ( ln_wave ) THEN |
|---|
| 229 | !Activated wave module but neither drag nor stokes drift activated |
|---|
| 230 | IF ( .NOT.(ln_cdgw .OR. ln_sdw) ) THEN |
|---|
| 231 | CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' ) |
|---|
| 232 | !drag coefficient read from wave model definable only with mfs bulk formulae and core |
|---|
| 233 | ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) ) THEN |
|---|
| 234 | CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core') |
|---|
| 235 | ENDIF |
|---|
| 236 | ELSE |
|---|
| 237 | IF ( ln_cdgw .OR. ln_sdw ) & |
|---|
| 238 | & CALL ctl_warn('Not Activated Wave Module (ln_wave=F) but & |
|---|
| 239 | & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ') |
|---|
| 240 | ENDIF |
|---|
| 241 | |
|---|
| 242 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 243 | icpt = 0 |
|---|
| 244 | IF( ln_ana ) THEN ; nsbc = 1 ; icpt = icpt + 1 ; ENDIF ! analytical formulation |
|---|
| 245 | IF( ln_flx ) THEN ; nsbc = 2 ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 246 | IF( ln_blk_clio ) THEN ; nsbc = 3 ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 247 | IF( ln_blk_core ) THEN ; nsbc = 4 ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 248 | IF( ln_blk_mfs ) THEN ; nsbc = 6 ; icpt = icpt + 1 ; ENDIF ! MFS bulk formulation |
|---|
| 249 | IF( ln_cpl ) THEN ; nsbc = 5 ; icpt = icpt + 1 ; ENDIF ! Coupled formulation |
|---|
| 250 | IF( cp_cfg == 'gyre') THEN ; nsbc = 0 ; ENDIF ! GYRE analytical formulation |
|---|
| 251 | IF( lk_esopa ) nsbc = -1 ! esopa test, ALL formulations |
|---|
| 252 | ! |
|---|
| 253 | IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN |
|---|
| 254 | WRITE(numout,*) |
|---|
| 255 | WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option ' |
|---|
| 256 | WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)' |
|---|
| 257 | WRITE(numout,*) ' We stop' |
|---|
| 258 | nstop = nstop + 1 |
|---|
| 259 | ENDIF |
|---|
| 260 | IF(lwp) THEN |
|---|
| 261 | WRITE(numout,*) |
|---|
| 262 | IF( nsbc == -1 ) WRITE(numout,*) ' ESOPA test All surface boundary conditions' |
|---|
| 263 | IF( nsbc == 0 ) WRITE(numout,*) ' GYRE analytical formulation' |
|---|
| 264 | IF( nsbc == 1 ) WRITE(numout,*) ' analytical formulation' |
|---|
| 265 | IF( nsbc == 2 ) WRITE(numout,*) ' flux formulation' |
|---|
| 266 | IF( nsbc == 3 ) WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 267 | IF( nsbc == 4 ) WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 268 | IF( nsbc == 5 ) WRITE(numout,*) ' coupled formulation' |
|---|
| 269 | IF( nsbc == 6 ) WRITE(numout,*) ' MFS Bulk formulation' |
|---|
| 270 | ENDIF |
|---|
| 271 | ! |
|---|
| 272 | CALL sbc_ssm_init ! Sea-surface mean fields initialisation |
|---|
| 273 | ! |
|---|
| 274 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialisation |
|---|
| 275 | ! |
|---|
| 276 | IF( nn_ice == 4 ) CALL cice_sbc_init( nsbc ) ! CICE initialisation |
|---|
| 277 | ! |
|---|
| 278 | END SUBROUTINE sbc_init |
|---|
| 279 | |
|---|
| 280 | |
|---|
| 281 | SUBROUTINE sbc( kt ) |
|---|
| 282 | !!--------------------------------------------------------------------- |
|---|
| 283 | !! *** ROUTINE sbc *** |
|---|
| 284 | !! |
|---|
| 285 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 286 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 287 | !! |
|---|
| 288 | !! ** Method : blah blah to be written ????????? |
|---|
| 289 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 290 | !! |
|---|
| 291 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 292 | !! time step, i.e. |
|---|
| 293 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 294 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 295 | !! - updte the ice fraction : fr_i |
|---|
| 296 | !!---------------------------------------------------------------------- |
|---|
| 297 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 298 | !!--------------------------------------------------------------------- |
|---|
| 299 | ! |
|---|
| 300 | IF( nn_timing == 1 ) CALL timing_start('sbc') |
|---|
| 301 | ! |
|---|
| 302 | ! ! ---------------------------------------- ! |
|---|
| 303 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 304 | ! ! ---------------------------------------- ! |
|---|
| 305 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 306 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 307 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 308 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 309 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 310 | emp_b(:,:) = emp(:,:) |
|---|
| 311 | sfx_b(:,:) = sfx(:,:) |
|---|
| 312 | ENDIF |
|---|
| 313 | ! ! ---------------------------------------- ! |
|---|
| 314 | ! ! forcing field computation ! |
|---|
| 315 | ! ! ---------------------------------------- ! |
|---|
| 316 | ! |
|---|
| 317 | IF( ln_apr_dyn ) CALL sbc_apr( kt ) ! atmospheric pressure provided at kt+0.5*nn_fsbc |
|---|
| 318 | ! (caution called before sbc_ssm) |
|---|
| 319 | ! |
|---|
| 320 | CALL sbc_ssm( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 321 | ! ! averaged over nf_sbc time-step |
|---|
| 322 | |
|---|
| 323 | IF (ln_cdgw) CALL sbc_wave_ecmwf( kt ) |
|---|
| 324 | ! Read wave parameters if Stokes-Coriolis forcing OR wave parameters for TKE are needed |
|---|
| 325 | ! Also read it if drag coefficient to ensure that we use the neutral 10m from WAM. |
|---|
| 326 | IF (ln_wavetke .OR. ln_tauoc .OR. ln_cdgw) THEN |
|---|
| 327 | CALL sbc_wavepar( kt ) |
|---|
| 328 | ENDIF |
|---|
| 329 | |
|---|
| 330 | IF (ln_wave) CALL sbc_wave( kt ) |
|---|
| 331 | !== sbc formulation ==! |
|---|
| 332 | |
|---|
| 333 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 334 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 335 | CASE( 0 ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration |
|---|
| 336 | CASE( 1 ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc |
|---|
| 337 | CASE( 2 ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 338 | CASE( 3 ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 339 | CASE( 4 ) ; CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 340 | CASE( 5 ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! coupled formulation |
|---|
| 341 | CASE( 6 ) ; CALL sbc_blk_mfs ( kt ) ! bulk formulation : MFS for the ocean |
|---|
| 342 | CASE( -1 ) |
|---|
| 343 | CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations |
|---|
| 344 | CALL sbc_gyre ( kt ) ! |
|---|
| 345 | CALL sbc_flx ( kt ) ! |
|---|
| 346 | CALL sbc_blk_clio( kt ) ! |
|---|
| 347 | CALL sbc_blk_core( kt ) ! |
|---|
| 348 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! |
|---|
| 349 | END SELECT |
|---|
| 350 | |
|---|
| 351 | ! !== Misc. Options ==! |
|---|
| 352 | |
|---|
| 353 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 354 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 355 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 356 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 357 | !is it useful? |
|---|
| 358 | CASE( 4 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 359 | END SELECT |
|---|
| 360 | |
|---|
| 361 | IF( ln_icebergs ) CALL icb_stp( kt ) ! compute icebergs |
|---|
| 362 | |
|---|
| 363 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 364 | |
|---|
| 365 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 366 | |
|---|
| 367 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 368 | |
|---|
| 369 | IF( nn_closea == 1 ) CALL sbc_clo( kt ) ! treatment of closed sea in the model domain |
|---|
| 370 | ! ! (update freshwater fluxes) |
|---|
| 371 | !RBbug do not understand why see ticket 667 |
|---|
| 372 | !clem-bugsal CALL lbc_lnk( emp, 'T', 1. ) |
|---|
| 373 | ! |
|---|
| 374 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 375 | ! ! ---------------------------------------- ! |
|---|
| 376 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 377 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 378 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 379 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 380 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 381 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 382 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 383 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 384 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b ) ! before freshwater flux (T-point) |
|---|
| 385 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 386 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 387 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b ) ! before salt flux (T-point) |
|---|
| 388 | ELSE |
|---|
| 389 | sfx_b (:,:) = sfx(:,:) |
|---|
| 390 | ENDIF |
|---|
| 391 | ELSE !* no restart: set from nit000 values |
|---|
| 392 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 393 | utau_b(:,:) = utau(:,:) |
|---|
| 394 | vtau_b(:,:) = vtau(:,:) |
|---|
| 395 | qns_b (:,:) = qns (:,:) |
|---|
| 396 | emp_b (:,:) = emp(:,:) |
|---|
| 397 | sfx_b (:,:) = sfx(:,:) |
|---|
| 398 | ENDIF |
|---|
| 399 | ENDIF |
|---|
| 400 | ! ! ---------------------------------------- ! |
|---|
| 401 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 402 | ! ! ---------------------------------------- ! |
|---|
| 403 | IF(lwp) WRITE(numout,*) |
|---|
| 404 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 405 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 406 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 407 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 408 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 409 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 410 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 411 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 412 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 413 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx ) |
|---|
| 414 | ENDIF |
|---|
| 415 | |
|---|
| 416 | ! ! ---------------------------------------- ! |
|---|
| 417 | ! ! Outputs and control print ! |
|---|
| 418 | ! ! ---------------------------------------- ! |
|---|
| 419 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 420 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 421 | CALL iom_put( "saltflx", sfx ) ! downward salt flux |
|---|
| 422 | ! (includes virtual salt flux beneath ice |
|---|
| 423 | ! in linear free surface case) |
|---|
| 424 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 425 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 426 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 427 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 428 | IF( nn_ice > 0 ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 429 | ENDIF |
|---|
| 430 | ! |
|---|
| 431 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 432 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 433 | CALL iom_put( "taum", taum ) ! wind stress module |
|---|
| 434 | CALL iom_put( "wspd", wndm ) ! wind speed module |
|---|
| 435 | ! |
|---|
| 436 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 437 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 438 | CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 439 | CALL prt_ctl(tab2d_1=(sfx-rnf) , clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 440 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 441 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 442 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 443 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 444 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 445 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 446 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 447 | ENDIF |
|---|
| 448 | |
|---|
| 449 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 450 | ! |
|---|
| 451 | IF( nn_timing == 1 ) CALL timing_stop('sbc') |
|---|
| 452 | ! |
|---|
| 453 | END SUBROUTINE sbc |
|---|
| 454 | |
|---|
| 455 | |
|---|
| 456 | SUBROUTINE sbc_final |
|---|
| 457 | !!--------------------------------------------------------------------- |
|---|
| 458 | !! *** ROUTINE sbc_final *** |
|---|
| 459 | !! |
|---|
| 460 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 461 | !!--------------------------------------------------------------------- |
|---|
| 462 | ! |
|---|
| 463 | IF( nn_ice == 4 ) CALL cice_sbc_final |
|---|
| 464 | ! |
|---|
| 465 | END SUBROUTINE sbc_final |
|---|
| 466 | |
|---|
| 467 | !!====================================================================== |
|---|
| 468 | END MODULE sbcmod |
|---|
