source: branches/2015/dev_r5021_UKMO1_CICE_coupling/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 5443

Last change on this file since 5443 was 5443, checked in by davestorkey, 5 years ago

Update 2015/dev_r5021_UKMO1_CICE_coupling branch to revision 5442 of the trunk.

File size: 23.5 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!                 !  2012-07  (J. Simeon, G. Madec, C. Ethe) Online coarsening of outputs
27   !!            3.7  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!----------------------------------------------------------------------
29
30   !!----------------------------------------------------------------------
31   !!   stp             : OPA system time-stepping
32   !!----------------------------------------------------------------------
33   USE step_oce         ! time stepping definition modules
34   USE iom
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   stp   ! called by opa.F90
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43!!gm   #  include "zdfddm_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51#if defined key_agrif
52   SUBROUTINE stp( )
53      INTEGER             ::   kstp   ! ocean time-step index
54#else
55   SUBROUTINE stp( kstp )
56      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
57#endif
58      !!----------------------------------------------------------------------
59      !!                     ***  ROUTINE stp  ***
60      !!
61      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
62      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
63      !!              - Tme stepping  of TRC (passive tracer eqs.)
64      !!
65      !! ** Method  : -1- Update forcings and data
66      !!              -2- Update ocean physics
67      !!              -3- Compute the t and s trends
68      !!              -4- Update t and s
69      !!              -5- Compute the momentum trends
70      !!              -6- Update the horizontal velocity
71      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
72      !!              -8- Outputs and diagnostics
73      !!----------------------------------------------------------------------
74      INTEGER ::   jk       ! dummy loop indice
75      INTEGER ::   indic    ! error indicator if < 0
76      INTEGER ::   kcall    ! optional integer argument (dom_vvl_sf_nxt)
77      !! ---------------------------------------------------------------------
78
79#if defined key_agrif
80      kstp = nit000 + Agrif_Nb_Step()
81!      IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
82!      IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp
83      IF ( kstp == (nit000 + 1) ) lk_agrif_fstep = .FALSE.
84# if defined key_iomput
85      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
86# endif
87#endif
88                             indic = 0           ! reset to no error condition
89      IF( kstp == nit000 ) THEN
90         ! must be done after nemo_init for AGRIF+XIOS+OASIS
91                      CALL iom_init(      cxios_context          )  ! iom_put initialization
92         IF( ln_crs ) CALL iom_init( TRIM(cxios_context)//"_crs" )  ! initialize context for coarse grid
93      ENDIF
94
95      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
96                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell iom we are at time step kstp
97      IF( ln_crs     )       CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell iom we are at time step kstp
98
99      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
100      ! Update data, open boundaries, surface boundary condition (including sea-ice)
101      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
102      IF( lk_tide    )   CALL sbc_tide( kstp )
103      IF( lk_bdy     )   CALL bdy_dta ( kstp, time_offset=+1 )   ! update dynamic & tracer data at open boundaries
104
105                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
106                                                      ! clem: moved here for bdy ice purpose
107
108      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
109      ! Update stochastic parameters and random T/S fluctuations
110      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
111                        CALL sto_par( kstp )          ! Stochastic parameters
112
113      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
114      ! Ocean physics update                (ua, va, tsa used as workspace)
115      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
116      !  THERMODYNAMICS
117                         CALL eos_rab( tsb, rab_b )       ! before local thermal/haline expension ratio at T-points
118                         CALL eos_rab( tsn, rab_n )       ! now    local thermal/haline expension ratio at T-points
119                         CALL bn2    ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency
120                         CALL bn2    ( tsn, rab_n, rn2  ) ! now    Brunt-Vaisala frequency
121      !
122      !  VERTICAL PHYSICS
123                         CALL zdf_bfr( kstp )         ! bottom friction (if quadratic)
124      !                                               ! Vertical eddy viscosity and diffusivity coefficients
125      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
126      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
127      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
128      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
129      IF( lk_zdfcst  ) THEN                              ! Constant Kz (reset avt, avm[uv] to the background value)
130         avt (:,:,:) = rn_avt0 * wmask (:,:,:)
131         avmu(:,:,:) = rn_avm0 * wumask(:,:,:)
132         avmv(:,:,:) = rn_avm0 * wvmask(:,:,:)
133      ENDIF
134      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
135         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
136      ENDIF
137      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
138
139      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
140
141      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
142         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
143
144                         CALL zdf_mxl( kstp )         ! mixed layer depth
145
146                                                      ! write TKE or GLS information in the restart file
147      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
148      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
149      !
150      !  LATERAL  PHYSICS
151      !
152      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
153         IF(ln_sto_eos ) CALL sto_pts( tsn )          ! Random T/S fluctuations
154                         CALL eos( tsb, rhd, gdept_0(:,:,:) )               ! before in situ density
155         IF( ln_zps .AND. .NOT. ln_isfcav)                               &
156            &            CALL zps_hde    ( kstp, jpts, tsb, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
157            &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
158         IF( ln_zps .AND.       ln_isfcav)                               &
159            &            CALL zps_hde_isf( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
160            &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
161            &                                   gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the first ocean level
162         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
163                         CALL ldf_slp_grif( kstp )
164         ELSE
165                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
166         ENDIF
167      ENDIF
168#if defined key_traldf_c2d
169      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
170#endif
171#if defined key_traldf_c3d && defined key_traldf_smag
172                          CALL ldf_tra_smag( kstp )      ! eddy induced velocity coefficient
173#  endif
174#if defined key_dynldf_c3d && defined key_dynldf_smag
175                          CALL ldf_dyn_smag( kstp )      ! eddy induced velocity coefficient
176#  endif
177
178      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
179      !  Ocean dynamics : hdiv, rot, ssh, e3, wn
180      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
181                         CALL ssh_nxt       ( kstp )  ! after ssh (includes call to div_cur)
182      IF( lk_vvl     )   CALL dom_vvl_sf_nxt( kstp )  ! after vertical scale factors
183                         CALL wzv           ( kstp )  ! now cross-level velocity
184
185      IF( lk_dynspg_ts ) THEN 
186          ! In case the time splitting case, update almost all momentum trends here:
187          ! Note that the computation of vertical velocity above, hence "after" sea level
188          ! is necessary to compute momentum advection for the rhs of barotropic loop:
189            IF(ln_sto_eos ) CALL sto_pts( tsn )                             ! Random T/S fluctuations
190                            CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation
191            IF( ln_zps .AND. .NOT. ln_isfcav)                               &
192               &            CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
193               &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
194            IF( ln_zps .AND.       ln_isfcav)                               &
195               &            CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
196               &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
197               &                                   gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
198
199                                  ua(:,:,:) = 0.e0             ! set dynamics trends to zero
200                                  va(:,:,:) = 0.e0
201          IF(  ln_asmiau .AND. &
202             & ln_dyninc       )  CALL dyn_asm_inc  ( kstp )   ! apply dynamics assimilation increment
203          IF( ln_neptsimp )       CALL dyn_nept_cor ( kstp )   ! subtract Neptune velocities (simplified)
204          IF( lk_bdy           )  CALL bdy_dyn3d_dmp( kstp )   ! bdy damping trends
205                                  CALL dyn_adv      ( kstp )   ! advection (vector or flux form)
206                                  CALL dyn_vor      ( kstp )   ! vorticity term including Coriolis
207                                  CALL dyn_ldf      ( kstp )   ! lateral mixing
208          IF( ln_neptsimp )       CALL dyn_nept_cor ( kstp )   ! add Neptune velocities (simplified)
209#if defined key_agrif
210          IF(.NOT. Agrif_Root())  CALL Agrif_Sponge_dyn        ! momentum sponge
211#endif
212                                  CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
213                                  CALL dyn_spg( kstp, indic )  ! surface pressure gradient
214
215                                  ua_sv(:,:,:) = ua(:,:,:)     ! Save trends (barotropic trend has been fully updated at this stage)
216                                  va_sv(:,:,:) = va(:,:,:)
217
218                                  CALL div_cur( kstp )         ! Horizontal divergence & Relative vorticity (2nd call in time-split case)
219          IF( lk_vvl     )        CALL dom_vvl_sf_nxt( kstp, kcall=2 )  ! after vertical scale factors (update depth average component)
220                                  CALL wzv           ( kstp )  ! now cross-level velocity
221      ENDIF
222
223      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
224      ! diagnostics and outputs             (ua, va, tsa used as workspace)
225      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
226      IF( lk_floats  )      CALL flo_stp( kstp )         ! drifting Floats
227      IF( lk_diahth  )      CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
228      IF( .NOT. ln_cpl )    CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
229      IF( lk_diadct  )      CALL dia_dct( kstp )         ! Transports
230      IF( lk_diaar5  )      CALL dia_ar5( kstp )         ! ar5 diag
231      IF( lk_diaharm )      CALL dia_harm( kstp )        ! Tidal harmonic analysis
232                            CALL dia_wri( kstp )         ! ocean model: outputs
233      !
234      IF( ln_crs     )      CALL crs_fld( kstp )         ! ocean model: online field coarsening & output
235
236#if defined key_top
237      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
238      ! Passive Tracer Model
239      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
240                         CALL trc_stp( kstp )         ! time-stepping
241#endif
242
243
244      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
245      ! Active tracers                              (ua, va used as workspace)
246      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
247                             tsa(:,:,:,:) = 0.e0            ! set tracer trends to zero
248
249      IF(  ln_asmiau .AND. &
250         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
251                             CALL tra_sbc    ( kstp )       ! surface boundary condition
252      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
253      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
254      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
255      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
256      IF( lk_bdy         )   CALL bdy_tra_dmp( kstp )       ! bdy damping trends
257                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
258      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
259                             CALL tra_ldf    ( kstp )       ! lateral mixing
260
261      IF( ln_diaptr      )   CALL dia_ptr                   ! Poleward adv/ldf TRansports diagnostics
262
263#if defined key_agrif
264      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
265#endif
266                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
267
268      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
269         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
270                             CALL tra_nxt( kstp )                ! tracer fields at next time step
271            IF( ln_sto_eos ) CALL sto_pts( tsn )                 ! Random T/S fluctuations
272                             CALL eos    ( tsa, rhd, rhop, fsdept_n(:,:,:) )  ! Time-filtered in situ density for hpg computation
273            IF( ln_zps .AND. .NOT. ln_isfcav)                                &
274               &             CALL zps_hde    ( kstp, jpts, tsa, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
275               &                                           rhd, gru , grv    )  ! of t, s, rd at the last ocean level
276            IF( ln_zps .AND.       ln_isfcav)                                &
277               &             CALL zps_hde_isf( kstp, jpts, tsa, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
278               &                                           rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
279               &                                    gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
280      ELSE                                                  ! centered hpg  (eos then time stepping)
281         IF ( .NOT. lk_dynspg_ts ) THEN                     ! eos already called in time-split case
282            IF( ln_sto_eos ) CALL sto_pts( tsn )    ! Random T/S fluctuations
283                             CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )  ! now in situ density for hpg computation
284         IF( ln_zps .AND. .NOT. ln_isfcav)                                   &
285               &             CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
286               &                                           rhd, gru , grv    )  ! of t, s, rd at the last ocean level
287         IF( ln_zps .AND.       ln_isfcav)                                   & 
288               &             CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
289               &                                           rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
290               &                                    gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
291         ENDIF
292         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
293                             CALL tra_nxt( kstp )                ! tracer fields at next time step
294      ENDIF
295
296      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
297      ! Dynamics                                    (tsa used as workspace)
298      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
299      IF( lk_dynspg_ts   )  THEN
300                                                             ! revert to previously computed momentum tendencies
301                                                             ! (not using ua, va as temporary arrays during tracers' update could avoid that)
302                               ua(:,:,:) = ua_sv(:,:,:)
303                               va(:,:,:) = va_sv(:,:,:)
304                                                             ! Revert now divergence and rotational to previously computed ones
305                                                             !(needed because of the time swap in div_cur, at the beginning of each time step)
306                               hdivn(:,:,:) = hdivb(:,:,:)
307                               rotn(:,:,:)  = rotb(:,:,:) 
308
309                               CALL dyn_bfr( kstp )         ! bottom friction
310                               CALL dyn_zdf( kstp )         ! vertical diffusion
311      ELSE
312                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
313                               va(:,:,:) = 0.e0
314
315        IF(  ln_asmiau .AND. &
316           & ln_dyninc      )  CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
317        IF( ln_bkgwri )        CALL asm_bkg_wri( kstp )     ! output background fields
318        IF( ln_neptsimp )      CALL dyn_nept_cor( kstp )    ! subtract Neptune velocities (simplified)
319        IF( lk_bdy          )  CALL bdy_dyn3d_dmp(kstp )    ! bdy damping trends
320                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
321                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
322                               CALL dyn_ldf( kstp )         ! lateral mixing
323        IF( ln_neptsimp )      CALL dyn_nept_cor( kstp )    ! add Neptune velocities (simplified)
324#if defined key_agrif
325        IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn        ! momemtum sponge
326#endif
327                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
328                               CALL dyn_bfr( kstp )         ! bottom friction
329                               CALL dyn_zdf( kstp )         ! vertical diffusion
330                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
331      ENDIF
332                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
333
334                               CALL ssh_swp( kstp )         ! swap of sea surface height
335      IF( lk_vvl           )   CALL dom_vvl_sf_swp( kstp )  ! swap of vertical scale factors
336
337      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
338      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
339
340      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
341      ! Control and restarts
342      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
343                               CALL stp_ctl( kstp, indic )
344      IF( indic < 0        )   THEN
345                               CALL ctl_stop( 'step: indic < 0' )
346                               CALL dia_wri_state( 'output.abort', kstp )
347      ENDIF
348      IF( kstp == nit000   )   THEN
349                 CALL iom_close( numror )     ! close input  ocean restart file
350         IF(lwm) CALL FLUSH    ( numond )     ! flush output namelist oce
351         IF( lwm.AND.numoni /= -1 ) CALL FLUSH    ( numoni )     ! flush output namelist ice
352      ENDIF
353      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
354
355      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
356      ! Coupled mode
357      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
358      IF( lk_oasis         )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
359      !
360#if defined key_iomput
361      IF( kstp == nitend .OR. indic < 0 ) THEN
362                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
363         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
364      ENDIF
365#endif
366      !
367      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
368      !
369   END SUBROUTINE stp
370
371   !!======================================================================
372END MODULE step
Note: See TracBrowser for help on using the repository browser.