1 | MODULE istate |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE istate *** |
---|
4 | !! Ocean state : initial state setting |
---|
5 | !!===================================================================== |
---|
6 | !! History : OPA ! 1989-12 (P. Andrich) Original code |
---|
7 | !! 5.0 ! 1991-11 (G. Madec) rewritting |
---|
8 | !! 6.0 ! 1996-01 (G. Madec) terrain following coordinates |
---|
9 | !! 8.0 ! 2001-09 (M. Levy, M. Ben Jelloul) istate_eel |
---|
10 | !! 8.0 ! 2001-09 (M. Levy, M. Ben Jelloul) istate_uvg |
---|
11 | !! NEMO 1.0 ! 2003-08 (G. Madec, C. Talandier) F90: Free form, modules + EEL R5 |
---|
12 | !! - ! 2004-05 (A. Koch-Larrouy) istate_gyre |
---|
13 | !! 2.0 ! 2006-07 (S. Masson) distributed restart using iom |
---|
14 | !! 3.3 ! 2010-10 (C. Ethe) merge TRC-TRA |
---|
15 | !! 3.4 ! 2011-04 (G. Madec) Merge of dtatem and dtasal & suppression of tb,tn/sb,sn |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | |
---|
18 | !!---------------------------------------------------------------------- |
---|
19 | !! istate_init : initial state setting |
---|
20 | !! istate_tem : analytical profile for initial Temperature |
---|
21 | !! istate_sal : analytical profile for initial Salinity |
---|
22 | !! istate_eel : initial state setting of EEL R5 configuration |
---|
23 | !! istate_gyre : initial state setting of GYRE configuration |
---|
24 | !! istate_uvg : initial velocity in geostropic balance |
---|
25 | !!---------------------------------------------------------------------- |
---|
26 | USE oce ! ocean dynamics and active tracers |
---|
27 | USE dom_oce ! ocean space and time domain |
---|
28 | USE c1d ! 1D vertical configuration |
---|
29 | USE daymod ! calendar |
---|
30 | USE eosbn2 ! eq. of state, Brunt Vaisala frequency (eos routine) |
---|
31 | USE ldftra_oce ! ocean active tracers: lateral physics |
---|
32 | USE zdf_oce ! ocean vertical physics |
---|
33 | USE phycst ! physical constants |
---|
34 | USE dtatsd ! data temperature and salinity (dta_tsd routine) |
---|
35 | USE dtauvd ! data: U & V current (dta_uvd routine) |
---|
36 | USE in_out_manager ! I/O manager |
---|
37 | USE iom ! I/O library |
---|
38 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
---|
39 | USE eosbn2 ! equation of state (eos bn2 routine) |
---|
40 | USE domvvl ! varying vertical mesh |
---|
41 | USE dynspg_oce ! pressure gradient schemes |
---|
42 | USE dynspg_flt ! filtered free surface |
---|
43 | USE sol_oce ! ocean solver variables |
---|
44 | USE lib_mpp ! MPP library |
---|
45 | USE restart ! restart |
---|
46 | USE wrk_nemo ! Memory allocation |
---|
47 | USE timing ! Timing |
---|
48 | |
---|
49 | IMPLICIT NONE |
---|
50 | PRIVATE |
---|
51 | |
---|
52 | PUBLIC istate_init ! routine called by step.F90 |
---|
53 | |
---|
54 | !! * Substitutions |
---|
55 | # include "domzgr_substitute.h90" |
---|
56 | # include "vectopt_loop_substitute.h90" |
---|
57 | !!---------------------------------------------------------------------- |
---|
58 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
59 | !! $Id$ |
---|
60 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
61 | !!---------------------------------------------------------------------- |
---|
62 | CONTAINS |
---|
63 | |
---|
64 | SUBROUTINE istate_init |
---|
65 | !!---------------------------------------------------------------------- |
---|
66 | !! *** ROUTINE istate_init *** |
---|
67 | !! |
---|
68 | !! ** Purpose : Initialization of the dynamics and tracer fields. |
---|
69 | !!---------------------------------------------------------------------- |
---|
70 | ! - ML - needed for initialization of e3t_b |
---|
71 | INTEGER :: ji,jj,jk ! dummy loop indices |
---|
72 | REAL(wp), POINTER, DIMENSION(:,:,:,:) :: zuvd ! U & V data workspace |
---|
73 | !!---------------------------------------------------------------------- |
---|
74 | ! |
---|
75 | IF( nn_timing == 1 ) CALL timing_start('istate_init') |
---|
76 | ! |
---|
77 | |
---|
78 | IF(lwp) WRITE(numout,*) ' ' |
---|
79 | IF(lwp) WRITE(numout,*) 'istate_ini : Initialization of the dynamics and tracers' |
---|
80 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
81 | |
---|
82 | CALL dta_tsd_init ! Initialisation of T & S input data |
---|
83 | IF( lk_c1d ) CALL dta_uvd_init ! Initialization of U & V input data |
---|
84 | |
---|
85 | rhd (:,:,: ) = 0.e0 |
---|
86 | rhop (:,:,: ) = 0.e0 |
---|
87 | rn2 (:,:,: ) = 0.e0 |
---|
88 | tsa (:,:,:,:) = 0.e0 |
---|
89 | |
---|
90 | IF( ln_rstart ) THEN ! Restart from a file |
---|
91 | ! ! ------------------- |
---|
92 | CALL rst_read ! Read the restart file |
---|
93 | CALL day_init ! model calendar (using both namelist and restart infos) |
---|
94 | ELSE |
---|
95 | ! ! Start from rest |
---|
96 | ! ! --------------- |
---|
97 | numror = 0 ! define numror = 0 -> no restart file to read |
---|
98 | neuler = 0 ! Set time-step indicator at nit000 (euler forward) |
---|
99 | CALL day_init ! model calendar (using both namelist and restart infos) |
---|
100 | ! ! Initialization of ocean to zero |
---|
101 | ! before fields ! now fields |
---|
102 | sshb (:,:) = 0._wp ; sshn (:,:) = 0._wp |
---|
103 | ub (:,:,:) = 0._wp ; un (:,:,:) = 0._wp |
---|
104 | vb (:,:,:) = 0._wp ; vn (:,:,:) = 0._wp |
---|
105 | rotb (:,:,:) = 0._wp ; rotn (:,:,:) = 0._wp |
---|
106 | hdivb(:,:,:) = 0._wp ; hdivn(:,:,:) = 0._wp |
---|
107 | ! |
---|
108 | IF( cp_cfg == 'eel' ) THEN |
---|
109 | CALL istate_eel ! EEL configuration : start from pre-defined U,V T-S fields |
---|
110 | ELSEIF( cp_cfg == 'gyre' ) THEN |
---|
111 | CALL istate_gyre ! GYRE configuration : start from pre-defined T-S fields |
---|
112 | ELSEIF( cp_cfg == 'isomip' .OR. cp_cfg == 'isomip2') THEN |
---|
113 | IF(lwp) WRITE(numout,*) 'Initialization of T+S for ISOMIP domain' |
---|
114 | tsn(:,:,:,jp_tem)=-1.9*tmask(:,:,:) ! ISOMIP configuration : start from constant T+S fields |
---|
115 | tsn(:,:,:,jp_sal)=34.4*tmask(:,:,:) |
---|
116 | tsb(:,:,:,:)=tsn(:,:,:,:) |
---|
117 | ELSE ! Initial T-S, U-V fields read in files |
---|
118 | IF ( ln_tsd_init ) THEN ! read 3D T and S data at nit000 |
---|
119 | CALL dta_tsd( nit000, tsb ) |
---|
120 | tsn(:,:,:,:) = tsb(:,:,:,:) |
---|
121 | ! |
---|
122 | ELSE ! Initial T-S fields defined analytically |
---|
123 | CALL istate_t_s |
---|
124 | ENDIF |
---|
125 | IF ( ln_uvd_init .AND. lk_c1d ) THEN ! read 3D U and V data at nit000 |
---|
126 | CALL wrk_alloc( jpi, jpj, jpk, 2, zuvd ) |
---|
127 | CALL dta_uvd( nit000, zuvd ) |
---|
128 | ub(:,:,:) = zuvd(:,:,:,1) ; un(:,:,:) = ub(:,:,:) |
---|
129 | vb(:,:,:) = zuvd(:,:,:,2) ; vn(:,:,:) = vb(:,:,:) |
---|
130 | CALL wrk_dealloc( jpi, jpj, jpk, 2, zuvd ) |
---|
131 | ENDIF |
---|
132 | ENDIF |
---|
133 | ! |
---|
134 | CALL eos( tsb, rhd, rhop, gdept_0(:,:,:) ) ! before potential and in situ densities |
---|
135 | #if ! defined key_c1d |
---|
136 | IF( ln_zps ) CALL zps_hde( nit000, jpts, tsb, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
---|
137 | & rhd, gru , grv, aru, arv, gzu, gzv, ge3ru, ge3rv, & ! |
---|
138 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
---|
139 | #endif |
---|
140 | ! |
---|
141 | ! - ML - sshn could be modified by istate_eel, so that initialization of fse3t_b is done here |
---|
142 | IF( lk_vvl ) THEN |
---|
143 | DO jk = 1, jpk |
---|
144 | fse3t_b(:,:,jk) = fse3t_n(:,:,jk) |
---|
145 | ENDDO |
---|
146 | ENDIF |
---|
147 | ! |
---|
148 | ENDIF |
---|
149 | ! |
---|
150 | IF( lk_agrif ) THEN ! read free surface arrays in restart file |
---|
151 | IF( ln_rstart ) THEN |
---|
152 | IF( lk_dynspg_flt ) THEN ! read or initialize the following fields |
---|
153 | ! ! gcx, gcxb for agrif_opa_init |
---|
154 | IF( sol_oce_alloc() > 0 ) CALL ctl_stop('agrif sol_oce_alloc: allocation of arrays failed') |
---|
155 | CALL flt_rst( nit000, 'READ' ) |
---|
156 | ENDIF |
---|
157 | ENDIF ! explicit case not coded yet with AGRIF |
---|
158 | ENDIF |
---|
159 | ! |
---|
160 | ! |
---|
161 | ! Initialize "now" and "before" barotropic velocities: |
---|
162 | ! Do it whatever the free surface method, these arrays |
---|
163 | ! being eventually used |
---|
164 | ! |
---|
165 | ! |
---|
166 | un_b(:,:) = 0._wp ; vn_b(:,:) = 0._wp |
---|
167 | ub_b(:,:) = 0._wp ; vb_b(:,:) = 0._wp |
---|
168 | ! |
---|
169 | DO jk = 1, jpkm1 |
---|
170 | #if defined key_vectopt_loop |
---|
171 | DO jj = 1, 1 !Vector opt. => forced unrolling |
---|
172 | DO ji = 1, jpij |
---|
173 | #else |
---|
174 | DO jj = 1, jpj |
---|
175 | DO ji = 1, jpi |
---|
176 | #endif |
---|
177 | un_b(ji,jj) = un_b(ji,jj) + fse3u_n(ji,jj,jk) * un(ji,jj,jk) * umask(ji,jj,jk) |
---|
178 | vn_b(ji,jj) = vn_b(ji,jj) + fse3v_n(ji,jj,jk) * vn(ji,jj,jk) * vmask(ji,jj,jk) |
---|
179 | ! |
---|
180 | ub_b(ji,jj) = ub_b(ji,jj) + fse3u_b(ji,jj,jk) * ub(ji,jj,jk) * umask(ji,jj,jk) |
---|
181 | vb_b(ji,jj) = vb_b(ji,jj) + fse3v_b(ji,jj,jk) * vb(ji,jj,jk) * vmask(ji,jj,jk) |
---|
182 | END DO |
---|
183 | END DO |
---|
184 | END DO |
---|
185 | ! |
---|
186 | un_b(:,:) = un_b(:,:) * hur (:,:) |
---|
187 | vn_b(:,:) = vn_b(:,:) * hvr (:,:) |
---|
188 | ! |
---|
189 | ub_b(:,:) = ub_b(:,:) * hur_b(:,:) |
---|
190 | vb_b(:,:) = vb_b(:,:) * hvr_b(:,:) |
---|
191 | ! |
---|
192 | ! |
---|
193 | IF( nn_timing == 1 ) CALL timing_stop('istate_init') |
---|
194 | ! |
---|
195 | END SUBROUTINE istate_init |
---|
196 | |
---|
197 | SUBROUTINE istate_t_s |
---|
198 | !!--------------------------------------------------------------------- |
---|
199 | !! *** ROUTINE istate_t_s *** |
---|
200 | !! |
---|
201 | !! ** Purpose : Intialization of the temperature field with an |
---|
202 | !! analytical profile or a file (i.e. in EEL configuration) |
---|
203 | !! |
---|
204 | !! ** Method : - temperature: use Philander analytic profile |
---|
205 | !! - salinity : use to a constant value 35.5 |
---|
206 | !! |
---|
207 | !! References : Philander ??? |
---|
208 | !!---------------------------------------------------------------------- |
---|
209 | INTEGER :: ji, jj, jk |
---|
210 | REAL(wp) :: zsal = 35.50 |
---|
211 | !!---------------------------------------------------------------------- |
---|
212 | ! |
---|
213 | IF(lwp) WRITE(numout,*) |
---|
214 | IF(lwp) WRITE(numout,*) 'istate_t_s : Philander s initial temperature profile' |
---|
215 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~ and constant salinity (',zsal,' psu)' |
---|
216 | ! |
---|
217 | DO jk = 1, jpk |
---|
218 | tsn(:,:,jk,jp_tem) = ( ( ( 7.5 - 0. * ABS( gphit(:,:) )/30. ) * ( 1.-TANH((fsdept(:,:,jk)-80.)/30.) ) & |
---|
219 | & + 10. * ( 5000. - fsdept(:,:,jk) ) /5000.) ) * tmask(:,:,jk) |
---|
220 | tsb(:,:,jk,jp_tem) = tsn(:,:,jk,jp_tem) |
---|
221 | END DO |
---|
222 | tsn(:,:,:,jp_sal) = zsal * tmask(:,:,:) |
---|
223 | tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal) |
---|
224 | ! |
---|
225 | END SUBROUTINE istate_t_s |
---|
226 | |
---|
227 | SUBROUTINE istate_eel |
---|
228 | !!---------------------------------------------------------------------- |
---|
229 | !! *** ROUTINE istate_eel *** |
---|
230 | !! |
---|
231 | !! ** Purpose : Initialization of the dynamics and tracers for EEL R5 |
---|
232 | !! configuration (channel with or without a topographic bump) |
---|
233 | !! |
---|
234 | !! ** Method : - set temprature field |
---|
235 | !! - set salinity field |
---|
236 | !! - set velocity field including horizontal divergence |
---|
237 | !! and relative vorticity fields |
---|
238 | !!---------------------------------------------------------------------- |
---|
239 | USE divcur ! hor. divergence & rel. vorticity (div_cur routine) |
---|
240 | USE iom |
---|
241 | |
---|
242 | INTEGER :: inum ! temporary logical unit |
---|
243 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
244 | INTEGER :: ijloc |
---|
245 | REAL(wp) :: zh1, zh2, zslope, zcst, zfcor ! temporary scalars |
---|
246 | REAL(wp) :: zt1 = 15._wp ! surface temperature value (EEL R5) |
---|
247 | REAL(wp) :: zt2 = 5._wp ! bottom temperature value (EEL R5) |
---|
248 | REAL(wp) :: zsal = 35.0_wp ! constant salinity (EEL R2, R5 and R6) |
---|
249 | REAL(wp) :: zueel = 0.1_wp ! constant uniform zonal velocity (EEL R5) |
---|
250 | REAL(wp), DIMENSION(jpiglo,jpjglo) :: zssh ! initial ssh over the global domain |
---|
251 | !!---------------------------------------------------------------------- |
---|
252 | |
---|
253 | SELECT CASE ( jp_cfg ) |
---|
254 | ! ! ==================== |
---|
255 | CASE ( 5 ) ! EEL R5 configuration |
---|
256 | ! ! ==================== |
---|
257 | ! |
---|
258 | ! set temperature field with a linear profile |
---|
259 | ! ------------------------------------------- |
---|
260 | IF(lwp) WRITE(numout,*) |
---|
261 | IF(lwp) WRITE(numout,*) 'istate_eel : EEL R5: linear temperature profile' |
---|
262 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
263 | ! |
---|
264 | zh1 = gdept_1d( 1 ) |
---|
265 | zh2 = gdept_1d(jpkm1) |
---|
266 | ! |
---|
267 | zslope = ( zt1 - zt2 ) / ( zh1 - zh2 ) |
---|
268 | zcst = ( zt1 * ( zh1 - zh2) - ( zt1 - zt2 ) * zh1 ) / ( zh1 - zh2 ) |
---|
269 | ! |
---|
270 | DO jk = 1, jpk |
---|
271 | tsn(:,:,jk,jp_tem) = ( zt2 + zt1 * exp( - fsdept(:,:,jk) / 1000 ) ) * tmask(:,:,jk) |
---|
272 | tsb(:,:,jk,jp_tem) = tsn(:,:,jk,jp_tem) |
---|
273 | END DO |
---|
274 | ! |
---|
275 | IF(lwp) CALL prizre( tsn(:,:,:,jp_tem), jpi , jpj , jpk , jpj/2 , & |
---|
276 | & 1 , jpi , 5 , 1 , jpk , & |
---|
277 | & 1 , 1. , numout ) |
---|
278 | ! |
---|
279 | ! set salinity field to a constant value |
---|
280 | ! -------------------------------------- |
---|
281 | IF(lwp) WRITE(numout,*) |
---|
282 | IF(lwp) WRITE(numout,*) 'istate_eel : EEL R5: constant salinity field, S = ', zsal |
---|
283 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
284 | ! |
---|
285 | tsn(:,:,:,jp_sal) = zsal * tmask(:,:,:) |
---|
286 | tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal) |
---|
287 | ! |
---|
288 | ! set the dynamics: U,V, hdiv, rot (and ssh if necessary) |
---|
289 | ! ---------------- |
---|
290 | ! Start EEL5 configuration with barotropic geostrophic velocities |
---|
291 | ! according the sshb and sshn SSH imposed. |
---|
292 | ! we assume a uniform grid (hence the use of e1t(1,1) for delta_y) |
---|
293 | ! we use the Coriolis frequency at mid-channel. |
---|
294 | ub(:,:,:) = zueel * umask(:,:,:) |
---|
295 | un(:,:,:) = ub(:,:,:) |
---|
296 | ijloc = mj0(INT(jpjglo-1)/2) |
---|
297 | zfcor = ff(1,ijloc) |
---|
298 | ! |
---|
299 | DO jj = 1, jpjglo |
---|
300 | zssh(:,jj) = - (FLOAT(jj)- FLOAT(jpjglo-1)/2.)*zueel*e1t(1,1)*zfcor/grav |
---|
301 | END DO |
---|
302 | ! |
---|
303 | IF(lwp) THEN |
---|
304 | WRITE(numout,*) ' Uniform zonal velocity for EEL R5:',zueel |
---|
305 | WRITE(numout,*) ' Geostrophic SSH profile as a function of y:' |
---|
306 | WRITE(numout,'(12(1x,f6.2))') zssh(1,:) |
---|
307 | ENDIF |
---|
308 | ! |
---|
309 | DO jj = 1, nlcj |
---|
310 | DO ji = 1, nlci |
---|
311 | sshb(ji,jj) = zssh( mig(ji) , mjg(jj) ) * tmask(ji,jj,1) |
---|
312 | END DO |
---|
313 | END DO |
---|
314 | sshb(nlci+1:jpi, : ) = 0.e0 ! set to zero extra mpp columns |
---|
315 | sshb( : ,nlcj+1:jpj) = 0.e0 ! set to zero extra mpp rows |
---|
316 | ! |
---|
317 | sshn(:,:) = sshb(:,:) ! set now ssh to the before value |
---|
318 | ! |
---|
319 | IF( nn_rstssh /= 0 ) THEN |
---|
320 | nn_rstssh = 0 ! hand-made initilization of ssh |
---|
321 | CALL ctl_warn( 'istate_eel: force nn_rstssh = 0' ) |
---|
322 | ENDIF |
---|
323 | ! |
---|
324 | CALL div_cur( nit000 ) ! horizontal divergence and relative vorticity (curl) |
---|
325 | ! N.B. the vertical velocity will be computed from the horizontal divergence field |
---|
326 | ! in istate by a call to wzv routine |
---|
327 | |
---|
328 | |
---|
329 | ! ! ========================== |
---|
330 | CASE ( 2 , 6 ) ! EEL R2 or R6 configuration |
---|
331 | ! ! ========================== |
---|
332 | ! |
---|
333 | ! set temperature field with a NetCDF file |
---|
334 | ! ---------------------------------------- |
---|
335 | IF(lwp) WRITE(numout,*) |
---|
336 | IF(lwp) WRITE(numout,*) 'istate_eel : EEL R2 or R6: read initial temperature in a NetCDF file' |
---|
337 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
338 | ! |
---|
339 | CALL iom_open ( 'eel.initemp', inum ) |
---|
340 | CALL iom_get ( inum, jpdom_data, 'initemp', tsb(:,:,:,jp_tem) ) ! read before temprature (tb) |
---|
341 | CALL iom_close( inum ) |
---|
342 | ! |
---|
343 | tsn(:,:,:,jp_tem) = tsb(:,:,:,jp_tem) ! set nox temperature to tb |
---|
344 | ! |
---|
345 | IF(lwp) CALL prizre( tsn(:,:,:,jp_tem), jpi , jpj , jpk , jpj/2 , & |
---|
346 | & 1 , jpi , 5 , 1 , jpk , & |
---|
347 | & 1 , 1. , numout ) |
---|
348 | ! |
---|
349 | ! set salinity field to a constant value |
---|
350 | ! -------------------------------------- |
---|
351 | IF(lwp) WRITE(numout,*) |
---|
352 | IF(lwp) WRITE(numout,*) 'istate_eel : EEL R5: constant salinity field, S = ', zsal |
---|
353 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
354 | ! |
---|
355 | tsn(:,:,:,jp_sal) = zsal * tmask(:,:,:) |
---|
356 | tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal) |
---|
357 | ! |
---|
358 | ! ! =========================== |
---|
359 | CASE DEFAULT ! NONE existing configuration |
---|
360 | ! ! =========================== |
---|
361 | WRITE(ctmp1,*) 'EEL with a ', jp_cfg,' km resolution is not coded' |
---|
362 | CALL ctl_stop( ctmp1 ) |
---|
363 | ! |
---|
364 | END SELECT |
---|
365 | ! |
---|
366 | END SUBROUTINE istate_eel |
---|
367 | |
---|
368 | |
---|
369 | SUBROUTINE istate_gyre |
---|
370 | !!---------------------------------------------------------------------- |
---|
371 | !! *** ROUTINE istate_gyre *** |
---|
372 | !! |
---|
373 | !! ** Purpose : Initialization of the dynamics and tracers for GYRE |
---|
374 | !! configuration (double gyre with rotated domain) |
---|
375 | !! |
---|
376 | !! ** Method : - set temprature field |
---|
377 | !! - set salinity field |
---|
378 | !!---------------------------------------------------------------------- |
---|
379 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
380 | INTEGER :: inum ! temporary logical unit |
---|
381 | INTEGER, PARAMETER :: ntsinit = 0 ! (0/1) (analytical/input data files) T&S initialization |
---|
382 | !!---------------------------------------------------------------------- |
---|
383 | |
---|
384 | SELECT CASE ( ntsinit) |
---|
385 | |
---|
386 | CASE ( 0 ) ! analytical T/S profil deduced from LEVITUS |
---|
387 | IF(lwp) WRITE(numout,*) |
---|
388 | IF(lwp) WRITE(numout,*) 'istate_gyre : initial analytical T and S profil deduced from LEVITUS ' |
---|
389 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' |
---|
390 | |
---|
391 | DO jk = 1, jpk |
---|
392 | DO jj = 1, jpj |
---|
393 | DO ji = 1, jpi |
---|
394 | tsn(ji,jj,jk,jp_tem) = ( 16. - 12. * TANH( (fsdept(ji,jj,jk) - 400) / 700 ) ) & |
---|
395 | & * (-TANH( (500-fsdept(ji,jj,jk)) / 150 ) + 1) / 2 & |
---|
396 | & + ( 15. * ( 1. - TANH( (fsdept(ji,jj,jk)-50.) / 1500.) ) & |
---|
397 | & - 1.4 * TANH((fsdept(ji,jj,jk)-100.) / 100.) & |
---|
398 | & + 7. * (1500. - fsdept(ji,jj,jk)) / 1500. ) & |
---|
399 | & * (-TANH( (fsdept(ji,jj,jk) - 500) / 150) + 1) / 2 |
---|
400 | tsn(ji,jj,jk,jp_tem) = tsn(ji,jj,jk,jp_tem) * tmask(ji,jj,jk) |
---|
401 | tsb(ji,jj,jk,jp_tem) = tsn(ji,jj,jk,jp_tem) |
---|
402 | |
---|
403 | tsn(ji,jj,jk,jp_sal) = ( 36.25 - 1.13 * TANH( (fsdept(ji,jj,jk) - 305) / 460 ) ) & |
---|
404 | & * (-TANH((500 - fsdept(ji,jj,jk)) / 150) + 1) / 2 & |
---|
405 | & + ( 35.55 + 1.25 * (5000. - fsdept(ji,jj,jk)) / 5000. & |
---|
406 | & - 1.62 * TANH( (fsdept(ji,jj,jk) - 60. ) / 650. ) & |
---|
407 | & + 0.2 * TANH( (fsdept(ji,jj,jk) - 35. ) / 100. ) & |
---|
408 | & + 0.2 * TANH( (fsdept(ji,jj,jk) - 1000.) / 5000.) ) & |
---|
409 | & * (-TANH((fsdept(ji,jj,jk) - 500) / 150) + 1) / 2 |
---|
410 | tsn(ji,jj,jk,jp_sal) = tsn(ji,jj,jk,jp_sal) * tmask(ji,jj,jk) |
---|
411 | tsb(ji,jj,jk,jp_sal) = tsn(ji,jj,jk,jp_sal) |
---|
412 | END DO |
---|
413 | END DO |
---|
414 | END DO |
---|
415 | |
---|
416 | CASE ( 1 ) ! T/S data fields read in dta_tem.nc/data_sal.nc files |
---|
417 | IF(lwp) WRITE(numout,*) |
---|
418 | IF(lwp) WRITE(numout,*) 'istate_gyre : initial T and S read from dta_tem.nc/data_sal.nc files' |
---|
419 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' |
---|
420 | IF(lwp) WRITE(numout,*) ' NetCDF FORMAT' |
---|
421 | |
---|
422 | ! Read temperature field |
---|
423 | ! ---------------------- |
---|
424 | CALL iom_open ( 'data_tem', inum ) |
---|
425 | CALL iom_get ( inum, jpdom_data, 'votemper', tsn(:,:,:,jp_tem) ) |
---|
426 | CALL iom_close( inum ) |
---|
427 | |
---|
428 | tsn(:,:,:,jp_tem) = tsn(:,:,:,jp_tem) * tmask(:,:,:) |
---|
429 | tsb(:,:,:,jp_tem) = tsn(:,:,:,jp_tem) |
---|
430 | |
---|
431 | ! Read salinity field |
---|
432 | ! ------------------- |
---|
433 | CALL iom_open ( 'data_sal', inum ) |
---|
434 | CALL iom_get ( inum, jpdom_data, 'vosaline', tsn(:,:,:,jp_sal) ) |
---|
435 | CALL iom_close( inum ) |
---|
436 | |
---|
437 | tsn(:,:,:,jp_sal) = tsn(:,:,:,jp_sal) * tmask(:,:,:) |
---|
438 | tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal) |
---|
439 | |
---|
440 | END SELECT |
---|
441 | |
---|
442 | IF(lwp) THEN |
---|
443 | WRITE(numout,*) |
---|
444 | WRITE(numout,*) ' Initial temperature and salinity profiles:' |
---|
445 | WRITE(numout, "(9x,' level gdept_1d temperature salinity ')" ) |
---|
446 | WRITE(numout, "(10x, i4, 3f10.2)" ) ( jk, gdept_1d(jk), tsn(2,2,jk,jp_tem), tsn(2,2,jk,jp_sal), jk = 1, jpk ) |
---|
447 | ENDIF |
---|
448 | |
---|
449 | END SUBROUTINE istate_gyre |
---|
450 | |
---|
451 | SUBROUTINE istate_uvg |
---|
452 | !!---------------------------------------------------------------------- |
---|
453 | !! *** ROUTINE istate_uvg *** |
---|
454 | !! |
---|
455 | !! ** Purpose : Compute the geostrophic velocities from (tn,sn) fields |
---|
456 | !! |
---|
457 | !! ** Method : Using the hydrostatic hypothesis the now hydrostatic |
---|
458 | !! pressure is computed by integrating the in-situ density from the |
---|
459 | !! surface to the bottom. |
---|
460 | !! p=integral [ rau*g dz ] |
---|
461 | !!---------------------------------------------------------------------- |
---|
462 | USE dynspg ! surface pressure gradient (dyn_spg routine) |
---|
463 | USE divcur ! hor. divergence & rel. vorticity (div_cur routine) |
---|
464 | USE lbclnk ! ocean lateral boundary condition (or mpp link) |
---|
465 | |
---|
466 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
467 | INTEGER :: indic ! ??? |
---|
468 | REAL(wp) :: zmsv, zphv, zmsu, zphu, zalfg ! temporary scalars |
---|
469 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zprn |
---|
470 | !!---------------------------------------------------------------------- |
---|
471 | ! |
---|
472 | CALL wrk_alloc( jpi, jpj, jpk, zprn) |
---|
473 | ! |
---|
474 | IF(lwp) WRITE(numout,*) |
---|
475 | IF(lwp) WRITE(numout,*) 'istate_uvg : Start from Geostrophy' |
---|
476 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
477 | |
---|
478 | ! Compute the now hydrostatic pressure |
---|
479 | ! ------------------------------------ |
---|
480 | |
---|
481 | zalfg = 0.5 * grav * rau0 |
---|
482 | |
---|
483 | zprn(:,:,1) = zalfg * fse3w(:,:,1) * ( 1 + rhd(:,:,1) ) ! Surface value |
---|
484 | |
---|
485 | DO jk = 2, jpkm1 ! Vertical integration from the surface |
---|
486 | zprn(:,:,jk) = zprn(:,:,jk-1) & |
---|
487 | & + zalfg * fse3w(:,:,jk) * ( 2. + rhd(:,:,jk) + rhd(:,:,jk-1) ) |
---|
488 | END DO |
---|
489 | |
---|
490 | ! Compute geostrophic balance |
---|
491 | ! --------------------------- |
---|
492 | DO jk = 1, jpkm1 |
---|
493 | DO jj = 2, jpjm1 |
---|
494 | DO ji = fs_2, fs_jpim1 ! vertor opt. |
---|
495 | zmsv = 1. / MAX( umask(ji-1,jj+1,jk) + umask(ji ,jj+1,jk) & |
---|
496 | + umask(ji-1,jj ,jk) + umask(ji ,jj ,jk) , 1. ) |
---|
497 | zphv = ( zprn(ji ,jj+1,jk) - zprn(ji-1,jj+1,jk) ) * umask(ji-1,jj+1,jk) / e1u(ji-1,jj+1) & |
---|
498 | + ( zprn(ji+1,jj+1,jk) - zprn(ji ,jj+1,jk) ) * umask(ji ,jj+1,jk) / e1u(ji ,jj+1) & |
---|
499 | + ( zprn(ji ,jj ,jk) - zprn(ji-1,jj ,jk) ) * umask(ji-1,jj ,jk) / e1u(ji-1,jj ) & |
---|
500 | + ( zprn(ji+1,jj ,jk) - zprn(ji ,jj ,jk) ) * umask(ji ,jj ,jk) / e1u(ji ,jj ) |
---|
501 | zphv = 1. / rau0 * zphv * zmsv * vmask(ji,jj,jk) |
---|
502 | |
---|
503 | zmsu = 1. / MAX( vmask(ji+1,jj ,jk) + vmask(ji ,jj ,jk) & |
---|
504 | + vmask(ji+1,jj-1,jk) + vmask(ji ,jj-1,jk) , 1. ) |
---|
505 | zphu = ( zprn(ji+1,jj+1,jk) - zprn(ji+1,jj ,jk) ) * vmask(ji+1,jj ,jk) / e2v(ji+1,jj ) & |
---|
506 | + ( zprn(ji ,jj+1,jk) - zprn(ji ,jj ,jk) ) * vmask(ji ,jj ,jk) / e2v(ji ,jj ) & |
---|
507 | + ( zprn(ji+1,jj ,jk) - zprn(ji+1,jj-1,jk) ) * vmask(ji+1,jj-1,jk) / e2v(ji+1,jj-1) & |
---|
508 | + ( zprn(ji ,jj ,jk) - zprn(ji ,jj-1,jk) ) * vmask(ji ,jj-1,jk) / e2v(ji ,jj-1) |
---|
509 | zphu = 1. / rau0 * zphu * zmsu * umask(ji,jj,jk) |
---|
510 | |
---|
511 | ! Compute the geostrophic velocities |
---|
512 | un(ji,jj,jk) = -2. * zphu / ( ff(ji,jj) + ff(ji ,jj-1) ) |
---|
513 | vn(ji,jj,jk) = 2. * zphv / ( ff(ji,jj) + ff(ji-1,jj ) ) |
---|
514 | END DO |
---|
515 | END DO |
---|
516 | END DO |
---|
517 | |
---|
518 | IF(lwp) WRITE(numout,*) ' we force to zero bottom velocity' |
---|
519 | |
---|
520 | ! Susbtract the bottom velocity (level jpk-1 for flat bottom case) |
---|
521 | ! to have a zero bottom velocity |
---|
522 | |
---|
523 | DO jk = 1, jpkm1 |
---|
524 | un(:,:,jk) = ( un(:,:,jk) - un(:,:,jpkm1) ) * umask(:,:,jk) |
---|
525 | vn(:,:,jk) = ( vn(:,:,jk) - vn(:,:,jpkm1) ) * vmask(:,:,jk) |
---|
526 | END DO |
---|
527 | |
---|
528 | CALL lbc_lnk( un, 'U', -1. ) |
---|
529 | CALL lbc_lnk( vn, 'V', -1. ) |
---|
530 | |
---|
531 | ub(:,:,:) = un(:,:,:) |
---|
532 | vb(:,:,:) = vn(:,:,:) |
---|
533 | |
---|
534 | ! WARNING !!!!! |
---|
535 | ! after initializing u and v, we need to calculate the initial streamfunction bsf. |
---|
536 | ! Otherwise, only the trend will be computed and the model will blow up (inconsistency). |
---|
537 | ! to do that, we call dyn_spg with a special trick: |
---|
538 | ! we fill ua and va with the velocities divided by dt, and the streamfunction will be brought to the |
---|
539 | ! right value assuming the velocities have been set up in one time step. |
---|
540 | ! we then set bsfd to zero (first guess for next step is d(psi)/dt = 0.) |
---|
541 | ! sets up s false trend to calculate the barotropic streamfunction. |
---|
542 | |
---|
543 | ua(:,:,:) = ub(:,:,:) / rdt |
---|
544 | va(:,:,:) = vb(:,:,:) / rdt |
---|
545 | |
---|
546 | ! calls dyn_spg. we assume euler time step, starting from rest. |
---|
547 | indic = 0 |
---|
548 | CALL dyn_spg( nit000, indic ) ! surface pressure gradient |
---|
549 | |
---|
550 | ! the new velocity is ua*rdt |
---|
551 | |
---|
552 | CALL lbc_lnk( ua, 'U', -1. ) |
---|
553 | CALL lbc_lnk( va, 'V', -1. ) |
---|
554 | |
---|
555 | ub(:,:,:) = ua(:,:,:) * rdt |
---|
556 | vb(:,:,:) = va(:,:,:) * rdt |
---|
557 | ua(:,:,:) = 0.e0 |
---|
558 | va(:,:,:) = 0.e0 |
---|
559 | un(:,:,:) = ub(:,:,:) |
---|
560 | vn(:,:,:) = vb(:,:,:) |
---|
561 | |
---|
562 | ! Compute the divergence and curl |
---|
563 | |
---|
564 | CALL div_cur( nit000 ) ! now horizontal divergence and curl |
---|
565 | |
---|
566 | hdivb(:,:,:) = hdivn(:,:,:) ! set the before to the now value |
---|
567 | rotb (:,:,:) = rotn (:,:,:) ! set the before to the now value |
---|
568 | ! |
---|
569 | CALL wrk_dealloc( jpi, jpj, jpk, zprn) |
---|
570 | ! |
---|
571 | END SUBROUTINE istate_uvg |
---|
572 | |
---|
573 | !!===================================================================== |
---|
574 | END MODULE istate |
---|
575 | |
---|