source: branches/2015/dev_r5021_UKMO1_CICE_coupling/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 5443

Last change on this file since 5443 was 5443, checked in by davestorkey, 5 years ago

Update 2015/dev_r5021_UKMO1_CICE_coupling branch to revision 5442 of the trunk.

File size: 58.4 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls       : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init  : initialization, namelist read, and parameters control
16   !!   gls_rst       : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE zdfbfr         ! bottom friction (only for rn_bfrz0)
23   USE sbc_oce        ! surface boundary condition: ocean
24   USE phycst         ! physical constants
25   USE zdfmxl         ! mixed layer
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp        ! MPP manager
28   USE wrk_nemo       ! work arrays
29   USE prtctl         ! Print control
30   USE in_out_manager ! I/O manager
31   USE iom            ! I/O manager library
32   USE timing         ! Timing
33   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   zdf_gls        ! routine called in step module
39   PUBLIC   zdf_gls_init   ! routine called in opa module
40   PUBLIC   gls_rst        ! routine called in step module
41
42   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
43   !
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   en      !: now turbulent kinetic energy
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avt_k   ! not enhanced Kz
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avm_k   ! not enhanced Kz
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avmu_k  ! not enhanced Kz
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avmv_k  ! not enhanced Kz
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
53
54   !                              !! ** Namelist  namzdf_gls  **
55   LOGICAL  ::   ln_length_lim     ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
56   LOGICAL  ::   ln_sigpsi         ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
57   INTEGER  ::   nn_bc_surf        ! surface boundary condition (=0/1)
58   INTEGER  ::   nn_bc_bot         ! bottom boundary condition (=0/1)
59   INTEGER  ::   nn_z0_met         ! Method for surface roughness computation
60   INTEGER  ::   nn_stab_func      ! stability functions G88, KC or Canuto (=0/1/2)
61   INTEGER  ::   nn_clos           ! closure 0/1/2/3 MY82/k-eps/k-w/gen
62   REAL(wp) ::   rn_clim_galp      ! Holt 2008 value for k-eps: 0.267
63   REAL(wp) ::   rn_epsmin         ! minimum value of dissipation (m2/s3)
64   REAL(wp) ::   rn_emin           ! minimum value of TKE (m2/s2)
65   REAL(wp) ::   rn_charn          ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
66   REAL(wp) ::   rn_crban          ! Craig and Banner constant for surface breaking waves mixing
67   REAL(wp) ::   rn_hsro           ! Minimum surface roughness
68   REAL(wp) ::   rn_frac_hs        ! Fraction of wave height as surface roughness (if nn_z0_met > 1)
69
70   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
71   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
72   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
73   REAL(wp) ::   rghmin        = -0.28_wp
74   REAL(wp) ::   rgh0          =  0.0329_wp
75   REAL(wp) ::   rghcri        =  0.03_wp
76   REAL(wp) ::   ra1           =  0.92_wp
77   REAL(wp) ::   ra2           =  0.74_wp
78   REAL(wp) ::   rb1           = 16.60_wp
79   REAL(wp) ::   rb2           = 10.10_wp         
80   REAL(wp) ::   re2           =  1.33_wp         
81   REAL(wp) ::   rl1           =  0.107_wp
82   REAL(wp) ::   rl2           =  0.0032_wp
83   REAL(wp) ::   rl3           =  0.0864_wp
84   REAL(wp) ::   rl4           =  0.12_wp
85   REAL(wp) ::   rl5           = 11.9_wp
86   REAL(wp) ::   rl6           =  0.4_wp
87   REAL(wp) ::   rl7           =  0.0_wp
88   REAL(wp) ::   rl8           =  0.48_wp
89   REAL(wp) ::   rm1           =  0.127_wp
90   REAL(wp) ::   rm2           =  0.00336_wp
91   REAL(wp) ::   rm3           =  0.0906_wp
92   REAL(wp) ::   rm4           =  0.101_wp
93   REAL(wp) ::   rm5           = 11.2_wp
94   REAL(wp) ::   rm6           =  0.4_wp
95   REAL(wp) ::   rm7           =  0.0_wp
96   REAL(wp) ::   rm8           =  0.318_wp
97   REAL(wp) ::   rtrans        =  0.1_wp
98   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
99   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rfact_tke                  !     -           -           -        -
100   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rfact_psi                  !     -           -           -        -
101   REAL(wp) ::   rsbc_zs1, rsbc_zs2                               !     -           -           -        -
102   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
103   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
104   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
105   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
106   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
107
108   !! * Substitutions
109#  include "domzgr_substitute.h90"
110#  include "vectopt_loop_substitute.h90"
111   !!----------------------------------------------------------------------
112   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
113   !! $Id$
114   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
115   !!----------------------------------------------------------------------
116CONTAINS
117
118   INTEGER FUNCTION zdf_gls_alloc()
119      !!----------------------------------------------------------------------
120      !!                ***  FUNCTION zdf_gls_alloc  ***
121      !!----------------------------------------------------------------------
122      ALLOCATE( en(jpi,jpj,jpk),  mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
123         &      avt_k (jpi,jpj,jpk) , avm_k (jpi,jpj,jpk),                    &
124         &      avmu_k(jpi,jpj,jpk) , avmv_k(jpi,jpj,jpk),                    &
125         &      ustars2(jpi,jpj), ustarb2(jpi,jpj)                      , STAT= zdf_gls_alloc )
126         !
127      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
128      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
129   END FUNCTION zdf_gls_alloc
130
131
132   SUBROUTINE zdf_gls( kt )
133      !!----------------------------------------------------------------------
134      !!                   ***  ROUTINE zdf_gls  ***
135      !!
136      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
137      !!              coefficients using the GLS turbulent closure scheme.
138      !!----------------------------------------------------------------------
139      INTEGER, INTENT(in) ::   kt ! ocean time step
140      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
141      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
142      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
143      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
144      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
145      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
146      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
147      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zkar
148      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
149      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
150      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
151      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
152      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
153      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
154      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi)
155      REAL(wp), POINTER, DIMENSION(:,:,:) ::   psi         ! psi at time now
156      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a    ! element of the first  matrix diagonal
157      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_b    ! element of the second matrix diagonal
158      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_c    ! element of the third  matrix diagonal
159      !!--------------------------------------------------------------------
160      !
161      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
162      !
163      CALL wrk_alloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
164      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi  )
165     
166      ! Preliminary computing
167
168      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
169
170      IF( kt /= nit000 ) THEN   ! restore before value to compute tke
171         avt (:,:,:) = avt_k (:,:,:)
172         avm (:,:,:) = avm_k (:,:,:)
173         avmu(:,:,:) = avmu_k(:,:,:)
174         avmv(:,:,:) = avmv_k(:,:,:) 
175      ENDIF
176
177      ! Compute surface and bottom friction at T-points
178!CDIR NOVERRCHK         
179      DO jj = 2, jpjm1         
180!CDIR NOVERRCHK         
181         DO ji = fs_2, fs_jpim1   ! vector opt.         
182            !
183            ! surface friction
184            ustars2(ji,jj) = r1_rau0 * taum(ji,jj) * tmask(ji,jj,1)
185            !   
186            ! bottom friction (explicit before friction)       
187            ! Note that we chose here not to bound the friction as in dynbfr)   
188            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &         
189               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )     
190            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &         
191               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )     
192            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)         
193         END DO         
194      END DO   
195
196      ! Set surface roughness length
197      SELECT CASE ( nn_z0_met )
198      !
199      CASE ( 0 )             ! Constant roughness         
200         zhsro(:,:) = rn_hsro
201      CASE ( 1 )             ! Standard Charnock formula
202         zhsro(:,:) = MAX(rsbc_zs1 * ustars2(:,:), rn_hsro)
203      CASE ( 2 )             ! Roughness formulae according to Rascle et al., Ocean Modelling (2008)
204         zdep(:,:)  = 30.*TANH(2.*0.3/(28.*SQRT(MAX(ustars2(:,:),rsmall))))             ! Wave age (eq. 10)
205         zhsro(:,:) = MAX(rsbc_zs2 * ustars2(:,:) * zdep(:,:)**1.5, rn_hsro) ! zhsro = rn_frac_hs * Hsw (eq. 11)
206      !
207      END SELECT
208
209      ! Compute shear and dissipation rate
210      DO jk = 2, jpkm1
211         DO jj = 2, jpjm1
212            DO ji = fs_2, fs_jpim1   ! vector opt.
213               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
214                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
215                  &                            / (  fse3uw_n(ji,jj,jk)               &
216                  &                            *    fse3uw_b(ji,jj,jk) )
217               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
218                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
219                  &                            / (  fse3vw_n(ji,jj,jk)               &
220                  &                            *    fse3vw_b(ji,jj,jk) )
221               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
222            END DO
223         END DO
224      END DO
225      !
226      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
227      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
228
229      ! Save tke at before time step
230      eb  (:,:,:) = en  (:,:,:)
231      mxlb(:,:,:) = mxln(:,:,:)
232
233      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
234         DO jk = 2, jpkm1
235            DO jj = 2, jpjm1 
236               DO ji = fs_2, fs_jpim1   ! vector opt.
237                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
238                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
239                  zcoef = ( zup / MAX( zdown, rsmall ) )
240                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
241               END DO
242            END DO
243         END DO
244      ENDIF
245
246      !!---------------------------------!!
247      !!   Equation to prognostic k      !!
248      !!---------------------------------!!
249      !
250      ! Now Turbulent kinetic energy (output in en)
251      ! -------------------------------
252      ! Resolution of a tridiagonal linear system by a "methode de chasse"
253      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
254      ! The surface boundary condition are set after
255      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
256      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
257      ! Warning : after this step, en : right hand side of the matrix
258
259      DO jk = 2, jpkm1
260         DO jj = 2, jpjm1
261            DO ji = fs_2, fs_jpim1   ! vector opt.
262               !
263               ! shear prod. at w-point weightened by mask
264               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
265                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
266               !
267               ! stratif. destruction
268               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
269               !
270               ! shear prod. - stratif. destruction
271               diss = eps(ji,jj,jk)
272               !
273               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
274               !
275               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
276               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
277               !
278               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
279               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
280               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
281               ! Otherwise, this should be rsc_psi/rsc_psi0
282               IF( ln_sigpsi ) THEN
283                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
284                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
285                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
286               ELSE
287                  zwall_psi(ji,jj,jk) = 1._wp
288               ENDIF
289               !
290               ! building the matrix
291               zcof = rfact_tke * tmask(ji,jj,jk)
292               !
293               ! lower diagonal
294               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
295                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
296               !
297               ! upper diagonal
298               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
299                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
300               !
301               ! diagonal
302               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
303                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
304               !
305               ! right hand side in en
306               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
307            END DO
308         END DO
309      END DO
310      !
311      z_elem_b(:,:,jpk) = 1._wp
312      !
313      ! Set surface condition on zwall_psi (1 at the bottom)
314      zwall_psi(:,:,1) = zwall_psi(:,:,2)
315      zwall_psi(:,:,jpk) = 1.
316      !
317      ! Surface boundary condition on tke
318      ! ---------------------------------
319      !
320      SELECT CASE ( nn_bc_surf )
321      !
322      CASE ( 0 )             ! Dirichlet case
323      ! First level
324      en(:,:,1) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
325      en(:,:,1) = MAX(en(:,:,1), rn_emin) 
326      z_elem_a(:,:,1) = en(:,:,1)
327      z_elem_c(:,:,1) = 0._wp
328      z_elem_b(:,:,1) = 1._wp
329      !
330      ! One level below
331      en(:,:,2) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1 * ((zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**(1.5_wp*ra_sf))**(2._wp/3._wp)
332      en(:,:,2) = MAX(en(:,:,2), rn_emin )
333      z_elem_a(:,:,2) = 0._wp 
334      z_elem_c(:,:,2) = 0._wp
335      z_elem_b(:,:,2) = 1._wp
336      !
337      !
338      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
339      !
340      ! Dirichlet conditions at k=1
341      en(:,:,1)       = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
342      en(:,:,1)       = MAX(en(:,:,1), rn_emin)     
343      z_elem_a(:,:,1) = en(:,:,1)
344      z_elem_c(:,:,1) = 0._wp
345      z_elem_b(:,:,1) = 1._wp
346      !
347      ! at k=2, set de/dz=Fw
348      !cbr
349      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
350      z_elem_a(:,:,2) = 0._wp
351      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1.-exp(-rtrans*fsdept(:,:,1)/zhsro(:,:)) ))
352      zflxs(:,:)      = rsbc_tke2 * ustars2(:,:)**1.5_wp * zkar(:,:) * ((zhsro(:,:)+fsdept(:,:,1))/zhsro(:,:) )**(1.5_wp*ra_sf)
353
354      en(:,:,2) = en(:,:,2) + zflxs(:,:)/fse3w(:,:,2)
355      !
356      !
357      END SELECT
358
359      ! Bottom boundary condition on tke
360      ! --------------------------------
361      !
362      SELECT CASE ( nn_bc_bot )
363      !
364      CASE ( 0 )             ! Dirichlet
365         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
366         !                      ! Balance between the production and the dissipation terms
367!CDIR NOVERRCHK
368         DO jj = 2, jpjm1
369!CDIR NOVERRCHK
370            DO ji = fs_2, fs_jpim1   ! vector opt.
371               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
372               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
373               !
374               ! Bottom level Dirichlet condition:
375               z_elem_a(ji,jj,ibot  ) = 0._wp
376               z_elem_c(ji,jj,ibot  ) = 0._wp
377               z_elem_b(ji,jj,ibot  ) = 1._wp
378               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
379               !
380               ! Just above last level, Dirichlet condition again
381               z_elem_a(ji,jj,ibotm1) = 0._wp
382               z_elem_c(ji,jj,ibotm1) = 0._wp
383               z_elem_b(ji,jj,ibotm1) = 1._wp
384               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
385            END DO
386         END DO
387         !
388      CASE ( 1 )             ! Neumman boundary condition
389         !                     
390!CDIR NOVERRCHK
391         DO jj = 2, jpjm1
392!CDIR NOVERRCHK
393            DO ji = fs_2, fs_jpim1   ! vector opt.
394               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
395               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
396               !
397               ! Bottom level Dirichlet condition:
398               z_elem_a(ji,jj,ibot) = 0._wp
399               z_elem_c(ji,jj,ibot) = 0._wp
400               z_elem_b(ji,jj,ibot) = 1._wp
401               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
402               !
403               ! Just above last level: Neumann condition
404               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
405               z_elem_c(ji,jj,ibotm1) = 0._wp
406            END DO
407         END DO
408         !
409      END SELECT
410
411      ! Matrix inversion (en prescribed at surface and the bottom)
412      ! ----------------------------------------------------------
413      !
414      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
415         DO jj = 2, jpjm1
416            DO ji = fs_2, fs_jpim1    ! vector opt.
417               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
418            END DO
419         END DO
420      END DO
421      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
422         DO jj = 2, jpjm1
423            DO ji = fs_2, fs_jpim1    ! vector opt.
424               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
425            END DO
426         END DO
427      END DO
428      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
429         DO jj = 2, jpjm1
430            DO ji = fs_2, fs_jpim1    ! vector opt.
431               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
432            END DO
433         END DO
434      END DO
435      !                                            ! set the minimum value of tke
436      en(:,:,:) = MAX( en(:,:,:), rn_emin )
437
438      !!----------------------------------------!!
439      !!   Solve prognostic equation for psi    !!
440      !!----------------------------------------!!
441
442      ! Set psi to previous time step value
443      !
444      SELECT CASE ( nn_clos )
445      !
446      CASE( 0 )               ! k-kl  (Mellor-Yamada)
447         DO jk = 2, jpkm1
448            DO jj = 2, jpjm1
449               DO ji = fs_2, fs_jpim1   ! vector opt.
450                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
451               END DO
452            END DO
453         END DO
454         !
455      CASE( 1 )               ! k-eps
456         DO jk = 2, jpkm1
457            DO jj = 2, jpjm1
458               DO ji = fs_2, fs_jpim1   ! vector opt.
459                  psi(ji,jj,jk)  = eps(ji,jj,jk)
460               END DO
461            END DO
462         END DO
463         !
464      CASE( 2 )               ! k-w
465         DO jk = 2, jpkm1
466            DO jj = 2, jpjm1
467               DO ji = fs_2, fs_jpim1   ! vector opt.
468                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
469               END DO
470            END DO
471         END DO
472         !
473      CASE( 3 )               ! generic
474         DO jk = 2, jpkm1
475            DO jj = 2, jpjm1
476               DO ji = fs_2, fs_jpim1   ! vector opt.
477                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
478               END DO
479            END DO
480         END DO
481         !
482      END SELECT
483      !
484      ! Now gls (output in psi)
485      ! -------------------------------
486      ! Resolution of a tridiagonal linear system by a "methode de chasse"
487      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
488      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
489      ! Warning : after this step, en : right hand side of the matrix
490
491      DO jk = 2, jpkm1
492         DO jj = 2, jpjm1
493            DO ji = fs_2, fs_jpim1   ! vector opt.
494               !
495               ! psi / k
496               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
497               !
498               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
499               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
500               !
501               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
502               !
503               ! shear prod. - stratif. destruction
504               prod = rpsi1 * zratio * shear(ji,jj,jk)
505               !
506               ! stratif. destruction
507               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
508               !
509               ! shear prod. - stratif. destruction
510               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
511               !
512               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
513               !
514               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
515               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
516               !                                                       
517               ! building the matrix
518               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
519               ! lower diagonal
520               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
521                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
522               ! upper diagonal
523               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
524                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
525               ! diagonal
526               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
527                  &                       + rdt * zdiss * tmask(ji,jj,jk)
528               !
529               ! right hand side in psi
530               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
531            END DO
532         END DO
533      END DO
534      !
535      z_elem_b(:,:,jpk) = 1._wp
536
537      ! Surface boundary condition on psi
538      ! ---------------------------------
539      !
540      SELECT CASE ( nn_bc_surf )
541      !
542      CASE ( 0 )             ! Dirichlet boundary conditions
543      !
544      ! Surface value
545      zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
546      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
547      z_elem_a(:,:,1) = psi(:,:,1)
548      z_elem_c(:,:,1) = 0._wp
549      z_elem_b(:,:,1) = 1._wp
550      !
551      ! One level below
552      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*fsdepw(:,:,2)/zhsro(:,:) )))
553      zdep(:,:)       = (zhsro(:,:) + fsdepw(:,:,2)) * zkar(:,:)
554      psi (:,:,2)     = rc0**rpp * en(:,:,2)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
555      z_elem_a(:,:,2) = 0._wp
556      z_elem_c(:,:,2) = 0._wp
557      z_elem_b(:,:,2) = 1._wp
558      !
559      !
560      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
561      !
562      ! Surface value: Dirichlet
563      zdep(:,:)       = zhsro(:,:) * rl_sf
564      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
565      z_elem_a(:,:,1) = psi(:,:,1)
566      z_elem_c(:,:,1) = 0._wp
567      z_elem_b(:,:,1) = 1._wp
568      !
569      ! Neumann condition at k=2
570      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
571      z_elem_a(:,:,2) = 0._wp
572      !
573      ! Set psi vertical flux at the surface:
574      zkar(:,:) = rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*fsdept(:,:,1)/zhsro(:,:) )) ! Lengh scale slope
575      zdep(:,:) = ((zhsro(:,:) + fsdept(:,:,1)) / zhsro(:,:))**(rmm*ra_sf)
576      zflxs(:,:) = (rnn + rsbc_tke1 * (rnn + rmm*ra_sf) * zdep(:,:))*(1._wp + rsbc_tke1*zdep(:,:))**(2._wp*rmm/3._wp-1_wp)
577      zdep(:,:) =  rsbc_psi1 * (zwall_psi(:,:,1)*avm(:,:,1)+zwall_psi(:,:,2)*avm(:,:,2)) * &
578             & ustars2(:,:)**rmm * zkar(:,:)**rnn * (zhsro(:,:) + fsdept(:,:,1))**(rnn-1.)
579      zflxs(:,:) = zdep(:,:) * zflxs(:,:)
580      psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
581
582      !   
583      !
584      END SELECT
585
586      ! Bottom boundary condition on psi
587      ! --------------------------------
588      !
589      SELECT CASE ( nn_bc_bot )
590      !
591      !
592      CASE ( 0 )             ! Dirichlet
593         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * rn_bfrz0
594         !                      ! Balance between the production and the dissipation terms
595!CDIR NOVERRCHK
596         DO jj = 2, jpjm1
597!CDIR NOVERRCHK
598            DO ji = fs_2, fs_jpim1   ! vector opt.
599               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
600               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
601               zdep(ji,jj) = vkarmn * rn_bfrz0
602               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
603               z_elem_a(ji,jj,ibot) = 0._wp
604               z_elem_c(ji,jj,ibot) = 0._wp
605               z_elem_b(ji,jj,ibot) = 1._wp
606               !
607               ! Just above last level, Dirichlet condition again (GOTM like)
608               zdep(ji,jj) = vkarmn * ( rn_bfrz0 + fse3t(ji,jj,ibotm1) )
609               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
610               z_elem_a(ji,jj,ibotm1) = 0._wp
611               z_elem_c(ji,jj,ibotm1) = 0._wp
612               z_elem_b(ji,jj,ibotm1) = 1._wp
613            END DO
614         END DO
615         !
616      CASE ( 1 )             ! Neumman boundary condition
617         !                     
618!CDIR NOVERRCHK
619         DO jj = 2, jpjm1
620!CDIR NOVERRCHK
621            DO ji = fs_2, fs_jpim1   ! vector opt.
622               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
623               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
624               !
625               ! Bottom level Dirichlet condition:
626               zdep(ji,jj) = vkarmn * rn_bfrz0
627               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
628               !
629               z_elem_a(ji,jj,ibot) = 0._wp
630               z_elem_c(ji,jj,ibot) = 0._wp
631               z_elem_b(ji,jj,ibot) = 1._wp
632               !
633               ! Just above last level: Neumann condition with flux injection
634               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
635               z_elem_c(ji,jj,ibotm1) = 0.
636               !
637               ! Set psi vertical flux at the bottom:
638               zdep(ji,jj) = rn_bfrz0 + 0.5_wp*fse3t(ji,jj,ibotm1)
639               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
640                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
641               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
642            END DO
643         END DO
644         !
645      END SELECT
646
647      ! Matrix inversion
648      ! ----------------
649      !
650      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
651         DO jj = 2, jpjm1
652            DO ji = fs_2, fs_jpim1    ! vector opt.
653               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
654            END DO
655         END DO
656      END DO
657      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
658         DO jj = 2, jpjm1
659            DO ji = fs_2, fs_jpim1    ! vector opt.
660               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
661            END DO
662         END DO
663      END DO
664      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
665         DO jj = 2, jpjm1
666            DO ji = fs_2, fs_jpim1    ! vector opt.
667               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
668            END DO
669         END DO
670      END DO
671
672      ! Set dissipation
673      !----------------
674
675      SELECT CASE ( nn_clos )
676      !
677      CASE( 0 )               ! k-kl  (Mellor-Yamada)
678         DO jk = 1, jpkm1
679            DO jj = 2, jpjm1
680               DO ji = fs_2, fs_jpim1   ! vector opt.
681                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / MAX( psi(ji,jj,jk), rn_epsmin)
682               END DO
683            END DO
684         END DO
685         !
686      CASE( 1 )               ! k-eps
687         DO jk = 1, jpkm1
688            DO jj = 2, jpjm1
689               DO ji = fs_2, fs_jpim1   ! vector opt.
690                  eps(ji,jj,jk) = psi(ji,jj,jk)
691               END DO
692            END DO
693         END DO
694         !
695      CASE( 2 )               ! k-w
696         DO jk = 1, jpkm1
697            DO jj = 2, jpjm1
698               DO ji = fs_2, fs_jpim1   ! vector opt.
699                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
700               END DO
701            END DO
702         END DO
703         !
704      CASE( 3 )               ! generic
705         zcoef = rc0**( 3._wp  + rpp/rnn )
706         zex1  =      ( 1.5_wp + rmm/rnn )
707         zex2  = -1._wp / rnn
708         DO jk = 1, jpkm1
709            DO jj = 2, jpjm1
710               DO ji = fs_2, fs_jpim1   ! vector opt.
711                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
712               END DO
713            END DO
714         END DO
715         !
716      END SELECT
717
718      ! Limit dissipation rate under stable stratification
719      ! --------------------------------------------------
720      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
721         DO jj = 2, jpjm1
722            DO ji = fs_2, fs_jpim1    ! vector opt.
723               ! limitation
724               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
725               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
726               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
727               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
728               IF (ln_length_lim) mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk) )
729            END DO
730         END DO
731      END DO 
732
733      !
734      ! Stability function and vertical viscosity and diffusivity
735      ! ---------------------------------------------------------
736      !
737      SELECT CASE ( nn_stab_func )
738      !
739      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
740         DO jk = 2, jpkm1
741            DO jj = 2, jpjm1
742               DO ji = fs_2, fs_jpim1   ! vector opt.
743                  ! zcof =  l²/q²
744                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
745                  ! Gh = -N²l²/q²
746                  gh = - rn2(ji,jj,jk) * zcof
747                  gh = MIN( gh, rgh0   )
748                  gh = MAX( gh, rghmin )
749                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
750                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
751                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
752                  !
753                  ! Store stability function in avmu and avmv
754                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
755                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
756               END DO
757            END DO
758         END DO
759         !
760      CASE ( 2, 3 )               ! Canuto stability functions
761         DO jk = 2, jpkm1
762            DO jj = 2, jpjm1
763               DO ji = fs_2, fs_jpim1   ! vector opt.
764                  ! zcof =  l²/q²
765                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
766                  ! Gh = -N²l²/q²
767                  gh = - rn2(ji,jj,jk) * zcof
768                  gh = MIN( gh, rgh0   )
769                  gh = MAX( gh, rghmin )
770                  gh = gh * rf6
771                  ! Gm =  M²l²/q² Shear number
772                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
773                  gm = MAX( shr * zcof , 1.e-10 )
774                  gm = gm * rf6
775                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
776                  ! Stability functions from Canuto
777                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
778                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
779                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
780                  !
781                  ! Store stability function in avmu and avmv
782                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
783                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
784               END DO
785            END DO
786         END DO
787         !
788      END SELECT
789
790      ! Boundary conditions on stability functions for momentum (Neumann):
791      ! Lines below are useless if GOTM style Dirichlet conditions are used
792
793      avmv(:,:,1) = avmv(:,:,2)
794
795      DO jj = 2, jpjm1
796         DO ji = fs_2, fs_jpim1   ! vector opt.
797            avmv(ji,jj,mbkt(ji,jj)+1) = avmv(ji,jj,mbkt(ji,jj))
798         END DO
799      END DO
800
801      ! Compute diffusivities/viscosities
802      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
803      DO jk = 1, jpk
804         DO jj = 2, jpjm1
805            DO ji = fs_2, fs_jpim1   ! vector opt.
806               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
807               zav           = zsqen * avmu(ji,jj,jk)
808               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
809               zav           = zsqen * avmv(ji,jj,jk)
810               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
811            END DO
812         END DO
813      END DO
814      !
815      ! Lateral boundary conditions (sign unchanged)
816      avt(:,:,1)  = 0._wp
817      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
818
819      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
820         DO jj = 2, jpjm1
821            DO ji = fs_2, fs_jpim1   ! vector opt.
822               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
823               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
824            END DO
825         END DO
826      END DO
827      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
828      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
829
830      IF(ln_ctl) THEN
831         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
832         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
833            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
834      ENDIF
835      !
836      avt_k (:,:,:) = avt (:,:,:)
837      avm_k (:,:,:) = avm (:,:,:)
838      avmu_k(:,:,:) = avmu(:,:,:)
839      avmv_k(:,:,:) = avmv(:,:,:)
840      !
841      CALL wrk_dealloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
842      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
843      !
844      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
845      !
846      !
847   END SUBROUTINE zdf_gls
848
849
850   SUBROUTINE zdf_gls_init
851      !!----------------------------------------------------------------------
852      !!                  ***  ROUTINE zdf_gls_init  ***
853      !!                     
854      !! ** Purpose :   Initialization of the vertical eddy diffivity and
855      !!      viscosity when using a gls turbulent closure scheme
856      !!
857      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
858      !!      called at the first timestep (nit000)
859      !!
860      !! ** input   :   Namlist namzdf_gls
861      !!
862      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
863      !!
864      !!----------------------------------------------------------------------
865      USE dynzdf_exp
866      USE trazdf_exp
867      !
868      INTEGER ::   jk    ! dummy loop indices
869      INTEGER ::   ios   ! Local integer output status for namelist read
870      REAL(wp)::   zcr   ! local scalar
871      !!
872      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
873         &            rn_clim_galp, ln_sigpsi, rn_hsro,      &
874         &            rn_crban, rn_charn, rn_frac_hs,        &
875         &            nn_bc_surf, nn_bc_bot, nn_z0_met,      &
876         &            nn_stab_func, nn_clos
877      !!----------------------------------------------------------
878      !
879      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
880      !
881      REWIND( numnam_ref )              ! Namelist namzdf_gls in reference namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
882      READ  ( numnam_ref, namzdf_gls, IOSTAT = ios, ERR = 901)
883901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in reference namelist', lwp )
884
885      REWIND( numnam_cfg )              ! Namelist namzdf_gls in configuration namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
886      READ  ( numnam_cfg, namzdf_gls, IOSTAT = ios, ERR = 902 )
887902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in configuration namelist', lwp )
888      IF(lwm) WRITE ( numond, namzdf_gls )
889
890      IF(lwp) THEN                     !* Control print
891         WRITE(numout,*)
892         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
893         WRITE(numout,*) '~~~~~~~~~~~~'
894         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
895         WRITE(numout,*) '      minimum value of en                           rn_emin        = ', rn_emin
896         WRITE(numout,*) '      minimum value of eps                          rn_epsmin      = ', rn_epsmin
897         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim  = ', ln_length_lim
898         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp   = ', rn_clim_galp
899         WRITE(numout,*) '      TKE Surface boundary condition                nn_bc_surf     = ', nn_bc_surf
900         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_bc_bot      = ', nn_bc_bot
901         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi      = ', ln_sigpsi
902         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
903         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
904         WRITE(numout,*) '      Surface roughness formula                     nn_z0_met      = ', nn_z0_met
905         WRITE(numout,*) '      Wave height frac. (used if nn_z0_met=2)       rn_frac_hs     = ', rn_frac_hs
906         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
907         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
908         WRITE(numout,*) '      Surface roughness (m)                         rn_hsro        = ', rn_hsro
909         WRITE(numout,*) '      Bottom roughness (m) (nambfr namelist)        rn_bfrz0       = ', rn_bfrz0
910      ENDIF
911
912      !                                !* allocate gls arrays
913      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
914
915      !                                !* Check of some namelist values
916      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_bc_surf is 0 or 1' )
917      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_bc_surf is 0 or 1' )
918      IF( nn_z0_met < 0 .OR. nn_z0_met > 2 ) CALL ctl_stop( 'bad flag: nn_z0_met is 0, 1 or 2' )
919      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'bad flag: nn_stab_func is 0, 1, 2 and 3' )
920      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'bad flag: nn_clos is 0, 1, 2 or 3' )
921
922      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
923      !
924      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
925         !
926         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
927         rpp     = 0._wp
928         rmm     = 1._wp
929         rnn     = 1._wp
930         rsc_tke = 1.96_wp
931         rsc_psi = 1.96_wp
932         rpsi1   = 0.9_wp
933         rpsi3p  = 1._wp
934         rpsi2   = 0.5_wp
935         !
936         SELECT CASE ( nn_stab_func )
937         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
938         CASE( 2 )      ;   rpsi3m = 2.62_wp       ! Canuto A stability functions
939         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
940         END SELECT
941         !
942      CASE( 1 )                              ! k-eps
943         !
944         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
945         rpp     =  3._wp
946         rmm     =  1.5_wp
947         rnn     = -1._wp
948         rsc_tke =  1._wp
949         rsc_psi =  1.2_wp  ! Schmidt number for psi
950         rpsi1   =  1.44_wp
951         rpsi3p  =  1._wp
952         rpsi2   =  1.92_wp
953         !
954         SELECT CASE ( nn_stab_func )
955         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
956         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
957         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
958         END SELECT
959         !
960      CASE( 2 )                              ! k-omega
961         !
962         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
963         rpp     = -1._wp
964         rmm     =  0.5_wp
965         rnn     = -1._wp
966         rsc_tke =  2._wp
967         rsc_psi =  2._wp
968         rpsi1   =  0.555_wp
969         rpsi3p  =  1._wp
970         rpsi2   =  0.833_wp
971         !
972         SELECT CASE ( nn_stab_func )
973         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
974         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
975         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
976         END SELECT
977         !
978      CASE( 3 )                              ! generic
979         !
980         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
981         rpp     = 2._wp
982         rmm     = 1._wp
983         rnn     = -0.67_wp
984         rsc_tke = 0.8_wp
985         rsc_psi = 1.07_wp
986         rpsi1   = 1._wp
987         rpsi3p  = 1._wp
988         rpsi2   = 1.22_wp
989         !
990         SELECT CASE ( nn_stab_func )
991         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
992         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
993         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
994         END SELECT
995         !
996      END SELECT
997
998      !
999      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1000      !
1001      CASE ( 0 )                             ! Galperin stability functions
1002         !
1003         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1004         rc2     =  0._wp
1005         rc3     =  0._wp
1006         rc_diff =  1._wp
1007         rc0     =  0.5544_wp
1008         rcm_sf  =  0.9884_wp
1009         rghmin  = -0.28_wp
1010         rgh0    =  0.0233_wp
1011         rghcri  =  0.02_wp
1012         !
1013      CASE ( 1 )                             ! Kantha-Clayson stability functions
1014         !
1015         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1016         rc2     =  0.7_wp
1017         rc3     =  0.2_wp
1018         rc_diff =  1._wp
1019         rc0     =  0.5544_wp
1020         rcm_sf  =  0.9884_wp
1021         rghmin  = -0.28_wp
1022         rgh0    =  0.0233_wp
1023         rghcri  =  0.02_wp
1024         !
1025      CASE ( 2 )                             ! Canuto A stability functions
1026         !
1027         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1028         rs0 = 1.5_wp * rl1 * rl5*rl5
1029         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1030         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1031         rs4 = 2._wp * rl5
1032         rs5 = 2._wp * rl4
1033         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1034            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1035         rd0 = 3._wp * rl5*rl5
1036         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1037         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1038         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1039         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1040         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1041         rc0 = 0.5268_wp
1042         rf6 = 8._wp / (rc0**6._wp)
1043         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1044         rcm_sf  =  0.7310_wp
1045         rghmin  = -0.28_wp
1046         rgh0    =  0.0329_wp
1047         rghcri  =  0.03_wp
1048         !
1049      CASE ( 3 )                             ! Canuto B stability functions
1050         !
1051         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1052         rs0 = 1.5_wp * rm1 * rm5*rm5
1053         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1054         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1055         rs4 = 2._wp * rm5
1056         rs5 = 2._wp * rm4
1057         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1058         rd0 = 3._wp * rm5*rm5
1059         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1060         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1061         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1062         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1063         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1064         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1065         rf6 = 8._wp / ( rc0**6._wp )
1066         rc_diff = SQRT(2._wp)/(rc0**3.)
1067         rcm_sf  =  0.7470_wp
1068         rghmin  = -0.28_wp
1069         rgh0    =  0.0444_wp
1070         rghcri  =  0.0414_wp
1071         !
1072      END SELECT
1073   
1074      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1075      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1076      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1077      IF( ln_sigpsi ) THEN
1078         ra_sf = -1.5 ! Set kinetic energy slope, then deduce rsc_psi and rl_sf
1079         ! Verification: retrieve Burchard (2001) results by uncomenting the line below:
1080         ! Note that the results depend on the value of rn_cm_sf which is constant (=rc0) in his work
1081         ! ra_sf = -SQRT(2./3.*rc0**3./rn_cm_sf*rn_sc_tke)/vkarmn
1082         rsc_psi0 = rsc_tke/(24.*rpsi2)*(-1.+(4.*rnn + ra_sf*(1.+4.*rmm))**2./(ra_sf**2.))
1083      ELSE
1084         rsc_psi0 = rsc_psi
1085      ENDIF
1086 
1087      !                                !* Shear free turbulence parameters
1088      !
1089      ra_sf  = -4._wp*rnn*SQRT(rsc_tke) / ( (1._wp+4._wp*rmm)*SQRT(rsc_tke) &
1090               &                              - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1091
1092      IF ( rn_crban==0._wp ) THEN
1093         rl_sf = vkarmn
1094      ELSE
1095         rl_sf = rc0 * SQRT(rc0/rcm_sf) * SQRT( ( (1._wp + 4._wp*rmm + 8._wp*rmm**2_wp)*rsc_tke          &
1096                 &                                       + 12._wp * rsc_psi0*rpsi2 - (1._wp + 4._wp*rmm) &
1097                 &                                                *SQRT(rsc_tke*(rsc_tke                 &
1098                 &                                                   + 24._wp*rsc_psi0*rpsi2)) )         &
1099                 &                                         /(12._wp*rnn**2.)                             &
1100                 &                                       )
1101      ENDIF
1102
1103      !
1104      IF(lwp) THEN                     !* Control print
1105         WRITE(numout,*)
1106         WRITE(numout,*) 'Limit values'
1107         WRITE(numout,*) '~~~~~~~~~~~~'
1108         WRITE(numout,*) 'Parameter  m = ',rmm
1109         WRITE(numout,*) 'Parameter  n = ',rnn
1110         WRITE(numout,*) 'Parameter  p = ',rpp
1111         WRITE(numout,*) 'rpsi1   = ',rpsi1
1112         WRITE(numout,*) 'rpsi2   = ',rpsi2
1113         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1114         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1115         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1116         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1117         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1118         WRITE(numout,*) 'rc0     = ',rc0
1119         WRITE(numout,*)
1120         WRITE(numout,*) 'Shear free turbulence parameters:'
1121         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1122         WRITE(numout,*) 'ra_sf   = ',ra_sf
1123         WRITE(numout,*) 'rl_sf   = ',rl_sf
1124         WRITE(numout,*)
1125      ENDIF
1126
1127      !                                !* Constants initialization
1128      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1129      rc03  = rc02 * rc0
1130      rc04  = rc03 * rc0
1131      rsbc_tke1 = -3._wp/2._wp*rn_crban*ra_sf*rl_sf                      ! Dirichlet + Wave breaking
1132      rsbc_tke2 = rdt * rn_crban / rl_sf                                 ! Neumann + Wave breaking
1133      zcr = MAX(rsmall, rsbc_tke1**(1./(-ra_sf*3._wp/2._wp))-1._wp )
1134      rtrans = 0.2_wp / zcr                                              ! Ad. inverse transition length between log and wave layer
1135      rsbc_zs1  = rn_charn/grav                                          ! Charnock formula for surface roughness
1136      rsbc_zs2  = rn_frac_hs / 0.85_wp / grav * 665._wp                  ! Rascle formula for surface roughness
1137      rsbc_psi1 = -0.5_wp * rdt * rc0**(rpp-2._wp*rmm) / rsc_psi
1138      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi ! Neumann + NO Wave breaking
1139
1140      rfact_tke = -0.5_wp / rsc_tke * rdt                                ! Cst used for the Diffusion term of tke
1141      rfact_psi = -0.5_wp / rsc_psi * rdt                                ! Cst used for the Diffusion term of tke
1142
1143      !                                !* Wall proximity function
1144      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1145
1146      !                                !* set vertical eddy coef. to the background value
1147      DO jk = 1, jpk
1148         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1149         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1150         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1151         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1152      END DO
1153      !                             
1154      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1155      !
1156      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1157      !
1158   END SUBROUTINE zdf_gls_init
1159
1160
1161   SUBROUTINE gls_rst( kt, cdrw )
1162      !!---------------------------------------------------------------------
1163      !!                   ***  ROUTINE ts_rst  ***
1164      !!                     
1165      !! ** Purpose :   Read or write TKE file (en) in restart file
1166      !!
1167      !! ** Method  :   use of IOM library
1168      !!                if the restart does not contain TKE, en is either
1169      !!                set to rn_emin or recomputed (nn_igls/=0)
1170      !!----------------------------------------------------------------------
1171      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1172      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1173      !
1174      INTEGER ::   jit, jk   ! dummy loop indices
1175      INTEGER ::   id1, id2, id3, id4, id5, id6
1176      INTEGER ::   ji, jj, ikbu, ikbv
1177      REAL(wp)::   cbx, cby
1178      !!----------------------------------------------------------------------
1179      !
1180      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1181         !                                   ! ---------------
1182         IF( ln_rstart ) THEN                   !* Read the restart file
1183            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1184            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1185            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1186            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1187            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1188            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1189            !
1190            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1191               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1192               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1193               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1194               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1195               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1196               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1197            ELSE                       
1198               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1199               en  (:,:,:) = rn_emin
1200               mxln(:,:,:) = 0.05       
1201               avt_k (:,:,:) = avt (:,:,:)
1202               avm_k (:,:,:) = avm (:,:,:)
1203               avmu_k(:,:,:) = avmu(:,:,:)
1204               avmv_k(:,:,:) = avmv(:,:,:)
1205               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1206            ENDIF
1207         ELSE                                   !* Start from rest
1208            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1209            en  (:,:,:) = rn_emin
1210            mxln(:,:,:) = 0.05       
1211         ENDIF
1212         !
1213      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1214         !                                   ! -------------------
1215         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1216         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en     ) 
1217         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt_k  )
1218         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm_k  )
1219         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu_k ) 
1220         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv_k )
1221         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln   )
1222         !
1223      ENDIF
1224      !
1225   END SUBROUTINE gls_rst
1226
1227#else
1228   !!----------------------------------------------------------------------
1229   !!   Dummy module :                                        NO TKE scheme
1230   !!----------------------------------------------------------------------
1231   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1232CONTAINS
1233   SUBROUTINE zdf_gls_init           ! Empty routine
1234      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1235   END SUBROUTINE zdf_gls_init
1236   SUBROUTINE zdf_gls( kt )          ! Empty routine
1237      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1238   END SUBROUTINE zdf_gls
1239   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1240      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1241      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1242      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1243   END SUBROUTINE gls_rst
1244#endif
1245
1246   !!======================================================================
1247END MODULE zdfgls
1248
Note: See TracBrowser for help on using the repository browser.