1 | MODULE limdiahsb |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE limdia_hsb *** |
---|
4 | !! LIM-3 sea ice model : diagnostics of ice model |
---|
5 | !!====================================================================== |
---|
6 | !! History : 3.4 ! 2012-10 (C. Rousset) original code |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | #if defined key_lim3 |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! 'key_lim3' LIM3 sea-ice model |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! lim_dia_hsb : computation and output of the time evolution of keys variables |
---|
13 | !! lim_dia_hsb_init : initialization and namelist read |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | USE ice ! LIM-3: sea-ice variable |
---|
16 | USE dom_ice ! LIM-3: sea-ice domain |
---|
17 | USE dom_oce ! ocean domain |
---|
18 | USE sbc_oce ! surface boundary condition: ocean fields |
---|
19 | USE sbc_ice ! Surface boundary condition: sea-ice fields |
---|
20 | USE daymod ! model calendar |
---|
21 | USE phycst ! physical constant |
---|
22 | USE in_out_manager ! I/O manager |
---|
23 | USE lib_mpp ! MPP library |
---|
24 | USE timing ! preformance summary |
---|
25 | USE iom ! I/O manager |
---|
26 | USE lib_fortran ! glob_sum |
---|
27 | USE limrst ! ice restart |
---|
28 | |
---|
29 | IMPLICIT NONE |
---|
30 | PRIVATE |
---|
31 | |
---|
32 | PUBLIC lim_diahsb ! routine called by ice_step.F90 |
---|
33 | PUBLIC lim_diahsb_init ! routine called in sbcice_lim.F90 |
---|
34 | |
---|
35 | REAL(wp), DIMENSION(:,:), ALLOCATABLE :: vol_loc_ini, sal_loc_ini, tem_loc_ini ! initial volume, salt and heat contents |
---|
36 | REAL(wp) :: frc_sal, frc_voltop, frc_volbot, frc_temtop, frc_tembot ! global forcing trends |
---|
37 | |
---|
38 | !! * Substitutions |
---|
39 | # include "vectopt_loop_substitute.h90" |
---|
40 | |
---|
41 | !!---------------------------------------------------------------------- |
---|
42 | !! NEMO/OPA 3.4 , NEMO Consortium (2012) |
---|
43 | !! $Id$ |
---|
44 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
45 | !!---------------------------------------------------------------------- |
---|
46 | |
---|
47 | CONTAINS |
---|
48 | |
---|
49 | SUBROUTINE lim_diahsb( kt ) |
---|
50 | !!--------------------------------------------------------------------------- |
---|
51 | !! *** ROUTINE lim_diahsb *** |
---|
52 | !! |
---|
53 | !! ** Purpose: Compute the ice global heat content, salt content and volume conservation |
---|
54 | !! |
---|
55 | !!--------------------------------------------------------------------------- |
---|
56 | INTEGER, INTENT(in) :: kt ! number of iteration |
---|
57 | !! |
---|
58 | real(wp) :: zbg_ivol, zbg_svol, zbg_area, zbg_isal, zbg_item ,zbg_stem |
---|
59 | REAL(wp) :: z_frc_voltop, z_frc_volbot, z_frc_sal, z_frc_temtop, z_frc_tembot |
---|
60 | REAL(wp) :: zdiff_vol, zdiff_sal, zdiff_tem |
---|
61 | !!--------------------------------------------------------------------------- |
---|
62 | IF( nn_timing == 1 ) CALL timing_start('lim_diahsb') |
---|
63 | |
---|
64 | ! ----------------------- ! |
---|
65 | ! 1 - Contents ! |
---|
66 | ! ----------------------- ! |
---|
67 | zbg_ivol = glob_sum( vt_i(:,:) * e12t(:,:) * tmask(:,:,1) * 1.e-9 ) ! ice volume (km3) |
---|
68 | zbg_svol = glob_sum( vt_s(:,:) * e12t(:,:) * tmask(:,:,1) * 1.e-9 ) ! snow volume (km3) |
---|
69 | zbg_area = glob_sum( at_i(:,:) * e12t(:,:) * tmask(:,:,1) * 1.e-6 ) ! area (km2) |
---|
70 | zbg_isal = glob_sum( SUM( smv_i(:,:,:), dim=3 ) * e12t(:,:) * tmask(:,:,1) * 1.e-9 ) ! salt content (pss*km3) |
---|
71 | zbg_item = glob_sum( et_i * e12t(:,:) * tmask(:,:,1) * 1.e-20 ) ! heat content (1.e20 J) |
---|
72 | zbg_stem = glob_sum( et_s * e12t(:,:) * tmask(:,:,1) * 1.e-20 ) ! heat content (1.e20 J) |
---|
73 | |
---|
74 | ! ---------------------------! |
---|
75 | ! 2 - Trends due to forcing ! |
---|
76 | ! ---------------------------! |
---|
77 | z_frc_volbot = r1_rau0 * glob_sum( - ( wfx_ice(:,:) + wfx_snw(:,:) + wfx_err_sub(:,:) ) * e12t(:,:) * tmask(:,:,1) * 1.e-9 ) ! freshwater flux ice/snow-ocean |
---|
78 | z_frc_voltop = r1_rau0 * glob_sum( - ( wfx_sub(:,:) + wfx_spr(:,:) ) * e12t(:,:) * tmask(:,:,1) * 1.e-9 ) ! freshwater flux ice/snow-atm |
---|
79 | z_frc_sal = r1_rau0 * glob_sum( - sfx(:,:) * e12t(:,:) * tmask(:,:,1) * 1.e-9 ) ! salt fluxes ice/snow-ocean |
---|
80 | z_frc_tembot = glob_sum( hfx_out(:,:) * e12t(:,:) * tmask(:,:,1) * 1.e-20 ) ! heat on top of ocean (and below ice) |
---|
81 | z_frc_temtop = glob_sum( hfx_in (:,:) * e12t(:,:) * tmask(:,:,1) * 1.e-20 ) ! heat on top of ice-coean |
---|
82 | ! |
---|
83 | frc_voltop = frc_voltop + z_frc_voltop * rdt_ice ! km3 |
---|
84 | frc_volbot = frc_volbot + z_frc_volbot * rdt_ice ! km3 |
---|
85 | frc_sal = frc_sal + z_frc_sal * rdt_ice ! km3*pss |
---|
86 | frc_temtop = frc_temtop + z_frc_temtop * rdt_ice ! 1.e20 J |
---|
87 | frc_tembot = frc_tembot + z_frc_tembot * rdt_ice ! 1.e20 J |
---|
88 | |
---|
89 | ! ----------------------- ! |
---|
90 | ! 3 - Content variations ! |
---|
91 | ! ----------------------- ! |
---|
92 | zdiff_vol = r1_rau0 * glob_sum( ( rhoic * vt_i(:,:) + rhosn * vt_s(:,:) - vol_loc_ini(:,:) & ! freshwater trend (km3) |
---|
93 | & ) * e12t(:,:) * tmask(:,:,1) * 1.e-9 ) |
---|
94 | zdiff_sal = r1_rau0 * glob_sum( ( rhoic * SUM( smv_i(:,:,:), dim=3 ) - sal_loc_ini(:,:) & ! salt content trend (km3*pss) |
---|
95 | & ) * e12t(:,:) * tmask(:,:,1) * 1.e-9 ) |
---|
96 | zdiff_tem = glob_sum( ( et_i(:,:) + et_s(:,:) - tem_loc_ini(:,:) & ! heat content trend (1.e20 J) |
---|
97 | ! & + SUM( qevap_ice * a_i_b, dim=3 ) & !! clem: I think this line should be commented (but needs a check) |
---|
98 | & ) * e12t(:,:) * tmask(:,:,1) * 1.e-20 ) |
---|
99 | |
---|
100 | ! ----------------------- ! |
---|
101 | ! 4 - Drifts ! |
---|
102 | ! ----------------------- ! |
---|
103 | zdiff_vol = zdiff_vol - ( frc_voltop + frc_volbot ) |
---|
104 | zdiff_sal = zdiff_sal - frc_sal |
---|
105 | zdiff_tem = zdiff_tem - ( frc_tembot - frc_temtop ) |
---|
106 | |
---|
107 | ! ----------------------- ! |
---|
108 | ! 5 - Diagnostics writing ! |
---|
109 | ! ----------------------- ! |
---|
110 | ! |
---|
111 | IF( iom_use('ibgvolume') ) CALL iom_put( 'ibgvolume' , zdiff_vol ) ! ice/snow volume drift (km3 equivalent ocean water) |
---|
112 | IF( iom_use('ibgsaltco') ) CALL iom_put( 'ibgsaltco' , zdiff_sal ) ! ice salt content drift (psu*km3 equivalent ocean water) |
---|
113 | IF( iom_use('ibgheatco') ) CALL iom_put( 'ibgheatco' , zdiff_tem ) ! ice/snow heat content drift (1.e20 J) |
---|
114 | IF( iom_use('ibgheatfx') ) CALL iom_put( 'ibgheatfx' , zdiff_tem / & ! ice/snow heat flux drift (W/m2) |
---|
115 | & glob_sum( e12t(:,:) * tmask(:,:,1) * 1.e-20 * kt*rdt ) ) |
---|
116 | |
---|
117 | IF( iom_use('ibgfrcvoltop') ) CALL iom_put( 'ibgfrcvoltop' , frc_voltop ) ! vol forcing ice/snw-atm (km3 equivalent ocean water) |
---|
118 | IF( iom_use('ibgfrcvolbot') ) CALL iom_put( 'ibgfrcvolbot' , frc_volbot ) ! vol forcing ice/snw-ocean (km3 equivalent ocean water) |
---|
119 | IF( iom_use('ibgfrcsal') ) CALL iom_put( 'ibgfrcsal' , frc_sal ) ! sal - forcing (psu*km3 equivalent ocean water) |
---|
120 | IF( iom_use('ibgfrctemtop') ) CALL iom_put( 'ibgfrctemtop' , frc_temtop ) ! heat on top of ice/snw/ocean (1.e20 J) |
---|
121 | IF( iom_use('ibgfrctembot') ) CALL iom_put( 'ibgfrctembot' , frc_tembot ) ! heat on top of ocean(below ice) (1.e20 J) |
---|
122 | IF( iom_use('ibgfrchfxtop') ) CALL iom_put( 'ibgfrchfxtop' , frc_temtop / & ! heat on top of ice/snw/ocean (W/m2) |
---|
123 | & glob_sum( e12t(:,:) * tmask(:,:,1) * 1.e-20 * kt*rdt ) ) |
---|
124 | IF( iom_use('ibgfrchfxbot') ) CALL iom_put( 'ibgfrchfxbot' , frc_tembot / & ! heat on top of ocean(below ice) (W/m2) |
---|
125 | & glob_sum( e12t(:,:) * tmask(:,:,1) * 1.e-20 * kt*rdt ) ) |
---|
126 | |
---|
127 | IF( iom_use('ibgvol_tot' ) ) CALL iom_put( 'ibgvol_tot' , zbg_ivol ) ! ice volume (km3) |
---|
128 | IF( iom_use('sbgvol_tot' ) ) CALL iom_put( 'sbgvol_tot' , zbg_svol ) ! snow volume (km3) |
---|
129 | IF( iom_use('ibgarea_tot') ) CALL iom_put( 'ibgarea_tot' , zbg_area ) ! ice area (km2) |
---|
130 | IF( iom_use('ibgsalt_tot') ) CALL iom_put( 'ibgsalt_tot' , zbg_isal ) ! ice salinity content (pss*km3) |
---|
131 | IF( iom_use('ibgheat_tot') ) CALL iom_put( 'ibgheat_tot' , zbg_item ) ! ice heat content (1.e20 J) |
---|
132 | IF( iom_use('sbgheat_tot') ) CALL iom_put( 'sbgheat_tot' , zbg_stem ) ! snow heat content (1.e20 J) |
---|
133 | ! |
---|
134 | IF( lrst_ice ) CALL lim_diahsb_rst( numit, 'WRITE' ) |
---|
135 | ! |
---|
136 | IF( nn_timing == 1 ) CALL timing_stop('lim_diahsb') |
---|
137 | ! |
---|
138 | END SUBROUTINE lim_diahsb |
---|
139 | |
---|
140 | |
---|
141 | SUBROUTINE lim_diahsb_init |
---|
142 | !!--------------------------------------------------------------------------- |
---|
143 | !! *** ROUTINE lim_diahsb_init *** |
---|
144 | !! |
---|
145 | !! ** Purpose: Initialization for the heat salt volume budgets |
---|
146 | !! |
---|
147 | !! ** Method : Compute initial heat content, salt content and volume |
---|
148 | !! |
---|
149 | !! ** Action : - Compute initial heat content, salt content and volume |
---|
150 | !! - Initialize forcing trends |
---|
151 | !! - Compute coefficients for conversion |
---|
152 | !!--------------------------------------------------------------------------- |
---|
153 | INTEGER :: ierror ! local integer |
---|
154 | !! |
---|
155 | !!NAMELIST/namicehsb/ blabla |
---|
156 | !!---------------------------------------------------------------------- |
---|
157 | ! |
---|
158 | !!REWIND ( numnam_ice ) ! Read Namelist namicehsb |
---|
159 | !!READ ( numnam_ice, namicehsb ) |
---|
160 | ! |
---|
161 | IF(lwp) THEN ! Control print |
---|
162 | WRITE(numout,*) |
---|
163 | WRITE(numout,*) 'lim_diahsb_init : check the heat and salt budgets' |
---|
164 | WRITE(numout,*) '~~~~~~~~~~~~' |
---|
165 | ENDIF |
---|
166 | ! |
---|
167 | ALLOCATE( vol_loc_ini(jpi,jpj), sal_loc_ini(jpi,jpj), tem_loc_ini(jpi,jpj), STAT=ierror ) |
---|
168 | IF( ierror > 0 ) THEN |
---|
169 | CALL ctl_stop( 'lim_diahsb: unable to allocate vol_loc_ini' ) |
---|
170 | RETURN |
---|
171 | ENDIF |
---|
172 | |
---|
173 | CALL lim_diahsb_rst( nstart, 'READ' ) !* read or initialize all required files |
---|
174 | ! |
---|
175 | END SUBROUTINE lim_diahsb_init |
---|
176 | |
---|
177 | SUBROUTINE lim_diahsb_rst( kt, cdrw ) |
---|
178 | !!--------------------------------------------------------------------- |
---|
179 | !! *** ROUTINE limdia_rst *** |
---|
180 | !! |
---|
181 | !! ** Purpose : Read or write DIA file in restart file |
---|
182 | !! |
---|
183 | !! ** Method : use of IOM library |
---|
184 | !!---------------------------------------------------------------------- |
---|
185 | INTEGER , INTENT(in) :: kt ! ice time-step |
---|
186 | CHARACTER(len=*), INTENT(in) :: cdrw ! "READ"/"WRITE" flag |
---|
187 | ! |
---|
188 | !!---------------------------------------------------------------------- |
---|
189 | ! |
---|
190 | IF( TRIM(cdrw) == 'READ' ) THEN ! Read/initialise |
---|
191 | IF( ln_rstart ) THEN !* Read the restart file |
---|
192 | ! |
---|
193 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
194 | IF(lwp) WRITE(numout,*) ' lim_diahsb_rst read at it= ', kt,' date= ', ndastp |
---|
195 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
196 | CALL iom_get( numrir, 'frc_voltop' , frc_voltop ) |
---|
197 | CALL iom_get( numrir, 'frc_volbot' , frc_volbot ) |
---|
198 | CALL iom_get( numrir, 'frc_temtop' , frc_temtop ) |
---|
199 | CALL iom_get( numrir, 'frc_tembot' , frc_tembot ) |
---|
200 | CALL iom_get( numrir, 'frc_sal' , frc_sal ) |
---|
201 | CALL iom_get( numrir, jpdom_autoglo, 'vol_loc_ini', vol_loc_ini ) |
---|
202 | CALL iom_get( numrir, jpdom_autoglo, 'tem_loc_ini', tem_loc_ini ) |
---|
203 | CALL iom_get( numrir, jpdom_autoglo, 'sal_loc_ini', sal_loc_ini ) |
---|
204 | ELSE |
---|
205 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
206 | IF(lwp) WRITE(numout,*) ' lim_diahsb at initial state ' |
---|
207 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
208 | ! set trends to 0 |
---|
209 | frc_voltop = 0._wp |
---|
210 | frc_volbot = 0._wp |
---|
211 | frc_temtop = 0._wp |
---|
212 | frc_tembot = 0._wp |
---|
213 | frc_sal = 0._wp |
---|
214 | ! record initial ice volume, salt and temp |
---|
215 | vol_loc_ini(:,:) = rhoic * vt_i(:,:) + rhosn * vt_s(:,:) ! ice/snow volume (kg/m2) |
---|
216 | tem_loc_ini(:,:) = et_i(:,:) + et_s(:,:) ! ice/snow heat content (J) |
---|
217 | sal_loc_ini(:,:) = rhoic * SUM( smv_i(:,:,:), dim=3 ) ! ice salt content (pss*kg/m2) |
---|
218 | |
---|
219 | ENDIF |
---|
220 | |
---|
221 | ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN ! Create restart file |
---|
222 | ! ! ------------------- |
---|
223 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
224 | IF(lwp) WRITE(numout,*) ' lim_diahsb_rst write at it= ', kt,' date= ', ndastp |
---|
225 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
226 | CALL iom_rstput( kt, nitrst, numriw, 'frc_voltop' , frc_voltop ) |
---|
227 | CALL iom_rstput( kt, nitrst, numriw, 'frc_volbot' , frc_volbot ) |
---|
228 | CALL iom_rstput( kt, nitrst, numriw, 'frc_temtop' , frc_temtop ) |
---|
229 | CALL iom_rstput( kt, nitrst, numriw, 'frc_tembot' , frc_tembot ) |
---|
230 | CALL iom_rstput( kt, nitrst, numriw, 'frc_sal' , frc_sal ) |
---|
231 | CALL iom_rstput( kt, nitrst, numriw, 'vol_loc_ini', vol_loc_ini ) |
---|
232 | CALL iom_rstput( kt, nitrst, numriw, 'tem_loc_ini', tem_loc_ini ) |
---|
233 | CALL iom_rstput( kt, nitrst, numriw, 'sal_loc_ini', sal_loc_ini ) |
---|
234 | ! |
---|
235 | ENDIF |
---|
236 | ! |
---|
237 | END SUBROUTINE lim_diahsb_rst |
---|
238 | |
---|
239 | #else |
---|
240 | !!---------------------------------------------------------------------- |
---|
241 | !! Default option : Empty module NO LIM sea-ice model |
---|
242 | !!---------------------------------------------------------------------- |
---|
243 | CONTAINS |
---|
244 | SUBROUTINE lim_diahsb ! Empty routine |
---|
245 | END SUBROUTINE lim_diahsb |
---|
246 | #endif |
---|
247 | !!====================================================================== |
---|
248 | END MODULE limdiahsb |
---|