source: branches/2014/dev_r4650_UKMO2_ice_shelves/NEMOGCM/NEMO/OPA_SRC/DYN/sshwzv.F90 @ 4726

Last change on this file since 4726 was 4726, checked in by mathiot, 6 years ago

ISF branch: change name of 2 variables (icedep ⇒ risfdep and lmask ⇒ ssmask), cosmetic changes and add ldfslp key

  • Property svn:keywords set to Id
File size: 14.0 KB
Line 
1MODULE sshwzv   
2   !!==============================================================================
3   !!                       ***  MODULE  sshwzv  ***
4   !! Ocean dynamics : sea surface height and vertical velocity
5   !!==============================================================================
6   !! History :  3.1  !  2009-02  (G. Madec, M. Leclair)  Original code
7   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
8   !!             -   !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
9   !!             -   !  2010-09  (D.Storkey and E.O'Dea) bug fixes for BDY module
10   !!            3.3  !  2011-10  (M. Leclair) split former ssh_wzv routine and remove all vvl related work
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   ssh_nxt        : after ssh
15   !!   ssh_swp        : filter ans swap the ssh arrays
16   !!   wzv            : compute now vertical velocity
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE sbc_oce         ! surface boundary condition: ocean
21   USE domvvl          ! Variable volume
22   USE divcur          ! hor. divergence and curl      (div & cur routines)
23   USE iom             ! I/O library
24   USE restart         ! only for lrst_oce
25   USE in_out_manager  ! I/O manager
26   USE prtctl          ! Print control
27   USE phycst
28   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
29   USE lib_mpp         ! MPP library
30   USE bdy_oce
31   USE bdy_par         
32   USE bdydyn2d        ! bdy_ssh routine
33   USE diaar5, ONLY:   lk_diaar5
34   USE iom
35#if defined key_agrif
36   USE agrif_opa_update
37   USE agrif_opa_interp
38#endif
39#if defined key_asminc   
40   USE asminc          ! Assimilation increment
41#endif
42   USE wrk_nemo        ! Memory Allocation
43   USE timing          ! Timing
44
45   IMPLICIT NONE
46   PRIVATE
47
48   PUBLIC   ssh_nxt    ! called by step.F90
49   PUBLIC   wzv        ! called by step.F90
50   PUBLIC   ssh_swp    ! called by step.F90
51
52   !! * Substitutions
53#  include "domzgr_substitute.h90"
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
57   !! $Id$
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE ssh_nxt( kt )
63      !!----------------------------------------------------------------------
64      !!                ***  ROUTINE ssh_nxt  ***
65      !!                   
66      !! ** Purpose :   compute the after ssh (ssha)
67      !!
68      !! ** Method  : - Using the incompressibility hypothesis, the ssh increment
69      !!      is computed by integrating the horizontal divergence and multiply by
70      !!      by the time step.
71      !!
72      !! ** action  :   ssha    : after sea surface height
73      !!
74      !! Reference  : Leclair, M., and G. Madec, 2009, Ocean Modelling.
75      !!----------------------------------------------------------------------
76      !
77      REAL(wp), POINTER, DIMENSION(:,:  ) ::  zhdiv
78      INTEGER, INTENT(in) ::   kt                      ! time step
79      !
80      INTEGER             ::   jk                      ! dummy loop indice
81      REAL(wp)            ::   z2dt, z1_rau0           ! local scalars
82      !!----------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start('ssh_nxt')
85      !
86      CALL wrk_alloc( jpi, jpj, zhdiv ) 
87      !
88      IF( kt == nit000 ) THEN
89         !
90         IF(lwp) WRITE(numout,*)
91         IF(lwp) WRITE(numout,*) 'ssh_nxt : after sea surface height'
92         IF(lwp) WRITE(numout,*) '~~~~~~~ '
93         !
94      ENDIF
95      !
96      CALL div_cur( kt )                              ! Horizontal divergence & Relative vorticity
97      !
98      z2dt = 2._wp * rdt                              ! set time step size (Euler/Leapfrog)
99      IF( neuler == 0 .AND. kt == nit000 )   z2dt = rdt
100
101      !                                           !------------------------------!
102      !                                           !   After Sea Surface Height   !
103      !                                           !------------------------------!
104      zhdiv(:,:) = 0._wp
105      DO jk = 1, jpkm1                                 ! Horizontal divergence of barotropic transports
106        zhdiv(:,:) = zhdiv(:,:) + fse3t_n(:,:,jk) * hdivn(:,:,jk)
107      END DO
108      !                                                ! Sea surface elevation time stepping
109      ! In time-split case we need a first guess of the ssh after (using the baroclinic timestep) in order to
110      ! compute the vertical velocity which can be used to compute the non-linear terms of the momentum equations.
111      !
112      z1_rau0 = 0.5_wp * r1_rau0
113      ssha(:,:) = (  sshb(:,:) - z2dt * ( z1_rau0 * ( emp_b(:,:) + emp(:,:) ) + zhdiv(:,:) )  ) * ssmask(:,:)
114
115#if ! defined key_dynspg_ts
116      ! These lines are not necessary with time splitting since
117      ! boundary condition on sea level is set during ts loop
118#if defined key_agrif
119      CALL agrif_ssh( kt )
120#endif
121#if defined key_bdy
122      IF (lk_bdy) THEN
123         CALL lbc_lnk( ssha, 'T', 1. ) ! Not sure that's necessary
124         CALL bdy_ssh( ssha ) ! Duplicate sea level across open boundaries
125      ENDIF
126#endif
127#endif
128
129#if defined key_asminc
130      !                                                ! Include the IAU weighted SSH increment
131      IF( lk_asminc .AND. ln_sshinc .AND. ln_asmiau ) THEN
132         CALL ssh_asm_inc( kt )
133         ssha(:,:) = ssha(:,:) + z2dt * ssh_iau(:,:)
134      ENDIF
135#endif
136
137      !                                           !------------------------------!
138      !                                           !           outputs            !
139      !                                           !------------------------------!
140      CALL iom_put( "ssh" , sshn                  )   ! sea surface height
141      CALL iom_put( "ssh2", sshn(:,:) * sshn(:,:) )   ! square of sea surface height
142      !
143      IF(ln_ctl)   CALL prt_ctl( tab2d_1=ssha, clinfo1=' ssha  - : ', mask1=tmask, ovlap=1 )
144      !
145      CALL wrk_dealloc( jpi, jpj, zhdiv ) 
146      !
147      IF( nn_timing == 1 )  CALL timing_stop('ssh_nxt')
148      !
149   END SUBROUTINE ssh_nxt
150
151   
152   SUBROUTINE wzv( kt )
153      !!----------------------------------------------------------------------
154      !!                ***  ROUTINE wzv  ***
155      !!                   
156      !! ** Purpose :   compute the now vertical velocity
157      !!
158      !! ** Method  : - Using the incompressibility hypothesis, the vertical
159      !!      velocity is computed by integrating the horizontal divergence 
160      !!      from the bottom to the surface minus the scale factor evolution.
161      !!        The boundary conditions are w=0 at the bottom (no flux) and.
162      !!
163      !! ** action  :   wn      : now vertical velocity
164      !!
165      !! Reference  : Leclair, M., and G. Madec, 2009, Ocean Modelling.
166      !!----------------------------------------------------------------------
167      !
168      INTEGER, INTENT(in) ::   kt           ! time step
169      REAL(wp), POINTER, DIMENSION(:,:  ) ::  z2d
170      REAL(wp), POINTER, DIMENSION(:,:,:) ::  z3d, zhdiv
171      !
172      INTEGER             ::   ji, jj, jk   ! dummy loop indices
173      REAL(wp)            ::   z1_2dt       ! local scalars
174      !!----------------------------------------------------------------------
175     
176      IF( nn_timing == 1 )  CALL timing_start('wzv')
177      !
178      IF( kt == nit000 ) THEN
179         !
180         IF(lwp) WRITE(numout,*)
181         IF(lwp) WRITE(numout,*) 'wzv : now vertical velocity '
182         IF(lwp) WRITE(numout,*) '~~~~~ '
183         !
184         wn(:,:,jpk) = 0._wp                  ! bottom boundary condition: w=0 (set once for all)
185         !
186      ENDIF
187      !                                           !------------------------------!
188      !                                           !     Now Vertical Velocity    !
189      !                                           !------------------------------!
190      z1_2dt = 1. / ( 2. * rdt )                         ! set time step size (Euler/Leapfrog)
191      IF( neuler == 0 .AND. kt == nit000 )   z1_2dt = 1. / rdt
192      !
193      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN      ! z_tilde and layer cases
194         CALL wrk_alloc( jpi, jpj, jpk, zhdiv ) 
195         !
196         DO jk = 1, jpkm1
197            ! horizontal divergence of thickness diffusion transport ( velocity multiplied by e3t)
198            ! - ML - note: computation already done in dom_vvl_sf_nxt. Could be optimized (not critical and clearer this way)
199            DO jj = 2, jpjm1
200               DO ji = fs_2, fs_jpim1   ! vector opt.
201                  zhdiv(ji,jj,jk) = r1_e12t(ji,jj) * ( un_td(ji,jj,jk) - un_td(ji-1,jj,jk) + vn_td(ji,jj,jk) - vn_td(ji,jj-1,jk) )
202               END DO
203            END DO
204         END DO
205         CALL lbc_lnk(zhdiv, 'T', 1.)  ! - ML - Perhaps not necessary: not used for horizontal "connexions"
206         !                             ! Is it problematic to have a wrong vertical velocity in boundary cells?
207         !                             ! Same question holds for hdivn. Perhaps just for security
208         DO jk = jpkm1, 1, -1                       ! integrate from the bottom the hor. divergence
209            ! computation of w
210            wn(:,:,jk) = wn(:,:,jk+1) - (   fse3t_n(:,:,jk) * hdivn(:,:,jk) + zhdiv(:,:,jk)                    &
211               &                          + z1_2dt * ( fse3t_a(:,:,jk) - fse3t_b(:,:,jk) ) ) * tmask(:,:,jk)
212         END DO
213         !          IF( ln_vvl_layer ) wn(:,:,:) = 0.e0
214         CALL wrk_dealloc( jpi, jpj, jpk, zhdiv ) 
215      ELSE   ! z_star and linear free surface cases
216         DO jk = jpkm1, 1, -1                       ! integrate from the bottom the hor. divergence
217            ! computation of w
218            wn(:,:,jk) = wn(:,:,jk+1) - (   fse3t_n(:,:,jk) * hdivn(:,:,jk)                                   &
219               &                          + z1_2dt * ( fse3t_a(:,:,jk) - fse3t_b(:,:,jk) ) ) * tmask(:,:,jk)
220         END DO
221      ENDIF
222
223#if defined key_bdy
224      IF (lk_bdy) THEN
225         DO jk = 1, jpkm1
226            wn(:,:,jk) = wn(:,:,jk) * bdytmask(:,:)
227         END DO
228      ENDIF
229#endif
230      !
231      !                                           !------------------------------!
232      !                                           !           outputs            !
233      !                                           !------------------------------!
234      CALL iom_put( "woce", wn )   ! vertical velocity
235      IF( lk_diaar5 ) THEN                            ! vertical mass transport & its square value
236         CALL wrk_alloc( jpi, jpj, z2d ) 
237         CALL wrk_alloc( jpi, jpj, jpk, z3d ) 
238         ! Caution: in the VVL case, it only correponds to the baroclinic mass transport.
239         z2d(:,:) = rau0 * e12t(:,:)
240         DO jk = 1, jpk
241            z3d(:,:,jk) = wn(:,:,jk) * z2d(:,:)
242         END DO
243         CALL iom_put( "w_masstr" , z3d                     ) 
244         CALL iom_put( "w_masstr2", z3d(:,:,:) * z3d(:,:,:) )
245         CALL wrk_dealloc( jpi, jpj, z2d  ) 
246         CALL wrk_dealloc( jpi, jpj, jpk, z3d ) 
247      ENDIF
248      !
249      IF( nn_timing == 1 )  CALL timing_stop('wzv')
250
251
252   END SUBROUTINE wzv
253
254   SUBROUTINE ssh_swp( kt )
255      !!----------------------------------------------------------------------
256      !!                    ***  ROUTINE ssh_nxt  ***
257      !!
258      !! ** Purpose :   achieve the sea surface  height time stepping by
259      !!              applying Asselin time filter and swapping the arrays
260      !!              ssha  already computed in ssh_nxt 
261      !!
262      !! ** Method  : - apply Asselin time fiter to now ssh (excluding the forcing
263      !!              from the filter, see Leclair and Madec 2010) and swap :
264      !!                sshn = ssha + atfp * ( sshb -2 sshn + ssha )
265      !!                            - atfp * rdt * ( emp_b - emp ) / rau0
266      !!                sshn = ssha
267      !!
268      !! ** action  : - sshb, sshn   : before & now sea surface height
269      !!                               ready for the next time step
270      !!
271      !! Reference  : Leclair, M., and G. Madec, 2009, Ocean Modelling.
272      !!----------------------------------------------------------------------
273      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
274      !!----------------------------------------------------------------------
275      !
276      IF( nn_timing == 1 )  CALL timing_start('ssh_swp')
277      !
278      IF( kt == nit000 ) THEN
279         IF(lwp) WRITE(numout,*)
280         IF(lwp) WRITE(numout,*) 'ssh_swp : Asselin time filter and swap of sea surface height'
281         IF(lwp) WRITE(numout,*) '~~~~~~~ '
282      ENDIF
283
284# if defined key_dynspg_ts
285      IF( ( neuler == 0 .AND. kt == nit000 ) .OR. ln_bt_fw ) THEN    !** Euler time-stepping: no filter
286# else
287      IF ( neuler == 0 .AND. kt == nit000 ) THEN   !** Euler time-stepping at first time-step : no filter
288#endif
289         sshb(:,:) = sshn(:,:)                           ! before <-- now
290         sshn(:,:) = ssha(:,:)                           ! now    <-- after  (before already = now)
291      ELSE                                         !** Leap-Frog time-stepping: Asselin filter + swap
292         sshb(:,:) = sshn(:,:) + atfp * ( sshb(:,:) - 2 * sshn(:,:) + ssha(:,:) )     ! before <-- now filtered
293         IF( lk_vvl ) sshb(:,:) = sshb(:,:) - atfp * rdt / rau0 * ( emp_b(:,:) - emp(:,:) ) * ssmask(:,:)
294         sshn(:,:) = ssha(:,:)                           ! now <-- after
295      ENDIF
296      !
297      ! Update velocity at AGRIF zoom boundaries
298#if defined key_agrif
299      IF ( .NOT.Agrif_Root() ) CALL Agrif_Update_Dyn( kt )
300#endif
301      !
302      IF(ln_ctl)   CALL prt_ctl( tab2d_1=sshb, clinfo1=' sshb  - : ', mask1=tmask, ovlap=1 )
303      !
304      IF( nn_timing == 1 )  CALL timing_stop('ssh_swp')
305      !
306   END SUBROUTINE ssh_swp
307
308   !!======================================================================
309END MODULE sshwzv
Note: See TracBrowser for help on using the repository browser.