1 | MODULE sbcwave |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE sbcwave *** |
---|
4 | !! Wave module |
---|
5 | !!====================================================================== |
---|
6 | !! History : 3.6 !2014-09 (Clementi E, Oddo P)New Stokes Drift Computation |
---|
7 | !! : 3.3.1 !2011-09 (Adani M) Original code: Drag Coefficient |
---|
8 | !! : 3.4 !2012-10 (Adani M) Stokes Drift |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | USE iom ! I/O manager library |
---|
11 | USE in_out_manager ! I/O manager |
---|
12 | USE lib_mpp ! distribued memory computing library |
---|
13 | USE fldread ! read input fields |
---|
14 | USE oce |
---|
15 | USE sbc_oce ! Surface boundary condition: ocean fields |
---|
16 | USE domvvl |
---|
17 | USE phycst |
---|
18 | |
---|
19 | !!---------------------------------------------------------------------- |
---|
20 | !! sbc_wave : read drag coefficient from wave model in netcdf files |
---|
21 | !!---------------------------------------------------------------------- |
---|
22 | |
---|
23 | IMPLICIT NONE |
---|
24 | PRIVATE |
---|
25 | |
---|
26 | PUBLIC sbc_wave ! routine called in sbc_blk_core or sbc_blk_mfs |
---|
27 | |
---|
28 | INTEGER , PARAMETER :: jpfld = 4 ! number of files to read for stokes drift |
---|
29 | INTEGER , PARAMETER :: jp_usd = 1 ! index of stokes drift (i-component) (m/s) at T-point |
---|
30 | INTEGER , PARAMETER :: jp_vsd = 2 ! index of stokes drift (j-component) (m/s) at T-point |
---|
31 | INTEGER , PARAMETER :: jp_swh = 3 ! index of significant wave hight (m) at T-point |
---|
32 | INTEGER , PARAMETER :: jp_wmp = 4 ! index of mean wave period (s) at T-point |
---|
33 | ! |
---|
34 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_cd ! structure of input fields (file informations, fields read) Drag Coefficient |
---|
35 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_sd ! structure of input fields (file informations, fields read) Stokes Drift |
---|
36 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_wn ! structure of input fields (file informations, fields read) wave number for Qiao |
---|
37 | REAL(wp),PUBLIC,ALLOCATABLE,DIMENSION (:,:) :: cdn_wave |
---|
38 | REAL(wp),ALLOCATABLE,DIMENSION (:,:) :: usd2d,vsd2d |
---|
39 | REAL(wp),PUBLIC,ALLOCATABLE,DIMENSION (:,:) :: swh,wmp,wnum |
---|
40 | REAL(wp),PUBLIC,ALLOCATABLE,DIMENSION (:,:) :: usd2dt,vsd2dt,tsd2d |
---|
41 | REAL(wp),PUBLIC,ALLOCATABLE,DIMENSION (:,:,:) :: usd3d,vsd3d,wsd3d |
---|
42 | |
---|
43 | !! * Substitutions |
---|
44 | # include "domzgr_substitute.h90" |
---|
45 | !!---------------------------------------------------------------------- |
---|
46 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
---|
47 | !! $Id: $ |
---|
48 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
49 | !!---------------------------------------------------------------------- |
---|
50 | CONTAINS |
---|
51 | |
---|
52 | SUBROUTINE sbc_wave( kt ) |
---|
53 | !!--------------------------------------------------------------------- |
---|
54 | !! *** ROUTINE sbc_apr *** |
---|
55 | !! |
---|
56 | !! ** Purpose : read drag coefficient from wave model in netcdf files. |
---|
57 | !! |
---|
58 | !! ** Method : - Read namelist namsbc_wave |
---|
59 | !! - Read Cd_n10 fields in netcdf files |
---|
60 | !! - Read stokes drift 2d in netcdf files |
---|
61 | !! - Read wave number in netcdf files |
---|
62 | !! - Compute 3d stokes drift using Breivik et al.,2014 |
---|
63 | !! formulation |
---|
64 | !! ** action : |
---|
65 | !! |
---|
66 | !!--------------------------------------------------------------------- |
---|
67 | USE oce, ONLY : un,vn,hdivn,rotn |
---|
68 | USE divcur |
---|
69 | USE wrk_nemo |
---|
70 | USE zdf_oce, ONLY : ln_zdfqiao |
---|
71 | #if defined key_bdy |
---|
72 | USE bdy_oce, ONLY : bdytmask |
---|
73 | #endif |
---|
74 | INTEGER, INTENT( in ) :: kt ! ocean time step |
---|
75 | INTEGER :: ierror ! return error code |
---|
76 | INTEGER :: ifpr, jj,ji,jk |
---|
77 | INTEGER :: ios ! Local integer output status for namelist read |
---|
78 | REAL(wp),DIMENSION(:,:,:),POINTER :: udummy,vdummy,hdivdummy,rotdummy |
---|
79 | REAL(wp) :: z2dt,z1_2dt |
---|
80 | REAL(wp) :: ztransp,zsp0, zk, zus,zvs |
---|
81 | REAL(wp), DIMENSION(jpi,jpj) :: zfac |
---|
82 | TYPE(FLD_N), DIMENSION(jpfld) :: slf_i ! array of namelist informations on the fields to read |
---|
83 | CHARACTER(len=100) :: cn_dir ! Root directory for location of drag coefficient files |
---|
84 | TYPE(FLD_N) :: sn_cdg, sn_usd, sn_vsd, & |
---|
85 | & sn_swh, sn_wmp, sn_wnum ! informations about the fields to be read |
---|
86 | !!--------------------------------------------------------------------- |
---|
87 | NAMELIST/namsbc_wave/ sn_cdg, cn_dir, sn_usd, sn_vsd, sn_swh, sn_wmp, sn_wnum |
---|
88 | !!--------------------------------------------------------------------- |
---|
89 | |
---|
90 | !!---------------------------------------------------------------------- |
---|
91 | ! |
---|
92 | ! |
---|
93 | ! ! -------------------- ! |
---|
94 | IF( kt == nit000 ) THEN ! First call kt=nit000 ! |
---|
95 | ! ! -------------------- ! |
---|
96 | REWIND( numnam_ref ) ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model |
---|
97 | READ ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901) |
---|
98 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp ) |
---|
99 | |
---|
100 | REWIND( numnam_cfg ) ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model |
---|
101 | READ ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 ) |
---|
102 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp ) |
---|
103 | IF(lwm) WRITE ( numond, namsbc_wave ) |
---|
104 | ! |
---|
105 | |
---|
106 | IF ( ln_cdgw ) THEN |
---|
107 | ALLOCATE( sf_cd(1), STAT=ierror ) !* allocate and fill sf_wave with sn_cdg |
---|
108 | IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_wave: unable to allocate sf_wave structure' ) |
---|
109 | ! |
---|
110 | ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1) ) |
---|
111 | IF( sn_cdg%ln_tint ) ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) ) |
---|
112 | CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave', 'Wave module ', 'namsbc_wave' ) |
---|
113 | ALLOCATE( cdn_wave(jpi,jpj) ) |
---|
114 | cdn_wave(:,:) = 0.0 |
---|
115 | ENDIF |
---|
116 | |
---|
117 | IF ( ln_sdw ) THEN |
---|
118 | slf_i(jp_usd) = sn_usd ; slf_i(jp_vsd) = sn_vsd; |
---|
119 | slf_i(jp_swh) = sn_swh ; slf_i(jp_wmp) = sn_wmp; |
---|
120 | ALLOCATE( sf_sd(jpfld), STAT=ierror ) !* allocate and fill sf_sd with stokes drift |
---|
121 | IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_wave: unable to allocate sf_wave structure' ) |
---|
122 | ! |
---|
123 | DO ifpr= 1, jpfld |
---|
124 | ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) ) |
---|
125 | IF( slf_i(ifpr)%ln_tint ) ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) ) |
---|
126 | END DO |
---|
127 | ! |
---|
128 | CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave', 'Wave module ', 'namsbc_wave' ) |
---|
129 | ALLOCATE( usd2d(jpi,jpj),vsd2d(jpi,jpj),usd2dt(jpi,jpj),vsd2dt(jpi,jpj)) |
---|
130 | ALLOCATE( usd3d(jpi,jpj,jpk),vsd3d(jpi,jpj,jpk),wsd3d(jpi,jpj,jpk) ) |
---|
131 | ALLOCATE( swh(jpi,jpj), wmp(jpi,jpj) ) |
---|
132 | usd2d(:,:) = 0.0 ; vsd2d(:,:) = 0.0 ; |
---|
133 | usd2dt(:,:) = 0.0 ; vsd2dt(:,:) = 0.0 ; |
---|
134 | usd3d(:,:,:) = 0.0 ; vsd3d(:,:,:) = 0.0 ; |
---|
135 | wsd3d(:,:,:) = 0.0 ; |
---|
136 | swh(:,:) = 0.0 ; wmp(:,:) = 0.0 ; |
---|
137 | IF ( ln_zdfqiao ) THEN |
---|
138 | ALLOCATE( sf_wn(1), STAT=ierror ) !* allocate and fillsf_wave with sn_wnum |
---|
139 | IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_wave: unable toallocate sf_wave structure' ) |
---|
140 | ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1) ) |
---|
141 | IF( sn_wnum%ln_tint ) ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) ) |
---|
142 | CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' ) |
---|
143 | ALLOCATE( wnum(jpi,jpj),tsd2d(jpi,jpj) ) |
---|
144 | wnum(:,:) = 0.0; tsd2d(:,:) = 0.0 |
---|
145 | ENDIF |
---|
146 | ENDIF |
---|
147 | ENDIF |
---|
148 | ! |
---|
149 | IF ( ln_cdgw ) THEN |
---|
150 | CALL fld_read( kt, nn_fsbc, sf_cd ) !* read drag coefficient from external forcing |
---|
151 | cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1) |
---|
152 | ENDIF |
---|
153 | IF ( ln_sdw ) THEN |
---|
154 | CALL fld_read( kt, nn_fsbc, sf_sd ) !* read wave parameters from external forcing |
---|
155 | swh(:,:) = sf_sd(jp_swh)%fnow(:,:,1) |
---|
156 | wmp(:,:) = sf_sd(jp_wmp)%fnow(:,:,1) |
---|
157 | usd2dt(:,:) = sf_sd(jp_usd)%fnow(:,:,1) |
---|
158 | vsd2dt(:,:) = sf_sd(jp_vsd)%fnow(:,:,1) |
---|
159 | !------------------------------------------------- |
---|
160 | ! Interpolate stokes drift into the grid_V and grid_V |
---|
161 | !------------------------------------------------- |
---|
162 | DO jj = 1, jpjm1 |
---|
163 | DO ji = 1, jpim1 |
---|
164 | usd2d(ji,jj) = 0.5 * ( 2. - umask(ji,jj,1) ) * ( usd2dt(ji,jj) * tmask(ji,jj,1) & |
---|
165 | & + usd2dt(ji+1,jj) * tmask(ji+1,jj,1) ) |
---|
166 | |
---|
167 | vsd2d(ji,jj) = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( vsd2dt(ji,jj) * tmask(ji,jj,1) & |
---|
168 | & + vsd2dt(ji,jj+1) * tmask(ji,jj+1,1) ) |
---|
169 | END DO |
---|
170 | END DO |
---|
171 | !Computation of the 3d Stokes Drift according to Breivik et al.,2014 |
---|
172 | !(DOI: 10.1175/JPO-D-14-0020.1) |
---|
173 | DO jk = 1, jpk |
---|
174 | DO jj = 1, jpj |
---|
175 | DO ji = 1, jpi |
---|
176 | |
---|
177 | ! On T grid |
---|
178 | ! Stokes transport speed estimated from Hs and Tmean |
---|
179 | ztransp = 2.0_wp*rpi*swh(ji,jj)**2.0_wp/(16.0_wp*MAX(wmp(ji,jj),0.0000001_wp)) |
---|
180 | |
---|
181 | ! Stokes surface speed |
---|
182 | zsp0 = SQRT( sf_sd(jp_usd)%fnow(ji,jj,1)**2 + sf_sd(jp_vsd)%fnow(ji,jj,1)**2) |
---|
183 | |
---|
184 | ! Wavenumber scale |
---|
185 | zk = ABS(zsp0)/MAX(ABS(5.97_wp*ztransp),0.0000001_wp) |
---|
186 | |
---|
187 | ! Depth attenuation |
---|
188 | zfac(ji,jj) = EXP(-2.0_wp*zk*fsdept(ji,jj,jk))/(1.0_wp+8.0_wp*zk*fsdept(ji,jj,jk)) |
---|
189 | |
---|
190 | END DO |
---|
191 | END DO |
---|
192 | ! |
---|
193 | DO jj = 1, jpj-1 |
---|
194 | DO ji = 1, jpi-1 |
---|
195 | ! Into the U and V Grid |
---|
196 | zus = 0.5 * ( 2. - umask(ji,jj,1) ) * ( zfac(ji,jj) * tmask(ji,jj,1) & |
---|
197 | & + zfac(ji+1,jj) * tmask(ji+1,jj,1) ) |
---|
198 | |
---|
199 | zvs = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( zfac(ji,jj) * tmask(ji,jj,1) & |
---|
200 | & + zfac(ji,jj+1) * tmask(ji,jj+1,1) ) |
---|
201 | |
---|
202 | usd3d(ji,jj,jk) = usd2d(ji,jj)*zus |
---|
203 | vsd3d(ji,jj,jk) = vsd2d(ji,jj)*zvs |
---|
204 | END DO |
---|
205 | END DO |
---|
206 | |
---|
207 | END DO |
---|
208 | |
---|
209 | CALL wrk_alloc( jpi,jpj,jpk,udummy,vdummy,hdivdummy,rotdummy) |
---|
210 | !------------------------------------------------------------------- |
---|
211 | ! Store horiz. velocity divergence and Rot in TMP array |
---|
212 | ! ------------------------------------------------------------------- |
---|
213 | |
---|
214 | udummy(:,:,:) = un(:,:,:) |
---|
215 | vdummy(:,:,:) = vn(:,:,:) |
---|
216 | hdivdummy(:,:,:) = hdivn(:,:,:) |
---|
217 | rotdummy(:,:,:) = rotn(:,:,:) |
---|
218 | un(:,:,:) = usd3d(:,:,:) |
---|
219 | vn(:,:,:) = vsd3d(:,:,:) |
---|
220 | |
---|
221 | ! Compute divergence using 3d stokes drift to calculate vertical SD |
---|
222 | ! velocity |
---|
223 | ! ------------------------------------------------------------------- |
---|
224 | |
---|
225 | CALL div_cur(kt) |
---|
226 | |
---|
227 | ! ------------------------------------------------------------------- |
---|
228 | ! !------------------------------! |
---|
229 | ! ! Now Vertical Velocity ! |
---|
230 | ! !------------------------------! |
---|
231 | z2dt = 2._wp * rdt ! set time step size (Euler/Leapfrog) |
---|
232 | |
---|
233 | z1_2dt = 1.e0 / z2dt |
---|
234 | DO jk = jpkm1, 1, -1 ! integrate from the bottom the hor. divergence |
---|
235 | ! - ML - need 3 lines here because replacement of fse3t by its expression yields too long lines otherwise |
---|
236 | wsd3d(:,:,jk) = wsd3d(:,:,jk+1) - fse3t_n(:,:,jk) * hdivn(:,:,jk) & |
---|
237 | & - ( fse3t_a(:,:,jk) - fse3t_b(:,:,jk) ) & |
---|
238 | & * tmask(:,:,jk) * z1_2dt |
---|
239 | #if defined key_bdy |
---|
240 | wsd3d(:,:,jk) = wsd3d(:,:,jk) * bdytmask(:,:) |
---|
241 | #endif |
---|
242 | END DO |
---|
243 | ! Back to state variables |
---|
244 | ! ------------------------------------------------------------------- |
---|
245 | hdivn(:,:,:) = hdivdummy(:,:,:) |
---|
246 | rotn(:,:,:) = rotdummy(:,:,:) |
---|
247 | vn(:,:,:) = vdummy(:,:,:) |
---|
248 | un(:,:,:) = udummy(:,:,:) |
---|
249 | |
---|
250 | CALL wrk_dealloc( jpi,jpj,jpk,udummy,vdummy,hdivdummy,rotdummy) |
---|
251 | ! |
---|
252 | IF ( ln_zdfqiao ) THEN |
---|
253 | wnum(:,:) = sf_wn(1)%fnow(:,:,1) |
---|
254 | ! Calculate the module of the stokes drift on T grid |
---|
255 | !------------------------------------------------- |
---|
256 | DO jj = 1, jpj |
---|
257 | DO ji = 1, jpi |
---|
258 | tsd2d(ji,jj) = ((sf_sd(jp_usd)%fnow(ji,jj,1) * tmask(ji,jj,1))**2.0 + & |
---|
259 | & (sf_sd(jp_vsd)%fnow(ji,jj,1) * tmask(ji,jj,1))**2.0)**0.5 |
---|
260 | END DO |
---|
261 | END DO |
---|
262 | ENDIF |
---|
263 | ENDIF |
---|
264 | |
---|
265 | |
---|
266 | END SUBROUTINE sbc_wave |
---|
267 | |
---|
268 | !!====================================================================== |
---|
269 | END MODULE sbcwave |
---|