New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/2015/dev_r5020_CNRS_DIAPTR/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5020_CNRS_DIAPTR/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 5137

Last change on this file since 5137 was 5137, checked in by cetlod, 9 years ago

dev_r5020_CNRS_DIAPTR: some improvments of poleward heat transport diagnostics before merging with the trunk
  • Property svn:keywords set to Id
File size: 16.9 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   defined key_ldfslp   ||   defined key_esopa
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE trc_oce         ! share passive tracers/Ocean variables
24   USE zdf_oce         ! ocean vertical physics
25   USE ldftra_oce      ! ocean active tracers: lateral physics
26   USE ldfslp          ! iso-neutral slopes
27   USE diaptr          ! poleward transport diagnostics
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O library
30#if defined key_diaar5
31   USE phycst          ! physical constants
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33#endif
34   USE wrk_nemo        ! Memory Allocation
35   USE timing          ! Timing
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_ldf_iso   ! routine called by step.F90
41
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44#  include "ldftra_substitute.h90"
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_ldf_iso( kt, kit000, cdtype, pgu, pgv,              &
54      &                                pgui, pgvi,                    &
55      &                                ptb, pta, kjpt, pahtb0 )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE tra_ldf_iso  ***
58      !!
59      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
60      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
61      !!      add it to the general trend of tracer equation.
62      !!
63      !! ** Method  :   The horizontal component of the lateral diffusive trends
64      !!      is provided by a 2nd order operator rotated along neural or geopo-
65      !!      tential surfaces to which an eddy induced advection can be added
66      !!      It is computed using before fields (forward in time) and isopyc-
67      !!      nal or geopotential slopes computed in routine ldfslp.
68      !!
69      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
70      !!      ========    with partial cell update if ln_zps=T.
71      !!
72      !!      2nd part :  horizontal fluxes of the lateral mixing operator
73      !!      ========   
74      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
75      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
76      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
77      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
78      !!      take the horizontal divergence of the fluxes:
79      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
80      !!      Add this trend to the general trend (ta,sa):
81      !!         ta = ta + difft
82      !!
83      !!      3rd part: vertical trends of the lateral mixing operator
84      !!      ========  (excluding the vertical flux proportional to dk[t] )
85      !!      vertical fluxes associated with the rotated lateral mixing:
86      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
87      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
88      !!      take the horizontal divergence of the fluxes:
89      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
90      !!      Add this trend to the general trend (ta,sa):
91      !!         pta = pta + difft
92      !!
93      !! ** Action :   Update pta arrays with the before rotated diffusion
94      !!----------------------------------------------------------------------
95      USE oce     , ONLY:   zftu => ua       , zftv  => va         ! (ua,va) used as workspace
96      !
97      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
98      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
99      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
100      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
101      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu , pgv    ! tracer gradient at pstep levels
102      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgui, pgvi   ! tracer gradient at pstep levels
103      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
104      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
105      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
106      !
107      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
108      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
109      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
110      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
111      REAL(wp), POINTER, DIMENSION(:,:  ) ::  z2d
112      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zdkt, zdk1t, zdit, zdjt, ztfw 
113      !!----------------------------------------------------------------------
114      !
115      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
116      !
117      CALL wrk_alloc( jpi, jpj,      z2d ) 
118      CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt, ztfw, zdkt, zdk1t ) 
119      !
120
121      IF( kt == kit000 )  THEN
122         IF(lwp) WRITE(numout,*)
123         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
124         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
125      ENDIF
126      !
127      !                                                          ! ===========
128      DO jn = 1, kjpt                                            ! tracer loop
129         !                                                       ! ===========
130         !                                               
131         !!----------------------------------------------------------------------
132         !!   I - masked horizontal derivative
133         !!----------------------------------------------------------------------
134         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
135         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
136         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
137         !!end
138
139         ! Horizontal tracer gradient
140         DO jk = 1, jpkm1
141            DO jj = 1, jpjm1
142               DO ji = 1, fs_jpim1   ! vector opt.
143                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
144                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
145               END DO
146            END DO
147         END DO
148         IF( ln_zps ) THEN      ! partial steps correction at the last ocean level
149            DO jj = 1, jpjm1
150               DO ji = 1, fs_jpim1   ! vector opt.
151! IF useless if zpshde defines pgu everywhere
152                  IF (mbku(ji,jj) > 1) zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
153                  IF (mbkv(ji,jj) > 1) zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
154                  ! (ISF)
155                  IF (miku(ji,jj) > 1) zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
156                  IF (mikv(ji,jj) > 1) zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
157               END DO
158            END DO
159         ENDIF
160
161         !!----------------------------------------------------------------------
162         !!   II - horizontal trend  (full)
163         !!----------------------------------------------------------------------
164!CDIR PARALLEL DO PRIVATE( zdk1t )
165         !                                                ! ===============
166         DO jj = 1, jpj                                 ! Horizontal slab
167            !                                             ! ===============
168            DO ji = 1, jpi   ! vector opt.
169               DO jk = mikt(ji,jj), jpkm1
170               ! 1. Vertical tracer gradient at level jk and jk+1
171               ! ------------------------------------------------
172               ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
173                  zdk1t(ji,jj,jk) = ( ptb(ji,jj,jk,jn) - ptb(ji,jj,jk+1,jn) ) * tmask(ji,jj,jk+1)
174               !
175                  IF( jk == mikt(ji,jj) ) THEN  ;   zdkt(ji,jj,jk) = zdk1t(ji,jj,jk)
176                  ELSE                          ;   zdkt(ji,jj,jk) = ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) * tmask(ji,jj,jk)
177                  ENDIF
178               END DO
179            END DO
180         END DO
181
182            ! 2. Horizontal fluxes
183            ! --------------------   
184         DO jj = 1 , jpjm1
185            DO ji = 1, fs_jpim1   ! vector opt.
186               DO jk = mikt(ji,jj), jpkm1
187                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * re2u_e1u(ji,jj) * fse3u_n(ji,jj,jk)
188                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * re1v_e2v(ji,jj) * fse3v_n(ji,jj,jk)
189                  !
190                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
191                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
192                  !
193                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
194                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
195                  !
196                  zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
197                  zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
198                  !
199                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
200                     &              + zcof1 * (  zdkt (ji+1,jj,jk) + zdk1t(ji,jj,jk)      &
201                     &                         + zdk1t(ji+1,jj,jk) + zdkt (ji,jj,jk)  )  ) * umask(ji,jj,jk)
202                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
203                     &              + zcof2 * (  zdkt (ji,jj+1,jk) + zdk1t(ji,jj,jk)      &
204                     &                         + zdk1t(ji,jj+1,jk) + zdkt (ji,jj,jk)  )  ) * vmask(ji,jj,jk)                 
205               END DO
206            END DO
207         END DO
208
209            ! II.4 Second derivative (divergence) and add to the general trend
210            ! ----------------------------------------------------------------
211         DO jj = 2 , jpjm1
212            DO ji = fs_2, fs_jpim1   ! vector opt.
213               DO jk = mikt(ji,jj), jpkm1
214                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
215                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
216                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
217               END DO
218            END DO
219            !                                          ! ===============
220         END DO                                        !   End of slab 
221         !                                             ! ===============
222         !
223         ! "Poleward" diffusive heat or salt transports (T-S case only)
224         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
225            ! note sign is reversed to give down-gradient diffusive transports (#1043)
226            IF( jn == jp_tem)   htr_ldf(:) = ptr_sj( -zftv(:,:,:) )
227            IF( jn == jp_sal)   str_ldf(:) = ptr_sj( -zftv(:,:,:) )
228         ENDIF
229 
230         IF( iom_use("udiff_heattr") .OR. iom_use("vdiff_heattr") ) THEN
231           !
232           IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
233               z2d(:,:) = 0._wp 
234               DO jk = 1, jpkm1
235                  DO jj = 2, jpjm1
236                     DO ji = fs_2, fs_jpim1   ! vector opt.
237                        z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
238                     END DO
239                  END DO
240               END DO
241               z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
242               CALL lbc_lnk( z2d, 'U', -1. )
243               CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
244               !
245               z2d(:,:) = 0._wp 
246               DO jk = 1, jpkm1
247                  DO jj = 2, jpjm1
248                     DO ji = fs_2, fs_jpim1   ! vector opt.
249                        z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
250                     END DO
251                  END DO
252               END DO
253               z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
254               CALL lbc_lnk( z2d, 'V', -1. )
255               CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
256            END IF
257            !
258         ENDIF
259
260         !!----------------------------------------------------------------------
261         !!   III - vertical trend of T & S (extra diagonal terms only)
262         !!----------------------------------------------------------------------
263         
264         ! Local constant initialization
265         ! -----------------------------
266         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
267         
268         ! Vertical fluxes
269         ! ---------------
270         
271         ! Surface and bottom vertical fluxes set to zero
272         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
273         
274         ! interior (2=<jk=<jpk-1)
275         DO jk = 2, jpkm1
276            DO jj = 2, jpjm1
277               DO ji = fs_2, fs_jpim1   ! vector opt.
278                  zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji,jj,jk-1)
279                  !
280                  zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
281                     &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
282                  zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
283                     &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
284                  !
285                  zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
286                  zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
287                  !
288                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
289                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
290                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
291                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
292               END DO
293            END DO
294         END DO
295         
296         
297         ! I.5 Divergence of vertical fluxes added to the general tracer trend
298         ! -------------------------------------------------------------------
299         DO jk = 1, jpkm1
300            DO jj = 2, jpjm1
301               DO ji = fs_2, fs_jpim1   ! vector opt.
302                  zbtr = 1.0 / ( e12t(ji,jj) * fse3t_n(ji,jj,jk) )
303                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
304                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
305               END DO
306            END DO
307         END DO
308         !
309      END DO
310      !
311      CALL wrk_dealloc( jpi, jpj, z2d ) 
312      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt, ztfw, zdkt, zdk1t ) 
313      !
314      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
315      !
316   END SUBROUTINE tra_ldf_iso
317
318#else
319   !!----------------------------------------------------------------------
320   !!   default option :   Dummy code   NO rotation of the diffusive tensor
321   !!----------------------------------------------------------------------
322CONTAINS
323   SUBROUTINE tra_ldf_iso( kt, kit000,cdtype, pgu, pgv, pgui, pgvi, ptb, pta, kjpt, pahtb0 )      ! Empty routine
324      INTEGER:: kt, kit000
325      CHARACTER(len=3) ::   cdtype
326      REAL, DIMENSION(:,:,:) ::   pgu, pgv, pgui, pgvi    ! tracer gradient at pstep levels
327      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
328      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt, kit000, cdtype,   &
329         &                       pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
330   END SUBROUTINE tra_ldf_iso
331#endif
332
333   !!==============================================================================
334END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.