New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

diaobs.F90 in branches/2015/dev_MetOffice_merge_2015/NEMOGCM/NEMO/OPA_SRC/OBS – NEMO

Context Navigation

source: branches/2015/dev_MetOffice_merge_2015/NEMOGCM/NEMO/OPA_SRC/OBS/diaobs.F90 @ 6010

Last change on this file since 6010 was 6009, checked in by timgraham, 9 years ago
Fix for sstbias correction and OBS simplification merge to work together correctly
Property svn:keywords set to `Id`
File size: 40.7 KB

Line
1	MODULE diaobs
2	!!======================================================================
3	!! * MODULE diaobs *
4	!! Observation diagnostics: Computation of the misfit between data and
5	!! their model equivalent
6	!!======================================================================
7
8	!!----------------------------------------------------------------------
9	!! dia_obs_init : Reading and prepare observations
10	!! dia_obs : Compute model equivalent to observations
11	!! dia_obs_wri : Write observational diagnostics
12	!! calc_date : Compute the date of timestep in YYYYMMDD.HHMMSS format
13	!! ini_date : Compute the initial date YYYYMMDD.HHMMSS
14	!! fin_date : Compute the final date YYYYMMDD.HHMMSS
15	!!----------------------------------------------------------------------
16	!! * Modules used
17	USE wrk_nemo ! Memory Allocation
18	USE par_kind ! Precision variables
19	USE in_out_manager ! I/O manager
20	USE par_oce
21	USE dom_oce ! Ocean space and time domain variables
22	USE obs_read_prof ! Reading and allocation of profile obs
23	USE obs_read_surf ! Reading and allocation of surface obs
24	USE obs_sstbias ! Bias correction routine for SST
25	USE obs_readmdt ! Reading and allocation of MDT for SLA.
26	USE obs_prep ! Preparation of obs. (grid search etc).
27	USE obs_oper ! Observation operators
28	USE obs_write ! Writing of observation related diagnostics
29	USE obs_grid ! Grid searching
30	USE obs_read_altbias ! Bias treatment for altimeter
31	USE obs_profiles_def ! Profile data definitions
32	USE obs_surf_def ! Surface data definitions
33	USE obs_types ! Definitions for observation types
34	USE mpp_map ! MPP mapping
35	USE lib_mpp ! For ctl_warn/stop
36
37	IMPLICIT NONE
38
39	!! * Routine accessibility
40	PRIVATE
41	PUBLIC dia_obs_init, & ! Initialize and read observations
42	& dia_obs, & ! Compute model equivalent to observations
43	& dia_obs_wri, & ! Write model equivalent to observations
44	& dia_obs_dealloc, & ! Deallocate dia_obs data
45	& calc_date ! Compute the date of a timestep
46
47	!! * Module variables
48	LOGICAL, PUBLIC :: ln_diaobs !: Logical switch for the obs operator
49	LOGICAL :: ln_sstnight !: Logical switch for night mean SST obs
50
51	INTEGER :: nn_1dint !: Vertical interpolation method
52	INTEGER :: nn_2dint !: Horizontal interpolation method
53	INTEGER, DIMENSION(imaxavtypes) :: &
54	& nn_profdavtypes !: Profile data types representing a daily average
55	INTEGER :: nproftypes !: Number of profile obs types
56	INTEGER :: nsurftypes !: Number of surface obs types
57	INTEGER, DIMENSION(:), ALLOCATABLE :: &
58	& nvarsprof, & !: Number of profile variables
59	& nvarssurf !: Number of surface variables
60	INTEGER, DIMENSION(:), ALLOCATABLE :: &
61	& nextrprof, & !: Number of profile extra variables
62	& nextrsurf !: Number of surface extra variables
63	INTEGER, PUBLIC, ALLOCATABLE, DIMENSION(:) :: sstbias_type !SST bias type
64	TYPE(obs_surf), PUBLIC, POINTER, DIMENSION(:) :: &
65	& surfdata, & !: Initial surface data
66	& surfdataqc !: Surface data after quality control
67	TYPE(obs_prof), PUBLIC, POINTER, DIMENSION(:) :: &
68	& profdata, & !: Initial profile data
69	& profdataqc !: Profile data after quality control
70
71	CHARACTER(len=6), PUBLIC, DIMENSION(:), ALLOCATABLE :: &
72	& cobstypesprof, & !: Profile obs types
73	& cobstypessurf !: Surface obs types
74
75	!!----------------------------------------------------------------------
76	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
77	!! $Id$
78	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
79	!!----------------------------------------------------------------------
80
81	!! * Substitutions
82	# include "domzgr_substitute.h90"
83	CONTAINS
84
85	SUBROUTINE dia_obs_init
86	!!----------------------------------------------------------------------
87	!! * ROUTINE dia_obs_init *
88	!!
89	!! ** Purpose : Initialize and read observations
90	!!
91	!! ** Method : Read the namelist and call reading routines
92	!!
93	!! ** Action : Read the namelist and call reading routines
94	!!
95	!! History :
96	!! ! 06-03 (K. Mogensen) Original code
97	!! ! 06-05 (A. Weaver) Reformatted
98	!! ! 06-10 (A. Weaver) Cleaning and add controls
99	!! ! 07-03 (K. Mogensen) General handling of profiles
100	!! ! 14-08 (J.While) Incorporated SST bias correction
101	!! ! 15-02 (M. Martin) Simplification of namelist and code
102	!!----------------------------------------------------------------------
103
104	IMPLICIT NONE
105
106	!! * Local declarations
107	INTEGER, PARAMETER :: &
108	& jpmaxnfiles = 1000 ! Maximum number of files for each obs type
109	INTEGER, DIMENSION(:), ALLOCATABLE :: &
110	& ifilesprof, & ! Number of profile files
111	& ifilessurf ! Number of surface files
112	INTEGER :: ios ! Local integer output status for namelist read
113	INTEGER :: jtype ! Counter for obs types
114	INTEGER :: jvar ! Counter for variables
115	INTEGER :: jfile ! Counter for files
116
117	CHARACTER(len=128), DIMENSION(jpmaxnfiles) :: &
118	& cn_profbfiles, & ! T/S profile input filenames
119	& cn_sstfbfiles, & ! Sea surface temperature input filenames
120	& cn_slafbfiles, & ! Sea level anomaly input filenames
121	& cn_sicfbfiles, & ! Seaice concentration input filenames
122	& cn_velfbfiles, & ! Velocity profile input filenames
123	& cn_sstbias_files ! SST bias input filenames
124	CHARACTER(LEN=128) :: &
125	& cn_altbiasfile ! Altimeter bias input filename
126	CHARACTER(len=128), DIMENSION(:,:), ALLOCATABLE :: &
127	& clproffiles, & ! Profile filenames
128	& clsurffiles ! Surface filenames
129
130	LOGICAL :: ln_t3d ! Logical switch for temperature profiles
131	LOGICAL :: ln_s3d ! Logical switch for salinity profiles
132	LOGICAL :: ln_sla ! Logical switch for sea level anomalies
133	LOGICAL :: ln_sst ! Logical switch for sea surface temperature
134	LOGICAL :: ln_sic ! Logical switch for sea ice concentration
135	LOGICAL :: ln_vel3d ! Logical switch for velocity (u,v) obs
136	LOGICAL :: ln_nea ! Logical switch to remove obs near land
137	LOGICAL :: ln_altbias ! Logical switch for altimeter bias
138	LOGICAL :: ln_sstbias !: Logical switch for bias corection of SST
139	LOGICAL :: ln_ignmis ! Logical switch for ignoring missing files
140	LOGICAL :: ln_s_at_t ! Logical switch to compute model S at T obs
141	LOGICAL :: llvar1 ! Logical for profile variable 1
142	LOGICAL :: llvar2 ! Logical for profile variable 1
143	LOGICAL :: llnightav ! Logical for calculating night-time averages
144	LOGICAL, DIMENSION(jpmaxnfiles) :: lmask ! Used for finding number of sstbias files
145
146	REAL(dp) :: rn_dobsini ! Obs window start date YYYYMMDD.HHMMSS
147	REAL(dp) :: rn_dobsend ! Obs window end date YYYYMMDD.HHMMSS
148	REAL(wp), POINTER, DIMENSION(:,:) :: &
149	& zglam1, & ! Model longitudes for profile variable 1
150	& zglam2 ! Model longitudes for profile variable 2
151	REAL(wp), POINTER, DIMENSION(:,:) :: &
152	& zgphi1, & ! Model latitudes for profile variable 1
153	& zgphi2 ! Model latitudes for profile variable 2
154	REAL(wp), POINTER, DIMENSION(:,:,:) :: &
155	& zmask1, & ! Model land/sea mask associated with variable 1
156	& zmask2 ! Model land/sea mask associated with variable 2
157
158	NAMELIST/namobs/ln_diaobs, ln_t3d, ln_s3d, ln_sla, &
159	& ln_sst, ln_sic, ln_vel3d, &
160	& ln_altbias, ln_nea, ln_grid_global, &
161	& ln_grid_search_lookup, &
162	& ln_ignmis, ln_s_at_t, ln_sstnight, &
163	& cn_profbfiles, cn_slafbfiles, &
164	& cn_sstfbfiles, cn_sicfbfiles, &
165	& cn_velfbfiles, cn_altbiasfile, &
166	& cn_gridsearchfile, rn_gridsearchres, &
167	& rn_dobsini, rn_dobsend, nn_1dint, nn_2dint, &
168	& nn_msshc, rn_mdtcorr, rn_mdtcutoff, &
169	& nn_profdavtypes, ln_sstbias, cn_sstbias_files
170
171	INTEGER :: jnumsstbias
172	CALL wrk_alloc( jpi, jpj, zglam1 )
173	CALL wrk_alloc( jpi, jpj, zglam2 )
174	CALL wrk_alloc( jpi, jpj, zgphi1 )
175	CALL wrk_alloc( jpi, jpj, zgphi2 )
176	CALL wrk_alloc( jpi, jpj, jpk, zmask1 )
177	CALL wrk_alloc( jpi, jpj, jpk, zmask2 )
178
179	!-----------------------------------------------------------------------
180	! Read namelist parameters
181	!-----------------------------------------------------------------------
182
183	!Initalise all values in namelist arrays
184	ALLOCATE(sstbias_type(jpmaxnfiles))
185	! Some namelist arrays need initialising
186	cn_profbfiles(:) = ''
187	cn_slafbfiles(:) = ''
188	cn_sstfbfiles(:) = ''
189	cn_sicfbfiles(:) = ''
190	cn_velfbfiles(:) = ''
191	cn_sstbias_files(:) = ''
192	nn_profdavtypes(:) = -1
193
194	CALL ini_date( rn_dobsini )
195	CALL fin_date( rn_dobsend )
196
197	! Read namelist namobs : control observation diagnostics
198	REWIND( numnam_ref ) ! Namelist namobs in reference namelist
199	READ ( numnam_ref, namobs, IOSTAT = ios, ERR = 901)
200	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namobs in reference namelist', lwp )
201
202	REWIND( numnam_cfg ) ! Namelist namobs in configuration namelist
203	READ ( numnam_cfg, namobs, IOSTAT = ios, ERR = 902 )
204	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namobs in configuration namelist', lwp )
205	IF(lwm) WRITE ( numond, namobs )
206
207	IF ( .NOT. ln_diaobs ) THEN
208	IF(lwp) WRITE(numout,cform_war)
209	IF(lwp) WRITE(numout,*)' ln_diaobs is set to false so not calling dia_obs'
210	RETURN
211	ENDIF
212
213	!-----------------------------------------------------------------------
214	! Set up list of observation types to be used
215	! and the files associated with each type
216	!-----------------------------------------------------------------------
217
218	nproftypes = COUNT( (/ln_t3d .OR. ln_s3d, ln_vel3d /) )
219	nsurftypes = COUNT( (/ln_sla, ln_sst, ln_sic /) )
220
221	IF (ln_sstbias) THEN
222	lmask(:) = .FALSE.
223	WHERE (cn_sstbias_files(:) /= '') lmask(:) = .TRUE.
224	jnumsstbias = COUNT(lmask)
225	lmask(:) = .FALSE.
226	ENDIF
227
228	IF ( nproftypes == 0 .AND. nsurftypes == 0 ) THEN
229	IF(lwp) WRITE(numout,cform_war)
230	IF(lwp) WRITE(numout,*) ' ln_diaobs is set to true, but all obs operator logical flags', &
231	& ' ln_t3d, ln_s3d, ln_sla, ln_sst, ln_sic, ln_vel3d', &
232	& ' are set to .FALSE. so turning off calls to dia_obs'
233	nwarn = nwarn + 1
234	ln_diaobs = .FALSE.
235	RETURN
236	ENDIF
237
238	IF ( nproftypes > 0 ) THEN
239
240	ALLOCATE( cobstypesprof(nproftypes) )
241	ALLOCATE( ifilesprof(nproftypes) )
242	ALLOCATE( clproffiles(nproftypes,jpmaxnfiles) )
243
244	jtype = 0
245	IF (ln_t3d .OR. ln_s3d) THEN
246	jtype = jtype + 1
247	clproffiles(jtype,:) = cn_profbfiles(:)
248	cobstypesprof(jtype) = 'prof '
249	ifilesprof(jtype) = 0
250	DO jfile = 1, jpmaxnfiles
251	IF ( trim(clproffiles(jtype,jfile)) /= '' ) &
252	ifilesprof(jtype) = ifilesprof(jtype) + 1
253	END DO
254	ENDIF
255	IF (ln_vel3d) THEN
256	jtype = jtype + 1
257	clproffiles(jtype,:) = cn_velfbfiles(:)
258	cobstypesprof(jtype) = 'vel '
259	ifilesprof(jtype) = 0
260	DO jfile = 1, jpmaxnfiles
261	IF ( trim(clproffiles(jtype,jfile)) /= '' ) &
262	ifilesprof(jtype) = ifilesprof(jtype) + 1
263	END DO
264	ENDIF
265
266	ENDIF
267
268	IF ( nsurftypes > 0 ) THEN
269
270	ALLOCATE( cobstypessurf(nsurftypes) )
271	ALLOCATE( ifilessurf(nsurftypes) )
272	ALLOCATE( clsurffiles(nsurftypes, jpmaxnfiles) )
273
274	jtype = 0
275	IF (ln_sla) THEN
276	jtype = jtype + 1
277	clsurffiles(jtype,:) = cn_slafbfiles(:)
278	cobstypessurf(jtype) = 'sla '
279	ifilessurf(jtype) = 0
280	DO jfile = 1, jpmaxnfiles
281	IF ( trim(clsurffiles(jtype,jfile)) /= '' ) &
282	ifilessurf(jtype) = ifilessurf(jtype) + 1
283	END DO
284	ENDIF
285	IF (ln_sst) THEN
286	jtype = jtype + 1
287	clsurffiles(jtype,:) = cn_sstfbfiles(:)
288	cobstypessurf(jtype) = 'sst '
289	ifilessurf(jtype) = 0
290	DO jfile = 1, jpmaxnfiles
291	IF ( trim(clsurffiles(jtype,jfile)) /= '' ) &
292	ifilessurf(jtype) = ifilessurf(jtype) + 1
293	END DO
294	ENDIF
295	#if defined key_lim2 \|\| defined key_lim3
296	IF (ln_sic) THEN
297	jtype = jtype + 1
298	clsurffiles(jtype,:) = cn_sicfbfiles(:)
299	cobstypessurf(jtype) = 'sic '
300	ifilessurf(jtype) = 0
301	DO jfile = 1, jpmaxnfiles
302	IF ( trim(clsurffiles(jtype,jfile)) /= '' ) &
303	ifilessurf(jtype) = ifilessurf(jtype) + 1
304	END DO
305	ENDIF
306	#endif
307
308	ENDIF
309
310	!Write namelist settings to stdout
311	IF(lwp) THEN
312	WRITE(numout,*)
313	WRITE(numout,*) 'dia_obs_init : Observation diagnostic initialization'
314	WRITE(numout,*) '~~~~~~~~~~~~'
315	WRITE(numout,*) ' Namelist namobs : set observation diagnostic parameters'
316	WRITE(numout,*) ' Logical switch for T profile observations ln_t3d = ', ln_t3d
317	WRITE(numout,*) ' Logical switch for S profile observations ln_s3d = ', ln_s3d
318	WRITE(numout,*) ' Logical switch for SLA observations ln_sla = ', ln_sla
319	WRITE(numout,*) ' Logical switch for SST observations ln_sst = ', ln_sst
320	WRITE(numout,*) ' Logical switch for Sea Ice observations ln_sic = ', ln_sic
321	WRITE(numout,*) ' Logical switch for velocity observations ln_vel3d = ', ln_vel3d
322	WRITE(numout,*) ' Global distribution of observations ln_grid_global = ',ln_grid_global
323	WRITE(numout,*) ' Logical switch for SST bias correction ln_sstbias = ', ln_sstbias
324	WRITE(numout,*) ' Logical switch for obs grid search lookup ln_grid_search_lookup = ',ln_grid_search_lookup
325	IF (ln_grid_search_lookup) &
326	WRITE(numout,*) ' Grid search lookup file header cn_gridsearchfile = ', cn_gridsearchfile
327	WRITE(numout,*) ' Initial date in window YYYYMMDD.HHMMSS rn_dobsini = ', rn_dobsini
328	WRITE(numout,*) ' Final date in window YYYYMMDD.HHMMSS rn_dobsend = ', rn_dobsend
329	WRITE(numout,*) ' Type of vertical interpolation method nn_1dint = ', nn_1dint
330	WRITE(numout,*) ' Type of horizontal interpolation method nn_2dint = ', nn_2dint
331	WRITE(numout,*) ' Rejection of observations near land switch ln_nea = ', ln_nea
332	WRITE(numout,*) ' MSSH correction scheme nn_msshc = ', nn_msshc
333	WRITE(numout,*) ' MDT correction rn_mdtcorr = ', rn_mdtcorr
334	WRITE(numout,*) ' MDT cutoff for computed correction rn_mdtcutoff = ', rn_mdtcutoff
335	WRITE(numout,*) ' Logical switch for alt bias ln_altbias = ', ln_altbias
336	WRITE(numout,*) ' Logical switch for ignoring missing files ln_ignmis = ', ln_ignmis
337	WRITE(numout,*) ' Daily average types nn_profdavtypes = ', nn_profdavtypes
338	WRITE(numout,*) ' Logical switch for night-time SST obs ln_sstnight = ', ln_sstnight
339	WRITE(numout,*) ' Number of profile obs types: ',nproftypes
340
341	IF ( nproftypes > 0 ) THEN
342	DO jtype = 1, nproftypes
343	DO jfile = 1, ifilesprof(jtype)
344	WRITE(numout,'(1X,2A)') ' '//cobstypesprof(jtype)//' input observation file names = ', &
345	TRIM(clproffiles(jtype,jfile))
346	END DO
347	END DO
348	ENDIF
349
350	WRITE(numout,*)' Number of surface obs types: ',nsurftypes
351	IF ( nsurftypes > 0 ) THEN
352	DO jtype = 1, nsurftypes
353	DO jfile = 1, ifilessurf(jtype)
354	WRITE(numout,'(1X,2A)') ' '//cobstypessurf(jtype)//' input observation file names = ', &
355	TRIM(clsurffiles(jtype,jfile))
356	END DO
357	END DO
358	ENDIF
359	WRITE(numout,*) '~~~~~~~~~~~~'
360
361	ENDIF
362
363	!-----------------------------------------------------------------------
364	! Obs operator parameter checking and initialisations
365	!-----------------------------------------------------------------------
366
367	IF ( ln_vel3d .AND. ( .NOT. ln_grid_global ) ) THEN
368	CALL ctl_stop( 'Velocity data only works with ln_grid_global=.true.' )
369	RETURN
370	ENDIF
371
372	IF ( ( nn_1dint < 0 ) .OR. ( nn_1dint > 1 ) ) THEN
373	CALL ctl_stop(' Choice of vertical (1D) interpolation method', &
374	& ' is not available')
375	ENDIF
376
377	IF ( ( nn_2dint < 0 ) .OR. ( nn_2dint > 4 ) ) THEN
378	CALL ctl_stop(' Choice of horizontal (2D) interpolation method', &
379	& ' is not available')
380	ENDIF
381
382	CALL obs_typ_init
383
384	CALL mppmap_init
385
386	CALL obs_grid_setup( )
387
388	!-----------------------------------------------------------------------
389	! Depending on switches read the various observation types
390	!-----------------------------------------------------------------------
391
392	IF ( nproftypes > 0 ) THEN
393
394	ALLOCATE(profdata(nproftypes))
395	ALLOCATE(profdataqc(nproftypes))
396	ALLOCATE(nvarsprof(nproftypes))
397	ALLOCATE(nextrprof(nproftypes))
398
399	DO jtype = 1, nproftypes
400
401	nvarsprof(jtype) = 2
402	IF ( TRIM(cobstypesprof(jtype)) == 'prof' ) THEN
403	nextrprof(jtype) = 1
404	llvar1 = ln_t3d
405	llvar2 = ln_s3d
406	zglam1 = glamt
407	zgphi1 = gphit
408	zmask1 = tmask
409	zglam2 = glamt
410	zgphi2 = gphit
411	zmask2 = tmask
412	ENDIF
413	IF ( TRIM(cobstypesprof(jtype)) == 'vel' ) THEN
414	nextrprof(jtype) = 2
415	llvar1 = ln_vel3d
416	llvar2 = ln_vel3d
417	zglam1 = glamu
418	zgphi1 = gphiu
419	zmask1 = umask
420	zglam2 = glamv
421	zgphi2 = gphiv
422	zmask2 = vmask
423	ENDIF
424
425	!Read in profile or profile obs types
426	CALL obs_rea_prof( profdata(jtype), ifilesprof(jtype), &
427	& clproffiles(jtype,1:ifilesprof(jtype)), &
428	& nvarsprof(jtype), nextrprof(jtype), nitend-nit000+2, &
429	& rn_dobsini, rn_dobsend, llvar1, llvar2, &
430	& ln_ignmis, ln_s_at_t, .FALSE., &
431	& kdailyavtypes = nn_profdavtypes )
432
433	DO jvar = 1, nvarsprof(jtype)
434	CALL obs_prof_staend( profdata(jtype), jvar )
435	END DO
436
437	CALL obs_pre_prof( profdata(jtype), profdataqc(jtype), &
438	& llvar1, llvar2, &
439	& jpi, jpj, jpk, &
440	& zmask1, zglam1, zgphi1, zmask2, zglam2, zgphi2, &
441	& ln_nea, kdailyavtypes = nn_profdavtypes )
442
443	END DO
444
445	DEALLOCATE( ifilesprof, clproffiles )
446
447	ENDIF
448
449	IF ( nsurftypes > 0 ) THEN
450
451	ALLOCATE(surfdata(nsurftypes))
452	ALLOCATE(surfdataqc(nsurftypes))
453	ALLOCATE(nvarssurf(nsurftypes))
454	ALLOCATE(nextrsurf(nsurftypes))
455
456	DO jtype = 1, nsurftypes
457
458	nvarssurf(jtype) = 1
459	nextrsurf(jtype) = 0
460	llnightav = .FALSE.
461	IF ( TRIM(cobstypessurf(jtype)) == 'sla' ) nextrsurf(jtype) = 2
462	IF ( TRIM(cobstypessurf(jtype)) == 'sst' ) llnightav = ln_sstnight
463
464	!Read in surface obs types
465	CALL obs_rea_surf( surfdata(jtype), ifilessurf(jtype), &
466	& clsurffiles(jtype,1:ifilessurf(jtype)), &
467	& nvarssurf(jtype), nextrsurf(jtype), nitend-nit000+2, &
468	& rn_dobsini, rn_dobsend, ln_ignmis, .FALSE., llnightav )
469
470
471	CALL obs_pre_surf( surfdata(jtype), surfdataqc(jtype), ln_nea )
472
473	IF ( TRIM(cobstypessurf(jtype)) == 'sla' ) THEN
474	CALL obs_rea_mdt( surfdataqc(jtype), nn_2dint )
475	IF ( ln_altbias ) CALL obs_rea_altbias ( surfdataqc(jtype), nn_2dint, cn_altbiasfile )
476	ENDIF
477	IF ( TRIM(cobstypessurf(jtype)) == 'sst' .AND. ln_sstbias ) THEN
478	!Read in bias field and correct SST.
479	IF ( jnumsstbias == 0 ) CALL ctl_stop("ln_sstbias set,"// &
480	" but no bias"// &
481	" files to read in")
482	CALL obs_app_sstbias( surfdataqc(jtype), nn_2dint, &
483	jnumsstbias, cn_sstbias_files(1:jnumsstbias) )
484	ENDIF
485	END DO
486
487	DEALLOCATE( ifilessurf, clsurffiles )
488
489	ENDIF
490
491	CALL wrk_dealloc( jpi, jpj, zglam1 )
492	CALL wrk_dealloc( jpi, jpj, zglam2 )
493	CALL wrk_dealloc( jpi, jpj, zgphi1 )
494	CALL wrk_dealloc( jpi, jpj, zgphi2 )
495	CALL wrk_dealloc( jpi, jpj, jpk, zmask1 )
496	CALL wrk_dealloc( jpi, jpj, jpk, zmask2 )
497
498	END SUBROUTINE dia_obs_init
499
500	SUBROUTINE dia_obs( kstp )
501	!!----------------------------------------------------------------------
502	!! * ROUTINE dia_obs *
503	!!
504	!! ** Purpose : Call the observation operators on each time step
505	!!
506	!! ** Method : Call the observation operators on each time step to
507	!! compute the model equivalent of the following data:
508	!! - Profile data, currently T/S or U/V
509	!! - Surface data, currently SST, SLA or sea-ice concentration.
510	!!
511	!! ** Action :
512	!!
513	!! History :
514	!! ! 06-03 (K. Mogensen) Original code
515	!! ! 06-05 (K. Mogensen) Reformatted
516	!! ! 06-10 (A. Weaver) Cleaning
517	!! ! 07-03 (K. Mogensen) General handling of profiles
518	!! ! 07-04 (G. Smith) Generalized surface operators
519	!! ! 08-10 (M. Valdivieso) obs operator for velocity profiles
520	!! ! 14-08 (J. While) observation operator for profiles in
521	!! generalised vertical coordinates
522	!! ! 15-08 (M. Martin) Combined surface/profile routines.
523	!!----------------------------------------------------------------------
524	!! * Modules used
525	USE dom_oce, ONLY : & ! Ocean space and time domain variables
526	#if defined key_vvl
527	& gdept_n
528	#else
529	& gdept_1d
530	#endif
531	USE phycst, ONLY : & ! Physical constants
532	& rday
533	USE oce, ONLY : & ! Ocean dynamics and tracers variables
534	& tsn, &
535	& un, vn, &
536	& sshn
537	USE phycst, ONLY : & ! Physical constants
538	& rday
539	#if defined key_lim3
540	USE ice, ONLY : & ! LIM3 Ice model variables
541	& frld
542	#endif
543	#if defined key_lim2
544	USE ice_2, ONLY : & ! LIM2 Ice model variables
545	& frld
546	#endif
547	IMPLICIT NONE
548
549	!! * Arguments
550	INTEGER, INTENT(IN) :: kstp ! Current timestep
551	!! * Local declarations
552	INTEGER :: idaystp ! Number of timesteps per day
553	INTEGER :: jtype ! Data loop variable
554	INTEGER :: jvar ! Variable number
555	INTEGER :: ji, jj ! Loop counters
556	REAL(wp), POINTER, DIMENSION(:,:,:) :: &
557	& zprofvar1, & ! Model values for 1st variable in a prof ob
558	& zprofvar2 ! Model values for 2nd variable in a prof ob
559	REAL(wp), POINTER, DIMENSION(:,:,:) :: &
560	& zprofmask1, & ! Mask associated with zprofvar1
561	& zprofmask2 ! Mask associated with zprofvar2
562	REAL(wp), POINTER, DIMENSION(:,:) :: &
563	& zsurfvar ! Model values equivalent to surface ob.
564	REAL(wp), POINTER, DIMENSION(:,:) :: &
565	& zglam1, & ! Model longitudes for prof variable 1
566	& zglam2, & ! Model longitudes for prof variable 2
567	& zgphi1, & ! Model latitudes for prof variable 1
568	& zgphi2 ! Model latitudes for prof variable 2
569	#if ! defined key_lim2 && ! defined key_lim3
570	REAL(wp), POINTER, DIMENSION(:,:) :: frld
571	#endif
572	LOGICAL :: llnightav ! Logical for calculating night-time average
573
574	!Allocate local work arrays
575	CALL wrk_alloc( jpi, jpj, jpk, zprofvar1 )
576	CALL wrk_alloc( jpi, jpj, jpk, zprofvar2 )
577	CALL wrk_alloc( jpi, jpj, jpk, zprofmask1 )
578	CALL wrk_alloc( jpi, jpj, jpk, zprofmask2 )
579	CALL wrk_alloc( jpi, jpj, zsurfvar )
580	CALL wrk_alloc( jpi, jpj, zglam1 )
581	CALL wrk_alloc( jpi, jpj, zglam2 )
582	CALL wrk_alloc( jpi, jpj, zgphi1 )
583	CALL wrk_alloc( jpi, jpj, zgphi2 )
584	#if ! defined key_lim2 && ! defined key_lim3
585	CALL wrk_alloc(jpi,jpj,frld)
586	#endif
587
588	IF(lwp) THEN
589	WRITE(numout,*)
590	WRITE(numout,*) 'dia_obs : Call the observation operators', kstp
591	WRITE(numout,*) '~~~~~~~'
592	ENDIF
593
594	idaystp = NINT( rday / rdt )
595
596	!-----------------------------------------------------------------------
597	! No LIM => frld == 0.0_wp
598	!-----------------------------------------------------------------------
599	#if ! defined key_lim2 && ! defined key_lim3
600	frld(:,:) = 0.0_wp
601	#endif
602	!-----------------------------------------------------------------------
603	! Call the profile and surface observation operators
604	!-----------------------------------------------------------------------
605
606	IF ( nproftypes > 0 ) THEN
607
608	DO jtype = 1, nproftypes
609
610	SELECT CASE ( TRIM(cobstypesprof(jtype)) )
611	CASE('prof')
612	zprofvar1(:,:,:) = tsn(:,:,:,jp_tem)
613	zprofvar2(:,:,:) = tsn(:,:,:,jp_sal)
614	zprofmask1(:,:,:) = tmask(:,:,:)
615	zprofmask2(:,:,:) = tmask(:,:,:)
616	zglam1(:,:) = glamt(:,:)
617	zglam2(:,:) = glamt(:,:)
618	zgphi1(:,:) = gphit(:,:)
619	zgphi2(:,:) = gphit(:,:)
620	CASE('vel')
621	zprofvar1(:,:,:) = un(:,:,:)
622	zprofvar2(:,:,:) = vn(:,:,:)
623	zprofmask1(:,:,:) = umask(:,:,:)
624	zprofmask2(:,:,:) = vmask(:,:,:)
625	zglam1(:,:) = glamu(:,:)
626	zglam2(:,:) = glamv(:,:)
627	zgphi1(:,:) = gphiu(:,:)
628	zgphi2(:,:) = gphiv(:,:)
629	END SELECT
630
631	IF( ln_zco .OR. ln_zps ) THEN
632	CALL obs_prof_opt( profdataqc(jtype), kstp, jpi, jpj, jpk, &
633	& nit000, idaystp, &
634	& zprofvar1, zprofvar2, &
635	& gdept_1d, zprofmask1, zprofmask2, &
636	& zglam1, zglam2, zgphi1, zgphi2, &
637	& nn_1dint, nn_2dint, &
638	& kdailyavtypes = nn_profdavtypes )
639	ELSE IF(TRIM(cobstypesprof(jtype)) == 'prof') THEN
640	!TG - THIS NEEDS MODIFICATION TO MATCH SIMPLIFICATION
641	CALL obs_pro_sco_opt( profdataqc(jtype), &
642	& kstp, jpi, jpj, jpk, nit000, idaystp, &
643	& zprofvar1, zprofvar2, &
644	& fsdept(:,:,:), fsdepw(:,:,:), &
645	& tmask, nn_1dint, nn_2dint, &
646	& kdailyavtypes = nn_profdavtypes )
647	ELSE
648	CALL ctl_stop('DIA_OBS: Generalised vertical interpolation not'// &
649	'yet working for velocity date (turn off velocity observations')
650	ENDIF
651
652	END DO
653
654	ENDIF
655
656	IF ( nsurftypes > 0 ) THEN
657
658	DO jtype = 1, nsurftypes
659
660	SELECT CASE ( TRIM(cobstypessurf(jtype)) )
661	CASE('sst')
662	zsurfvar(:,:) = tsn(:,:,1,jp_tem)
663	llnightav = ln_sstnight
664	CASE('sla')
665	zsurfvar(:,:) = sshn(:,:)
666	llnightav = .FALSE.
667	#if defined key_lim2 \|\| defined key_lim3
668	CASE('sic')
669	IF ( kstp == 0 ) THEN
670	IF ( lwp .AND. surfdataqc(jtype)%nsstpmpp(1) > 0 ) THEN
671	CALL ctl_warn( 'Sea-ice not initialised on zeroth '// &
672	& 'time-step but some obs are valid then.' )
673	WRITE(numout,*)surfdataqc(jtype)%nsstpmpp(1), &
674	& ' sea-ice obs will be missed'
675	ENDIF
676	surfdataqc(jtype)%nsurfup = surfdataqc(jtype)%nsurfup + &
677	& surfdataqc(jtype)%nsstp(1)
678	CYCLE
679	ELSE
680	zsurfvar(:,:) = 1._wp - frld(:,:)
681	ENDIF
682
683	llnightav = .FALSE.
684	#endif
685	END SELECT
686
687	CALL obs_surf_opt( surfdataqc(jtype), kstp, jpi, jpj, &
688	& nit000, idaystp, zsurfvar, tmask(:,:,1), &
689	& nn_2dint, llnightav )
690
691	END DO
692
693	ENDIF
694
695	CALL wrk_dealloc( jpi, jpj, jpk, zprofvar1 )
696	CALL wrk_dealloc( jpi, jpj, jpk, zprofvar2 )
697	CALL wrk_dealloc( jpi, jpj, jpk, zprofmask1 )
698	CALL wrk_dealloc( jpi, jpj, jpk, zprofmask2 )
699	CALL wrk_dealloc( jpi, jpj, zsurfvar )
700	CALL wrk_dealloc( jpi, jpj, zglam1 )
701	CALL wrk_dealloc( jpi, jpj, zglam2 )
702	CALL wrk_dealloc( jpi, jpj, zgphi1 )
703	CALL wrk_dealloc( jpi, jpj, zgphi2 )
704	#if ! defined key_lim2 && ! defined key_lim3
705	CALL wrk_dealloc(jpi,jpj,frld)
706	#endif
707
708	END SUBROUTINE dia_obs
709
710	SUBROUTINE dia_obs_wri
711	!!----------------------------------------------------------------------
712	!! * ROUTINE dia_obs_wri *
713	!!
714	!! ** Purpose : Call observation diagnostic output routines
715	!!
716	!! ** Method : Call observation diagnostic output routines
717	!!
718	!! ** Action :
719	!!
720	!! History :
721	!! ! 06-03 (K. Mogensen) Original code
722	!! ! 06-05 (K. Mogensen) Reformatted
723	!! ! 06-10 (A. Weaver) Cleaning
724	!! ! 07-03 (K. Mogensen) General handling of profiles
725	!! ! 08-09 (M. Valdivieso) Velocity component (U,V) profiles
726	!! ! 15-08 (M. Martin) Combined writing for prof and surf types
727	!!----------------------------------------------------------------------
728	!! * Modules used
729	USE obs_rot_vel ! Rotation of velocities
730
731	IMPLICIT NONE
732
733	!! * Local declarations
734	INTEGER :: jtype ! Data set loop variable
735	INTEGER :: jo, jvar, jk
736	REAL(wp), DIMENSION(:), ALLOCATABLE :: &
737	& zu, &
738	& zv
739
740	!-----------------------------------------------------------------------
741	! Depending on switches call various observation output routines
742	!-----------------------------------------------------------------------
743
744	IF ( nproftypes > 0 ) THEN
745
746	DO jtype = 1, nproftypes
747
748	IF ( TRIM(cobstypesprof(jtype)) == 'vel' ) THEN
749
750	! For velocity data, rotate the model velocities to N/S, E/W
751	! using the compressed data structure.
752	ALLOCATE( &
753	& zu(profdataqc(jtype)%nvprot(1)), &
754	& zv(profdataqc(jtype)%nvprot(2)) &
755	& )
756
757	CALL obs_rotvel( profdataqc(jtype), nn_2dint, zu, zv )
758
759	DO jo = 1, profdataqc(jtype)%nprof
760	DO jvar = 1, 2
761	DO jk = profdataqc(jtype)%npvsta(jo,jvar), profdataqc(jtype)%npvend(jo,jvar)
762
763	IF ( jvar == 1 ) THEN
764	profdataqc(jtype)%var(jvar)%vmod(jk) = zu(jk)
765	ELSE
766	profdataqc(jtype)%var(jvar)%vmod(jk) = zv(jk)
767	ENDIF
768
769	END DO
770	END DO
771	END DO
772
773	DEALLOCATE( zu )
774	DEALLOCATE( zv )
775
776	END IF
777
778	CALL obs_prof_decompress( profdataqc(jtype), &
779	& profdata(jtype), .TRUE., numout )
780
781	CALL obs_wri_prof( profdata(jtype) )
782
783	END DO
784
785	ENDIF
786
787	IF ( nsurftypes > 0 ) THEN
788
789	DO jtype = 1, nsurftypes
790
791	CALL obs_surf_decompress( surfdataqc(jtype), &
792	& surfdata(jtype), .TRUE., numout )
793
794	CALL obs_wri_surf( surfdata(jtype) )
795
796	END DO
797
798	ENDIF
799
800	END SUBROUTINE dia_obs_wri
801
802	SUBROUTINE dia_obs_dealloc
803	IMPLICIT NONE
804	!!----------------------------------------------------------------------
805	!! * ROUTINE dia_obs_dealloc *
806	!!
807	!! ** Purpose : To deallocate data to enable the obs_oper online loop.
808	!! Specifically: dia_obs_init --> dia_obs --> dia_obs_wri
809	!!
810	!! ** Method : Clean up various arrays left behind by the obs_oper.
811	!!
812	!! ** Action :
813	!!
814	!!----------------------------------------------------------------------
815	! obs_grid deallocation
816	CALL obs_grid_deallocate
817
818	! diaobs deallocation
819	IF ( nproftypes > 0 ) &
820	& DEALLOCATE( cobstypesprof, profdata, profdataqc, nvarsprof, nextrprof )
821
822	IF ( nsurftypes > 0 ) &
823	& DEALLOCATE( cobstypessurf, surfdata, surfdataqc, nvarssurf, nextrsurf )
824
825	END SUBROUTINE dia_obs_dealloc
826
827	SUBROUTINE calc_date( kstp, ddobs )
828	!!----------------------------------------------------------------------
829	!! * ROUTINE calc_date *
830	!!
831	!! ** Purpose : Get date in double precision YYYYMMDD.HHMMSS format
832	!!
833	!! ** Method : Get date in double precision YYYYMMDD.HHMMSS format
834	!!
835	!! ** Action : Get date in double precision YYYYMMDD.HHMMSS format
836	!!
837	!! ** Action : Get initial date in double precision YYYYMMDD.HHMMSS format
838	!!
839	!! History :
840	!! ! 06-03 (K. Mogensen) Original code
841	!! ! 06-05 (K. Mogensen) Reformatted
842	!! ! 06-10 (A. Weaver) Cleaning
843	!! ! 06-10 (G. Smith) Calculates initial date the same as method for final date
844	!! ! 10-05 (D. Lea) Update to month length calculation for NEMO vn3.2
845	!! ! 2014-09 (D. Lea) New generic routine now deals with arbitrary initial time of day
846	!!----------------------------------------------------------------------
847	USE phycst, ONLY : & ! Physical constants
848	& rday
849	USE dom_oce, ONLY : & ! Ocean space and time domain variables
850	& rdt
851
852	IMPLICIT NONE
853
854	!! * Arguments
855	REAL(KIND=dp), INTENT(OUT) :: ddobs ! Date in YYYYMMDD.HHMMSS
856	INTEGER :: kstp
857
858	!! * Local declarations
859	INTEGER :: iyea ! date - (year, month, day, hour, minute)
860	INTEGER :: imon
861	INTEGER :: iday
862	INTEGER :: ihou
863	INTEGER :: imin
864	INTEGER :: imday ! Number of days in month.
865	INTEGER, DIMENSION(12) :: &
866	& imonth_len ! Length in days of the months of the current year
867	REAL(wp) :: zdayfrc ! Fraction of day
868
869	INTEGER, DIMENSION(12) :: imonth_len !: length in days of the months of the current year
870
871	!!----------------------------------------------------------------------
872	!! Initial date initialization (year, month, day, hour, minute)
873	!!----------------------------------------------------------------------
874	iyea = ndate0 / 10000
875	imon = ( ndate0 - iyea * 10000 ) / 100
876	iday = ndate0 - iyea * 10000 - imon * 100
877	ihou = nn_time0 / 100
878	imin = ( nn_time0 - ihou * 100 )
879
880	!!----------------------------------------------------------------------
881	!! Compute number of days + number of hours + min since initial time
882	!!----------------------------------------------------------------------
883	zdayfrc = kstp * rdt / rday
884	zdayfrc = zdayfrc - aint(zdayfrc)
885	imin = imin + int( zdayfrc * 24 * 60 )
886	DO WHILE (imin >= 60)
887	imin=imin-60
888	ihou=ihou+1
889	END DO
890	DO WHILE (ihou >= 24)
891	ihou=ihou-24
892	iday=iday+1
893	END DO
894	iday = iday + kstp * rdt / rday
895
896	!-----------------------------------------------------------------------
897	! Convert number of days (iday) into a real date
898	!----------------------------------------------------------------------
899
900	CALL calc_month_len( iyea, imonth_len )
901
902	DO WHILE ( iday > imonth_len(imon) )
903	iday = iday - imonth_len(imon)
904	imon = imon + 1
905	IF ( imon > 12 ) THEN
906	imon = 1
907	iyea = iyea + 1
908	CALL calc_month_len( iyea, imonth_len ) ! update month lengths
909	ENDIF
910	END DO
911
912	!----------------------------------------------------------------------
913	! Convert it into YYYYMMDD.HHMMSS format.
914	!----------------------------------------------------------------------
915	ddobs = iyea * 10000_dp + imon * 100_dp + &
916	& iday + ihou * 0.01_dp + imin * 0.0001_dp
917
918	END SUBROUTINE calc_date
919
920	SUBROUTINE ini_date( ddobsini )
921	!!----------------------------------------------------------------------
922	!! * ROUTINE ini_date *
923	!!
924	!! ** Purpose : Get initial date in double precision YYYYMMDD.HHMMSS format
925	!!
926	!! ** Method :
927	!!
928	!! ** Action :
929	!!
930	!! History :
931	!! ! 06-03 (K. Mogensen) Original code
932	!! ! 06-05 (K. Mogensen) Reformatted
933	!! ! 06-10 (A. Weaver) Cleaning
934	!! ! 10-05 (D. Lea) Update to month length calculation for NEMO vn3.2
935	!! ! 2014-09 (D. Lea) Change to call generic routine calc_date
936	!!----------------------------------------------------------------------
937
938	IMPLICIT NONE
939
940	!! * Arguments
941	REAL(KIND=dp), INTENT(OUT) :: ddobsini ! Initial date in YYYYMMDD.HHMMSS
942
943	CALL calc_date( nit000 - 1, ddobsini )
944
945	END SUBROUTINE ini_date
946
947	SUBROUTINE fin_date( ddobsfin )
948	!!----------------------------------------------------------------------
949	!! * ROUTINE fin_date *
950	!!
951	!! ** Purpose : Get final date in double precision YYYYMMDD.HHMMSS format
952	!!
953	!! ** Method :
954	!!
955	!! ** Action :
956	!!
957	!! History :
958	!! ! 06-03 (K. Mogensen) Original code
959	!! ! 06-05 (K. Mogensen) Reformatted
960	!! ! 06-10 (A. Weaver) Cleaning
961	!! ! 10-05 (D. Lea) Update to month length calculation for NEMO vn3.2
962	!! ! 2014-09 (D. Lea) Change to call generic routine calc_date
963	!!----------------------------------------------------------------------
964
965	IMPLICIT NONE
966
967	!! * Arguments
968	REAL(dp), INTENT(OUT) :: ddobsfin ! Final date in YYYYMMDD.HHMMSS
969
970	CALL calc_date( nitend, ddobsfin )
971
972	END SUBROUTINE fin_date
973
974	END MODULE diaobs

Note: See TracBrowser for help on using the repository browser.

Download in other formats: