| 1 | MODULE traqsr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traqsr *** |
|---|
| 4 | !! Ocean physics: solar radiation penetration in the top ocean levels |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (G. Madec) |
|---|
| 8 | !! ! 1996-01 (G. Madec) s-coordinates |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! - ! 2005-11 (G. Madec) zco, zps, sco coordinate |
|---|
| 11 | !! 3.2 ! 2009-04 (G. Madec & NEMO team) |
|---|
| 12 | !! 4.0 ! 2012-05 (C. Rousset) store attenuation coef for use in ice model |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! tra_qsr : trend due to the solar radiation penetration |
|---|
| 17 | !! tra_qsr_init : solar radiation penetration initialization |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | USE oce ! ocean dynamics and active tracers |
|---|
| 20 | USE dom_oce ! ocean space and time domain |
|---|
| 21 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 22 | USE trc_oce ! share SMS/Ocean variables |
|---|
| 23 | USE trdmod_oce ! ocean variables trends |
|---|
| 24 | USE trdtra ! ocean active tracers trends |
|---|
| 25 | USE in_out_manager ! I/O manager |
|---|
| 26 | USE phycst ! physical constants |
|---|
| 27 | USE prtctl ! Print control |
|---|
| 28 | USE iom ! I/O manager |
|---|
| 29 | USE fldread ! read input fields |
|---|
| 30 | USE restart ! ocean restart |
|---|
| 31 | USE lib_mpp ! MPP library |
|---|
| 32 | USE wrk_nemo ! Memory Allocation |
|---|
| 33 | USE timing ! Timing |
|---|
| 34 | USE sbc_ice, ONLY : lk_lim3 |
|---|
| 35 | |
|---|
| 36 | IMPLICIT NONE |
|---|
| 37 | PRIVATE |
|---|
| 38 | |
|---|
| 39 | PUBLIC tra_qsr ! routine called by step.F90 (ln_traqsr=T) |
|---|
| 40 | PUBLIC tra_qsr_init ! routine called by opa.F90 |
|---|
| 41 | |
|---|
| 42 | ! !!* Namelist namtra_qsr: penetrative solar radiation |
|---|
| 43 | LOGICAL , PUBLIC :: ln_traqsr !: light absorption (qsr) flag |
|---|
| 44 | LOGICAL , PUBLIC :: ln_qsr_rgb !: Red-Green-Blue light absorption flag |
|---|
| 45 | LOGICAL , PUBLIC :: ln_qsr_2bd !: 2 band light absorption flag |
|---|
| 46 | LOGICAL , PUBLIC :: ln_qsr_bio !: bio-model light absorption flag |
|---|
| 47 | LOGICAL , PUBLIC :: ln_qsr_ice !: light penetration for ice-model LIM3 (clem) |
|---|
| 48 | INTEGER , PUBLIC :: nn_chldta !: use Chlorophyll data (=1) or not (=0) |
|---|
| 49 | REAL(wp), PUBLIC :: rn_abs !: fraction absorbed in the very near surface (RGB & 2 bands) |
|---|
| 50 | REAL(wp), PUBLIC :: rn_si0 !: very near surface depth of extinction (RGB & 2 bands) |
|---|
| 51 | REAL(wp), PUBLIC :: rn_si1 !: deepest depth of extinction (water type I) (2 bands) |
|---|
| 52 | |
|---|
| 53 | ! Module variables |
|---|
| 54 | REAL(wp) :: xsi0r !: inverse of rn_si0 |
|---|
| 55 | REAL(wp) :: xsi1r !: inverse of rn_si1 |
|---|
| 56 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_chl ! structure of input Chl (file informations, fields read) |
|---|
| 57 | INTEGER, PUBLIC :: nksr ! levels below which the light cannot penetrate ( depth larger than 391 m) |
|---|
| 58 | REAL(wp), DIMENSION(3,61) :: rkrgb !: tabulated attenuation coefficients for RGB absorption |
|---|
| 59 | |
|---|
| 60 | !! * Substitutions |
|---|
| 61 | # include "domzgr_substitute.h90" |
|---|
| 62 | # include "vectopt_loop_substitute.h90" |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 65 | !! $Id$ |
|---|
| 66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | CONTAINS |
|---|
| 69 | |
|---|
| 70 | SUBROUTINE tra_qsr( kt ) |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE tra_qsr *** |
|---|
| 73 | !! |
|---|
| 74 | !! ** Purpose : Compute the temperature trend due to the solar radiation |
|---|
| 75 | !! penetration and add it to the general temperature trend. |
|---|
| 76 | !! |
|---|
| 77 | !! ** Method : The profile of the solar radiation within the ocean is defined |
|---|
| 78 | !! through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs |
|---|
| 79 | !! Considering the 2 wavebands case: |
|---|
| 80 | !! I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) ) |
|---|
| 81 | !! The temperature trend associated with the solar radiation penetration |
|---|
| 82 | !! is given by : zta = 1/e3t dk[ I ] / (rau0*Cp) |
|---|
| 83 | !! At the bottom, boudary condition for the radiation is no flux : |
|---|
| 84 | !! all heat which has not been absorbed in the above levels is put |
|---|
| 85 | !! in the last ocean level. |
|---|
| 86 | !! In z-coordinate case, the computation is only done down to the |
|---|
| 87 | !! level where I(k) < 1.e-15 W/m2. In addition, the coefficients |
|---|
| 88 | !! used for the computation are calculated one for once as they |
|---|
| 89 | !! depends on k only. |
|---|
| 90 | !! |
|---|
| 91 | !! ** Action : - update ta with the penetrative solar radiation trend |
|---|
| 92 | !! - save the trend in ttrd ('key_trdtra') |
|---|
| 93 | !! |
|---|
| 94 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 95 | !! Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516. |
|---|
| 96 | !!---------------------------------------------------------------------- |
|---|
| 97 | ! |
|---|
| 98 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 99 | ! |
|---|
| 100 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 101 | INTEGER :: irgb ! local integers |
|---|
| 102 | REAL(wp) :: zchl, zcoef, zfact ! local scalars |
|---|
| 103 | REAL(wp) :: zc0, zc1, zc2, zc3 ! - - |
|---|
| 104 | REAL(wp) :: zzc0, zzc1, zzc2, zzc3 ! - - |
|---|
| 105 | REAL(wp) :: zz0, zz1, z1_e3t ! - - |
|---|
| 106 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 107 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt |
|---|
| 108 | !!---------------------------------------------------------------------- |
|---|
| 109 | ! |
|---|
| 110 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr') |
|---|
| 111 | ! |
|---|
| 112 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 113 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 114 | ! |
|---|
| 115 | IF( kt == nit000 ) THEN |
|---|
| 116 | IF(lwp) WRITE(numout,*) |
|---|
| 117 | IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation' |
|---|
| 118 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 119 | IF( .NOT.ln_traqsr ) RETURN |
|---|
| 120 | ENDIF |
|---|
| 121 | |
|---|
| 122 | IF( l_trdtra ) THEN ! Save ta and sa trends |
|---|
| 123 | CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 124 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 125 | ENDIF |
|---|
| 126 | |
|---|
| 127 | ! Set before qsr tracer content field |
|---|
| 128 | ! *********************************** |
|---|
| 129 | IF( kt == nit000 ) THEN ! Set the forcing field at nit000 - 1 |
|---|
| 130 | ! ! ----------------------------------- |
|---|
| 131 | qsr_hc(:,:,:) = 0.e0 |
|---|
| 132 | ! |
|---|
| 133 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 134 | & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 135 | IF(lwp) WRITE(numout,*) ' nit000-1 qsr tracer content forcing field red in the restart file' |
|---|
| 136 | zfact = 0.5e0 |
|---|
| 137 | CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b ) ! before heat content trend due to Qsr flux |
|---|
| 138 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 139 | zfact = 1.e0 |
|---|
| 140 | qsr_hc_b(:,:,:) = 0.e0 |
|---|
| 141 | ENDIF |
|---|
| 142 | ELSE ! Swap of forcing field |
|---|
| 143 | ! ! --------------------- |
|---|
| 144 | zfact = 0.5e0 |
|---|
| 145 | qsr_hc_b(:,:,:) = qsr_hc(:,:,:) |
|---|
| 146 | ENDIF |
|---|
| 147 | ! Compute now qsr tracer content field |
|---|
| 148 | ! ************************************ |
|---|
| 149 | |
|---|
| 150 | ! ! ============================================== ! |
|---|
| 151 | IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN ! bio-model fluxes : all vertical coordinates ! |
|---|
| 152 | ! ! ============================================== ! |
|---|
| 153 | DO jk = 1, jpkm1 |
|---|
| 154 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) ) |
|---|
| 155 | END DO |
|---|
| 156 | ! Add to the general trend |
|---|
| 157 | DO jk = 1, jpkm1 |
|---|
| 158 | DO jj = 2, jpjm1 |
|---|
| 159 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 160 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 161 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 162 | END DO |
|---|
| 163 | END DO |
|---|
| 164 | END DO |
|---|
| 165 | CALL iom_put( 'qsr3d', etot3 ) ! Shortwave Radiation 3D distribution |
|---|
| 166 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 167 | IF ( lk_lim3 .AND. ln_qsr_ice ) THEN |
|---|
| 168 | DO jj = 1, jpj |
|---|
| 169 | DO ji = 1, jpi |
|---|
| 170 | IF ( qsr(ji,jj) /= 0._wp ) THEN |
|---|
| 171 | oatte(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) ) |
|---|
| 172 | iatte(ji,jj) = oatte(ji,jj) |
|---|
| 173 | ENDIF |
|---|
| 174 | END DO |
|---|
| 175 | END DO |
|---|
| 176 | ENDIF |
|---|
| 177 | ! ! ============================================== ! |
|---|
| 178 | ELSE ! Ocean alone : |
|---|
| 179 | ! ! ============================================== ! |
|---|
| 180 | ! |
|---|
| 181 | ! ! ------------------------- ! |
|---|
| 182 | IF( ln_qsr_rgb) THEN ! R-G-B light penetration ! |
|---|
| 183 | ! ! ------------------------- ! |
|---|
| 184 | ! Set chlorophyl concentration |
|---|
| 185 | IF( nn_chldta == 1 .OR. lk_vvl ) THEN !* Variable Chlorophyll or ocean volume |
|---|
| 186 | ! |
|---|
| 187 | IF( nn_chldta == 1 ) THEN !* Variable Chlorophyll |
|---|
| 188 | ! |
|---|
| 189 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 190 | ! |
|---|
| 191 | !CDIR COLLAPSE |
|---|
| 192 | !CDIR NOVERRCHK |
|---|
| 193 | DO jj = 1, jpj ! Separation in R-G-B depending of the surface Chl |
|---|
| 194 | !CDIR NOVERRCHK |
|---|
| 195 | DO ji = 1, jpi |
|---|
| 196 | zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) ) |
|---|
| 197 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 198 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 199 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 200 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 201 | END DO |
|---|
| 202 | END DO |
|---|
| 203 | ELSE ! Variable ocean volume but constant chrlorophyll |
|---|
| 204 | zchl = 0.05 ! constant chlorophyll |
|---|
| 205 | irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 ) |
|---|
| 206 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 207 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 208 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 209 | ENDIF |
|---|
| 210 | ! |
|---|
| 211 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 212 | ze0(:,:,1) = rn_abs * qsr(:,:) |
|---|
| 213 | ze1(:,:,1) = zcoef * qsr(:,:) |
|---|
| 214 | ze2(:,:,1) = zcoef * qsr(:,:) |
|---|
| 215 | ze3(:,:,1) = zcoef * qsr(:,:) |
|---|
| 216 | zea(:,:,1) = qsr(:,:) |
|---|
| 217 | ! |
|---|
| 218 | DO jk = 2, nksr+1 |
|---|
| 219 | !CDIR NOVERRCHK |
|---|
| 220 | DO jj = 1, jpj |
|---|
| 221 | !CDIR NOVERRCHK |
|---|
| 222 | DO ji = 1, jpi |
|---|
| 223 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r ) |
|---|
| 224 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 225 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 226 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 227 | ze0(ji,jj,jk) = zc0 |
|---|
| 228 | ze1(ji,jj,jk) = zc1 |
|---|
| 229 | ze2(ji,jj,jk) = zc2 |
|---|
| 230 | ze3(ji,jj,jk) = zc3 |
|---|
| 231 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 232 | END DO |
|---|
| 233 | END DO |
|---|
| 234 | END DO |
|---|
| 235 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 236 | IF ( lk_lim3 .AND. ln_qsr_ice ) THEN |
|---|
| 237 | DO jj = 1, jpj |
|---|
| 238 | DO ji = 1, jpi |
|---|
| 239 | zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r ) |
|---|
| 240 | zzc1 = zcoef * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) ) |
|---|
| 241 | zzc2 = zcoef * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) ) |
|---|
| 242 | zzc3 = zcoef * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) ) |
|---|
| 243 | oatte(ji,jj) = 1.0 - ( zzc0 + zzc1 + zzc2 + zzc3 ) * tmask(ji,jj,2) |
|---|
| 244 | iatte(ji,jj) = 1.0 - ( zzc0 + zzc1 + zcoef + zcoef ) * tmask(ji,jj,2) |
|---|
| 245 | END DO |
|---|
| 246 | END DO |
|---|
| 247 | ENDIF |
|---|
| 248 | ! |
|---|
| 249 | DO jk = 1, nksr ! compute and add qsr trend to ta |
|---|
| 250 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 251 | END DO |
|---|
| 252 | zea(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 253 | CALL iom_put( 'qsr3d', zea ) ! Shortwave Radiation 3D distribution |
|---|
| 254 | ! |
|---|
| 255 | ELSE !* Constant Chlorophyll |
|---|
| 256 | DO jk = 1, nksr |
|---|
| 257 | qsr_hc(:,:,jk) = etot3(:,:,jk) * qsr(:,:) |
|---|
| 258 | END DO |
|---|
| 259 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 260 | IF ( lk_lim3 .AND. ln_qsr_ice ) THEN |
|---|
| 261 | oatte(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 262 | iatte(:,:) = oatte(:,:) |
|---|
| 263 | ENDIF |
|---|
| 264 | ENDIF |
|---|
| 265 | |
|---|
| 266 | ENDIF |
|---|
| 267 | ! ! ------------------------- ! |
|---|
| 268 | IF( ln_qsr_2bd ) THEN ! 2 band light penetration ! |
|---|
| 269 | ! ! ------------------------- ! |
|---|
| 270 | ! |
|---|
| 271 | IF( lk_vvl ) THEN !* variable volume |
|---|
| 272 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 273 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 274 | DO jk = 1, nksr ! solar heat absorbed at T-point in the top 400m |
|---|
| 275 | DO jj = 1, jpj |
|---|
| 276 | DO ji = 1, jpi |
|---|
| 277 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 278 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 279 | qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) |
|---|
| 280 | END DO |
|---|
| 281 | END DO |
|---|
| 282 | END DO |
|---|
| 283 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 284 | IF ( lk_lim3 .AND. ln_qsr_ice ) THEN |
|---|
| 285 | DO jj = 1, jpj |
|---|
| 286 | DO ji = 1, jpi |
|---|
| 287 | zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r ) |
|---|
| 288 | zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r ) |
|---|
| 289 | oatte(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp |
|---|
| 290 | iatte(ji,jj) = oatte(ji,jj) |
|---|
| 291 | END DO |
|---|
| 292 | END DO |
|---|
| 293 | ENDIF |
|---|
| 294 | ELSE !* constant volume: coef. computed one for all |
|---|
| 295 | DO jk = 1, nksr |
|---|
| 296 | DO jj = 2, jpjm1 |
|---|
| 297 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 298 | ! (ISF) no light penetration below the ice shelves |
|---|
| 299 | qsr_hc(ji,jj,jk) = etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1) |
|---|
| 300 | END DO |
|---|
| 301 | END DO |
|---|
| 302 | END DO |
|---|
| 303 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 304 | IF ( lk_lim3 .AND. ln_qsr_ice ) THEN |
|---|
| 305 | oatte(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 306 | iatte(:,:) = oatte(:,:) |
|---|
| 307 | ENDIF |
|---|
| 308 | ! |
|---|
| 309 | ENDIF |
|---|
| 310 | ! |
|---|
| 311 | ENDIF |
|---|
| 312 | ! |
|---|
| 313 | ! Add to the general trend |
|---|
| 314 | DO jk = 1, nksr |
|---|
| 315 | DO jj = 2, jpjm1 |
|---|
| 316 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 317 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 318 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 319 | END DO |
|---|
| 320 | END DO |
|---|
| 321 | END DO |
|---|
| 322 | ! |
|---|
| 323 | ENDIF |
|---|
| 324 | ! |
|---|
| 325 | IF( lrst_oce ) THEN ! Write in the ocean restart file |
|---|
| 326 | ! ******************************* |
|---|
| 327 | IF(lwp) WRITE(numout,*) |
|---|
| 328 | IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ', & |
|---|
| 329 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 330 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 331 | CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc ) |
|---|
| 332 | ! |
|---|
| 333 | ENDIF |
|---|
| 334 | |
|---|
| 335 | IF( l_trdtra ) THEN ! qsr tracers trends saved for diagnostics |
|---|
| 336 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 337 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_trd_qsr, ztrdt ) |
|---|
| 338 | CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 339 | ENDIF |
|---|
| 340 | ! ! print mean trends (used for debugging) |
|---|
| 341 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr - Ta: ', mask1=tmask, clinfo3='tra-ta' ) |
|---|
| 342 | ! |
|---|
| 343 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 344 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 345 | ! |
|---|
| 346 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr') |
|---|
| 347 | ! |
|---|
| 348 | END SUBROUTINE tra_qsr |
|---|
| 349 | |
|---|
| 350 | |
|---|
| 351 | SUBROUTINE tra_qsr_init |
|---|
| 352 | !!---------------------------------------------------------------------- |
|---|
| 353 | !! *** ROUTINE tra_qsr_init *** |
|---|
| 354 | !! |
|---|
| 355 | !! ** Purpose : Initialization for the penetrative solar radiation |
|---|
| 356 | !! |
|---|
| 357 | !! ** Method : The profile of solar radiation within the ocean is set |
|---|
| 358 | !! from two length scale of penetration (rn_si0,rn_si1) and a ratio |
|---|
| 359 | !! (rn_abs). These parameters are read in the namtra_qsr namelist. The |
|---|
| 360 | !! default values correspond to clear water (type I in Jerlov' |
|---|
| 361 | !! (1968) classification. |
|---|
| 362 | !! called by tra_qsr at the first timestep (nit000) |
|---|
| 363 | !! |
|---|
| 364 | !! ** Action : - initialize rn_si0, rn_si1 and rn_abs |
|---|
| 365 | !! |
|---|
| 366 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 367 | !!---------------------------------------------------------------------- |
|---|
| 368 | ! |
|---|
| 369 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 370 | INTEGER :: irgb, ierror, ioptio, nqsr ! local integer |
|---|
| 371 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 372 | REAL(wp) :: zz0, zc0 , zc1, zcoef ! local scalars |
|---|
| 373 | REAL(wp) :: zz1, zc2 , zc3, zchl ! - - |
|---|
| 374 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 375 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea |
|---|
| 376 | ! |
|---|
| 377 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 378 | TYPE(FLD_N) :: sn_chl ! informations about the chlorofyl field to be read |
|---|
| 379 | !! |
|---|
| 380 | NAMELIST/namtra_qsr/ sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice, & |
|---|
| 381 | & nn_chldta, rn_abs, rn_si0, rn_si1 |
|---|
| 382 | !!---------------------------------------------------------------------- |
|---|
| 383 | |
|---|
| 384 | ! |
|---|
| 385 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr_init') |
|---|
| 386 | ! |
|---|
| 387 | ! clem init for oatte and iatte |
|---|
| 388 | IF( .NOT. ln_rstart ) THEN |
|---|
| 389 | oatte(:,:) = 1._wp |
|---|
| 390 | iatte(:,:) = 1._wp |
|---|
| 391 | ENDIF |
|---|
| 392 | ! |
|---|
| 393 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 394 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 395 | ! |
|---|
| 396 | |
|---|
| 397 | REWIND( numnam_ref ) ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration |
|---|
| 398 | READ ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901) |
|---|
| 399 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp ) |
|---|
| 400 | |
|---|
| 401 | REWIND( numnam_cfg ) ! Namelist namtra_qsr in configuration namelist : Ratio and length of penetration |
|---|
| 402 | READ ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 ) |
|---|
| 403 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp ) |
|---|
| 404 | IF(lwm) WRITE ( numond, namtra_qsr ) |
|---|
| 405 | ! |
|---|
| 406 | IF(lwp) THEN ! control print |
|---|
| 407 | WRITE(numout,*) |
|---|
| 408 | WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation' |
|---|
| 409 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 410 | WRITE(numout,*) ' Namelist namtra_qsr : set the parameter of penetration' |
|---|
| 411 | WRITE(numout,*) ' Light penetration (T) or not (F) ln_traqsr = ', ln_traqsr |
|---|
| 412 | WRITE(numout,*) ' RGB (Red-Green-Blue) light penetration ln_qsr_rgb = ', ln_qsr_rgb |
|---|
| 413 | WRITE(numout,*) ' 2 band light penetration ln_qsr_2bd = ', ln_qsr_2bd |
|---|
| 414 | WRITE(numout,*) ' bio-model light penetration ln_qsr_bio = ', ln_qsr_bio |
|---|
| 415 | WRITE(numout,*) ' light penetration for ice-model LIM3 ln_qsr_ice = ', ln_qsr_ice |
|---|
| 416 | WRITE(numout,*) ' RGB : Chl data (=1) or cst value (=0) nn_chldta = ', nn_chldta |
|---|
| 417 | WRITE(numout,*) ' RGB & 2 bands: fraction of light (rn_si1) rn_abs = ', rn_abs |
|---|
| 418 | WRITE(numout,*) ' RGB & 2 bands: shortess depth of extinction rn_si0 = ', rn_si0 |
|---|
| 419 | WRITE(numout,*) ' 2 bands: longest depth of extinction rn_si1 = ', rn_si1 |
|---|
| 420 | WRITE(numout,*) ' light penetration for ice-model LIM3 ln_qsr_ice = ', ln_qsr_ice |
|---|
| 421 | ENDIF |
|---|
| 422 | |
|---|
| 423 | IF( ln_traqsr ) THEN ! control consistency |
|---|
| 424 | ! |
|---|
| 425 | IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio ) THEN |
|---|
| 426 | CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' ) |
|---|
| 427 | ln_qsr_bio = .FALSE. |
|---|
| 428 | ENDIF |
|---|
| 429 | ! |
|---|
| 430 | ioptio = 0 ! Parameter control |
|---|
| 431 | IF( ln_qsr_rgb ) ioptio = ioptio + 1 |
|---|
| 432 | IF( ln_qsr_2bd ) ioptio = ioptio + 1 |
|---|
| 433 | IF( ln_qsr_bio ) ioptio = ioptio + 1 |
|---|
| 434 | ! |
|---|
| 435 | IF( ioptio /= 1 ) & |
|---|
| 436 | CALL ctl_stop( ' Choose ONE type of light penetration in namelist namtra_qsr', & |
|---|
| 437 | & ' 2 bands, 3 RGB bands or bio-model light penetration' ) |
|---|
| 438 | ! |
|---|
| 439 | IF( ln_qsr_rgb .AND. nn_chldta == 0 ) nqsr = 1 |
|---|
| 440 | IF( ln_qsr_rgb .AND. nn_chldta == 1 ) nqsr = 2 |
|---|
| 441 | IF( ln_qsr_2bd ) nqsr = 3 |
|---|
| 442 | IF( ln_qsr_bio ) nqsr = 4 |
|---|
| 443 | ! |
|---|
| 444 | IF(lwp) THEN ! Print the choice |
|---|
| 445 | WRITE(numout,*) |
|---|
| 446 | IF( nqsr == 1 ) WRITE(numout,*) ' R-G-B light penetration - Constant Chlorophyll' |
|---|
| 447 | IF( nqsr == 2 ) WRITE(numout,*) ' R-G-B light penetration - Chl data ' |
|---|
| 448 | IF( nqsr == 3 ) WRITE(numout,*) ' 2 bands light penetration' |
|---|
| 449 | IF( nqsr == 4 ) WRITE(numout,*) ' bio-model light penetration' |
|---|
| 450 | ENDIF |
|---|
| 451 | ! |
|---|
| 452 | ENDIF |
|---|
| 453 | ! ! ===================================== ! |
|---|
| 454 | IF( ln_traqsr ) THEN ! Initialisation of Light Penetration ! |
|---|
| 455 | ! ! ===================================== ! |
|---|
| 456 | ! |
|---|
| 457 | xsi0r = 1.e0 / rn_si0 |
|---|
| 458 | xsi1r = 1.e0 / rn_si1 |
|---|
| 459 | ! ! ---------------------------------- ! |
|---|
| 460 | IF( ln_qsr_rgb ) THEN ! Red-Green-Blue light penetration ! |
|---|
| 461 | ! ! ---------------------------------- ! |
|---|
| 462 | ! |
|---|
| 463 | CALL trc_oce_rgb( rkrgb ) !* tabulated attenuation coef. |
|---|
| 464 | ! |
|---|
| 465 | ! !* level of light extinction |
|---|
| 466 | IF( ln_sco ) THEN ; nksr = jpkm1 |
|---|
| 467 | ELSE ; nksr = trc_oce_ext_lev( r_si2, 0.33e2 ) |
|---|
| 468 | ENDIF |
|---|
| 469 | |
|---|
| 470 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 471 | ! |
|---|
| 472 | IF( nn_chldta == 1 ) THEN !* Chl data : set sf_chl structure |
|---|
| 473 | IF(lwp) WRITE(numout,*) |
|---|
| 474 | IF(lwp) WRITE(numout,*) ' Chlorophyll read in a file' |
|---|
| 475 | ALLOCATE( sf_chl(1), STAT=ierror ) |
|---|
| 476 | IF( ierror > 0 ) THEN |
|---|
| 477 | CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' ) ; RETURN |
|---|
| 478 | ENDIF |
|---|
| 479 | ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1) ) |
|---|
| 480 | IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 481 | ! ! fill sf_chl with sn_chl and control print |
|---|
| 482 | CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init', & |
|---|
| 483 | & 'Solar penetration function of read chlorophyll', 'namtra_qsr' ) |
|---|
| 484 | ! |
|---|
| 485 | ELSE !* constant Chl : compute once for all the distribution of light (etot3) |
|---|
| 486 | IF(lwp) WRITE(numout,*) |
|---|
| 487 | IF(lwp) WRITE(numout,*) ' Constant Chlorophyll concentration = 0.05' |
|---|
| 488 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 489 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 490 | ELSE ! constant volume: computes one for all |
|---|
| 491 | IF(lwp) WRITE(numout,*) ' fixed volume: light distribution computed one for all' |
|---|
| 492 | ! |
|---|
| 493 | zchl = 0.05 ! constant chlorophyll |
|---|
| 494 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 495 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 496 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 497 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 498 | ! |
|---|
| 499 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 500 | ze0(:,:,1) = rn_abs |
|---|
| 501 | ze1(:,:,1) = zcoef |
|---|
| 502 | ze2(:,:,1) = zcoef |
|---|
| 503 | ze3(:,:,1) = zcoef |
|---|
| 504 | zea(:,:,1) = tmask(:,:,1) ! = ( ze0+ze1+z2+ze3 ) * tmask |
|---|
| 505 | |
|---|
| 506 | DO jk = 2, nksr+1 |
|---|
| 507 | !CDIR NOVERRCHK |
|---|
| 508 | DO jj = 1, jpj |
|---|
| 509 | !CDIR NOVERRCHK |
|---|
| 510 | DO ji = 1, jpi |
|---|
| 511 | zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r ) |
|---|
| 512 | zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 513 | zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 514 | zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 515 | ze0(ji,jj,jk) = zc0 |
|---|
| 516 | ze1(ji,jj,jk) = zc1 |
|---|
| 517 | ze2(ji,jj,jk) = zc2 |
|---|
| 518 | ze3(ji,jj,jk) = zc3 |
|---|
| 519 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 520 | END DO |
|---|
| 521 | END DO |
|---|
| 522 | END DO |
|---|
| 523 | ! |
|---|
| 524 | DO jk = 1, nksr |
|---|
| 525 | ! (ISF) no light penetration below the ice shelves |
|---|
| 526 | etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1) |
|---|
| 527 | END DO |
|---|
| 528 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 529 | ENDIF |
|---|
| 530 | ENDIF |
|---|
| 531 | ! |
|---|
| 532 | ENDIF |
|---|
| 533 | ! ! ---------------------------------- ! |
|---|
| 534 | IF( ln_qsr_2bd ) THEN ! 2 bands light penetration ! |
|---|
| 535 | ! ! ---------------------------------- ! |
|---|
| 536 | ! |
|---|
| 537 | ! ! level of light extinction |
|---|
| 538 | nksr = trc_oce_ext_lev( rn_si1, 1.e2 ) |
|---|
| 539 | IF(lwp) THEN |
|---|
| 540 | WRITE(numout,*) |
|---|
| 541 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 542 | ENDIF |
|---|
| 543 | ! |
|---|
| 544 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 545 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 546 | ELSE ! constant volume: computes one for all |
|---|
| 547 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 548 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 549 | DO jk = 1, nksr !* solar heat absorbed at T-point computed once for all |
|---|
| 550 | DO jj = 1, jpj ! top 400 meters |
|---|
| 551 | DO ji = 1, jpi |
|---|
| 552 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 553 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 554 | etot3(ji,jj,jk) = ( zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1) ) * tmask(ji,jj,1) |
|---|
| 555 | END DO |
|---|
| 556 | END DO |
|---|
| 557 | END DO |
|---|
| 558 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 559 | ! |
|---|
| 560 | ENDIF |
|---|
| 561 | ENDIF |
|---|
| 562 | ! ! ===================================== ! |
|---|
| 563 | ELSE ! No light penetration ! |
|---|
| 564 | ! ! ===================================== ! |
|---|
| 565 | IF(lwp) THEN |
|---|
| 566 | WRITE(numout,*) |
|---|
| 567 | WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration' |
|---|
| 568 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 569 | ENDIF |
|---|
| 570 | ENDIF |
|---|
| 571 | ! |
|---|
| 572 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 573 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 574 | ! |
|---|
| 575 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr_init') |
|---|
| 576 | ! |
|---|
| 577 | END SUBROUTINE tra_qsr_init |
|---|
| 578 | |
|---|
| 579 | !!====================================================================== |
|---|
| 580 | END MODULE traqsr |
|---|
