New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/2015/dev_MetOffice_merge_2015/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/2015/dev_MetOffice_merge_2015/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 6012

Last change on this file since 6012 was 6006, checked in by mathiot, 9 years ago

Merged ice sheet coupling branch
  • Property svn:keywords set to Id
File size: 14.4 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_lim3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diurnal_bulk
30   
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   rst_opn         ! routine called by step module
35   PUBLIC   rst_write       ! routine called by step module
36   PUBLIC   rst_read        ! routine called by istate module
37   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE rst_opn( kt )
50      !!---------------------------------------------------------------------
51      !!                   ***  ROUTINE rst_opn  ***
52      !!                     
53      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
54      !!              + open the restart when we are one time step before nitrst
55      !!                   - restart header is defined when kt = nitrst-1
56      !!                   - restart data  are written when kt = nitrst
57      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
58      !!----------------------------------------------------------------------
59      INTEGER, INTENT(in) ::   kt     ! ocean time-step
60      !!
61      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
62      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
63      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
64      !!----------------------------------------------------------------------
65      !
66      IF( kt == nit000 ) THEN   ! default definitions
67         lrst_oce = .FALSE.   
68         IF( ln_rst_list ) THEN
69            nrst_lst = 1
70            nitrst = nstocklist( nrst_lst )
71         ELSE
72            nitrst = nitend
73         ENDIF
74      ENDIF
75
76      ! frequency-based restart dumping (nn_stock)
77      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
78         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
79         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
80         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
81      ENDIF
82      ! to get better performances with NetCDF format:
83      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
84      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
85      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
86         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
87            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
88            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
89            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
90            ENDIF
91            ! create the file
92            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
93            clpath = TRIM(cn_ocerst_outdir)
94            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
95            IF(lwp) THEN
96               WRITE(numout,*)
97               SELECT CASE ( jprstlib )
98               CASE ( jprstdimg )   ;   WRITE(numout,*)                            &
99                   '             open ocean restart binary file: ',TRIM(clpath)//clname
100               CASE DEFAULT         ;   WRITE(numout,*)                            &
101                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
102               END SELECT
103               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
104               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
105               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
106               ENDIF
107            ENDIF
108            !
109            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
110            lrst_oce = .TRUE.
111         ENDIF
112      ENDIF
113      !
114   END SUBROUTINE rst_opn
115
116
117   SUBROUTINE rst_write( kt )
118      !!---------------------------------------------------------------------
119      !!                   ***  ROUTINE rstwrite  ***
120      !!                     
121      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
122      !!
123      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
124      !!              file, save fields which are necessary for restart
125      !!----------------------------------------------------------------------
126      INTEGER, INTENT(in) ::   kt   ! ocean time-step
127      !!----------------------------------------------------------------------
128
129                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
130                     CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
131      IF ( .NOT. ln_diurnal_only ) THEN
132                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
133                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
134                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
135                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
136                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
137                     !
138                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
139                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
140                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
141                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
142                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
143                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
144
145                  ! extra variable needed for the ice sheet coupling
146                  IF ( ln_iscpl ) THEN
147                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask     ) ! need to extrapolate T/S
148                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask     ) ! need to correct barotropic velocity
149                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask     ) ! need to correct barotropic velocity
150                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask    ) ! need to correct barotropic velocity
151                     CALL iom_rstput( kt, nitrst, numrow, 'fse3t_n', fse3t_n(:,:,:) )   ! need to compute temperature correction
152                     CALL iom_rstput( kt, nitrst, numrow, 'fse3u_n', fse3u_n(:,:,:) )   ! need to compute bt conservation
153                     CALL iom_rstput( kt, nitrst, numrow, 'fse3v_n', fse3v_n(:,:,:) )   ! need to compute bt conservation
154                     CALL iom_rstput( kt, nitrst, numrow, 'fsdepw_n', fsdepw_n(:,:,:) ) ! need to compute extrapolation if vvl
155                  END IF
156      ENDIF
157     
158      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst    ) 
159
160      IF( kt == nitrst ) THEN
161         CALL iom_close( numrow )     ! close the restart file (only at last time step)
162!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
163!!gm  not sure what to do here   ===>>>  ask to Sebastian
164         lrst_oce = .FALSE.
165            IF( ln_rst_list ) THEN
166               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
167               nitrst = nstocklist( nrst_lst )
168            ENDIF
169            lrst_oce = .FALSE.
170      ENDIF
171      !
172   END SUBROUTINE rst_write
173
174
175   SUBROUTINE rst_read_open
176      !!----------------------------------------------------------------------
177      !!                   ***  ROUTINE rst_read_open  ***
178      !!
179      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
180      !!
181      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
182      !!                the file has already been opened
183      !!----------------------------------------------------------------------
184      INTEGER        ::   jlibalt = jprstlib
185      LOGICAL        ::   llok
186      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
187      !!----------------------------------------------------------------------
188      !
189      IF( numror <= 0 ) THEN
190         IF(lwp) THEN                                             ! Contol prints
191            WRITE(numout,*)
192            SELECT CASE ( jprstlib )
193            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
194            CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
195            END SELECT
196            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
197            WRITE(numout,*) '~~~~~~~~'
198         ENDIF
199
200         clpath = TRIM(cn_ocerst_indir)
201         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
202         IF ( jprstlib == jprstdimg ) THEN
203           ! eventually read netcdf file (monobloc)  for restarting on different number of processors
204           ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
205           INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
206           IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
207         ENDIF
208         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
209      ENDIF
210   END SUBROUTINE rst_read_open
211
212
213   SUBROUTINE rst_read
214      !!----------------------------------------------------------------------
215      !!                   ***  ROUTINE rst_read  ***
216      !!
217      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
218      !!
219      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
220      !!----------------------------------------------------------------------
221      REAL(wp) ::   zrdt, zrdttra1
222      INTEGER  ::   jk
223      !!----------------------------------------------------------------------
224
225      CALL rst_read_open           ! open restart for reading (if not already opened)
226
227      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
228      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
229         CALL iom_get( numror, 'rdt', zrdt )
230         IF( zrdt /= rdt )   neuler = 0
231      ENDIF
232      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
233         CALL iom_get( numror, 'rdttra1', zrdttra1 )
234         IF( zrdttra1 /= rdttra(1) )   neuler = 0
235      ENDIF
236       
237     
238      ! Diurnal DSST
239      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst  ) 
240      IF ( ln_diurnal_only ) THEN
241         IF(lwp) WRITE( numout, * ) &
242         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
243         rhop = rau0
244         CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,1,jp_tem) ) 
245         RETURN
246      ENDIF 
247     
248      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
249         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
250         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
251         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
252         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
253         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
254      ELSE
255         neuler = 0
256      ENDIF
257      !
258      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
259      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
260      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
261      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
262      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
263      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
264         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
265      ELSE
266         CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )   
267      ENDIF
268      !
269      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
270         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
271         ub   (:,:,:)   = un   (:,:,:)
272         vb   (:,:,:)   = vn   (:,:,:)
273         sshb (:,:)     = sshn (:,:)
274         !
275         IF( lk_vvl ) THEN
276            DO jk = 1, jpk
277               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
278            END DO
279         ENDIF
280         !
281      ENDIF
282      !
283   END SUBROUTINE rst_read
284
285   !!=====================================================================
286END MODULE restart
Note: See TracBrowser for help on using the repository browser.