| 1 | MODULE p4zche |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zche *** |
|---|
| 4 | !! TOP : PISCES Sea water chemistry computed following OCMIP protocol |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1988 (E. Maier-Reimer) Original code |
|---|
| 7 | !! - ! 1998 (O. Aumont) addition |
|---|
| 8 | !! - ! 1999 (C. Le Quere) modification |
|---|
| 9 | !! NEMO 1.0 ! 2004 (O. Aumont) modification |
|---|
| 10 | !! - ! 2006 (R. Gangsto) modification |
|---|
| 11 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 12 | !! ! 2011-02 (J. Simeon, J.Orr ) update O2 solubility constants |
|---|
| 13 | !! 3.6 ! 2016-03 (O. Aumont) Change chemistry to MOCSY standards |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | #if defined key_pisces |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! 'key_pisces*' PISCES bio-model |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | !! p4z_che : Sea water chemistry computed following OCMIP protocol |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 22 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 23 | USE lib_mpp ! MPP library |
|---|
| 24 | USE eosbn2, ONLY : nn_eos |
|---|
| 25 | |
|---|
| 26 | IMPLICIT NONE |
|---|
| 27 | PRIVATE |
|---|
| 28 | |
|---|
| 29 | PUBLIC p4z_che ! |
|---|
| 30 | PUBLIC p4z_che_alloc ! |
|---|
| 31 | PUBLIC p4z_che_ahini ! |
|---|
| 32 | PUBLIC p4z_che_solve_hi ! |
|---|
| 33 | |
|---|
| 34 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: sio3eq ! chemistry of Si |
|---|
| 35 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: fekeq ! chemistry of Fe |
|---|
| 36 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: chemc ! Solubilities of O2 and CO2 |
|---|
| 37 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: chemo2 ! Solubilities of O2 and CO2 |
|---|
| 38 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: fesol ! solubility of Fe |
|---|
| 39 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: tempis ! In situ temperature |
|---|
| 40 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: salinprac ! Practical salinity |
|---|
| 41 | |
|---|
| 42 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: akb3 !: ??? |
|---|
| 43 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: akw3 !: ??? |
|---|
| 44 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: akf3 !: ??? |
|---|
| 45 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: aks3 !: ??? |
|---|
| 46 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ak1p3 !: ??? |
|---|
| 47 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ak2p3 !: ??? |
|---|
| 48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ak3p3 !: ??? |
|---|
| 49 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: aksi3 !: ??? |
|---|
| 50 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: borat !: ??? |
|---|
| 51 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: fluorid !: ??? |
|---|
| 52 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: sulfat !: ??? |
|---|
| 53 | |
|---|
| 54 | !!* Variable for chemistry of the CO2 cycle |
|---|
| 55 | |
|---|
| 56 | REAL(wp), PUBLIC :: atcox = 0.20946 ! units atm |
|---|
| 57 | |
|---|
| 58 | REAL(wp) :: o2atm = 1. / ( 1000. * 0.20946 ) |
|---|
| 59 | |
|---|
| 60 | REAL(wp) :: rgas = 83.14472 ! universal gas constants |
|---|
| 61 | REAL(wp) :: oxyco = 1. / 22.4144 ! converts from liters of an ideal gas to moles |
|---|
| 62 | |
|---|
| 63 | ! ! coeff. for seawater pressure correction : millero 95 |
|---|
| 64 | ! ! AGRIF doesn't like the DATA instruction |
|---|
| 65 | REAL(wp) :: devk10 = -25.5 |
|---|
| 66 | REAL(wp) :: devk11 = -15.82 |
|---|
| 67 | REAL(wp) :: devk12 = -29.48 |
|---|
| 68 | REAL(wp) :: devk13 = -20.02 |
|---|
| 69 | REAL(wp) :: devk14 = -18.03 |
|---|
| 70 | REAL(wp) :: devk15 = -9.78 |
|---|
| 71 | REAL(wp) :: devk16 = -48.76 |
|---|
| 72 | REAL(wp) :: devk17 = -14.51 |
|---|
| 73 | REAL(wp) :: devk18 = -23.12 |
|---|
| 74 | REAL(wp) :: devk19 = -26.57 |
|---|
| 75 | REAL(wp) :: devk110 = -29.48 |
|---|
| 76 | ! |
|---|
| 77 | REAL(wp) :: devk20 = 0.1271 |
|---|
| 78 | REAL(wp) :: devk21 = -0.0219 |
|---|
| 79 | REAL(wp) :: devk22 = 0.1622 |
|---|
| 80 | REAL(wp) :: devk23 = 0.1119 |
|---|
| 81 | REAL(wp) :: devk24 = 0.0466 |
|---|
| 82 | REAL(wp) :: devk25 = -0.0090 |
|---|
| 83 | REAL(wp) :: devk26 = 0.5304 |
|---|
| 84 | REAL(wp) :: devk27 = 0.1211 |
|---|
| 85 | REAL(wp) :: devk28 = 0.1758 |
|---|
| 86 | REAL(wp) :: devk29 = 0.2020 |
|---|
| 87 | REAL(wp) :: devk210 = 0.1622 |
|---|
| 88 | ! |
|---|
| 89 | REAL(wp) :: devk30 = 0. |
|---|
| 90 | REAL(wp) :: devk31 = 0. |
|---|
| 91 | REAL(wp) :: devk32 = 2.608E-3 |
|---|
| 92 | REAL(wp) :: devk33 = -1.409e-3 |
|---|
| 93 | REAL(wp) :: devk34 = 0.316e-3 |
|---|
| 94 | REAL(wp) :: devk35 = -0.942e-3 |
|---|
| 95 | REAL(wp) :: devk36 = 0. |
|---|
| 96 | REAL(wp) :: devk37 = -0.321e-3 |
|---|
| 97 | REAL(wp) :: devk38 = -2.647e-3 |
|---|
| 98 | REAL(wp) :: devk39 = -3.042e-3 |
|---|
| 99 | REAL(wp) :: devk310 = -2.6080e-3 |
|---|
| 100 | ! |
|---|
| 101 | REAL(wp) :: devk40 = -3.08E-3 |
|---|
| 102 | REAL(wp) :: devk41 = 1.13E-3 |
|---|
| 103 | REAL(wp) :: devk42 = -2.84E-3 |
|---|
| 104 | REAL(wp) :: devk43 = -5.13E-3 |
|---|
| 105 | REAL(wp) :: devk44 = -4.53e-3 |
|---|
| 106 | REAL(wp) :: devk45 = -3.91e-3 |
|---|
| 107 | REAL(wp) :: devk46 = -11.76e-3 |
|---|
| 108 | REAL(wp) :: devk47 = -2.67e-3 |
|---|
| 109 | REAL(wp) :: devk48 = -5.15e-3 |
|---|
| 110 | REAL(wp) :: devk49 = -4.08e-3 |
|---|
| 111 | REAL(wp) :: devk410 = -2.84e-3 |
|---|
| 112 | ! |
|---|
| 113 | REAL(wp) :: devk50 = 0.0877E-3 |
|---|
| 114 | REAL(wp) :: devk51 = -0.1475E-3 |
|---|
| 115 | REAL(wp) :: devk52 = 0. |
|---|
| 116 | REAL(wp) :: devk53 = 0.0794E-3 |
|---|
| 117 | REAL(wp) :: devk54 = 0.09e-3 |
|---|
| 118 | REAL(wp) :: devk55 = 0.054e-3 |
|---|
| 119 | REAL(wp) :: devk56 = 0.3692E-3 |
|---|
| 120 | REAL(wp) :: devk57 = 0.0427e-3 |
|---|
| 121 | REAL(wp) :: devk58 = 0.09e-3 |
|---|
| 122 | REAL(wp) :: devk59 = 0.0714e-3 |
|---|
| 123 | REAL(wp) :: devk510 = 0.0 |
|---|
| 124 | ! |
|---|
| 125 | ! General parameters |
|---|
| 126 | REAL(wp), PARAMETER :: pp_rdel_ah_target = 1.E-4_wp |
|---|
| 127 | REAL(wp), PARAMETER :: pp_ln10 = 2.302585092994045684018_wp |
|---|
| 128 | |
|---|
| 129 | ! Maximum number of iterations for each method |
|---|
| 130 | INTEGER, PARAMETER :: jp_maxniter_atgen = 20 |
|---|
| 131 | |
|---|
| 132 | ! Bookkeeping variables for each method |
|---|
| 133 | ! - SOLVE_AT_GENERAL |
|---|
| 134 | INTEGER :: niter_atgen = jp_maxniter_atgen |
|---|
| 135 | |
|---|
| 136 | !!* Substitution |
|---|
| 137 | #include "top_substitute.h90" |
|---|
| 138 | !!---------------------------------------------------------------------- |
|---|
| 139 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 140 | !! $Id$ |
|---|
| 141 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 142 | !!---------------------------------------------------------------------- |
|---|
| 143 | CONTAINS |
|---|
| 144 | |
|---|
| 145 | SUBROUTINE p4z_che |
|---|
| 146 | !!--------------------------------------------------------------------- |
|---|
| 147 | !! *** ROUTINE p4z_che *** |
|---|
| 148 | !! |
|---|
| 149 | !! ** Purpose : Sea water chemistry computed following OCMIP protocol |
|---|
| 150 | !! |
|---|
| 151 | !! ** Method : - ... |
|---|
| 152 | !!--------------------------------------------------------------------- |
|---|
| 153 | INTEGER :: ji, jj, jk |
|---|
| 154 | REAL(wp) :: ztkel, ztkel1, zt , zsal , zsal2 , zbuf1 , zbuf2 |
|---|
| 155 | REAL(wp) :: ztgg , ztgg2, ztgg3 , ztgg4 , ztgg5 |
|---|
| 156 | REAL(wp) :: zpres, ztc , zcl , zcpexp, zoxy , zcpexp2 |
|---|
| 157 | REAL(wp) :: zsqrt, ztr , zlogt , zcek1, zc1, zplat |
|---|
| 158 | REAL(wp) :: zis , zis2 , zsal15, zisqrt, za1, za2 |
|---|
| 159 | REAL(wp) :: zckb , zck1 , zck2 , zckw , zak1 , zak2 , zakb , zaksp0, zakw |
|---|
| 160 | REAL(wp) :: zck1p, zck2p, zck3p, zcksi, zak1p, zak2p, zak3p, zaksi |
|---|
| 161 | REAL(wp) :: zst , zft , zcks , zckf , zaksp1 |
|---|
| 162 | REAL(wp) :: total2free, free2SWS, total2SWS, SWS2total |
|---|
| 163 | |
|---|
| 164 | !!--------------------------------------------------------------------- |
|---|
| 165 | ! |
|---|
| 166 | IF( nn_timing == 1 ) CALL timing_start('p4z_che') |
|---|
| 167 | ! |
|---|
| 168 | ! Computation of chemical constants require practical salinity |
|---|
| 169 | ! Thus, when TEOS08 is used, absolute salinity is converted to |
|---|
| 170 | ! practical salinity |
|---|
| 171 | ! ------------------------------------------------------------- |
|---|
| 172 | IF (nn_eos == -1) THEN |
|---|
| 173 | salinprac(:,:,:) = tsn(:,:,:,jp_sal) * 35.0 / 35.16504 |
|---|
| 174 | ELSE |
|---|
| 175 | salinprac(:,:,:) = tsn(:,:,:,jp_sal) |
|---|
| 176 | ENDIF |
|---|
| 177 | |
|---|
| 178 | ! |
|---|
| 179 | ! Computations of chemical constants require in situ temperature |
|---|
| 180 | ! Here a quite simple formulation is used to convert |
|---|
| 181 | ! potential temperature to in situ temperature. The errors is less than |
|---|
| 182 | ! 0.04°C relative to an exact computation |
|---|
| 183 | ! --------------------------------------------------------------------- |
|---|
| 184 | DO jk = 1, jpk |
|---|
| 185 | DO jj = 1, jpj |
|---|
| 186 | DO ji = 1, jpi |
|---|
| 187 | zpres = fsdept(ji,jj,jk) / 1000. |
|---|
| 188 | za1 = 0.04 * ( 1.0 + 0.185 * tsn(ji,jj,jk,jp_tem) + 0.035 * (salinprac(ji,jj,jk) - 35.0) ) |
|---|
| 189 | za2 = 0.0075 * ( 1.0 - tsn(ji,jj,jk,jp_tem) / 30.0 ) |
|---|
| 190 | tempis(ji,jj,jk) = tsn(ji,jj,jk,jp_tem) - za1 * zpres + za2 * zpres**2 |
|---|
| 191 | END DO |
|---|
| 192 | END DO |
|---|
| 193 | END DO |
|---|
| 194 | ! |
|---|
| 195 | ! CHEMICAL CONSTANTS - SURFACE LAYER |
|---|
| 196 | ! ---------------------------------- |
|---|
| 197 | !CDIR NOVERRCHK |
|---|
| 198 | DO jj = 1, jpj |
|---|
| 199 | !CDIR NOVERRCHK |
|---|
| 200 | DO ji = 1, jpi |
|---|
| 201 | ! ! SET ABSOLUTE TEMPERATURE |
|---|
| 202 | ztkel = tempis(ji,jj,1) + 273.15 |
|---|
| 203 | zt = ztkel * 0.01 |
|---|
| 204 | zsal = salinprac(ji,jj,1) + ( 1.- tmask(ji,jj,1) ) * 35. |
|---|
| 205 | ! ! LN(K0) OF SOLUBILITY OF CO2 (EQ. 12, WEISS, 1980) |
|---|
| 206 | ! ! AND FOR THE ATMOSPHERE FOR NON IDEAL GAS |
|---|
| 207 | zcek1 = 9345.17/ztkel - 60.2409 + 23.3585 * LOG(zt) + zsal*(0.023517 - 0.00023656*ztkel & |
|---|
| 208 | & + 0.0047036e-4*ztkel**2) |
|---|
| 209 | chemc(ji,jj,1) = EXP( zcek1 ) * 1E-6 * rhop(ji,jj,1) / 1000. ! mol/(L atm) |
|---|
| 210 | chemc(ji,jj,2) = -1636.75 + 12.0408*ztkel - 0.0327957*ztkel**2 + 0.0000316528*ztkel**3 |
|---|
| 211 | chemc(ji,jj,3) = 57.7 - 0.118*ztkel |
|---|
| 212 | ! |
|---|
| 213 | END DO |
|---|
| 214 | END DO |
|---|
| 215 | |
|---|
| 216 | ! OXYGEN SOLUBILITY - DEEP OCEAN |
|---|
| 217 | ! ------------------------------- |
|---|
| 218 | !CDIR NOVERRCHK |
|---|
| 219 | DO jk = 1, jpk |
|---|
| 220 | !CDIR NOVERRCHK |
|---|
| 221 | DO jj = 1, jpj |
|---|
| 222 | !CDIR NOVERRCHK |
|---|
| 223 | DO ji = 1, jpi |
|---|
| 224 | ztkel = tempis(ji,jj,jk) + 273.15 |
|---|
| 225 | zsal = salinprac(ji,jj,jk) + ( 1.- tmask(ji,jj,jk) ) * 35. |
|---|
| 226 | zsal2 = zsal * zsal |
|---|
| 227 | ztgg = LOG( ( 298.15 - tempis(ji,jj,jk) ) / ztkel ) ! Set the GORDON & GARCIA scaled temperature |
|---|
| 228 | ztgg2 = ztgg * ztgg |
|---|
| 229 | ztgg3 = ztgg2 * ztgg |
|---|
| 230 | ztgg4 = ztgg3 * ztgg |
|---|
| 231 | ztgg5 = ztgg4 * ztgg |
|---|
| 232 | |
|---|
| 233 | zoxy = 2.00856 + 3.22400 * ztgg + 3.99063 * ztgg2 + 4.80299 * ztgg3 & |
|---|
| 234 | & + 9.78188e-1 * ztgg4 + 1.71069 * ztgg5 + zsal * ( -6.24097e-3 & |
|---|
| 235 | & - 6.93498e-3 * ztgg - 6.90358e-3 * ztgg2 - 4.29155e-3 * ztgg3 ) & |
|---|
| 236 | & - 3.11680e-7 * zsal2 |
|---|
| 237 | chemo2(ji,jj,jk) = ( EXP( zoxy ) * o2atm ) * oxyco * atcox ! mol/(L atm) |
|---|
| 238 | END DO |
|---|
| 239 | END DO |
|---|
| 240 | END DO |
|---|
| 241 | |
|---|
| 242 | |
|---|
| 243 | |
|---|
| 244 | ! CHEMICAL CONSTANTS - DEEP OCEAN |
|---|
| 245 | ! ------------------------------- |
|---|
| 246 | !CDIR NOVERRCHK |
|---|
| 247 | DO jk = 1, jpk |
|---|
| 248 | !CDIR NOVERRCHK |
|---|
| 249 | DO jj = 1, jpj |
|---|
| 250 | !CDIR NOVERRCHK |
|---|
| 251 | DO ji = 1, jpi |
|---|
| 252 | |
|---|
| 253 | ! SET PRESSION ACCORDING TO SAUNDER (1980) |
|---|
| 254 | zplat = SIN ( ABS(gphit(ji,jj)*3.141592654/180.) ) |
|---|
| 255 | zc1 = 5.92E-3 + zplat**2 * 5.25E-3 |
|---|
| 256 | zpres = ((1-zc1)-SQRT(((1-zc1)**2)-(8.84E-6*fsdept(ji,jj,jk)))) / 4.42E-6 |
|---|
| 257 | zpres = zpres / 10.0 |
|---|
| 258 | |
|---|
| 259 | ! SET ABSOLUTE TEMPERATURE |
|---|
| 260 | ztkel = tempis(ji,jj,jk) + 273.15 |
|---|
| 261 | zsal = salinprac(ji,jj,jk) + ( 1.-tmask(ji,jj,jk) ) * 35. |
|---|
| 262 | zsqrt = SQRT( zsal ) |
|---|
| 263 | zsal15 = zsqrt * zsal |
|---|
| 264 | zlogt = LOG( ztkel ) |
|---|
| 265 | ztr = 1. / ztkel |
|---|
| 266 | zis = 19.924 * zsal / ( 1000.- 1.005 * zsal ) |
|---|
| 267 | zis2 = zis * zis |
|---|
| 268 | zisqrt = SQRT( zis ) |
|---|
| 269 | ztc = tempis(ji,jj,jk) + ( 1.- tmask(ji,jj,jk) ) * 20. |
|---|
| 270 | |
|---|
| 271 | ! CHLORINITY (WOOSTER ET AL., 1969) |
|---|
| 272 | zcl = zsal / 1.80655 |
|---|
| 273 | |
|---|
| 274 | ! TOTAL SULFATE CONCENTR. [MOLES/kg soln] |
|---|
| 275 | zst = 0.14 * zcl /96.062 |
|---|
| 276 | |
|---|
| 277 | ! TOTAL FLUORIDE CONCENTR. [MOLES/kg soln] |
|---|
| 278 | zft = 0.000067 * zcl /18.9984 |
|---|
| 279 | |
|---|
| 280 | ! DISSOCIATION CONSTANT FOR SULFATES on free H scale (Dickson 1990) |
|---|
| 281 | zcks = EXP(-4276.1 * ztr + 141.328 - 23.093 * zlogt & |
|---|
| 282 | & + (-13856. * ztr + 324.57 - 47.986 * zlogt) * zisqrt & |
|---|
| 283 | & + (35474. * ztr - 771.54 + 114.723 * zlogt) * zis & |
|---|
| 284 | & - 2698. * ztr * zis**1.5 + 1776.* ztr * zis2 & |
|---|
| 285 | & + LOG(1.0 - 0.001005 * zsal)) |
|---|
| 286 | |
|---|
| 287 | ! DISSOCIATION CONSTANT FOR FLUORIDES on free H scale (Dickson and Riley 79) |
|---|
| 288 | zckf = EXP( 1590.2*ztr - 12.641 + 1.525*zisqrt & |
|---|
| 289 | & + LOG(1.0d0 - 0.001005d0*zsal) & |
|---|
| 290 | & + LOG(1.0d0 + zst/zcks)) |
|---|
| 291 | |
|---|
| 292 | ! DISSOCIATION CONSTANT FOR CARBONATE AND BORATE |
|---|
| 293 | zckb= (-8966.90 - 2890.53*zsqrt - 77.942*zsal & |
|---|
| 294 | & + 1.728*zsal15 - 0.0996*zsal*zsal)*ztr & |
|---|
| 295 | & + (148.0248 + 137.1942*zsqrt + 1.62142*zsal) & |
|---|
| 296 | & + (-24.4344 - 25.085*zsqrt - 0.2474*zsal) & |
|---|
| 297 | & * zlogt + 0.053105*zsqrt*ztkel |
|---|
| 298 | |
|---|
| 299 | ! DISSOCIATION COEFFICIENT FOR CARBONATE ACCORDING TO |
|---|
| 300 | ! MEHRBACH (1973) REFIT BY MILLERO (1995), seawater scale |
|---|
| 301 | zck1 = -1.0*(3633.86*ztr - 61.2172 + 9.6777*zlogt & |
|---|
| 302 | - 0.011555*zsal + 0.0001152*zsal*zsal) |
|---|
| 303 | zck2 = -1.0*(471.78*ztr + 25.9290 - 3.16967*zlogt & |
|---|
| 304 | - 0.01781*zsal + 0.0001122*zsal*zsal) |
|---|
| 305 | |
|---|
| 306 | ! PKW (H2O) (MILLERO, 1995) from composite data |
|---|
| 307 | zckw = -13847.26 * ztr + 148.9652 - 23.6521 * zlogt + ( 118.67 * ztr & |
|---|
| 308 | - 5.977 + 1.0495 * zlogt ) * zsqrt - 0.01615 * zsal |
|---|
| 309 | |
|---|
| 310 | ! CONSTANTS FOR PHOSPHATE (MILLERO, 1995) |
|---|
| 311 | zck1p = -4576.752*ztr + 115.540 - 18.453*zlogt & |
|---|
| 312 | & + (-106.736*ztr + 0.69171) * zsqrt & |
|---|
| 313 | & + (-0.65643*ztr - 0.01844) * zsal |
|---|
| 314 | |
|---|
| 315 | zck2p = -8814.715*ztr + 172.1033 - 27.927*zlogt & |
|---|
| 316 | & + (-160.340*ztr + 1.3566)*zsqrt & |
|---|
| 317 | & + (0.37335*ztr - 0.05778)*zsal |
|---|
| 318 | |
|---|
| 319 | zck3p = -3070.75*ztr - 18.126 & |
|---|
| 320 | & + (17.27039*ztr + 2.81197) * zsqrt & |
|---|
| 321 | & + (-44.99486*ztr - 0.09984) * zsal |
|---|
| 322 | |
|---|
| 323 | ! CONSTANT FOR SILICATE, MILLERO (1995) |
|---|
| 324 | zcksi = -8904.2*ztr + 117.400 - 19.334*zlogt & |
|---|
| 325 | & + (-458.79*ztr + 3.5913) * zisqrt & |
|---|
| 326 | & + (188.74*ztr - 1.5998) * zis & |
|---|
| 327 | & + (-12.1652*ztr + 0.07871) * zis2 & |
|---|
| 328 | & + LOG(1.0 - 0.001005*zsal) |
|---|
| 329 | |
|---|
| 330 | ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE IN SEAWATER |
|---|
| 331 | ! (S=27-43, T=2-25 DEG C) at pres =0 (atmos. pressure) (MUCCI 1983) |
|---|
| 332 | zaksp0 = -171.9065 -0.077993*ztkel + 2839.319*ztr + 71.595*LOG10( ztkel ) & |
|---|
| 333 | & + (-0.77712 + 0.00284263*ztkel + 178.34*ztr) * zsqrt & |
|---|
| 334 | & - 0.07711*zsal + 0.0041249*zsal15 |
|---|
| 335 | |
|---|
| 336 | ! CONVERT FROM DIFFERENT PH SCALES |
|---|
| 337 | total2free = 1.0/(1.0 + zst/zcks) |
|---|
| 338 | free2SWS = 1. + zst/zcks + zft/(zckf*total2free) |
|---|
| 339 | total2SWS = total2free * free2SWS |
|---|
| 340 | SWS2total = 1.0 / total2SWS |
|---|
| 341 | |
|---|
| 342 | ! K1, K2 OF CARBONIC ACID, KB OF BORIC ACID, KW (H2O) (LIT.?) |
|---|
| 343 | zak1 = 10**(zck1) * total2SWS |
|---|
| 344 | zak2 = 10**(zck2) * total2SWS |
|---|
| 345 | zakb = EXP( zckb ) * total2SWS |
|---|
| 346 | zakw = EXP( zckw ) |
|---|
| 347 | zaksp1 = 10**(zaksp0) |
|---|
| 348 | zak1p = exp( zck1p ) |
|---|
| 349 | zak2p = exp( zck2p ) |
|---|
| 350 | zak3p = exp( zck3p ) |
|---|
| 351 | zaksi = exp( zcksi ) |
|---|
| 352 | zckf = zckf * total2SWS |
|---|
| 353 | |
|---|
| 354 | ! FORMULA FOR CPEXP AFTER EDMOND & GIESKES (1970) |
|---|
| 355 | ! (REFERENCE TO CULBERSON & PYTKOQICZ (1968) AS MADE |
|---|
| 356 | ! IN BROECKER ET AL. (1982) IS INCORRECT; HERE RGAS IS |
|---|
| 357 | ! TAKEN TENFOLD TO CORRECT FOR THE NOTATION OF pres IN |
|---|
| 358 | ! DBAR INSTEAD OF BAR AND THE EXPRESSION FOR CPEXP IS |
|---|
| 359 | ! MULTIPLIED BY LN(10.) TO ALLOW USE OF EXP-FUNCTION |
|---|
| 360 | ! WITH BASIS E IN THE FORMULA FOR AKSPP (CF. EDMOND |
|---|
| 361 | ! & GIESKES (1970), P. 1285-1286 (THE SMALL |
|---|
| 362 | ! FORMULA ON P. 1286 IS RIGHT AND CONSISTENT WITH THE |
|---|
| 363 | ! SIGN IN PARTIAL MOLAR VOLUME CHANGE AS SHOWN ON P. 1285)) |
|---|
| 364 | zcpexp = zpres / (rgas*ztkel) |
|---|
| 365 | zcpexp2 = zpres * zcpexp |
|---|
| 366 | |
|---|
| 367 | ! KB OF BORIC ACID, K1,K2 OF CARBONIC ACID PRESSURE |
|---|
| 368 | ! CORRECTION AFTER CULBERSON AND PYTKOWICZ (1968) |
|---|
| 369 | ! (CF. BROECKER ET AL., 1982) |
|---|
| 370 | |
|---|
| 371 | zbuf1 = - ( devk10 + devk20 * ztc + devk30 * ztc * ztc ) |
|---|
| 372 | zbuf2 = 0.5 * ( devk40 + devk50 * ztc ) |
|---|
| 373 | ak13(ji,jj,jk) = zak1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 374 | |
|---|
| 375 | zbuf1 = - ( devk11 + devk21 * ztc + devk31 * ztc * ztc ) |
|---|
| 376 | zbuf2 = 0.5 * ( devk41 + devk51 * ztc ) |
|---|
| 377 | ak23(ji,jj,jk) = zak2 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 378 | |
|---|
| 379 | zbuf1 = - ( devk12 + devk22 * ztc + devk32 * ztc * ztc ) |
|---|
| 380 | zbuf2 = 0.5 * ( devk42 + devk52 * ztc ) |
|---|
| 381 | akb3(ji,jj,jk) = zakb * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 382 | |
|---|
| 383 | zbuf1 = - ( devk13 + devk23 * ztc + devk33 * ztc * ztc ) |
|---|
| 384 | zbuf2 = 0.5 * ( devk43 + devk53 * ztc ) |
|---|
| 385 | akw3(ji,jj,jk) = zakw * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 386 | |
|---|
| 387 | zbuf1 = - ( devk14 + devk24 * ztc + devk34 * ztc * ztc ) |
|---|
| 388 | zbuf2 = 0.5 * ( devk44 + devk54 * ztc ) |
|---|
| 389 | aks3(ji,jj,jk) = zcks * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 390 | |
|---|
| 391 | zbuf1 = - ( devk15 + devk25 * ztc + devk35 * ztc * ztc ) |
|---|
| 392 | zbuf2 = 0.5 * ( devk45 + devk55 * ztc ) |
|---|
| 393 | akf3(ji,jj,jk) = zckf * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 394 | |
|---|
| 395 | zbuf1 = - ( devk17 + devk27 * ztc + devk37 * ztc * ztc ) |
|---|
| 396 | zbuf2 = 0.5 * ( devk47 + devk57 * ztc ) |
|---|
| 397 | ak1p3(ji,jj,jk) = zak1p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 398 | |
|---|
| 399 | zbuf1 = - ( devk18 + devk28 * ztc + devk38 * ztc * ztc ) |
|---|
| 400 | zbuf2 = 0.5 * ( devk48 + devk58 * ztc ) |
|---|
| 401 | ak2p3(ji,jj,jk) = zak2p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 402 | |
|---|
| 403 | zbuf1 = - ( devk19 + devk29 * ztc + devk39 * ztc * ztc ) |
|---|
| 404 | zbuf2 = 0.5 * ( devk49 + devk59 * ztc ) |
|---|
| 405 | ak3p3(ji,jj,jk) = zak3p * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 406 | |
|---|
| 407 | zbuf1 = - ( devk110 + devk210 * ztc + devk310 * ztc * ztc ) |
|---|
| 408 | zbuf2 = 0.5 * ( devk410 + devk510 * ztc ) |
|---|
| 409 | aksi3(ji,jj,jk) = zaksi * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 410 | |
|---|
| 411 | ! CONVERT FROM DIFFERENT PH SCALES |
|---|
| 412 | total2free = 1.0/(1.0 + zst/aks3(ji,jj,jk)) |
|---|
| 413 | free2SWS = 1. + zst/aks3(ji,jj,jk) + zft/akf3(ji,jj,jk) |
|---|
| 414 | total2SWS = total2free * free2SWS |
|---|
| 415 | SWS2total = 1.0 / total2SWS |
|---|
| 416 | |
|---|
| 417 | ! Convert to total scale |
|---|
| 418 | ak13(ji,jj,jk) = ak13(ji,jj,jk) * SWS2total |
|---|
| 419 | ak23(ji,jj,jk) = ak23(ji,jj,jk) * SWS2total |
|---|
| 420 | akb3(ji,jj,jk) = akb3(ji,jj,jk) * SWS2total |
|---|
| 421 | akw3(ji,jj,jk) = akw3(ji,jj,jk) * SWS2total |
|---|
| 422 | ak1p3(ji,jj,jk) = ak1p3(ji,jj,jk) * SWS2total |
|---|
| 423 | ak2p3(ji,jj,jk) = ak2p3(ji,jj,jk) * SWS2total |
|---|
| 424 | ak3p3(ji,jj,jk) = ak3p3(ji,jj,jk) * SWS2total |
|---|
| 425 | aksi3(ji,jj,jk) = aksi3(ji,jj,jk) * SWS2total |
|---|
| 426 | akf3(ji,jj,jk) = akf3(ji,jj,jk) / total2free |
|---|
| 427 | |
|---|
| 428 | ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE |
|---|
| 429 | ! AS FUNCTION OF PRESSURE FOLLOWING MILLERO |
|---|
| 430 | ! (P. 1285) AND BERNER (1976) |
|---|
| 431 | zbuf1 = - ( devk16 + devk26 * ztc + devk36 * ztc * ztc ) |
|---|
| 432 | zbuf2 = 0.5 * ( devk46 + devk56 * ztc ) |
|---|
| 433 | aksp(ji,jj,jk) = zaksp1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 434 | |
|---|
| 435 | ! TOTAL F, S, and BORATE CONCENTR. [MOLES/L] |
|---|
| 436 | borat(ji,jj,jk) = 0.0002414 * zcl / 10.811 |
|---|
| 437 | sulfat(ji,jj,jk) = zst |
|---|
| 438 | fluorid(ji,jj,jk) = zft |
|---|
| 439 | |
|---|
| 440 | ! Iron and SIO3 saturation concentration from ... |
|---|
| 441 | sio3eq(ji,jj,jk) = EXP( LOG( 10.) * ( 6.44 - 968. / ztkel ) ) * 1.e-6 |
|---|
| 442 | fekeq (ji,jj,jk) = 10**( 17.27 - 1565.7 / ztkel ) |
|---|
| 443 | |
|---|
| 444 | ! Liu and Millero (1999) only valid 5 - 50 degC |
|---|
| 445 | ztkel1 = MAX( 5. , tempis(ji,jj,jk) ) + 273.16 |
|---|
| 446 | fesol(ji,jj,jk,1) = 10**((-13.486) - (0.1856* (zis**0.5)) + (0.3073*zis) + (5254.0/ztkel1)) |
|---|
| 447 | fesol(ji,jj,jk,2) = 10**(2.517 - (0.885*(zis**0.5)) + (0.2139 * zis) - (1320.0/ztkel1) ) |
|---|
| 448 | fesol(ji,jj,jk,3) = 10**(0.4511 - (0.3305*(zis**0.5)) - (1996.0/ztkel1) ) |
|---|
| 449 | fesol(ji,jj,jk,4) = 10**(-0.2965 - (0.7881*(zis**0.5)) - (4086.0/ztkel1) ) |
|---|
| 450 | fesol(ji,jj,jk,5) = 10**(4.4466 - (0.8505*(zis**0.5)) - (7980.0/ztkel1) ) |
|---|
| 451 | END DO |
|---|
| 452 | END DO |
|---|
| 453 | END DO |
|---|
| 454 | ! |
|---|
| 455 | IF( nn_timing == 1 ) CALL timing_stop('p4z_che') |
|---|
| 456 | ! |
|---|
| 457 | END SUBROUTINE p4z_che |
|---|
| 458 | |
|---|
| 459 | SUBROUTINE p4z_che_ahini( p_hini ) |
|---|
| 460 | !!--------------------------------------------------------------------- |
|---|
| 461 | !! *** ROUTINE ahini_for_at *** |
|---|
| 462 | !! |
|---|
| 463 | !! Subroutine returns the root for the 2nd order approximation of the |
|---|
| 464 | !! DIC -- B_T -- A_CB equation for [H+] (reformulated as a cubic |
|---|
| 465 | !! polynomial) around the local minimum, if it exists. |
|---|
| 466 | !! Returns * 1E-03_wp if p_alkcb <= 0 |
|---|
| 467 | !! * 1E-10_wp if p_alkcb >= 2*p_dictot + p_bortot |
|---|
| 468 | !! * 1E-07_wp if 0 < p_alkcb < 2*p_dictot + p_bortot |
|---|
| 469 | !! and the 2nd order approximation does not have |
|---|
| 470 | !! a solution |
|---|
| 471 | !!--------------------------------------------------------------------- |
|---|
| 472 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT) :: p_hini |
|---|
| 473 | INTEGER :: ji, jj, jk |
|---|
| 474 | REAL(wp) :: zca1, zba1 |
|---|
| 475 | REAL(wp) :: zd, zsqrtd, zhmin |
|---|
| 476 | REAL(wp) :: za2, za1, za0 |
|---|
| 477 | REAL(wp) :: p_dictot, p_bortot, p_alkcb |
|---|
| 478 | |
|---|
| 479 | IF( nn_timing == 1 ) CALL timing_start('p4z_che_ahini') |
|---|
| 480 | ! |
|---|
| 481 | DO jk = 1, jpk |
|---|
| 482 | DO jj = 1, jpj |
|---|
| 483 | DO ji = 1, jpi |
|---|
| 484 | p_alkcb = trb(ji,jj,jk,jptal) * 1000. / (rhop(ji,jj,jk) + rtrn) |
|---|
| 485 | p_dictot = trb(ji,jj,jk,jpdic) * 1000. / (rhop(ji,jj,jk) + rtrn) |
|---|
| 486 | p_bortot = borat(ji,jj,jk) |
|---|
| 487 | IF (p_alkcb <= 0.) THEN |
|---|
| 488 | p_hini(ji,jj,jk) = 1.e-3 |
|---|
| 489 | ELSEIF (p_alkcb >= (2.*p_dictot + p_bortot)) THEN |
|---|
| 490 | p_hini(ji,jj,jk) = 1.e-10_wp |
|---|
| 491 | ELSE |
|---|
| 492 | zca1 = p_dictot/( p_alkcb + rtrn ) |
|---|
| 493 | zba1 = p_bortot/ (p_alkcb + rtrn ) |
|---|
| 494 | ! Coefficients of the cubic polynomial |
|---|
| 495 | za2 = aKb3(ji,jj,jk)*(1. - zba1) + ak13(ji,jj,jk)*(1.-zca1) |
|---|
| 496 | za1 = ak13(ji,jj,jk)*akb3(ji,jj,jk)*(1. - zba1 - zca1) & |
|---|
| 497 | & + ak13(ji,jj,jk)*ak23(ji,jj,jk)*(1. - (zca1+zca1)) |
|---|
| 498 | za0 = ak13(ji,jj,jk)*ak23(ji,jj,jk)*akb3(ji,jj,jk)*(1. - zba1 - (zca1+zca1)) |
|---|
| 499 | ! Taylor expansion around the minimum |
|---|
| 500 | zd = za2*za2 - 3.*za1 ! Discriminant of the quadratic equation |
|---|
| 501 | ! for the minimum close to the root |
|---|
| 502 | |
|---|
| 503 | IF(zd > 0.) THEN ! If the discriminant is positive |
|---|
| 504 | zsqrtd = SQRT(zd) |
|---|
| 505 | IF(za2 < 0) THEN |
|---|
| 506 | zhmin = (-za2 + zsqrtd)/3. |
|---|
| 507 | ELSE |
|---|
| 508 | zhmin = -za1/(za2 + zsqrtd) |
|---|
| 509 | ENDIF |
|---|
| 510 | p_hini(ji,jj,jk) = zhmin + SQRT(-(za0 + zhmin*(za1 + zhmin*(za2 + zhmin)))/zsqrtd) |
|---|
| 511 | ELSE |
|---|
| 512 | p_hini(ji,jj,jk) = 1.e-7 |
|---|
| 513 | ENDIF |
|---|
| 514 | ! |
|---|
| 515 | ENDIF |
|---|
| 516 | END DO |
|---|
| 517 | END DO |
|---|
| 518 | END DO |
|---|
| 519 | ! |
|---|
| 520 | IF( nn_timing == 1 ) CALL timing_stop('p4z_che_ahini') |
|---|
| 521 | ! |
|---|
| 522 | END SUBROUTINE p4z_che_ahini |
|---|
| 523 | |
|---|
| 524 | !=============================================================================== |
|---|
| 525 | SUBROUTINE anw_infsup( p_alknw_inf, p_alknw_sup ) |
|---|
| 526 | |
|---|
| 527 | ! Subroutine returns the lower and upper bounds of "non-water-selfionization" |
|---|
| 528 | ! contributions to total alkalinity (the infimum and the supremum), i.e |
|---|
| 529 | ! inf(TA - [OH-] + [H+]) and sup(TA - [OH-] + [H+]) |
|---|
| 530 | |
|---|
| 531 | ! Argument variables |
|---|
| 532 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT) :: p_alknw_inf |
|---|
| 533 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT) :: p_alknw_sup |
|---|
| 534 | |
|---|
| 535 | p_alknw_inf(:,:,:) = -trb(:,:,:,jppo4) * 1000. / (rhop(:,:,:) + rtrn) - sulfat(:,:,:) & |
|---|
| 536 | & - fluorid(:,:,:) |
|---|
| 537 | p_alknw_sup(:,:,:) = (2. * trb(:,:,:,jpdic) + 2. * trb(:,:,:,jppo4) + trb(:,:,:,jpsil) ) & |
|---|
| 538 | & * 1000. / (rhop(:,:,:) + rtrn) + borat(:,:,:) |
|---|
| 539 | |
|---|
| 540 | END SUBROUTINE anw_infsup |
|---|
| 541 | |
|---|
| 542 | |
|---|
| 543 | SUBROUTINE p4z_che_solve_hi( p_hini, zhi ) |
|---|
| 544 | |
|---|
| 545 | ! Universal pH solver that converges from any given initial value, |
|---|
| 546 | ! determines upper an lower bounds for the solution if required |
|---|
| 547 | |
|---|
| 548 | ! Argument variables |
|---|
| 549 | !-------------------- |
|---|
| 550 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(IN) :: p_hini |
|---|
| 551 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(OUT) :: zhi |
|---|
| 552 | |
|---|
| 553 | ! Local variables |
|---|
| 554 | !----------------- |
|---|
| 555 | INTEGER :: ji, jj, jk, jn |
|---|
| 556 | REAL(wp) :: zh_ini, zh, zh_prev, zh_lnfactor |
|---|
| 557 | REAL(wp) :: zdelta, zh_delta |
|---|
| 558 | REAL(wp) :: zeqn, zdeqndh, zalka |
|---|
| 559 | REAL(wp) :: aphscale |
|---|
| 560 | REAL(wp) :: znumer_dic, zdnumer_dic, zdenom_dic, zalk_dic, zdalk_dic |
|---|
| 561 | REAL(wp) :: znumer_bor, zdnumer_bor, zdenom_bor, zalk_bor, zdalk_bor |
|---|
| 562 | REAL(wp) :: znumer_po4, zdnumer_po4, zdenom_po4, zalk_po4, zdalk_po4 |
|---|
| 563 | REAL(wp) :: znumer_sil, zdnumer_sil, zdenom_sil, zalk_sil, zdalk_sil |
|---|
| 564 | REAL(wp) :: znumer_so4, zdnumer_so4, zdenom_so4, zalk_so4, zdalk_so4 |
|---|
| 565 | REAL(wp) :: znumer_flu, zdnumer_flu, zdenom_flu, zalk_flu, zdalk_flu |
|---|
| 566 | REAL(wp) :: zalk_wat, zdalk_wat |
|---|
| 567 | REAL(wp) :: zfact, p_alktot, zdic, zbot, zpt, zst, zft, zsit |
|---|
| 568 | LOGICAL :: l_exitnow |
|---|
| 569 | REAL(wp), PARAMETER :: pz_exp_threshold = 1.0 |
|---|
| 570 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalknw_inf, zalknw_sup, rmask, zh_min, zh_max, zeqn_absmin |
|---|
| 571 | |
|---|
| 572 | IF( nn_timing == 1 ) CALL timing_start('p4z_che_solve_hi') |
|---|
| 573 | ! Allocate temporary workspace |
|---|
| 574 | CALL wrk_alloc( jpi, jpj, jpk, zalknw_inf, zalknw_sup, rmask ) |
|---|
| 575 | CALL wrk_alloc( jpi, jpj, jpk, zh_min, zh_max, zeqn_absmin ) |
|---|
| 576 | |
|---|
| 577 | CALL anw_infsup( zalknw_inf, zalknw_sup ) |
|---|
| 578 | |
|---|
| 579 | rmask(:,:,:) = tmask(:,:,:) |
|---|
| 580 | zhi(:,:,:) = 0. |
|---|
| 581 | |
|---|
| 582 | ! TOTAL H+ scale: conversion factor for Htot = aphscale * Hfree |
|---|
| 583 | DO jk = 1, jpk |
|---|
| 584 | DO jj = 1, jpj |
|---|
| 585 | DO ji = 1, jpi |
|---|
| 586 | IF (rmask(ji,jj,jk) == 1.) THEN |
|---|
| 587 | p_alktot = trb(ji,jj,jk,jptal) * 1000. / (rhop(ji,jj,jk) + rtrn) |
|---|
| 588 | aphscale = 1. + sulfat(ji,jj,jk)/aks3(ji,jj,jk) |
|---|
| 589 | zh_ini = p_hini(ji,jj,jk) |
|---|
| 590 | |
|---|
| 591 | zdelta = (p_alktot-zalknw_inf(ji,jj,jk))**2 + 4.*akw3(ji,jj,jk)/aphscale |
|---|
| 592 | |
|---|
| 593 | IF(p_alktot >= zalknw_inf(ji,jj,jk)) THEN |
|---|
| 594 | zh_min(ji,jj,jk) = 2.*akw3(ji,jj,jk) /( p_alktot-zalknw_inf(ji,jj,jk) + SQRT(zdelta) ) |
|---|
| 595 | ELSE |
|---|
| 596 | zh_min(ji,jj,jk) = aphscale*(-(p_alktot-zalknw_inf(ji,jj,jk)) + SQRT(zdelta) ) / 2. |
|---|
| 597 | ENDIF |
|---|
| 598 | |
|---|
| 599 | zdelta = (p_alktot-zalknw_sup(ji,jj,jk))**2 + 4.*akw3(ji,jj,jk)/aphscale |
|---|
| 600 | |
|---|
| 601 | IF(p_alktot <= zalknw_sup(ji,jj,jk)) THEN |
|---|
| 602 | zh_max(ji,jj,jk) = aphscale*(-(p_alktot-zalknw_sup(ji,jj,jk)) + SQRT(zdelta) ) / 2. |
|---|
| 603 | ELSE |
|---|
| 604 | zh_max(ji,jj,jk) = 2.*akw3(ji,jj,jk) /( p_alktot-zalknw_sup(ji,jj,jk) + SQRT(zdelta) ) |
|---|
| 605 | ENDIF |
|---|
| 606 | |
|---|
| 607 | zhi(ji,jj,jk) = MAX(MIN(zh_max(ji,jj,jk), zh_ini), zh_min(ji,jj,jk)) |
|---|
| 608 | ENDIF |
|---|
| 609 | END DO |
|---|
| 610 | END DO |
|---|
| 611 | END DO |
|---|
| 612 | |
|---|
| 613 | zeqn_absmin(:,:,:) = HUGE(1._wp) |
|---|
| 614 | |
|---|
| 615 | DO jn = 1, jp_maxniter_atgen |
|---|
| 616 | DO jk = 1, jpk |
|---|
| 617 | DO jj = 1, jpj |
|---|
| 618 | DO ji = 1, jpi |
|---|
| 619 | IF (rmask(ji,jj,jk) == 1.) THEN |
|---|
| 620 | zfact = rhop(ji,jj,jk) / 1000. + rtrn |
|---|
| 621 | p_alktot = trb(ji,jj,jk,jptal) / zfact |
|---|
| 622 | zdic = trb(ji,jj,jk,jpdic) / zfact |
|---|
| 623 | zbot = borat(ji,jj,jk) |
|---|
| 624 | zpt = trb(ji,jj,jk,jppo4) / zfact * po4r |
|---|
| 625 | zsit = trb(ji,jj,jk,jpsil) / zfact |
|---|
| 626 | zst = sulfat (ji,jj,jk) |
|---|
| 627 | zft = fluorid(ji,jj,jk) |
|---|
| 628 | aphscale = 1. + sulfat(ji,jj,jk)/aks3(ji,jj,jk) |
|---|
| 629 | zh = zhi(ji,jj,jk) |
|---|
| 630 | zh_prev = zh |
|---|
| 631 | |
|---|
| 632 | ! H2CO3 - HCO3 - CO3 : n=2, m=0 |
|---|
| 633 | znumer_dic = 2.*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*ak13(ji,jj,jk) |
|---|
| 634 | zdenom_dic = ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*(ak13(ji,jj,jk) + zh) |
|---|
| 635 | zalk_dic = zdic * (znumer_dic/zdenom_dic) |
|---|
| 636 | zdnumer_dic = ak13(ji,jj,jk)*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh & |
|---|
| 637 | *(4.*ak13(ji,jj,jk)*ak23(ji,jj,jk) + zh*ak13(ji,jj,jk)) |
|---|
| 638 | zdalk_dic = -zdic*(zdnumer_dic/zdenom_dic**2) |
|---|
| 639 | |
|---|
| 640 | |
|---|
| 641 | ! B(OH)3 - B(OH)4 : n=1, m=0 |
|---|
| 642 | znumer_bor = akb3(ji,jj,jk) |
|---|
| 643 | zdenom_bor = akb3(ji,jj,jk) + zh |
|---|
| 644 | zalk_bor = zbot * (znumer_bor/zdenom_bor) |
|---|
| 645 | zdnumer_bor = akb3(ji,jj,jk) |
|---|
| 646 | zdalk_bor = -zbot*(zdnumer_bor/zdenom_bor**2) |
|---|
| 647 | |
|---|
| 648 | |
|---|
| 649 | ! H3PO4 - H2PO4 - HPO4 - PO4 : n=3, m=1 |
|---|
| 650 | znumer_po4 = 3.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk) & |
|---|
| 651 | & + zh*(2.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh* ak1p3(ji,jj,jk)) |
|---|
| 652 | zdenom_po4 = ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk) & |
|---|
| 653 | & + zh*( ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh*(ak1p3(ji,jj,jk) + zh)) |
|---|
| 654 | zalk_po4 = zpt * (znumer_po4/zdenom_po4 - 1.) ! Zero level of H3PO4 = 1 |
|---|
| 655 | zdnumer_po4 = ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk) & |
|---|
| 656 | & + zh*(4.*ak1p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk) & |
|---|
| 657 | & + zh*(9.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk)*ak3p3(ji,jj,jk) & |
|---|
| 658 | & + ak1p3(ji,jj,jk)*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) & |
|---|
| 659 | & + zh*(4.*ak1p3(ji,jj,jk)*ak2p3(ji,jj,jk) + zh * ak1p3(ji,jj,jk) ) ) ) |
|---|
| 660 | zdalk_po4 = -zpt * (zdnumer_po4/zdenom_po4**2) |
|---|
| 661 | |
|---|
| 662 | ! H4SiO4 - H3SiO4 : n=1, m=0 |
|---|
| 663 | znumer_sil = aksi3(ji,jj,jk) |
|---|
| 664 | zdenom_sil = aksi3(ji,jj,jk) + zh |
|---|
| 665 | zalk_sil = zsit * (znumer_sil/zdenom_sil) |
|---|
| 666 | zdnumer_sil = aksi3(ji,jj,jk) |
|---|
| 667 | zdalk_sil = -zsit * (zdnumer_sil/zdenom_sil**2) |
|---|
| 668 | |
|---|
| 669 | ! HSO4 - SO4 : n=1, m=1 |
|---|
| 670 | aphscale = 1.0 + zst/aks3(ji,jj,jk) |
|---|
| 671 | znumer_so4 = aks3(ji,jj,jk) * aphscale |
|---|
| 672 | zdenom_so4 = aks3(ji,jj,jk) * aphscale + zh |
|---|
| 673 | zalk_so4 = zst * (znumer_so4/zdenom_so4 - 1.) |
|---|
| 674 | zdnumer_so4 = aks3(ji,jj,jk) |
|---|
| 675 | zdalk_so4 = -zst * (zdnumer_so4/zdenom_so4**2) |
|---|
| 676 | |
|---|
| 677 | ! HF - F : n=1, m=1 |
|---|
| 678 | znumer_flu = akf3(ji,jj,jk) |
|---|
| 679 | zdenom_flu = akf3(ji,jj,jk) + zh |
|---|
| 680 | zalk_flu = zft * (znumer_flu/zdenom_flu - 1.) |
|---|
| 681 | zdnumer_flu = akf3(ji,jj,jk) |
|---|
| 682 | zdalk_flu = -zft * (zdnumer_flu/zdenom_flu**2) |
|---|
| 683 | |
|---|
| 684 | ! H2O - OH |
|---|
| 685 | aphscale = 1.0 + zst/aks3(ji,jj,jk) |
|---|
| 686 | zalk_wat = akw3(ji,jj,jk)/zh - zh/aphscale |
|---|
| 687 | zdalk_wat = -akw3(ji,jj,jk)/zh**2 - 1./aphscale |
|---|
| 688 | |
|---|
| 689 | ! CALCULATE [ALK]([CO3--], [HCO3-]) |
|---|
| 690 | zeqn = zalk_dic + zalk_bor + zalk_po4 + zalk_sil & |
|---|
| 691 | & + zalk_so4 + zalk_flu & |
|---|
| 692 | & + zalk_wat - p_alktot |
|---|
| 693 | |
|---|
| 694 | zalka = p_alktot - (zalk_bor + zalk_po4 + zalk_sil & |
|---|
| 695 | & + zalk_so4 + zalk_flu + zalk_wat) |
|---|
| 696 | |
|---|
| 697 | zdeqndh = zdalk_dic + zdalk_bor + zdalk_po4 + zdalk_sil & |
|---|
| 698 | & + zdalk_so4 + zdalk_flu + zdalk_wat |
|---|
| 699 | |
|---|
| 700 | ! Adapt bracketing interval |
|---|
| 701 | IF(zeqn > 0._wp) THEN |
|---|
| 702 | zh_min(ji,jj,jk) = zh_prev |
|---|
| 703 | ELSEIF(zeqn < 0._wp) THEN |
|---|
| 704 | zh_max(ji,jj,jk) = zh_prev |
|---|
| 705 | ENDIF |
|---|
| 706 | |
|---|
| 707 | IF(ABS(zeqn) >= 0.5_wp*zeqn_absmin(ji,jj,jk)) THEN |
|---|
| 708 | ! if the function evaluation at the current point is |
|---|
| 709 | ! not decreasing faster than with a bisection step (at least linearly) |
|---|
| 710 | ! in absolute value take one bisection step on [ph_min, ph_max] |
|---|
| 711 | ! ph_new = (ph_min + ph_max)/2d0 |
|---|
| 712 | ! |
|---|
| 713 | ! In terms of [H]_new: |
|---|
| 714 | ! [H]_new = 10**(-ph_new) |
|---|
| 715 | ! = 10**(-(ph_min + ph_max)/2d0) |
|---|
| 716 | ! = SQRT(10**(-(ph_min + phmax))) |
|---|
| 717 | ! = SQRT(zh_max * zh_min) |
|---|
| 718 | zh = SQRT(zh_max(ji,jj,jk) * zh_min(ji,jj,jk)) |
|---|
| 719 | zh_lnfactor = (zh - zh_prev)/zh_prev ! Required to test convergence below |
|---|
| 720 | ELSE |
|---|
| 721 | ! dzeqn/dpH = dzeqn/d[H] * d[H]/dpH |
|---|
| 722 | ! = -zdeqndh * LOG(10) * [H] |
|---|
| 723 | ! \Delta pH = -zeqn/(zdeqndh*d[H]/dpH) = zeqn/(zdeqndh*[H]*LOG(10)) |
|---|
| 724 | ! |
|---|
| 725 | ! pH_new = pH_old + \deltapH |
|---|
| 726 | ! |
|---|
| 727 | ! [H]_new = 10**(-pH_new) |
|---|
| 728 | ! = 10**(-pH_old - \Delta pH) |
|---|
| 729 | ! = [H]_old * 10**(-zeqn/(zdeqndh*[H]_old*LOG(10))) |
|---|
| 730 | ! = [H]_old * EXP(-LOG(10)*zeqn/(zdeqndh*[H]_old*LOG(10))) |
|---|
| 731 | ! = [H]_old * EXP(-zeqn/(zdeqndh*[H]_old)) |
|---|
| 732 | |
|---|
| 733 | zh_lnfactor = -zeqn/(zdeqndh*zh_prev) |
|---|
| 734 | |
|---|
| 735 | IF(ABS(zh_lnfactor) > pz_exp_threshold) THEN |
|---|
| 736 | zh = zh_prev*EXP(zh_lnfactor) |
|---|
| 737 | ELSE |
|---|
| 738 | zh_delta = zh_lnfactor*zh_prev |
|---|
| 739 | zh = zh_prev + zh_delta |
|---|
| 740 | ENDIF |
|---|
| 741 | |
|---|
| 742 | IF( zh < zh_min(ji,jj,jk) ) THEN |
|---|
| 743 | ! if [H]_new < [H]_min |
|---|
| 744 | ! i.e., if ph_new > ph_max then |
|---|
| 745 | ! take one bisection step on [ph_prev, ph_max] |
|---|
| 746 | ! ph_new = (ph_prev + ph_max)/2d0 |
|---|
| 747 | ! In terms of [H]_new: |
|---|
| 748 | ! [H]_new = 10**(-ph_new) |
|---|
| 749 | ! = 10**(-(ph_prev + ph_max)/2d0) |
|---|
| 750 | ! = SQRT(10**(-(ph_prev + phmax))) |
|---|
| 751 | ! = SQRT([H]_old*10**(-ph_max)) |
|---|
| 752 | ! = SQRT([H]_old * zh_min) |
|---|
| 753 | zh = SQRT(zh_prev * zh_min(ji,jj,jk)) |
|---|
| 754 | zh_lnfactor = (zh - zh_prev)/zh_prev ! Required to test convergence below |
|---|
| 755 | ENDIF |
|---|
| 756 | |
|---|
| 757 | IF( zh > zh_max(ji,jj,jk) ) THEN |
|---|
| 758 | ! if [H]_new > [H]_max |
|---|
| 759 | ! i.e., if ph_new < ph_min, then |
|---|
| 760 | ! take one bisection step on [ph_min, ph_prev] |
|---|
| 761 | ! ph_new = (ph_prev + ph_min)/2d0 |
|---|
| 762 | ! In terms of [H]_new: |
|---|
| 763 | ! [H]_new = 10**(-ph_new) |
|---|
| 764 | ! = 10**(-(ph_prev + ph_min)/2d0) |
|---|
| 765 | ! = SQRT(10**(-(ph_prev + ph_min))) |
|---|
| 766 | ! = SQRT([H]_old*10**(-ph_min)) |
|---|
| 767 | ! = SQRT([H]_old * zhmax) |
|---|
| 768 | zh = SQRT(zh_prev * zh_max(ji,jj,jk)) |
|---|
| 769 | zh_lnfactor = (zh - zh_prev)/zh_prev ! Required to test convergence below |
|---|
| 770 | ENDIF |
|---|
| 771 | ENDIF |
|---|
| 772 | |
|---|
| 773 | zeqn_absmin(ji,jj,jk) = MIN( ABS(zeqn), zeqn_absmin(ji,jj,jk)) |
|---|
| 774 | |
|---|
| 775 | ! Stop iterations once |\delta{[H]}/[H]| < rdel |
|---|
| 776 | ! <=> |(zh - zh_prev)/zh_prev| = |EXP(-zeqn/(zdeqndh*zh_prev)) -1| < rdel |
|---|
| 777 | ! |EXP(-zeqn/(zdeqndh*zh_prev)) -1| ~ |zeqn/(zdeqndh*zh_prev)| |
|---|
| 778 | |
|---|
| 779 | ! Alternatively: |
|---|
| 780 | ! |\Delta pH| = |zeqn/(zdeqndh*zh_prev*LOG(10))| |
|---|
| 781 | ! ~ 1/LOG(10) * |\Delta [H]|/[H] |
|---|
| 782 | ! < 1/LOG(10) * rdel |
|---|
| 783 | |
|---|
| 784 | ! Hence |zeqn/(zdeqndh*zh)| < rdel |
|---|
| 785 | |
|---|
| 786 | ! rdel <-- pp_rdel_ah_target |
|---|
| 787 | l_exitnow = (ABS(zh_lnfactor) < pp_rdel_ah_target) |
|---|
| 788 | |
|---|
| 789 | IF(l_exitnow) THEN |
|---|
| 790 | rmask(ji,jj,jk) = 0. |
|---|
| 791 | ENDIF |
|---|
| 792 | |
|---|
| 793 | zhi(ji,jj,jk) = zh |
|---|
| 794 | |
|---|
| 795 | IF(jn >= jp_maxniter_atgen) THEN |
|---|
| 796 | zhi(ji,jj,jk) = -1._wp |
|---|
| 797 | ENDIF |
|---|
| 798 | |
|---|
| 799 | ENDIF |
|---|
| 800 | END DO |
|---|
| 801 | END DO |
|---|
| 802 | END DO |
|---|
| 803 | END DO |
|---|
| 804 | ! |
|---|
| 805 | CALL wrk_dealloc( jpi, jpj, jpk, zalknw_inf, zalknw_sup, rmask ) |
|---|
| 806 | CALL wrk_dealloc( jpi, jpj, jpk, zh_min, zh_max, zeqn_absmin ) |
|---|
| 807 | |
|---|
| 808 | |
|---|
| 809 | IF( nn_timing == 1 ) CALL timing_stop('p4z_che_solve_hi') |
|---|
| 810 | |
|---|
| 811 | |
|---|
| 812 | END SUBROUTINE p4z_che_solve_hi |
|---|
| 813 | |
|---|
| 814 | INTEGER FUNCTION p4z_che_alloc() |
|---|
| 815 | !!---------------------------------------------------------------------- |
|---|
| 816 | !! *** ROUTINE p4z_che_alloc *** |
|---|
| 817 | !!---------------------------------------------------------------------- |
|---|
| 818 | INTEGER :: ierr(3) ! Local variables |
|---|
| 819 | !!---------------------------------------------------------------------- |
|---|
| 820 | |
|---|
| 821 | ierr(:) = 0 |
|---|
| 822 | |
|---|
| 823 | ALLOCATE( sio3eq(jpi,jpj,jpk), fekeq(jpi,jpj,jpk), chemc(jpi,jpj,3), chemo2(jpi,jpj,jpk), STAT=ierr(1) ) |
|---|
| 824 | |
|---|
| 825 | ALLOCATE( akb3(jpi,jpj,jpk) , tempis(jpi, jpj, jpk), & |
|---|
| 826 | & akw3(jpi,jpj,jpk) , borat (jpi,jpj,jpk) , & |
|---|
| 827 | & aks3(jpi,jpj,jpk) , akf3(jpi,jpj,jpk) , & |
|---|
| 828 | & ak1p3(jpi,jpj,jpk) , ak2p3(jpi,jpj,jpk) , & |
|---|
| 829 | & ak3p3(jpi,jpj,jpk) , aksi3(jpi,jpj,jpk) , & |
|---|
| 830 | & fluorid(jpi,jpj,jpk) , sulfat(jpi,jpj,jpk) , & |
|---|
| 831 | & salinprac(jpi,jpj,jpk), STAT=ierr(2) ) |
|---|
| 832 | |
|---|
| 833 | ALLOCATE( fesol(jpi,jpj,jpk,5), STAT=ierr(3) ) |
|---|
| 834 | |
|---|
| 835 | !* Variable for chemistry of the CO2 cycle |
|---|
| 836 | p4z_che_alloc = MAXVAL( ierr ) |
|---|
| 837 | ! |
|---|
| 838 | IF( p4z_che_alloc /= 0 ) CALL ctl_warn('p4z_che_alloc : failed to allocate arrays.') |
|---|
| 839 | ! |
|---|
| 840 | END FUNCTION p4z_che_alloc |
|---|
| 841 | |
|---|
| 842 | #else |
|---|
| 843 | !!====================================================================== |
|---|
| 844 | !! Dummy module : No PISCES bio-model |
|---|
| 845 | !!====================================================================== |
|---|
| 846 | CONTAINS |
|---|
| 847 | SUBROUTINE p4z_che( kt ) ! Empty routine |
|---|
| 848 | INTEGER, INTENT(in) :: kt |
|---|
| 849 | WRITE(*,*) 'p4z_che: You should not have seen this print! error?', kt |
|---|
| 850 | END SUBROUTINE p4z_che |
|---|
| 851 | #endif |
|---|
| 852 | |
|---|
| 853 | !!====================================================================== |
|---|
| 854 | END MODULE p4zche |
|---|
