New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 5053

Last change on this file since 5053 was 5053, checked in by clem, 9 years ago

LIM3 cleaning continues. No change in the physics besides the introduction of the monocategory sea ice
  • Property svn:keywords set to Id
File size: 38.9 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE oce     , ONLY : fraqsr_1lev 
25   USE ice            ! LIM: sea-ice variables
26   USE par_ice        ! LIM: sea-ice parameters
27   USE sbc_oce        ! Surface boundary condition: ocean fields
28   USE sbc_ice        ! Surface boundary condition: ice fields
29   USE thd_ice        ! LIM thermodynamic sea-ice variables
30   USE dom_ice        ! LIM sea-ice domain
31   USE domvvl         ! domain: variable volume level
32   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
33   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
34   USE limthd_sal     ! LIM: thermodynamics, ice salinity
35   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
36   USE limthd_lac     ! LIM-3 lateral accretion
37   USE limitd_th      ! remapping thickness distribution
38   USE limtab         ! LIM: 1D <==> 2D transformation
39   USE limvar         ! LIM: sea-ice variables
40   USE lbclnk         ! lateral boundary condition - MPP links
41   USE lib_mpp        ! MPP library
42   USE wrk_nemo       ! work arrays
43   USE in_out_manager ! I/O manager
44   USE prtctl         ! Print control
45   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
46   USE timing         ! Timing
47   USE limcons        ! conservation tests
48   USE limctl
49
50   IMPLICIT NONE
51   PRIVATE
52
53   PUBLIC   lim_thd        ! called by limstp module
54   PUBLIC   lim_thd_init   ! called by sbc_lim_init
55
56   !! * Substitutions
57#  include "domzgr_substitute.h90"
58#  include "vectopt_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
61   !! $Id$
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE lim_thd( kt )
67      !!-------------------------------------------------------------------
68      !!                ***  ROUTINE lim_thd  ***       
69      !! 
70      !! ** Purpose : This routine manages ice thermodynamics
71      !!         
72      !! ** Action : - Initialisation of some variables
73      !!             - Some preliminary computation (oceanic heat flux
74      !!               at the ice base, snow acc.,heat budget of the leads)
75      !!             - selection of the icy points and put them in an array
76      !!             - call lim_thd_dif  for vertical heat diffusion
77      !!             - call lim_thd_dh   for vertical ice growth and melt
78      !!             - call lim_thd_ent  for enthalpy remapping
79      !!             - call lim_thd_sal  for ice desalination
80      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
81      !!             - back to the geographic grid
82      !!     
83      !! ** References :
84      !!---------------------------------------------------------------------
85      INTEGER, INTENT(in) :: kt    ! number of iteration
86      !!
87      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
88      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
89      INTEGER  :: ii, ij           ! temporary dummy loop index
90      REAL(wp) :: zfric_u, zqld, zqfr
91      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
92      REAL(wp), PARAMETER :: zfric_umin = 0._wp        ! lower bound for the friction velocity (cice value=5.e-04)
93      REAL(wp), PARAMETER :: zch        = 0.0057_wp    ! heat transfer coefficient
94      !
95      REAL(wp), POINTER, DIMENSION(:,:) ::  zqsr, zqns
96      !!-------------------------------------------------------------------
97      CALL wrk_alloc( jpi, jpj, zqsr, zqns )
98
99      IF( nn_timing == 1 )  CALL timing_start('limthd')
100
101      ! conservation test
102      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
103
104      !------------------------------------------------------------------------!
105      ! 1) Initialization of some variables                                    !
106      !------------------------------------------------------------------------!
107      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
108
109      !--------------------
110      ! 1.2) Heat content   
111      !--------------------
112      ! Change the units of heat content; from global units to J.m3
113      DO jl = 1, jpl
114         DO jk = 1, nlay_i
115            DO jj = 1, jpj
116               DO ji = 1, jpi
117                  !0 if no ice and 1 if yes
118                  rswitch = 1.0 - MAX(  0.0 , SIGN( 1.0 , - v_i(ji,jj,jl) + epsi10 )  )
119                  !Energy of melting q(S,T) [J.m-3]
120                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_i(ji,jj,jl) , epsi10 ) ) * REAL( nlay_i )
121                  !convert units ! very important that this line is here       
122                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * unit_fac 
123               END DO
124            END DO
125         END DO
126         DO jk = 1, nlay_s
127            DO jj = 1, jpj
128               DO ji = 1, jpi
129                  !0 if no ice and 1 if yes
130                  rswitch = 1.0 - MAX(  0.0 , SIGN( 1.0 , - v_s(ji,jj,jl) + epsi10 )  )
131                  !Energy of melting q(S,T) [J.m-3]
132                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_s(ji,jj,jl) , epsi10 ) ) * REAL( nlay_s )
133                  !convert units ! very important that this line is here
134                  e_s(ji,jj,jk,jl) = e_s(ji,jj,jk,jl) * unit_fac 
135               END DO
136            END DO
137         END DO
138      END DO
139
140      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
141      !-----------------------------------------------------------------------------!
142
143      !--- Ocean solar and non solar fluxes to be used in zqld
144      IF ( .NOT. lk_cpl ) THEN   ! --- forced case, fluxes to the lead are the same as over the ocean
145         !
146         zqsr(:,:) = qsr(:,:)      ; zqns(:,:) = qns(:,:)
147         !
148      ELSE                       ! --- coupled case, fluxes to the lead are total - intercepted
149         !
150         zqsr(:,:) = qsr_tot(:,:)  ; zqns(:,:) = qns_tot(:,:)
151         !
152         DO jl = 1, jpl
153            DO jj = 1, jpj
154               DO ji = 1, jpi
155                  zqsr(ji,jj) = zqsr(ji,jj) - qsr_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
156                  zqns(ji,jj) = zqns(ji,jj) - qns_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
157               END DO
158            END DO
159         END DO
160         !
161      ENDIF
162
163      DO jj = 1, jpj
164         DO ji = 1, jpi
165            rswitch  = tms(ji,jj) * ( 1._wp - MAX( 0._wp , SIGN( 1._wp , - at_i(ji,jj) + epsi10 ) ) ) ! 0 if no ice
166            !
167            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
168            !           !  practically no "direct lateral ablation"
169            !           
170            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
171            !           !  temperature and turbulent mixing (McPhee, 1992)
172            !
173
174            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
175            ! REMARK valid at least in forced mode from clem
176            ! precip is included in qns but not in qns_ice
177            IF ( lk_cpl ) THEN
178               zqld =  tms(ji,jj) * rdt_ice *  &
179                  &    (   zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj)               &   ! pfrld already included in coupled mode
180                  &    + ( pfrld(ji,jj)**betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *     &   ! heat content of precip
181                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )   &
182                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt ) )
183            ELSE
184               zqld =  tms(ji,jj) * rdt_ice *  &
185                  &      ( pfrld(ji,jj) * ( zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj) )    &
186                  &    + ( pfrld(ji,jj)**betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *             &  ! heat content of precip
187                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )           &
188                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt ) )
189            ENDIF
190
191            !-- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
192            zqfr = tms(ji,jj) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
193
194            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
195            qlead(ji,jj) = MIN( 0._wp , zqld - zqfr ) 
196
197            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
198            IF( at_i(ji,jj) > epsi10 .AND. zqld > 0._wp ) THEN
199               fhld (ji,jj) = zqld * r1_rdtice / at_i(ji,jj) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
200               qlead(ji,jj) = 0._wp
201            ELSE
202               fhld (ji,jj) = 0._wp
203            ENDIF
204            !
205            !-- Energy from the turbulent oceanic heat flux --- !
206            !clem zfric_u        = MAX ( MIN( SQRT( ust2s(ji,jj) ) , zfric_umax ) , zfric_umin )
207            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
208            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
209            ! upper bound for fhtur: we do not want SST to drop below Tfreeze.
210            ! So we say that the heat retrieved from the ocean (fhtur+fhld) must be < to the heat necessary to reach Tfreeze (zqfr)   
211            ! This is not a clean budget, so that should be corrected at some point
212            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - fhld(ji,jj) - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
213
214            ! -----------------------------------------
215            ! Net heat flux on top of ice-ocean [W.m-2]
216            ! -----------------------------------------
217            !     First  step here      : heat flux at the ocean surface + precip
218            !     Second step below     : heat flux at the ice   surface (after limthd_dif)
219            hfx_in(ji,jj) = hfx_in(ji,jj)                                                                                         & 
220               ! heat flux above the ocean
221               &    +             pfrld(ji,jj)   * ( zqns(ji,jj) + zqsr(ji,jj) )                                                  &
222               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
223               &    +   ( 1._wp - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
224               &    +   ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt )
225
226            ! -----------------------------------------------------------------------------
227            ! Net heat flux that is retroceded to the ocean or taken from the ocean [W.m-2]
228            ! -----------------------------------------------------------------------------
229            !     First  step here              :  non solar + precip - qlead - qturb
230            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
231            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
232            hfx_out(ji,jj) = hfx_out(ji,jj)                                                                                       & 
233               ! Non solar heat flux received by the ocean
234               &    +        pfrld(ji,jj) * qns(ji,jj)                                                                            &
235               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
236               &    +      ( pfrld(ji,jj)**betas - pfrld(ji,jj) ) * sprecip(ji,jj)       &
237               &         * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
238               &    +      ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt )       &
239               ! heat flux taken from the ocean where there is open water ice formation
240               &    -      qlead(ji,jj) * r1_rdtice                                                                               &
241               ! heat flux taken from the ocean during bottom growth/melt (fhld should be 0 while bott growth)
242               &    -      at_i(ji,jj) * fhtur(ji,jj)                                                                             &
243               &    -      at_i(ji,jj) *  fhld(ji,jj)
244
245         END DO
246      END DO
247
248      !------------------------------------------------------------------------------!
249      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
250      !------------------------------------------------------------------------------!
251
252      DO jl = 1, jpl      !loop over ice categories
253
254         IF( kt == nit000 .AND. lwp ) THEN
255            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
256            WRITE(numout,*) ' ~~~~~~~~'
257         ENDIF
258
259         nbpb = 0
260         DO jj = 1, jpj
261            DO ji = 1, jpi
262               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
263                  nbpb      = nbpb  + 1
264                  npb(nbpb) = (jj - 1) * jpi + ji
265               ENDIF
266            END DO
267         END DO
268
269         ! debug point to follow
270         jiindex_1d = 0
271         IF( ln_nicep ) THEN
272            DO ji = mi0(jiindx), mi1(jiindx)
273               DO jj = mj0(jjindx), mj1(jjindx)
274                  jiindex_1d = (jj - 1) * jpi + ji
275                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
276               END DO
277            END DO
278         ENDIF
279
280         !------------------------------------------------------------------------------!
281         ! 4) Thermodynamic computation
282         !------------------------------------------------------------------------------!
283
284         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
285
286         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
287
288            !-------------------------
289            ! 4.1 Move to 1D arrays
290            !-------------------------
291
292            CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
293            CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
294            CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
295            CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
296
297            CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
298            CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
299            DO jk = 1, nlay_s
300               CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
301               CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
302            END DO
303            DO jk = 1, nlay_i
304               CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
305               CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
306               CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
307            END DO
308
309            CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
310            CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
311            CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
312            CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
313            CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
314            CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
315            IF( .NOT. lk_cpl ) THEN
316               CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
317               CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
318            ENDIF
319            CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
320            CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
321            CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
322            CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
323            CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
324            CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
325
326            CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
327            CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
328
329            CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
330            CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
331            CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
332            CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
333            CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
334            CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
335
336            CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
337            CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
338            CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
339            CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
340            CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
341            CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
342
343            CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
344            CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
345            CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
346            CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
347            CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
348            CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
349            CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
350            CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
351            CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
352            CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
353            CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
354            CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
355
356            !--------------------------------
357            ! 4.3) Thermodynamic processes
358            !--------------------------------
359
360            !--------------------------------------!
361            ! --- Ice/Snow Temperature profile --- !
362            !--------------------------------------!
363            CALL lim_thd_dif( 1, nbpb )
364
365            !---------------------------------!
366            ! --- Ice/Snow thickness ---      !
367            !---------------------------------!
368            CALL lim_thd_dh( 1, nbpb )   
369
370            ! --- Ice enthalpy remapping --- !
371            CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) ) 
372                                           
373            !---------------------------------!
374            ! --- Ice salinity ---            !
375            !---------------------------------!
376            CALL lim_thd_sal( 1, nbpb )   
377
378            !---------------------------------!
379            ! --- temperature update ---      !
380            !---------------------------------!
381            CALL lim_thd_temp( 1, nbpb )
382
383            !------------------------------------!
384            ! --- lateral melting if monocat --- !
385            !------------------------------------!
386            IF ( ( ( nn_monocat == 1 ) .OR. ( nn_monocat == 4 ) ) .AND. ( jpl == 1 ) ) THEN
387               CALL lim_thd_lam( 1, nbpb )
388            END IF
389
390            !--------------------------------
391            ! 4.4) Move 1D to 2D vectors
392            !--------------------------------
393
394               CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
395               CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
396               CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
397               CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
398               CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
399               CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
400            DO jk = 1, nlay_s
401               CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
402               CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
403            END DO
404            DO jk = 1, nlay_i
405               CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
406               CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
407               CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
408            END DO
409               CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
410
411               CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
412               CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
413
414               CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
415               CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
416               CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
417               CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
418               CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
419               CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
420
421               CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
422               CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
423               CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
424               CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
425               CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
426               CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
427
428              CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
429              CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
430              CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
431              CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
432              CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
433              CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
434              CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
435              CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
436              CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
437              CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
438              CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
439              CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
440            !
441              CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
442              CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
443            !
444            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
445         ENDIF
446         !
447      END DO
448
449      !------------------------------------------------------------------------------!
450      ! 5) Global variables, diagnostics
451      !------------------------------------------------------------------------------!
452
453      !------------------------
454      ! Ice heat content             
455      !------------------------
456      ! Enthalpies are global variables we have to readjust the units (heat content in Joules)
457      DO jl = 1, jpl
458         DO jk = 1, nlay_i
459            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_i(:,:,jl) / ( unit_fac * REAL( nlay_i ) )
460         END DO
461      END DO
462
463      !------------------------
464      ! Snow heat content             
465      !------------------------
466      ! Enthalpies are global variables we have to readjust the units (heat content in Joules)
467      DO jl = 1, jpl
468         DO jk = 1, nlay_s
469            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_s(:,:,jl) / ( unit_fac * REAL( nlay_s ) )
470         END DO
471      END DO
472 
473      !------------------------
474      ! Ice natural aging             
475      !------------------------
476      oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * rdt_ice /rday
477
478      !----------------------------------
479      ! Change thickness to volume
480      !----------------------------------
481      CALL lim_var_eqv2glo
482
483      !--------------------------------------------
484      ! 5.4) Diagnostic thermodynamic growth rates
485      !--------------------------------------------
486      IF( ln_nicep )   CALL lim_prt( kt, jiindx, jjindx, 1, ' - ice thermodyn. - ' )   ! control print
487
488      IF(ln_ctl) THEN            ! Control print
489         CALL prt_ctl_info(' ')
490         CALL prt_ctl_info(' - Cell values : ')
491         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
492         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_thd  : cell area :')
493         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
494         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
495         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
496         DO jl = 1, jpl
497            CALL prt_ctl_info(' ')
498            CALL prt_ctl_info(' - Category : ', ivar1=jl)
499            CALL prt_ctl_info('   ~~~~~~~~~~')
500            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
501            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
502            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
503            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
504            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
505            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
506            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
507            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
508            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
509            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
510            DO jk = 1, nlay_i
511               CALL prt_ctl_info(' ')
512               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
513               CALL prt_ctl_info('   ~~~~~~~')
514               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
515               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
516            END DO
517         END DO
518      ENDIF
519      !
520      !
521      CALL wrk_dealloc( jpi, jpj, zqsr, zqns )
522
523      !------------------------------------------------------------------------------|
524      !  1) Transport of ice between thickness categories.                           |
525      !------------------------------------------------------------------------------|
526      ! Given thermodynamic growth rates, transport ice between
527      ! thickness categories.
528      IF( jpl > 1 )   CALL lim_itd_th_rem( 1, jpl, kt )
529      !
530      CALL lim_var_glo2eqv    ! only for info
531      CALL lim_var_agg(1)
532
533      !------------------------------------------------------------------------------|
534      !  3) Add frazil ice growing in leads.
535      !------------------------------------------------------------------------------|
536      CALL lim_thd_lac
537      CALL lim_var_glo2eqv    ! only for info
538     
539      IF(ln_ctl) THEN   ! Control print
540         CALL prt_ctl_info(' ')
541         CALL prt_ctl_info(' - Cell values : ')
542         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
543         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_itd_th  : cell area :')
544         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
545         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
546         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
547         DO jl = 1, jpl
548            CALL prt_ctl_info(' ')
549            CALL prt_ctl_info(' - Category : ', ivar1=jl)
550            CALL prt_ctl_info('   ~~~~~~~~~~')
551            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
552            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
553            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
554            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
555            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
556            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
557            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
558            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
559            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
560            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
561            DO jk = 1, nlay_i
562               CALL prt_ctl_info(' ')
563               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
564               CALL prt_ctl_info('   ~~~~~~~')
565               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
566               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
567            END DO
568         END DO
569      ENDIF
570      !
571      ! conservation test
572      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
573
574      IF( nn_timing == 1 )  CALL timing_stop('limthd')
575
576   END SUBROUTINE lim_thd 
577
578   SUBROUTINE lim_thd_temp( kideb, kiut )
579      !!-----------------------------------------------------------------------
580      !!                   ***  ROUTINE lim_thd_temp ***
581      !!                 
582      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
583      !!
584      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
585      !!-------------------------------------------------------------------
586      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
587      !!
588      INTEGER  ::   ji, jk   ! dummy loop indices
589      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
590      !!-------------------------------------------------------------------
591      ! Recover ice temperature
592      DO jk = 1, nlay_i
593         DO ji = kideb, kiut
594            ztmelts       =  -tmut * s_i_1d(ji,jk) + rtt
595            ! Conversion q(S,T) -> T (second order equation)
596            zaaa          =  cpic
597            zbbb          =  ( rcp - cpic ) * ( ztmelts - rtt ) + q_i_1d(ji,jk) / rhoic - lfus
598            zccc          =  lfus * ( ztmelts - rtt )
599            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
600            t_i_1d(ji,jk) =  rtt - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
601           
602            ! mask temperature
603            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
604            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rtt
605         END DO
606      END DO
607
608   END SUBROUTINE lim_thd_temp
609
610   SUBROUTINE lim_thd_lam( kideb, kiut )
611      !!-----------------------------------------------------------------------
612      !!                   ***  ROUTINE lim_thd_lam ***
613      !!                 
614      !! ** Purpose :   Lateral melting in case monocategory
615      !!                          ( dA = A/2h dh )
616      !!-----------------------------------------------------------------------
617      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
618      INTEGER             ::   ji            ! dummy loop indices
619      REAL(wp)            ::   zhi_bef       ! ice thickness before thermo
620      REAL(wp)            ::   zdh_mel       ! net melting
621
622      DO ji = kideb, kiut
623         zhi_bef = ht_i_1d(ji) - ( dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) )
624         zdh_mel = MIN( 0._wp,     dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) )
625         IF( zdh_mel < 0._wp )   &
626            &   a_i_1d(ji) = MAX( 0._wp, a_i_1d(ji) + a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi10 ) ) ) 
627      END DO
628      at_i_1d(:) = a_i_1d(:)
629     
630   END SUBROUTINE lim_thd_lam
631
632   SUBROUTINE lim_thd_init
633      !!-----------------------------------------------------------------------
634      !!                   ***  ROUTINE lim_thd_init ***
635      !!                 
636      !! ** Purpose :   Physical constants and parameters linked to the ice
637      !!              thermodynamics
638      !!
639      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
640      !!              parameter values called at the first timestep (nit000)
641      !!
642      !! ** input   :   Namelist namicether
643      !!-------------------------------------------------------------------
644      INTEGER  ::   ios                 ! Local integer output status for namelist read
645      NAMELIST/namicethd/ hiccrit, fraz_swi, maxfrazb, vfrazb, Cfrazb,    &
646         &                hiclim, parsub, betas,                          & 
647         &                kappa_i, nconv_i_thd, maxer_i_thd, thcon_i_swi, &
648         &                nn_monocat
649      !!-------------------------------------------------------------------
650      !
651      IF(lwp) THEN
652         WRITE(numout,*)
653         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
654         WRITE(numout,*) '~~~~~~~'
655      ENDIF
656      !
657      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
658      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
659901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
660
661      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
662      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
663902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
664      IF(lwm) WRITE ( numoni, namicethd )
665      !
666      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
667         nn_monocat = 0
668         WRITE(numout, *) ' nn_monocat must be 0 in multi-category case '
669      ENDIF
670
671      IF( lk_cpl .AND. parsub /= 0.0 )   CALL ctl_stop( 'In coupled mode, use parsub = 0. or send dqla' )
672      !
673      IF(lwp) THEN                          ! control print
674         WRITE(numout,*)
675         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
676         WRITE(numout,*)'      ice thick. for lateral accretion                        hiccrit      = ', hiccrit
677         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       fraz_swi     = ', fraz_swi
678         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   maxfrazb     = ', maxfrazb
679         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  vfrazb       = ', vfrazb
680         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          Cfrazb       = ', Cfrazb
681         WRITE(numout,*)'      minimum ice thickness                                   hiclim       = ', hiclim 
682         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
683         WRITE(numout,*)'      switch for snow sublimation  (=1) or not (=0)           parsub       = ', parsub 
684         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          betas        = ', betas
685         WRITE(numout,*)'      extinction radiation parameter in sea ice               kappa_i      = ', kappa_i
686         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nconv_i_thd  = ', nconv_i_thd
687         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        maxer_i_thd  = ', maxer_i_thd
688         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     thcon_i_swi  = ', thcon_i_swi
689         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
690         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
691      ENDIF
692      !
693   END SUBROUTINE lim_thd_init
694
695#else
696   !!----------------------------------------------------------------------
697   !!   Default option         Dummy module          NO  LIM3 sea-ice model
698   !!----------------------------------------------------------------------
699#endif
700
701   !!======================================================================
702END MODULE limthd
Note: See TracBrowser for help on using the repository browser.