1 | MODULE traadv_tvd_crs |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE traadv_tvd *** |
---|
4 | !! Ocean tracers: horizontal & vertical advective trend |
---|
5 | !!============================================================================== |
---|
6 | !! History : OPA ! 1995-12 (L. Mortier) Original code |
---|
7 | !! ! 2000-01 (H. Loukos) adapted to ORCA |
---|
8 | !! ! 2000-10 (MA Foujols E.Kestenare) include file not routine |
---|
9 | !! ! 2000-12 (E. Kestenare M. Levy) fix bug in trtrd indexes |
---|
10 | !! ! 2001-07 (E. Durand G. Madec) adaptation to ORCA config |
---|
11 | !! 8.5 ! 2002-06 (G. Madec) F90: Free form and module |
---|
12 | !! NEMO 1.0 ! 2004-01 (A. de Miranda, G. Madec, J.M. Molines ): advective bbl |
---|
13 | !! 2.0 ! 2008-04 (S. Cravatte) add the i-, j- & k- trends computation |
---|
14 | !! - ! 2009-11 (V. Garnier) Surface pressure gradient organization |
---|
15 | !! 3.3 ! 2010-05 (C. Ethe, G. Madec) merge TRC-TRA + switch from velocity to transport |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | |
---|
18 | !!---------------------------------------------------------------------- |
---|
19 | !! tra_adv_tvd : update the tracer trend with the horizontal |
---|
20 | !! and vertical advection trends using a TVD scheme |
---|
21 | !! nonosc : compute monotonic tracer fluxes by a nonoscillatory |
---|
22 | !! algorithm |
---|
23 | !!---------------------------------------------------------------------- |
---|
24 | USE oce ! ocean dynamics and active tracers |
---|
25 | USE dom_oce , ONLY : lk_vvl |
---|
26 | USE trd_oce ! tracers trends |
---|
27 | USE trdtra ! tracers trends |
---|
28 | USE in_out_manager ! I/O manager |
---|
29 | USE dynspg_oce ! choice/control of key cpp for surface pressure gradient |
---|
30 | USE lib_mpp ! MPP library |
---|
31 | USE lbclnk ! ocean lateral boundary condition (or mpp link) |
---|
32 | USE diaptr ! poleward transport diagnostics |
---|
33 | USE trc_oce ! share passive tracers/Ocean variables |
---|
34 | USE wrk_nemo ! Memory Allocation |
---|
35 | USE timing ! Timing |
---|
36 | USE crs |
---|
37 | USE crslbclnk |
---|
38 | |
---|
39 | IMPLICIT NONE |
---|
40 | PRIVATE |
---|
41 | |
---|
42 | PUBLIC tra_adv_tvd_crs ! routine called by step.F90 |
---|
43 | |
---|
44 | LOGICAL :: l_trd ! flag to compute trends |
---|
45 | |
---|
46 | !! * Substitutions |
---|
47 | # include "domzgr_substitute.h90" |
---|
48 | # include "vectopt_loop_substitute.h90" |
---|
49 | !!---------------------------------------------------------------------- |
---|
50 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
51 | !! $Id: traadv_tvd.F90 3294 2012-01-28 16:44:18Z rblod $ |
---|
52 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
53 | !!---------------------------------------------------------------------- |
---|
54 | CONTAINS |
---|
55 | |
---|
56 | SUBROUTINE tra_adv_tvd_crs ( kt, kit000, cdtype, p2dt, pun, pvn, pwn, & |
---|
57 | & ptb, ptn, pta, kjpt ) |
---|
58 | !!---------------------------------------------------------------------- |
---|
59 | !! *** ROUTINE tra_adv_tvd *** |
---|
60 | !! |
---|
61 | !! ** Purpose : Compute the now trend due to total advection of |
---|
62 | !! tracers and add it to the general trend of tracer equations |
---|
63 | !! |
---|
64 | !! ** Method : TVD scheme, i.e. 2nd order centered scheme with |
---|
65 | !! corrected flux (monotonic correction) |
---|
66 | !! note: - this advection scheme needs a leap-frog time scheme |
---|
67 | !! |
---|
68 | !! ** Action : - update (pta) with the now advective tracer trends |
---|
69 | !! - save the trends |
---|
70 | !!---------------------------------------------------------------------- |
---|
71 | !cbr ça fait des trucs bizarres USE oce , ONLY: zwx => ua , zwy => va ! (ua,va) used as workspace |
---|
72 | ! |
---|
73 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
74 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
---|
75 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
---|
76 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
---|
77 | REAL(wp), DIMENSION( jpk ), INTENT(in ) :: p2dt ! vertical profile of tracer time-step |
---|
78 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: pun, pvn, pwn ! 3 ocean velocity components |
---|
79 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptb, ptn ! before and now tracer fields |
---|
80 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pta ! tracer trend |
---|
81 | ! |
---|
82 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
---|
83 | REAL(wp) :: z2dtt, zbtr, ztra ! local scalar |
---|
84 | REAL(wp) :: zfp_ui, zfp_vj, zfp_wk ! - - |
---|
85 | REAL(wp) :: zfm_ui, zfm_vj, zfm_wk ! - - |
---|
86 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz,zwx,zwy |
---|
87 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz |
---|
88 | |
---|
89 | INTEGER :: iji, ijj, ijk ! dummy loop indices |
---|
90 | REAL(wp) :: zmin,zmax |
---|
91 | !!---------------------------------------------------------------------- |
---|
92 | ! |
---|
93 | |
---|
94 | IF( nn_timing == 1 ) CALL timing_start('tra_adv_tvd') |
---|
95 | ! |
---|
96 | CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zwx, zwy ) |
---|
97 | ! |
---|
98 | IF( kt == kit000 ) THEN |
---|
99 | IF(lwp) WRITE(numout,*) |
---|
100 | IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype |
---|
101 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' |
---|
102 | ! |
---|
103 | l_trd = .FALSE. |
---|
104 | IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE. |
---|
105 | |
---|
106 | IF(lwp) WRITE(numout,*)"jpi jpj jpkm1 ",jpi,jpj,jpkm1 |
---|
107 | ENDIF |
---|
108 | ! |
---|
109 | IF( l_trd ) THEN |
---|
110 | CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz ) |
---|
111 | ztrdx(:,:,:) = 0.e0 ; ztrdy(:,:,:) = 0.e0 ; ztrdz(:,:,:) = 0.e0 |
---|
112 | ENDIF |
---|
113 | ! |
---|
114 | zwi(:,:,:) = 0.e0 |
---|
115 | ! |
---|
116 | ! ! =========== |
---|
117 | DO jn = 1, kjpt ! tracer loop |
---|
118 | ! ! =========== |
---|
119 | ! 1. Bottom value : flux set to zero |
---|
120 | ! ---------------------------------- |
---|
121 | zwx(:,:,jpk) = 0.e0 ; zwz(:,:,jpk) = 0.e0 |
---|
122 | zwy(:,:,jpk) = 0.e0 ; zwi(:,:,jpk) = 0.e0 |
---|
123 | |
---|
124 | ! 2. upstream advection with initial mass fluxes & intermediate update |
---|
125 | ! -------------------------------------------------------------------- |
---|
126 | |
---|
127 | ! upstream tracer flux in the i and j direction |
---|
128 | DO jk = 1, jpkm1 |
---|
129 | DO jj = 2, jpj_crs-1 |
---|
130 | DO ji = 2, jpi_crs-1 |
---|
131 | ! upstream scheme |
---|
132 | zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) ) |
---|
133 | zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) ) |
---|
134 | zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) ) |
---|
135 | zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) ) |
---|
136 | zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj ,jk,jn) ) |
---|
137 | zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji ,jj+1,jk,jn) ) |
---|
138 | END DO |
---|
139 | END DO |
---|
140 | END DO |
---|
141 | CALL crs_lbc_lnk( zwx, 'U', -1._wp ) |
---|
142 | CALL crs_lbc_lnk( zwy, 'V', -1._wp ) |
---|
143 | ! upstream tracer flux in the k direction |
---|
144 | ! Surface value |
---|
145 | IF( lk_vvl ) THEN ; zwz(:,:, 1 ) = 0.e0 ! volume variable |
---|
146 | ELSE ; zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn) ! linear free surface |
---|
147 | ENDIF |
---|
148 | ! Interior value |
---|
149 | DO jk = 2, jpkm1 |
---|
150 | DO jj = 2, jpj_crs-1 |
---|
151 | DO ji = nldi_crs, nlei_crs |
---|
152 | zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) ) |
---|
153 | zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) ) |
---|
154 | zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) |
---|
155 | END DO |
---|
156 | END DO |
---|
157 | END DO |
---|
158 | CALL crs_lbc_lnk( zwz, 'T', 1. ) |
---|
159 | |
---|
160 | ! total advective trend |
---|
161 | DO jk = 1, jpkm1 |
---|
162 | z2dtt = p2dt(jk) |
---|
163 | DO jj = 2, jpj_crs-1 |
---|
164 | DO ji = 2, jpi_crs-1 |
---|
165 | zbtr = r1_bt_crs(ji,jj,jk) |
---|
166 | ! total intermediate advective trends |
---|
167 | ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj ,jk ) & |
---|
168 | & + zwy(ji,jj,jk) - zwy(ji ,jj-1,jk ) & |
---|
169 | & + zwz(ji,jj,jk) - zwz(ji ,jj ,jk+1) ) |
---|
170 | |
---|
171 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra |
---|
172 | zwi(ji,jj,jk) = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask_crs(ji,jj,jk) |
---|
173 | END DO |
---|
174 | END DO |
---|
175 | END DO |
---|
176 | |
---|
177 | ! ! Lateral boundary conditions on zwi (unchanged sign) |
---|
178 | CALL crs_lbc_lnk( zwi, 'T', 1. ) |
---|
179 | |
---|
180 | ! ! trend diagnostics (contribution of upstream fluxes) |
---|
181 | IF( l_trd ) THEN |
---|
182 | ! store intermediate advective trends |
---|
183 | ztrdx(:,:,:) = zwx(:,:,:) ; ztrdy(:,:,:) = zwy(:,:,:) ; ztrdz(:,:,:) = zwz(:,:,:) |
---|
184 | END IF |
---|
185 | |
---|
186 | ! 3. antidiffusive flux : high order minus low order |
---|
187 | ! -------------------------------------------------- |
---|
188 | ! antidiffusive flux on i and j |
---|
189 | DO jk = 1, jpkm1 |
---|
190 | DO jj = 2, jpj_crs-1 |
---|
191 | DO ji = 2, jpi_crs-1 |
---|
192 | zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk) |
---|
193 | zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk) |
---|
194 | END DO |
---|
195 | END DO |
---|
196 | END DO |
---|
197 | ! antidiffusive flux on k |
---|
198 | zwz(:,:,1) = 0.e0 ! Surface value |
---|
199 | ! |
---|
200 | DO jk = 2, jpkm1 ! Interior value |
---|
201 | DO jj = 2, jpj_crs-1 |
---|
202 | DO ji = 2, jpi_crs-1 |
---|
203 | zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk) |
---|
204 | END DO |
---|
205 | END DO |
---|
206 | END DO |
---|
207 | CALL crs_lbc_lnk( zwx, 'U', -1. ) ; CALL crs_lbc_lnk( zwy, 'V', -1. ) ! Lateral bondary conditions |
---|
208 | CALL crs_lbc_lnk( zwz, 'W', 1. ) |
---|
209 | |
---|
210 | ! 4. monotonicity algorithm |
---|
211 | ! ------------------------- |
---|
212 | CALL nonosc_crs( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt ) |
---|
213 | |
---|
214 | ! 5. final trend with corrected fluxes |
---|
215 | ! ------------------------------------ |
---|
216 | DO jk = 1, jpkm1 |
---|
217 | DO jj = 2, jpj_crs-1 |
---|
218 | DO ji = 2, jpi_crs-1 |
---|
219 | zbtr = r1_bt_crs(ji,jj,jk) |
---|
220 | ! total advective trends |
---|
221 | ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj ,jk ) & |
---|
222 | & + zwy(ji,jj,jk) - zwy(ji ,jj-1,jk ) & |
---|
223 | & + zwz(ji,jj,jk) - zwz(ji ,jj ,jk+1) ) |
---|
224 | ! add them to the general tracer trends |
---|
225 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra |
---|
226 | |
---|
227 | |
---|
228 | END DO |
---|
229 | END DO |
---|
230 | END DO |
---|
231 | |
---|
232 | ! ! trend diagnostics (contribution of upstream fluxes) |
---|
233 | IF( l_trd ) THEN |
---|
234 | ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:) ! <<< Add to previously computed |
---|
235 | ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:) ! <<< Add to previously computed |
---|
236 | ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:) ! <<< Add to previously computed |
---|
237 | |
---|
238 | CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) ) |
---|
239 | CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) |
---|
240 | CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) |
---|
241 | END IF |
---|
242 | ! |
---|
243 | END DO |
---|
244 | ! |
---|
245 | |
---|
246 | CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz , zwx, zwy ) |
---|
247 | IF( l_trd ) CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz ) |
---|
248 | ! |
---|
249 | IF( nn_timing == 1 ) CALL timing_stop('tra_adv_tvd') |
---|
250 | ! |
---|
251 | END SUBROUTINE tra_adv_tvd_crs |
---|
252 | |
---|
253 | |
---|
254 | SUBROUTINE nonosc_crs( pbef, paa, pbb, pcc, paft, p2dt ) |
---|
255 | !!--------------------------------------------------------------------- |
---|
256 | !! *** ROUTINE nonosc *** |
---|
257 | !! |
---|
258 | !! ** Purpose : compute monotonic tracer fluxes from the upstream |
---|
259 | !! scheme and the before field by a nonoscillatory algorithm |
---|
260 | !! |
---|
261 | !! ** Method : ... ??? |
---|
262 | !! warning : pbef and paft must be masked, but the boundaries |
---|
263 | !! conditions on the fluxes are not necessary zalezak (1979) |
---|
264 | !! drange (1995) multi-dimensional forward-in-time and upstream- |
---|
265 | !! in-space based differencing for fluid |
---|
266 | !!---------------------------------------------------------------------- |
---|
267 | ! |
---|
268 | !!---------------------------------------------------------------------- |
---|
269 | REAL(wp), DIMENSION(jpk) , INTENT(in ) :: p2dt ! vertical profile of tracer time-step |
---|
270 | REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in ) :: pbef, paft ! before & after field |
---|
271 | REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) :: paa, pbb, pcc ! monotonic fluxes in the 3 directions |
---|
272 | ! |
---|
273 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
274 | INTEGER :: ikm1 ! local integer |
---|
275 | REAL(wp) :: zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt ! local scalars |
---|
276 | REAL(wp) :: zau, zbu, zcu, zav, zbv, zcv, zup, zdo ! - - |
---|
277 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo |
---|
278 | !!---------------------------------------------------------------------- |
---|
279 | ! |
---|
280 | IF( nn_timing == 1 ) CALL timing_start('nonosc') |
---|
281 | ! |
---|
282 | CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo ) |
---|
283 | ! |
---|
284 | |
---|
285 | zbig = 1.e+40_wp |
---|
286 | zrtrn = 1.e-15_wp |
---|
287 | zbetup(:,:,jpk) = 0._wp ; zbetdo(:,:,jpk) = 0._wp |
---|
288 | |
---|
289 | |
---|
290 | ! Search local extrema |
---|
291 | ! -------------------- |
---|
292 | ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land |
---|
293 | zbup = MAX( pbef * tmask_crs - zbig * ( 1.e0 - tmask_crs ), & |
---|
294 | & paft * tmask_crs - zbig * ( 1.e0 - tmask_crs ) ) |
---|
295 | zbdo = MIN( pbef * tmask_crs + zbig * ( 1.e0 - tmask_crs ), & |
---|
296 | & paft * tmask_crs + zbig * ( 1.e0 - tmask_crs ) ) |
---|
297 | |
---|
298 | DO jk = 1, jpkm1 |
---|
299 | ikm1 = MAX(jk-1,1) |
---|
300 | z2dtt = p2dt(jk) |
---|
301 | DO jj = 2, jpj_crs-1 |
---|
302 | DO ji = 2, jpi_crs-1 |
---|
303 | |
---|
304 | ! search maximum in neighbourhood |
---|
305 | zup = MAX( zbup(ji ,jj ,jk ), & |
---|
306 | & zbup(ji-1,jj ,jk ), zbup(ji+1,jj ,jk ), & |
---|
307 | & zbup(ji ,jj-1,jk ), zbup(ji ,jj+1,jk ), & |
---|
308 | & zbup(ji ,jj ,ikm1), zbup(ji ,jj ,jk+1) ) |
---|
309 | |
---|
310 | ! search minimum in neighbourhood |
---|
311 | zdo = MIN( zbdo(ji ,jj ,jk ), & |
---|
312 | & zbdo(ji-1,jj ,jk ), zbdo(ji+1,jj ,jk ), & |
---|
313 | & zbdo(ji ,jj-1,jk ), zbdo(ji ,jj+1,jk ), & |
---|
314 | & zbdo(ji ,jj ,ikm1), zbdo(ji ,jj ,jk+1) ) |
---|
315 | |
---|
316 | ! positive part of the flux |
---|
317 | zpos = MAX( 0., paa(ji-1,jj ,jk ) ) - MIN( 0., paa(ji ,jj ,jk ) ) & |
---|
318 | & + MAX( 0., pbb(ji ,jj-1,jk ) ) - MIN( 0., pbb(ji ,jj ,jk ) ) & |
---|
319 | & + MAX( 0., pcc(ji ,jj ,jk+1) ) - MIN( 0., pcc(ji ,jj ,jk ) ) |
---|
320 | |
---|
321 | ! negative part of the flux |
---|
322 | zneg = MAX( 0., paa(ji ,jj ,jk ) ) - MIN( 0., paa(ji-1,jj ,jk ) ) & |
---|
323 | & + MAX( 0., pbb(ji ,jj ,jk ) ) - MIN( 0., pbb(ji ,jj-1,jk ) ) & |
---|
324 | & + MAX( 0., pcc(ji ,jj ,jk ) ) - MIN( 0., pcc(ji ,jj ,jk+1) ) |
---|
325 | |
---|
326 | ! up & down beta terms |
---|
327 | zbt = bt_crs(ji,jj,jk) / z2dtt |
---|
328 | zbetup(ji,jj,jk) = ( zup - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt |
---|
329 | zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo ) / ( zneg + zrtrn ) * zbt |
---|
330 | END DO |
---|
331 | END DO |
---|
332 | END DO |
---|
333 | CALL crs_lbc_lnk( zbetup, 'T', 1. ) ; CALL crs_lbc_lnk( zbetdo, 'T', 1. ) ! lateral boundary cond. (unchanged sign) |
---|
334 | |
---|
335 | ! 3. monotonic flux in the i & j direction (paa & pbb) |
---|
336 | ! ---------------------------------------- |
---|
337 | DO jk = 1, jpkm1 |
---|
338 | DO jj = 2, jpj_crs-1 |
---|
339 | DO ji = 2, jpi_crs-1 |
---|
340 | zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) ) |
---|
341 | zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) ) |
---|
342 | zcu = ( 0.5 + SIGN( 0.5 , paa(ji,jj,jk) ) ) |
---|
343 | paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu ) |
---|
344 | |
---|
345 | zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) ) |
---|
346 | zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) ) |
---|
347 | zcv = ( 0.5 + SIGN( 0.5 , pbb(ji,jj,jk) ) ) |
---|
348 | pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv ) |
---|
349 | |
---|
350 | ! monotonic flux in the k direction, i.e. pcc |
---|
351 | ! ------------------------------------------- |
---|
352 | za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) ) |
---|
353 | zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) ) |
---|
354 | zc = ( 0.5 + SIGN( 0.5 , pcc(ji,jj,jk+1) ) ) |
---|
355 | pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb ) |
---|
356 | END DO |
---|
357 | END DO |
---|
358 | END DO |
---|
359 | |
---|
360 | CALL crs_lbc_lnk( paa, 'U', -1. ) ; CALL crs_lbc_lnk( pbb, 'V', -1. ) ! lateral boundary condition (changed sign) |
---|
361 | ! |
---|
362 | CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo ) |
---|
363 | ! |
---|
364 | IF( nn_timing == 1 ) CALL timing_stop('nonosc') |
---|
365 | ! |
---|
366 | END SUBROUTINE nonosc_crs |
---|
367 | |
---|
368 | !!====================================================================== |
---|
369 | END MODULE traadv_tvd_crs |
---|