New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/2015/dev_merge_2015/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/2015/dev_merge_2015/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 6060

Last change on this file since 6060 was 6060, checked in by timgraham, 8 years ago

Merged dev_r5836_noc2_VVL_BY_DEFAULT into branch
  • Property svn:keywords set to Id
File size: 12.8 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_lim3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   rst_opn         ! routine called by step module
34   PUBLIC   rst_write       ! routine called by step module
35   PUBLIC   rst_read        ! routine called by istate module
36   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
37
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE rst_opn( kt )
48      !!---------------------------------------------------------------------
49      !!                   ***  ROUTINE rst_opn  ***
50      !!                     
51      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
52      !!              + open the restart when we are one time step before nitrst
53      !!                   - restart header is defined when kt = nitrst-1
54      !!                   - restart data  are written when kt = nitrst
55      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
56      !!----------------------------------------------------------------------
57      INTEGER, INTENT(in) ::   kt     ! ocean time-step
58      !!
59      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
60      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
61      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
62      !!----------------------------------------------------------------------
63      !
64      IF( kt == nit000 ) THEN   ! default definitions
65         lrst_oce = .FALSE.   
66         IF( ln_rst_list ) THEN
67            nrst_lst = 1
68            nitrst = nstocklist( nrst_lst )
69         ELSE
70            nitrst = nitend
71         ENDIF
72      ENDIF
73
74      ! frequency-based restart dumping (nn_stock)
75      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
76         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
77         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
78         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
79      ENDIF
80      ! to get better performances with NetCDF format:
81      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
82      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
83      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
84         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
85            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
86            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
87            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
88            ENDIF
89            ! create the file
90            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
91            clpath = TRIM(cn_ocerst_outdir)
92            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
93            IF(lwp) THEN
94               WRITE(numout,*)
95               SELECT CASE ( jprstlib )
96               CASE ( jprstdimg )   ;   WRITE(numout,*)                            &
97                   '             open ocean restart binary file: ',TRIM(clpath)//clname
98               CASE DEFAULT         ;   WRITE(numout,*)                            &
99                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
100               END SELECT
101               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
102               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
103               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
104               ENDIF
105            ENDIF
106            !
107            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
108            lrst_oce = .TRUE.
109         ENDIF
110      ENDIF
111      !
112   END SUBROUTINE rst_opn
113
114
115   SUBROUTINE rst_write( kt )
116      !!---------------------------------------------------------------------
117      !!                   ***  ROUTINE rstwrite  ***
118      !!                     
119      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
120      !!
121      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
122      !!              file, save fields which are necessary for restart
123      !!----------------------------------------------------------------------
124      INTEGER, INTENT(in) ::   kt   ! ocean time-step
125      !!----------------------------------------------------------------------
126
127                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
128                     CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
129
130                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
131                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
132                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
133                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
134                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
135                     !
136                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
137                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
138                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
139                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
140                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
141                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
142      IF( kt == nitrst ) THEN
143         CALL iom_close( numrow )     ! close the restart file (only at last time step)
144!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
145!!gm  not sure what to do here   ===>>>  ask to Sebastian
146         lrst_oce = .FALSE.
147            IF( ln_rst_list ) THEN
148               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
149               nitrst = nstocklist( nrst_lst )
150            ENDIF
151            lrst_oce = .FALSE.
152      ENDIF
153      !
154   END SUBROUTINE rst_write
155
156
157   SUBROUTINE rst_read_open
158      !!----------------------------------------------------------------------
159      !!                   ***  ROUTINE rst_read_open  ***
160      !!
161      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
162      !!
163      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
164      !!                the file has already been opened
165      !!----------------------------------------------------------------------
166      INTEGER        ::   jlibalt = jprstlib
167      LOGICAL        ::   llok
168      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
169      !!----------------------------------------------------------------------
170      !
171      IF( numror <= 0 ) THEN
172         IF(lwp) THEN                                             ! Contol prints
173            WRITE(numout,*)
174            SELECT CASE ( jprstlib )
175            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
176            CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
177            END SELECT
178            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
179            WRITE(numout,*) '~~~~~~~~'
180         ENDIF
181
182         clpath = TRIM(cn_ocerst_indir)
183         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
184         IF ( jprstlib == jprstdimg ) THEN
185           ! eventually read netcdf file (monobloc)  for restarting on different number of processors
186           ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
187           INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
188           IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
189         ENDIF
190         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
191      ENDIF
192   END SUBROUTINE rst_read_open
193
194
195   SUBROUTINE rst_read
196      !!----------------------------------------------------------------------
197      !!                   ***  ROUTINE rst_read  ***
198      !!
199      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
200      !!
201      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
202      !!----------------------------------------------------------------------
203      REAL(wp) ::   zrdt, zrdttra1
204      INTEGER  ::   jk
205      LOGICAL  ::   llok
206      !!----------------------------------------------------------------------
207
208      CALL rst_read_open           ! open restart for reading (if not already opened)
209
210      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
211      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
212         CALL iom_get( numror, 'rdt', zrdt )
213         IF( zrdt /= rdt )   neuler = 0
214      ENDIF
215      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
216         CALL iom_get( numror, 'rdttra1', zrdttra1 )
217         IF( zrdttra1 /= rdttra(1) )   neuler = 0
218      ENDIF
219      !
220      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
221         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
222         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
223         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
224         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
225         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
226      ELSE
227         neuler = 0
228      ENDIF
229      !
230      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
231      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
232      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
233      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
234      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
235      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
236         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
237      ELSE
238         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
239      ENDIF
240      !
241      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
242         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
243         ub   (:,:,:)   = un   (:,:,:)
244         vb   (:,:,:)   = vn   (:,:,:)
245         sshb (:,:)     = sshn (:,:)
246         !
247         IF( .NOT.ln_linssh ) THEN
248            DO jk = 1, jpk
249               e3t_b(:,:,jk) = e3t_n(:,:,jk)
250            END DO
251         ENDIF
252         !
253      ENDIF
254      !
255   END SUBROUTINE rst_read
256
257   !!=====================================================================
258END MODULE restart
Note: See TracBrowser for help on using the repository browser.