| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
|---|
| 12 | !! - ! 2012 (D. Iovino) salt flux change |
|---|
| 13 | !! - ! 2012-05 (C. Rousset) add penetration solar flux |
|---|
| 14 | !! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | #if defined key_lim3 |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! lim_sbc_alloc : allocate the limsbc arrays |
|---|
| 21 | !! lim_sbc_init : initialisation |
|---|
| 22 | !! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 23 | !! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE par_oce ! ocean parameters |
|---|
| 26 | USE phycst ! physical constants |
|---|
| 27 | USE dom_oce ! ocean domain |
|---|
| 28 | USE ice ! LIM sea-ice variables |
|---|
| 29 | USE sbc_ice ! Surface boundary condition: sea-ice fields |
|---|
| 30 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 31 | USE sbccpl |
|---|
| 32 | USE oce , ONLY : fraqsr_1lev, sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass |
|---|
| 33 | USE albedo ! albedo parameters |
|---|
| 34 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 35 | USE lib_mpp ! MPP library |
|---|
| 36 | USE wrk_nemo ! work arrays |
|---|
| 37 | USE in_out_manager ! I/O manager |
|---|
| 38 | USE prtctl ! Print control |
|---|
| 39 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 40 | USE traqsr ! add penetration of solar flux in the calculation of heat budget |
|---|
| 41 | USE iom |
|---|
| 42 | USE domvvl ! Variable volume |
|---|
| 43 | USE limctl |
|---|
| 44 | |
|---|
| 45 | IMPLICIT NONE |
|---|
| 46 | PRIVATE |
|---|
| 47 | |
|---|
| 48 | PUBLIC lim_sbc_init ! called by sbc_lim_init |
|---|
| 49 | PUBLIC lim_sbc_flx ! called by sbc_ice_lim |
|---|
| 50 | PUBLIC lim_sbc_tau ! called by sbc_ice_lim |
|---|
| 51 | |
|---|
| 52 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 53 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s] |
|---|
| 54 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice) |
|---|
| 55 | |
|---|
| 56 | !! * Substitutions |
|---|
| 57 | # include "vectopt_loop_substitute.h90" |
|---|
| 58 | # include "domzgr_substitute.h90" |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 61 | !! $Id$ |
|---|
| 62 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | CONTAINS |
|---|
| 65 | |
|---|
| 66 | INTEGER FUNCTION lim_sbc_alloc() |
|---|
| 67 | !!------------------------------------------------------------------- |
|---|
| 68 | !! *** ROUTINE lim_sbc_alloc *** |
|---|
| 69 | !!------------------------------------------------------------------- |
|---|
| 70 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 71 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc) |
|---|
| 72 | ! |
|---|
| 73 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc ) |
|---|
| 74 | IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays') |
|---|
| 75 | END FUNCTION lim_sbc_alloc |
|---|
| 76 | |
|---|
| 77 | |
|---|
| 78 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 79 | !!------------------------------------------------------------------- |
|---|
| 80 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 81 | !! |
|---|
| 82 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 83 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 84 | !! |
|---|
| 85 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 86 | !! at the ice-ocean interface. |
|---|
| 87 | !! - Update the ocean sbc |
|---|
| 88 | !! |
|---|
| 89 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 90 | !! - qns : sea heat flux: non solar |
|---|
| 91 | !! - emp : freshwater budget: volume flux |
|---|
| 92 | !! - sfx : salt flux |
|---|
| 93 | !! - fr_i : ice fraction |
|---|
| 94 | !! - tn_ice : sea-ice surface temperature |
|---|
| 95 | !! - alb_ice : sea-ice albedo (lk_cpl=T) |
|---|
| 96 | !! |
|---|
| 97 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 98 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 99 | !! These refs are now obsolete since everything has been revised |
|---|
| 100 | !! The ref should be Rousset et al., 2015 |
|---|
| 101 | !!--------------------------------------------------------------------- |
|---|
| 102 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 103 | INTEGER :: ji, jj, jl, jk ! dummy loop indices |
|---|
| 104 | REAL(wp) :: zemp ! local scalars |
|---|
| 105 | REAL(wp) :: zf_mass ! Heat flux associated with mass exchange ice->ocean (W.m-2) |
|---|
| 106 | REAL(wp) :: zfcm1 ! New solar flux received by the ocean |
|---|
| 107 | ! |
|---|
| 108 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_cs, zalb_os ! 2D/3D workspace |
|---|
| 109 | !!--------------------------------------------------------------------- |
|---|
| 110 | |
|---|
| 111 | ! make calls for heat fluxes before it is modified |
|---|
| 112 | IF( iom_use('qsr_oce') ) CALL iom_put( "qsr_oce" , qsr(:,:) * pfrld(:,:) ) ! solar flux at ocean surface |
|---|
| 113 | IF( iom_use('qns_oce') ) CALL iom_put( "qns_oce" , qns(:,:) * pfrld(:,:) ) ! non-solar flux at ocean surface |
|---|
| 114 | IF( iom_use('qsr_ice') ) CALL iom_put( "qsr_ice" , SUM( qsr_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) ) ! solar flux at ice surface |
|---|
| 115 | IF( iom_use('qns_ice') ) CALL iom_put( "qns_ice" , SUM( qns_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) ) ! non-solar flux at ice surface |
|---|
| 116 | IF( iom_use('qtr_ice') ) CALL iom_put( "qtr_ice" , SUM( ftr_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) ) ! solar flux transmitted thru ice |
|---|
| 117 | IF( iom_use('qt_oce' ) ) CALL iom_put( "qt_oce" , ( qsr(:,:) + qns(:,:) ) * pfrld(:,:) ) |
|---|
| 118 | IF( iom_use('qt_ice' ) ) CALL iom_put( "qt_ice" , SUM( ( qns_ice(:,:,:) + qsr_ice(:,:,:) ) * a_i_b(:,:,:), dim=3 ) ) |
|---|
| 119 | |
|---|
| 120 | ! pfrld is the lead fraction at the previous time step (actually between TRP and THD) |
|---|
| 121 | DO jj = 1, jpj |
|---|
| 122 | DO ji = 1, jpi |
|---|
| 123 | |
|---|
| 124 | !------------------------------------------! |
|---|
| 125 | ! heat flux at the ocean surface ! |
|---|
| 126 | !------------------------------------------! |
|---|
| 127 | ! Solar heat flux reaching the ocean = zfcm1 (W.m-2) |
|---|
| 128 | !--------------------------------------------------- |
|---|
| 129 | IF( lk_cpl ) THEN |
|---|
| 130 | !!! LIM2 version zqsr = qsr_tot(ji,jj) + ( fstric(ji,jj) - qsr_ice(ji,jj,1) ) * ( 1.0 - pfrld(ji,jj) ) |
|---|
| 131 | zfcm1 = qsr_tot(ji,jj) |
|---|
| 132 | DO jl = 1, jpl |
|---|
| 133 | zfcm1 = zfcm1 + ( ftr_ice(ji,jj,jl) - qsr_ice(ji,jj,jl) ) * a_i_b(ji,jj,jl) |
|---|
| 134 | END DO |
|---|
| 135 | ELSE |
|---|
| 136 | !!! LIM2 version zqsr = pfrld(ji,jj) * qsr(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 137 | zfcm1 = pfrld(ji,jj) * qsr(ji,jj) |
|---|
| 138 | DO jl = 1, jpl |
|---|
| 139 | zfcm1 = zfcm1 + a_i_b(ji,jj,jl) * ftr_ice(ji,jj,jl) |
|---|
| 140 | END DO |
|---|
| 141 | ENDIF |
|---|
| 142 | |
|---|
| 143 | ! Total heat flux reaching the ocean = hfx_out (W.m-2) |
|---|
| 144 | !--------------------------------------------------- |
|---|
| 145 | zf_mass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC) |
|---|
| 146 | hfx_out(ji,jj) = hfx_out(ji,jj) + zf_mass + zfcm1 |
|---|
| 147 | |
|---|
| 148 | ! New qsr and qns used to compute the oceanic heat flux at the next time step |
|---|
| 149 | !--------------------------------------------------- |
|---|
| 150 | qsr(ji,jj) = zfcm1 |
|---|
| 151 | qns(ji,jj) = hfx_out(ji,jj) - zfcm1 |
|---|
| 152 | |
|---|
| 153 | !------------------------------------------! |
|---|
| 154 | ! mass flux at the ocean surface ! |
|---|
| 155 | !------------------------------------------! |
|---|
| 156 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 157 | ! ------------------------------------------------------------------------------------- |
|---|
| 158 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 159 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 160 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 161 | ! Associated to Ice formation AND Ice melting |
|---|
| 162 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 163 | ! |
|---|
| 164 | ! computing freshwater exchanges at the ice/ocean interface |
|---|
| 165 | IF( lk_cpl ) THEN |
|---|
| 166 | zemp = - emp_tot(ji,jj) + emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! |
|---|
| 167 | & + wfx_snw(ji,jj) |
|---|
| 168 | ELSE |
|---|
| 169 | zemp = emp(ji,jj) * pfrld(ji,jj) & ! evaporation over oceanic fraction |
|---|
| 170 | & - tprecip(ji,jj) * ( 1._wp - pfrld(ji,jj) ) & ! all precipitation reach the ocean |
|---|
| 171 | & + sprecip(ji,jj) * ( 1._wp - pfrld(ji,jj)**rn_betas ) ! except solid precip intercepted by sea-ice |
|---|
| 172 | ENDIF |
|---|
| 173 | |
|---|
| 174 | ! mass flux from ice/ocean |
|---|
| 175 | wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) & |
|---|
| 176 | + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) |
|---|
| 177 | |
|---|
| 178 | ! mass flux at the ocean/ice interface |
|---|
| 179 | fmmflx(ji,jj) = - wfx_ice(ji,jj) * r1_rdtice ! F/M mass flux save at least for biogeochemical model |
|---|
| 180 | emp(ji,jj) = zemp - wfx_ice(ji,jj) - wfx_snw(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange) |
|---|
| 181 | |
|---|
| 182 | END DO |
|---|
| 183 | END DO |
|---|
| 184 | |
|---|
| 185 | !------------------------------------------! |
|---|
| 186 | ! salt flux at the ocean surface ! |
|---|
| 187 | !------------------------------------------! |
|---|
| 188 | sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:) & |
|---|
| 189 | & + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:) |
|---|
| 190 | |
|---|
| 191 | !-------------------------------------------------------------! |
|---|
| 192 | ! mass of snow and ice per unit area for embedded sea-ice ! |
|---|
| 193 | !-------------------------------------------------------------! |
|---|
| 194 | IF( nn_ice_embd /= 0 ) THEN |
|---|
| 195 | ! save mass from the previous ice time step |
|---|
| 196 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 197 | ! new mass per unit area |
|---|
| 198 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 199 | ! time evolution of snow+ice mass |
|---|
| 200 | snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice |
|---|
| 201 | ENDIF |
|---|
| 202 | |
|---|
| 203 | !-----------------------------------------------! |
|---|
| 204 | ! Storing the transmitted variables ! |
|---|
| 205 | !-----------------------------------------------! |
|---|
| 206 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 207 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 208 | |
|---|
| 209 | !------------------------------------------------! |
|---|
| 210 | ! Snow/ice albedo (only if sent to coupler) ! |
|---|
| 211 | !------------------------------------------------! |
|---|
| 212 | IF( lk_cpl ) THEN ! coupled case |
|---|
| 213 | |
|---|
| 214 | CALL wrk_alloc( jpi, jpj, jpl, zalb_cs, zalb_os ) |
|---|
| 215 | |
|---|
| 216 | CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos |
|---|
| 217 | |
|---|
| 218 | alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 219 | |
|---|
| 220 | CALL wrk_dealloc( jpi, jpj, jpl, zalb_cs, zalb_os ) |
|---|
| 221 | |
|---|
| 222 | ENDIF |
|---|
| 223 | |
|---|
| 224 | IF( ln_nicep ) CALL lim_prt( kt, jiindx, jjindx, 3, ' - Final state lim_sbc - ' ) ! control print |
|---|
| 225 | |
|---|
| 226 | IF(ln_ctl) THEN |
|---|
| 227 | CALL prt_ctl( tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ' ) |
|---|
| 228 | CALL prt_ctl( tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=sfx , clinfo2=' sfx : ' ) |
|---|
| 229 | CALL prt_ctl( tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ' ) |
|---|
| 230 | CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl ) |
|---|
| 231 | ENDIF |
|---|
| 232 | |
|---|
| 233 | END SUBROUTINE lim_sbc_flx |
|---|
| 234 | |
|---|
| 235 | |
|---|
| 236 | SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce ) |
|---|
| 237 | !!------------------------------------------------------------------- |
|---|
| 238 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 239 | !! |
|---|
| 240 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 241 | !! |
|---|
| 242 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 243 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 244 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 245 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 246 | !! - update the modulus of stress at ocean surface |
|---|
| 247 | !! taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce | |
|---|
| 248 | !! * at each ocean time step (every kt): |
|---|
| 249 | !! compute linearized ice-ocean stresses as |
|---|
| 250 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 251 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 252 | !! |
|---|
| 253 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 254 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 255 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 256 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 257 | !! |
|---|
| 258 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 259 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 260 | !!--------------------------------------------------------------------- |
|---|
| 261 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 262 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 263 | !! |
|---|
| 264 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 265 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 266 | REAL(wp) :: zat_v, zvtau_ice, zv_t ! - - |
|---|
| 267 | !!--------------------------------------------------------------------- |
|---|
| 268 | ! |
|---|
| 269 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 270 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 271 | DO ji = fs_2, fs_jpim1 |
|---|
| 272 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 273 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 274 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 275 | ! ! |U_ice-U_oce|^2 |
|---|
| 276 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 277 | ! ! update the ocean stress modulus |
|---|
| 278 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt |
|---|
| 279 | tmod_io(ji,jj) = rhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 280 | END DO |
|---|
| 281 | END DO |
|---|
| 282 | CALL lbc_lnk( taum, 'T', 1. ) ; CALL lbc_lnk( tmod_io, 'T', 1. ) |
|---|
| 283 | ! |
|---|
| 284 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 285 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 286 | ! |
|---|
| 287 | ENDIF |
|---|
| 288 | ! |
|---|
| 289 | ! !== every ocean time-step ==! |
|---|
| 290 | ! |
|---|
| 291 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 292 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 293 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 294 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 295 | ! ! linearized quadratic drag formulation |
|---|
| 296 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 297 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 298 | ! ! stresses at the ocean surface |
|---|
| 299 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 300 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 301 | END DO |
|---|
| 302 | END DO |
|---|
| 303 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 304 | ! |
|---|
| 305 | IF(ln_ctl) CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 306 | & tab2d_2=vtau, clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 307 | ! |
|---|
| 308 | END SUBROUTINE lim_sbc_tau |
|---|
| 309 | |
|---|
| 310 | |
|---|
| 311 | SUBROUTINE lim_sbc_init |
|---|
| 312 | !!------------------------------------------------------------------- |
|---|
| 313 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 314 | !! |
|---|
| 315 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 316 | !! the temporal evolution of key variables |
|---|
| 317 | !! |
|---|
| 318 | !! ** input : Namelist namicedia |
|---|
| 319 | !!------------------------------------------------------------------- |
|---|
| 320 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 321 | REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar |
|---|
| 322 | IF(lwp) WRITE(numout,*) |
|---|
| 323 | IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition' |
|---|
| 324 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ ' |
|---|
| 325 | |
|---|
| 326 | ! ! allocate lim_sbc array |
|---|
| 327 | IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' ) |
|---|
| 328 | ! |
|---|
| 329 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 330 | sice_0(:,:) = sice |
|---|
| 331 | ! |
|---|
| 332 | IF( cp_cfg == "orca" ) THEN ! decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 333 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 334 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 335 | soce_0(:,:) = 4._wp |
|---|
| 336 | sice_0(:,:) = 2._wp |
|---|
| 337 | END WHERE |
|---|
| 338 | ENDIF |
|---|
| 339 | |
|---|
| 340 | IF( .NOT. ln_rstart ) THEN |
|---|
| 341 | fraqsr_1lev(:,:) = 1._wp |
|---|
| 342 | ENDIF |
|---|
| 343 | ! |
|---|
| 344 | IF( .NOT. ln_rstart ) THEN |
|---|
| 345 | ! ! embedded sea ice |
|---|
| 346 | IF( nn_ice_embd /= 0 ) THEN ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass |
|---|
| 347 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) |
|---|
| 348 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 349 | ELSE |
|---|
| 350 | snwice_mass (:,:) = 0.0_wp ! no mass exchanges |
|---|
| 351 | snwice_mass_b(:,:) = 0.0_wp ! no mass exchanges |
|---|
| 352 | ENDIF |
|---|
| 353 | IF( nn_ice_embd == 2 ) THEN ! full embedment (case 2) deplete the initial ssh below sea-ice area |
|---|
| 354 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 355 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 356 | #if defined key_vvl |
|---|
| 357 | ! key_vvl necessary? clem: yes for compilation purpose |
|---|
| 358 | DO jk = 1,jpkm1 ! adjust initial vertical scale factors |
|---|
| 359 | fse3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 360 | fse3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 361 | ENDDO |
|---|
| 362 | fse3t_a(:,:,:) = fse3t_b(:,:,:) |
|---|
| 363 | ! Reconstruction of all vertical scale factors at now and before time |
|---|
| 364 | ! steps |
|---|
| 365 | ! ============================================================================= |
|---|
| 366 | ! Horizontal scale factor interpolations |
|---|
| 367 | ! -------------------------------------- |
|---|
| 368 | CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3u_b(:,:,:), 'U' ) |
|---|
| 369 | CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3v_b(:,:,:), 'V' ) |
|---|
| 370 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3u_n(:,:,:), 'U' ) |
|---|
| 371 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3v_n(:,:,:), 'V' ) |
|---|
| 372 | CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3f_n(:,:,:), 'F' ) |
|---|
| 373 | ! Vertical scale factor interpolations |
|---|
| 374 | ! ------------------------------------ |
|---|
| 375 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3w_n (:,:,:), 'W' ) |
|---|
| 376 | CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3uw_n(:,:,:), 'UW' ) |
|---|
| 377 | CALL dom_vvl_interpol( fse3v_n(:,:,:), fse3vw_n(:,:,:), 'VW' ) |
|---|
| 378 | CALL dom_vvl_interpol( fse3u_b(:,:,:), fse3uw_b(:,:,:), 'UW' ) |
|---|
| 379 | CALL dom_vvl_interpol( fse3v_b(:,:,:), fse3vw_b(:,:,:), 'VW' ) |
|---|
| 380 | ! t- and w- points depth |
|---|
| 381 | ! ---------------------- |
|---|
| 382 | fsdept_n(:,:,1) = 0.5_wp * fse3w_n(:,:,1) |
|---|
| 383 | fsdepw_n(:,:,1) = 0.0_wp |
|---|
| 384 | fsde3w_n(:,:,1) = fsdept_n(:,:,1) - sshn(:,:) |
|---|
| 385 | DO jk = 2, jpk |
|---|
| 386 | fsdept_n(:,:,jk) = fsdept_n(:,:,jk-1) + fse3w_n(:,:,jk) |
|---|
| 387 | fsdepw_n(:,:,jk) = fsdepw_n(:,:,jk-1) + fse3t_n(:,:,jk-1) |
|---|
| 388 | fsde3w_n(:,:,jk) = fsdept_n(:,:,jk ) - sshn (:,:) |
|---|
| 389 | END DO |
|---|
| 390 | #endif |
|---|
| 391 | ENDIF |
|---|
| 392 | ENDIF ! .NOT. ln_rstart |
|---|
| 393 | ! |
|---|
| 394 | |
|---|
| 395 | END SUBROUTINE lim_sbc_init |
|---|
| 396 | |
|---|
| 397 | #else |
|---|
| 398 | !!---------------------------------------------------------------------- |
|---|
| 399 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 400 | !!---------------------------------------------------------------------- |
|---|
| 401 | CONTAINS |
|---|
| 402 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 403 | END SUBROUTINE lim_sbc |
|---|
| 404 | #endif |
|---|
| 405 | |
|---|
| 406 | !!====================================================================== |
|---|
| 407 | END MODULE limsbc |
|---|
