New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2014/dev_r4650_UKMO11_restart_functionality/NEMOGCM/NEMO/OFF_SRC – NEMO

source: branches/2014/dev_r4650_UKMO11_restart_functionality/NEMOGCM/NEMO/OFF_SRC/nemogcm.F90 @ 5214

Last change on this file since 5214 was 5214, checked in by davestorkey, 9 years ago

Merge in changes from the trunk up to rev 5107.

File size: 29.8 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            4.0  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   nemo_gcm        : off-line: solve ocean tracer only
12   !!   nemo_init       : initialization of the nemo model
13   !!   nemo_ctl        : initialisation of algorithm flag
14   !!   nemo_closefile  : close remaining files
15   !!----------------------------------------------------------------------
16   USE dom_oce         ! ocean space domain variables
17   USE oce             ! dynamics and tracers variables
18   USE c1d             ! 1D configuration
19   USE domcfg          ! domain configuration               (dom_cfg routine)
20   USE domain          ! domain initialization             (dom_init routine)
21   USE istate          ! initial state setting          (istate_init routine)
22   USE eosbn2          ! equation of state            (eos bn2 routine)
23   !              ! ocean physics
24   USE ldftra          ! lateral diffusivity setting    (ldf_tra_init routine)
25   USE ldfslp          ! slopes of neutral surfaces     (ldf_slp_init routine)
26   USE traqsr          ! solar radiation penetration    (tra_qsr_init routine)
27   USE trabbl          ! bottom boundary layer          (tra_bbl_init routine)
28   USE zdfini          ! vertical physics: initialization
29   USE sbcmod          ! surface boundary condition       (sbc_init     routine)
30   USE phycst          ! physical constant                  (par_cst routine)
31   USE dtadyn          ! Lecture and Interpolation of the dynamical fields
32   USE trcini          ! Initilization of the passive tracers
33   USE daymod          ! calendar                         (day     routine)
34   USE trcstp          ! passive tracer time-stepping      (trc_stp routine)
35   USE dtadyn          ! Lecture and interpolation of the dynamical fields
36   USE stpctl          ! time stepping control            (stp_ctl routine)
37   !              ! I/O & MPP
38   USE iom             ! I/O library
39   USE in_out_manager  ! I/O manager
40   USE mppini          ! shared/distributed memory setting (mpp_init routine)
41   USE lib_mpp         ! distributed memory computing
42#if defined key_iomput
43   USE xios
44#endif
45   USE prtctl          ! Print control                    (prt_ctl_init routine)
46   USE timing          ! Timing
47   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
48   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
49
50   USE trc
51   USE trcnam
52   USE trcrst
53   USE diaptr         ! Need to initialise this as some variables are used in if statements later
54
55   IMPLICIT NONE
56   PRIVATE
57   
58   PUBLIC   nemo_gcm   ! called by nemo.F90
59
60   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
61
62   !!----------------------------------------------------------------------
63   !! NEMO/OFF 3.3 , NEMO Consortium (2010)
64   !! $Id: nemogcm.F90 2528 2010-12-27 17:33:53Z rblod $
65   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
66   !!----------------------------------------------------------------------
67CONTAINS
68
69   SUBROUTINE nemo_gcm
70      !!----------------------------------------------------------------------
71      !!                     ***  ROUTINE nemo_gcm  ***
72      !!
73      !! ** Purpose :   nemo solves the primitive equations on an orthogonal
74      !!      curvilinear mesh on the sphere.
75      !!
76      !! ** Method  : - model general initialization
77      !!              - launch the time-stepping (dta_dyn and trc_stp)
78      !!              - finalize the run by closing files and communications
79      !!
80      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
81      !!              Madec, 2008, internal report, IPSL.
82      !!----------------------------------------------------------------------
83      INTEGER :: istp, indic       ! time step index
84      !!----------------------------------------------------------------------
85
86      CALL nemo_init  ! Initializations
87
88      ! check that all process are still there... If some process have an error,
89      ! they will never enter in step and other processes will wait until the end of the cpu time!
90      IF( lk_mpp )   CALL mpp_max( nstop )
91
92      !                            !-----------------------!
93      !                            !==   time stepping   ==!
94      !                            !-----------------------!
95      istp = nit000
96      !
97      CALL iom_init( "nemo" )            ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
98      !
99      DO WHILE ( istp <= nitend .AND. nstop == 0 )    ! time stepping
100         !
101         IF( istp /= nit000 )   CALL day      ( istp )         ! Calendar (day was already called at nit000 in day_init)
102                                CALL iom_setkt( istp - nit000 + 1, "nemo" )   ! say to iom that we are at time step kstp
103                                CALL dta_dyn  ( istp )         ! Interpolation of the dynamical fields
104                                CALL trc_stp  ( istp )         ! time-stepping
105                                CALL stp_ctl  ( istp, indic )  ! Time loop: control and print
106         istp = istp + 1
107         IF( lk_mpp )   CALL mpp_max( nstop )
108      END DO
109#if defined key_iomput
110      CALL iom_context_finalize( "nemo" ) ! needed for XIOS+AGRIF
111#endif
112
113      !                            !------------------------!
114      !                            !==  finalize the run  ==!
115      !                            !------------------------!
116      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
117
118      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
119         WRITE(numout,cform_err)
120         WRITE(numout,*) nstop, ' error have been found'
121      ENDIF
122      !
123      IF( nn_timing == 1 )   CALL timing_finalize
124      !
125      CALL nemo_closefile
126      !
127# if defined key_iomput
128      CALL xios_finalize             ! end mpp communications
129# else
130      IF( lk_mpp )   CALL mppstop       ! end mpp communications
131# endif
132      !
133   END SUBROUTINE nemo_gcm
134
135
136   SUBROUTINE nemo_init
137      !!----------------------------------------------------------------------
138      !!                     ***  ROUTINE nemo_init ***
139      !!
140      !! ** Purpose :   initialization of the nemo model in off-line mode
141      !!----------------------------------------------------------------------
142      INTEGER ::   ji            ! dummy loop indices
143      INTEGER ::   ilocal_comm   ! local integer
144      INTEGER ::   ios
145      CHARACTER(len=80), DIMENSION(16) ::   cltxt
146      !!
147      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
148         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
149         &             nn_bench, nn_timing
150      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
151         &             jpizoom, jpjzoom, jperio
152      !!----------------------------------------------------------------------
153      cltxt = ''
154      !
155      !                             ! Open reference namelist and configuration namelist files
156      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
157      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
158      !
159      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
160      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
161901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
162
163      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
164      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
165902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
166
167      !
168      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
169      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
170903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
171
172      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
173      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
174904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
175
176      !
177      !                             !--------------------------------------------!
178      !                             !  set communicator & select the local node  !
179      !                             !  NB: mynode also opens output.namelist.dyn !
180      !                             !      on unit number numond on first proc   !
181      !                             !--------------------------------------------!
182#if defined key_iomput
183      CALL  xios_initialize( "nemo",return_comm=ilocal_comm )
184      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
185#else
186      ilocal_comm = 0
187      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
188#endif
189
190      narea = narea + 1                       ! mynode return the rank of proc (0 --> jpnij -1 )
191
192      lwm = (narea == 1)                      ! control of output namelists
193      lwp = (narea == 1) .OR. ln_ctl          ! control of all listing output print
194
195      IF(lwm) THEN
196         ! write merged namelists from earlier to output namelist now that the
197         ! file has been opened in call to mynode. nammpp has already been
198         ! written in mynode (if lk_mpp_mpi)
199         WRITE( numond, namctl )
200         WRITE( numond, namcfg )
201      ENDIF
202
203      ! If dimensions of processor grid weren't specified in the namelist file
204      ! then we calculate them here now that we have our communicator size
205      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
206#if   defined key_mpp_mpi
207         CALL nemo_partition(mppsize)
208#else
209         jpni = 1
210         jpnj = 1
211         jpnij = jpni*jpnj
212#endif
213      END IF
214
215      ! Calculate domain dimensions given calculated jpni and jpnj
216      ! This used to be done in par_oce.F90 when they were parameters rather
217      ! than variables
218      jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
219      jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
220      jpk = jpkdta                                             ! third dim
221      jpim1 = jpi-1                                            ! inner domain indices
222      jpjm1 = jpj-1                                            !   "           "
223      jpkm1 = jpk-1                                            !   "           "
224      jpij  = jpi*jpj                                          !  jpi x j
225
226
227      IF(lwp) THEN                            ! open listing units
228         !
229         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
230         !
231         WRITE(numout,*)
232         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
233         WRITE(numout,*) '                       NEMO team'
234         WRITE(numout,*) '            Ocean General Circulation Model'
235         WRITE(numout,*) '                  version 3.5  (2012) '
236         WRITE(numout,*)
237         WRITE(numout,*)
238         DO ji = 1, SIZE(cltxt) 
239            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
240         END DO
241         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
242         !
243      ENDIF
244
245      ! Now we know the dimensions of the grid and numout has been set we can
246      ! allocate arrays
247      CALL nemo_alloc()
248
249      !                             !--------------------------------!
250      !                             !  Model general initialization  !
251      !                             !--------------------------------!
252
253      CALL nemo_ctl                           ! Control prints & Benchmark
254
255      !                                      ! Domain decomposition
256      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
257      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
258      ENDIF
259      !
260      IF( nn_timing == 1 )  CALL timing_init
261      !
262
263      !                                      ! General initialization
264      IF( nn_timing == 1 )  CALL timing_start( 'nemo_init')
265      !
266                            CALL     phy_cst    ! Physical constants
267                            CALL     eos_init   ! Equation of state
268      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
269                            CALL     dom_cfg    ! Domain configuration
270                            CALL     dom_init   ! Domain
271                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
272
273      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
274
275      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
276
277      !                                     ! Ocean physics
278                            CALL     sbc_init   ! Forcings : surface module
279#if ! defined key_degrad
280                            CALL ldf_tra_init   ! Lateral ocean tracer physics
281#endif
282      IF( lk_ldfslp )       CALL ldf_slp_init   ! slope of lateral mixing
283
284      !                                     ! Active tracers
285                            CALL tra_qsr_init   ! penetrative solar radiation qsr
286      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
287
288                            CALL trc_nam_run  ! Needed to get restart parameters for passive tracers
289      IF( ln_rsttr ) THEN
290        neuler = 1   ! Set time-step indicator at nit000 (leap-frog)
291        CALL trc_rst_cal( nit000, 'READ' )   ! calendar
292      ELSE
293        neuler = 0                  ! Set time-step indicator at nit000 (euler)
294        CALL day_init               ! set calendar
295      ENDIF
296      !                                     ! Dynamics
297                            CALL dta_dyn_init   ! Initialization for the dynamics
298
299      !                                     ! Passive tracers
300                            CALL     trc_init   ! Passive tracers initialization
301      !
302      ! Initialise diaptr as some variables are used in if statements later (in
303      ! various advection and diffusion routines.
304                            CALL dia_ptr_init
305      !
306      IF(lwp) WRITE(numout,cform_aaa)       ! Flag AAAAAAA
307      !
308      IF( nn_timing == 1 )  CALL timing_stop( 'nemo_init')
309      !
310   END SUBROUTINE nemo_init
311
312
313   SUBROUTINE nemo_ctl
314      !!----------------------------------------------------------------------
315      !!                     ***  ROUTINE nemo_ctl  ***
316      !!
317      !! ** Purpose :   control print setting
318      !!
319      !! ** Method  : - print namctl information and check some consistencies
320      !!----------------------------------------------------------------------
321      !
322      IF(lwp) THEN                  ! Parameter print
323         WRITE(numout,*)
324         WRITE(numout,*) 'nemo_flg: Control prints & Benchmark'
325         WRITE(numout,*) '~~~~~~~ '
326         WRITE(numout,*) '   Namelist namctl'
327         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
328         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
329         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
330         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
331         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
332         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
333         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
334         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
335         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
336      ENDIF
337      !
338      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
339      nictls    = nn_ictls
340      nictle    = nn_ictle
341      njctls    = nn_jctls
342      njctle    = nn_jctle
343      isplt     = nn_isplt
344      jsplt     = nn_jsplt
345      nbench    = nn_bench
346     IF(lwp) THEN                  ! control print
347         WRITE(numout,*)
348         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
349         WRITE(numout,*) '~~~~~~~ '
350         WRITE(numout,*) '   Namelist namcfg'
351         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
352         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
353         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
354         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
355         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
356         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
357         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
358         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
359         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
360         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
361      ENDIF
362      !                             ! Parameter control
363      !
364      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
365         IF( lk_mpp ) THEN
366            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real splitted domain
367         ELSE
368            IF( isplt == 1 .AND. jsplt == 1  ) THEN
369               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
370                  &           ' - the print control will be done over the whole domain' )
371            ENDIF
372            ijsplt = isplt * jsplt            ! total number of processors ijsplt
373         ENDIF
374         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
375         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
376         !
377         !                              ! indices used for the SUM control
378         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
379            lsp_area = .FALSE.
380         ELSE                                             ! print control done over a specific  area
381            lsp_area = .TRUE.
382            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
383               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
384               nictls = 1
385            ENDIF
386            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
387               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
388               nictle = jpiglo
389            ENDIF
390            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
391               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
392               njctls = 1
393            ENDIF
394            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
395               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
396               njctle = jpjglo
397            ENDIF
398         ENDIF
399      ENDIF
400      !
401      IF( nbench == 1 )   THEN            ! Benchmark
402         SELECT CASE ( cp_cfg )
403         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
404         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
405            &                                 ' cp_cfg="gyre" in namelsit &namcfg or set nbench = 0' )
406         END SELECT
407      ENDIF
408      !
409      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
410         &                                               'with the IOM Input/Output manager. '        ,   &
411         &                                               'Compile with key_iomput enabled' )
412      !
413      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
414         &                                               'f2003 standard. '                              ,  &
415         &                                               'Compile with key_nosignedzero enabled' )
416      !
417   END SUBROUTINE nemo_ctl
418
419
420   SUBROUTINE nemo_closefile
421      !!----------------------------------------------------------------------
422      !!                     ***  ROUTINE nemo_closefile  ***
423      !!
424      !! ** Purpose :   Close the files
425      !!----------------------------------------------------------------------
426      !
427      IF ( lk_mpp ) CALL mppsync
428      !
429      CALL iom_close                                 ! close all input/output files managed by iom_*
430      !
431      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
432      IF( numnam_ref /= -1 )   CLOSE( numnam_ref )   ! oce reference namelist
433      IF( numnam_cfg /= -1 )   CLOSE( numnam_cfg )   ! oce configuration namelist
434      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
435      numout = 6                                     ! redefine numout in case it is used after this point...
436      !
437   END SUBROUTINE nemo_closefile
438
439
440   SUBROUTINE nemo_alloc
441      !!----------------------------------------------------------------------
442      !!                     ***  ROUTINE nemo_alloc  ***
443      !!
444      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
445      !!
446      !! ** Method  :
447      !!----------------------------------------------------------------------
448      USE diawri,       ONLY: dia_wri_alloc
449      USE dom_oce,      ONLY: dom_oce_alloc
450      USE zdf_oce,      ONLY: zdf_oce_alloc
451      USE ldftra_oce,   ONLY: ldftra_oce_alloc
452      USE trc_oce,      ONLY: trc_oce_alloc
453      !
454      INTEGER :: ierr
455      !!----------------------------------------------------------------------
456      !
457      ierr =        oce_alloc       ()          ! ocean
458      ierr = ierr + dia_wri_alloc   ()
459      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
460      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
461      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
462      !
463      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
464      !
465      IF( lk_mpp    )   CALL mpp_sum( ierr )
466      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
467      !
468   END SUBROUTINE nemo_alloc
469
470
471   SUBROUTINE nemo_partition( num_pes )
472      !!----------------------------------------------------------------------
473      !!                 ***  ROUTINE nemo_partition  ***
474      !!
475      !! ** Purpose :   
476      !!
477      !! ** Method  :
478      !!----------------------------------------------------------------------
479      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
480      !
481      INTEGER, PARAMETER :: nfactmax = 20
482      INTEGER :: nfact ! The no. of factors returned
483      INTEGER :: ierr  ! Error flag
484      INTEGER :: ji
485      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
486      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
487      !!----------------------------------------------------------------------
488
489      ierr = 0
490
491      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
492
493      IF( nfact <= 1 ) THEN
494         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
495         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
496         jpnj = 1
497         jpni = num_pes
498      ELSE
499         ! Search through factors for the pair that are closest in value
500         mindiff = 1000000
501         imin    = 1
502         DO ji = 1, nfact-1, 2
503            idiff = ABS( ifact(ji) - ifact(ji+1) )
504            IF( idiff < mindiff ) THEN
505               mindiff = idiff
506               imin = ji
507            ENDIF
508         END DO
509         jpnj = ifact(imin)
510         jpni = ifact(imin + 1)
511      ENDIF
512      !
513      jpnij = jpni*jpnj
514      !
515   END SUBROUTINE nemo_partition
516
517
518   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
519      !!----------------------------------------------------------------------
520      !!                     ***  ROUTINE factorise  ***
521      !!
522      !! ** Purpose :   return the prime factors of n.
523      !!                knfax factors are returned in array kfax which is of
524      !!                maximum dimension kmaxfax.
525      !! ** Method  :
526      !!----------------------------------------------------------------------
527      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
528      INTEGER                    , INTENT(  out) ::   kerr, knfax
529      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
530      !
531      INTEGER :: ifac, jl, inu
532      INTEGER, PARAMETER :: ntest = 14
533      INTEGER :: ilfax(ntest)
534      !
535      ! lfax contains the set of allowed factors.
536      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
537         &                            128,   64,   32,   16,    8,   4,   2  /
538      !!----------------------------------------------------------------------
539
540      ! Clear the error flag and initialise output vars
541      kerr = 0
542      kfax = 1
543      knfax = 0
544
545      ! Find the factors of n.
546      IF( kn == 1 )   GOTO 20
547
548      ! nu holds the unfactorised part of the number.
549      ! knfax holds the number of factors found.
550      ! l points to the allowed factor list.
551      ! ifac holds the current factor.
552
553      inu   = kn
554      knfax = 0
555
556      DO jl = ntest, 1, -1
557         !
558         ifac = ilfax(jl)
559         IF( ifac > inu )   CYCLE
560
561         ! Test whether the factor will divide.
562
563         IF( MOD(inu,ifac) == 0 ) THEN
564            !
565            knfax = knfax + 1            ! Add the factor to the list
566            IF( knfax > kmaxfax ) THEN
567               kerr = 6
568               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
569               return
570            ENDIF
571            kfax(knfax) = ifac
572            ! Store the other factor that goes with this one
573            knfax = knfax + 1
574            kfax(knfax) = inu / ifac
575            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
576         ENDIF
577         !
578      END DO
579
580   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
581      !
582   END SUBROUTINE factorise
583
584#if defined key_mpp_mpi
585   SUBROUTINE nemo_northcomms
586      !!======================================================================
587      !!                     ***  ROUTINE  nemo_northcomms  ***
588      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
589      !!                       point-to-point messaging
590      !!=====================================================================
591      !!----------------------------------------------------------------------
592      !!
593      !! ** Purpose :   Initialization of the northern neighbours lists.
594      !!----------------------------------------------------------------------
595      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
596      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S.
597      !Mocavero, CMCC)
598      !!----------------------------------------------------------------------
599
600      INTEGER  ::   sxM, dxM, sxT, dxT, jn
601      INTEGER  ::   njmppmax
602
603      njmppmax = MAXVAL( njmppt )
604
605      !initializes the north-fold communication variables
606      isendto(:) = 0
607      nsndto = 0
608
609      !if I am a process in the north
610      IF ( njmpp == njmppmax ) THEN
611          !sxM is the first point (in the global domain) needed to compute the
612          !north-fold for the current process
613          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
614          !dxM is the last point (in the global domain) needed to compute the
615          !north-fold for the current process
616          dxM = jpiglo - nimppt(narea) + 2
617
618          !loop over the other north-fold processes to find the processes
619          !managing the points belonging to the sxT-dxT range
620
621          DO jn = 1, jpni
622                !sxT is the first point (in the global domain) of the jn
623                !process
624                sxT = nfiimpp(jn, jpnj)
625                !dxT is the last point (in the global domain) of the jn
626                !process
627                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
628                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
629                   nsndto = nsndto + 1
630                     isendto(nsndto) = jn
631                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
632                   nsndto = nsndto + 1
633                     isendto(nsndto) = jn
634                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
635                   nsndto = nsndto + 1
636                     isendto(nsndto) = jn
637                END IF
638          END DO
639          nfsloop = 1
640          nfeloop = nlci
641          DO jn = 2,jpni-1
642           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
643              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
644                 nfsloop = nldi
645              ENDIF
646              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
647                 nfeloop = nlei
648              ENDIF
649           ENDIF
650        END DO
651
652      ENDIF
653      l_north_nogather = .TRUE.
654   END SUBROUTINE nemo_northcomms
655#else
656   SUBROUTINE nemo_northcomms      ! Dummy routine
657      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
658   END SUBROUTINE nemo_northcomms
659#endif
660   !!======================================================================
661END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.