New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_crs.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_crs.F90 @ 8091

Last change on this file since 8091 was 8091, checked in by cbricaud, 7 years ago

use masked horizontal surface to the vertical fluxes in isopycnal diffusion for passive tracers in CRS mode

  • Property svn:executable set to *
File size: 15.7 KB
Line 
1MODULE traldf_iso_crs
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   ( defined key_ldfslp   ||   defined key_esopa ) && defined key_crs
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21   USE ldfslp_crs          ! iso-neutral slopes
22   USE diaptr          ! poleward transport diagnostics
23   USE in_out_manager  ! I/O manager
24   USE iom             ! I/O library
25#if defined key_diaar5
26   USE phycst          ! physical constants
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28#endif
29   USE wrk_nemo        ! Memory Allocation
30   USE timing          ! Timing
31!cbr   USE oce_trc
32   USE ldftra_oce, ONLY: rldf
33   USE iom, ONLY : iom_put,iom_swap
34   USE crs
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_ldf_iso_crs   ! routine called by step.F90
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "ldftra_substitute.h90"
44#  include "vectopt_loop_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
47   !! $Id: traldf_iso.F90 3294 2012-01-28 16:44:18Z rblod $
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE tra_ldf_iso_crs( kt, kit000, cdtype, pgu, pgv,              &
53      &                                ptb, pta, kjpt, pahtb0 )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE tra_ldf_iso  ***
56      !!
57      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
58      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
59      !!      add it to the general trend of tracer equation.
60      !!
61      !! ** Method  :   The horizontal component of the lateral diffusive trends
62      !!      is provided by a 2nd order operator rotated along neural or geopo-
63      !!      tential surfaces to which an eddy induced advection can be added
64      !!      It is computed using before fields (forward in time) and isopyc-
65      !!      nal or geopotential slopes computed in routine ldfslp.
66      !!
67      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
68      !!      ========    with partial cell update if ln_zps=T.
69      !!
70      !!      2nd part :  horizontal fluxes of the lateral mixing operator
71      !!      ========   
72      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
73      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
74      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
75      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
76      !!      take the horizontal divergence of the fluxes:
77      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
78      !!      Add this trend to the general trend (ta,sa):
79      !!         ta = ta + difft
80      !!
81      !!      3rd part: vertical trends of the lateral mixing operator
82      !!      ========  (excluding the vertical flux proportional to dk[t] )
83      !!      vertical fluxes associated with the rotated lateral mixing:
84      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
85      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
86      !!      take the horizontal divergence of the fluxes:
87      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
88      !!      Add this trend to the general trend (ta,sa):
89      !!         pta = pta + difft
90      !!
91      !! ** Action :   Update pta arrays with the before rotated diffusion
92      !!----------------------------------------------------------------------
93      !
94      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
95      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
96      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
97      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
98      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
99      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
100      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
101      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
102      !
103      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
104      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
105      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
106      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
107#if defined key_diaar5
108      REAL(wp)                         ::   zztmp               ! local scalar
109#endif
110      REAL(wp)                         ::   zmin,zmax
111      REAL(wp), POINTER, DIMENSION(:,:  ) ::  zdkt, zdk1t, z2d
112      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zdit, zdjt, ztfw , zftu,  zftv 
113      !!----------------------------------------------------------------------
114      !
115      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
116      !
117      CALL wrk_alloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
118      CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt, ztfw , zftu, zftv ) 
119      !
120
121      IF( kt == kit000 )  THEN
122         IF(lwp) WRITE(numout,*)
123         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
124         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
125      ENDIF
126      !
127      !                                                          ! ===========
128      DO jn = 1, kjpt                                            ! tracer loop
129         !                                                       ! ===========
130         !                                               
131         !!----------------------------------------------------------------------
132         !!   I - masked horizontal derivative
133         !!----------------------------------------------------------------------
134         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
135         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
136         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
137         !!end
138
139         ! Horizontal tracer gradient
140         DO jk = 1, jpkm1
141            DO jj = 1, jpjm1
142               DO ji = 1, fs_jpim1   ! vector opt.
143                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask_crs(ji,jj,jk)
144                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask_crs(ji,jj,jk)
145               END DO
146            END DO
147         END DO
148         IF( ln_zps ) THEN      ! partial steps correction at the last ocean level
149            DO jj = 1, jpjm1
150               DO ji = 1, fs_jpim1   ! vector opt.
151                  zdit(ji,jj,mbku_crs(ji,jj)) = pgu(ji,jj,jn)         
152                  zdjt(ji,jj,mbkv_crs(ji,jj)) = pgv(ji,jj,jn)     
153               END DO
154            END DO
155         ENDIF
156
157         !!----------------------------------------------------------------------
158         !!   II - horizontal trend  (full)
159         !!----------------------------------------------------------------------
160!CDIR PARALLEL DO PRIVATE( zdk1t )
161         !                                                ! ===============
162         DO jk = 1, jpkm1                                 ! Horizontal slab
163            !                                             ! ===============
164            ! 1. Vertical tracer gradient at level jk and jk+1
165            ! ------------------------------------------------
166            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
167            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask_crs(:,:,jk+1)
168            !
169            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)
170            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask_crs(:,:,jk)
171            ENDIF
172
173            ! 2. Horizontal fluxes
174            ! --------------------   
175            DO jj = 1 , jpjm1
176               DO ji = 1, fs_jpim1   ! vector opt.
177                  zabe1 = ( fsahtu_crs(ji,jj,jk) + pahtb0 ) * e2e3u_msk(ji,jj,jk) / e1u_crs(ji,jj)
178                  zabe2 = ( fsahtv_crs(ji,jj,jk) + pahtb0 ) * e1e3v_msk(ji,jj,jk) / e2v_crs(ji,jj)
179
180                  zmsku = 1. / MAX(  tmask_crs(ji+1,jj,jk  ) + tmask_crs(ji,jj,jk+1)   &
181                     &             + tmask_crs(ji+1,jj,jk+1) + tmask_crs(ji,jj,jk  ), 1. )
182                  !
183                  zmskv = 1. / MAX(  tmask_crs(ji,jj+1,jk  ) + tmask_crs(ji,jj,jk+1)   &
184                     &             + tmask_crs(ji,jj+1,jk+1) + tmask_crs(ji,jj,jk  ), 1. )
185                  !
186                  zcof1 = - fsahtu_crs(ji,jj,jk) * e2e3u_msk(ji,jj,jk) * uslp_crs(ji,jj,jk) * zmsku / MAX( 1._wp , fse3u_max_crs(ji,jj,jk))
187                  zcof2 = - fsahtv_crs(ji,jj,jk) * e1e3v_msk(ji,jj,jk) * vslp_crs(ji,jj,jk) * zmskv / MAX( 1._wp , fse3v_max_crs(ji,jj,jk))
188                  !
189                  zftu(ji,jj,jk ) = ( zabe1 * zdit(ji,jj,jk)   &
190                     &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
191                     &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask_crs(ji,jj,jk)
192                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
193                     &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
194                     &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask_crs(ji,jj,jk)                 
195               END DO
196            END DO
197
198            ! II.4 Second derivative (divergence) and add to the general trend
199            ! ----------------------------------------------------------------
200            DO jj = 2 , jpjm1
201               DO ji = fs_2, fs_jpim1   ! vector opt.
202                  zbtr = r1_bt_crs(ji,jj,jk)
203                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
204                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
205
206               END DO
207            END DO
208            !                                          ! ===============
209         END DO                                        !   End of slab 
210         !                                             ! ===============
211         !
212 
213#if defined key_diaar5
214         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
215            z2d(:,:) = 0._wp 
216            zztmp = rau0 * rcp 
217            DO jk = 1, jpkm1
218               DO jj = 2, jpjm1
219                  DO ji = fs_2, fs_jpim1   ! vector opt.
220                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
221                  END DO
222               END DO
223            END DO
224            z2d(:,:) = zztmp * z2d(:,:)
225            CALL crs_lbc_lnk( z2d, 'U', -1. )
226         !   CALL crs_iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
227            z2d(:,:) = 0._wp 
228            DO jk = 1, jpkm1
229               DO jj = 2, jpjm1
230                  DO ji = fs_2, fs_jpim1   ! vector opt.
231                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
232                  END DO
233               END DO
234            END DO
235            z2d(:,:) = zztmp * z2d(:,:)
236            CALL crs_lbc_lnk( z2d, 'V', -1. )
237            ! CALL crs_iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
238         END IF
239#endif
240
241         !!----------------------------------------------------------------------
242         !!   III - vertical trend of T & S (extra diagonal terms only)
243         !!----------------------------------------------------------------------
244         
245         ! Local constant initialization
246         ! -----------------------------
247         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
248         
249         ! Vertical fluxes
250         ! ---------------
251         
252         ! Surface and bottom vertical fluxes set to zero
253         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
254         
255         ! interior (2=<jk=<jpk-1)
256         DO jk = 2, jpkm1
257            DO jj = 2, jpjm1
258               DO ji = fs_2, fs_jpim1   ! vector opt.
259                  zcoef0 = - fsahtw_crs(ji,jj,jk) * tmask_crs(ji,jj,jk)
260                  !
261                  zmsku = 1./MAX(   umask_crs(ji  ,jj,jk-1) + umask_crs(ji-1,jj,jk)      &
262                     &            + umask_crs(ji-1,jj,jk-1) + umask_crs(ji  ,jj,jk), 1.  )
263                  zmskv = 1./MAX(   vmask_crs(ji,jj  ,jk-1) + vmask_crs(ji,jj-1,jk)      &
264                     &            + vmask_crs(ji,jj-1,jk-1) + vmask_crs(ji,jj  ,jk), 1.  )
265                  !
266                  zcoef3 = zcoef0 * e1e2w_msk(ji,jj,jk) * zmsku * wslpi_crs(ji,jj,jk) / e1t_crs(ji,jj)
267                  zcoef4 = zcoef0 * e1e2w_msk(ji,jj,jk) * zmskv * wslpj_crs(ji,jj,jk) / e2t_crs(ji,jj)
268                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
269                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
270                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
271                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
272               END DO
273            END DO
274         END DO
275         
276         
277         ! I.5 Divergence of vertical fluxes added to the general tracer trend
278         ! -------------------------------------------------------------------
279         DO jk = 1, jpkm1
280            DO jj = 2, jpjm1
281               DO ji = fs_2, fs_jpim1   ! vector opt.
282                  zbtr = r1_bt_crs(ji,jj,jk)
283                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
284                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
285
286               END DO
287            END DO
288         END DO
289         !
290      END DO
291      !
292      CALL wrk_dealloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
293      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt, ztfw , zftu, zftv ) 
294      !
295      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
296      !
297   END SUBROUTINE tra_ldf_iso_crs
298
299#else
300   !!----------------------------------------------------------------------
301   !!   default option :   Dummy code   NO rotation of the diffusive tensor
302   !!----------------------------------------------------------------------
303CONTAINS
304   SUBROUTINE tra_ldf_iso_crs( kt, kit000,cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
305      INTEGER:: kt, kit000
306      CHARACTER(len=3) ::   cdtype
307      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
308      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
309      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt, kit000, cdtype,   &
310         &                       pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
311   END SUBROUTINE tra_ldf_iso_crs
312#endif
313
314   !!==============================================================================
315END MODULE traldf_iso_crs
Note: See TracBrowser for help on using the repository browser.