New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limupdate2.F90 in branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3/limupdate2.F90 @ 5055

Last change on this file since 5055 was 5055, checked in by clem, 9 years ago

LIM3: removing par_ice and put jpl, nlay_i and nlay_s as namelist parameters
File size: 14.1 KB
Line 
1MODULE limupdate2
2   !!======================================================================
3   !!                     ***  MODULE  limupdate2  ***
4   !!   LIM-3 : Update of sea-ice global variables at the end of the time step
5   !!======================================================================
6   !! History :  3.0  !  2006-04  (M. Vancoppenolle) Original code
7   !!            3.6  !  2014-06  (C. Rousset)       Complete rewriting/cleaning
8   !!----------------------------------------------------------------------
9#if defined key_lim3
10   !!----------------------------------------------------------------------
11   !!   'key_lim3'                                      LIM3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!    lim_update2   : computes update of sea-ice global variables from trend terms
14   !!----------------------------------------------------------------------
15   USE limrhg          ! ice rheology
16
17   USE dom_oce
18   USE oce             ! dynamics and tracers variables
19   USE in_out_manager
20   USE sbc_oce         ! Surface boundary condition: ocean fields
21   USE sbc_ice         ! Surface boundary condition: ice fields
22   USE dom_ice
23   USE phycst          ! physical constants
24   USE ice
25   USE limdyn
26   USE limtrp
27   USE limthd
28   USE limsbc
29   USE limdiahsb
30   USE limwri
31   USE limrst
32   USE thd_ice         ! LIM thermodynamic sea-ice variables
33   USE limitd_th
34   USE limitd_me
35   USE limvar
36   USE prtctl           ! Print control
37   USE lbclnk           ! lateral boundary condition - MPP exchanges
38   USE wrk_nemo         ! work arrays
39   USE lib_fortran     ! glob_sum
40   USE timing          ! Timing
41   USE limcons        ! conservation tests
42   USE limctl
43
44   IMPLICIT NONE
45   PRIVATE
46
47   PUBLIC   lim_update2   ! routine called by ice_step
48
49   !! * Substitutions
50#  include "vectopt_loop_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
53   !! $Id: limupdate.F90 3294 2012-01-28 16:44:18Z rblod $
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE lim_update2( kt )
59      !!-------------------------------------------------------------------
60      !!               ***  ROUTINE lim_update2  ***
61      !!               
62      !! ** Purpose :  Computes update of sea-ice global variables at
63      !!               the end of the time step.
64      !!
65      !!---------------------------------------------------------------------
66      INTEGER, INTENT(in) :: kt    ! number of iteration
67      INTEGER  ::   ji, jj, jk, jl    ! dummy loop indices
68      INTEGER  ::   i_ice_switch
69      REAL(wp) ::   zh, zsal
70      !
71      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
72      !!-------------------------------------------------------------------
73      IF( nn_timing == 1 )  CALL timing_start('limupdate2')
74
75      IF( kt == nit000 .AND. lwp ) THEN
76         WRITE(numout,*) ' lim_update2 '
77         WRITE(numout,*) ' ~~~~~~~~~~~ '
78      ENDIF
79
80      ! conservation test
81      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limupdate2', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
82
83      !-----------------
84      ! zap small values
85      !-----------------
86      CALL lim_var_agg( 1 )
87      CALL lim_var_zapsmall
88      CALL lim_var_glo2eqv
89
90      !----------------------------------------------------
91      ! Rebin categories with thickness out of bounds
92      !----------------------------------------------------
93      IF ( jpl > 1 )   CALL lim_itd_th_reb(1, jpl)
94
95      !----------------------------------------------------------------------
96      ! Constrain the thickness of the smallest category above hiclim
97      !----------------------------------------------------------------------
98      DO jj = 1, jpj 
99         DO ji = 1, jpi
100            IF( v_i(ji,jj,1) > 0._wp .AND. ht_i(ji,jj,1) < hiclim ) THEN
101               zh             = hiclim / ht_i(ji,jj,1)
102               ht_s(ji,jj,1) = ht_s(ji,jj,1) * zh
103               ht_i(ji,jj,1) = ht_i(ji,jj,1) * zh
104               a_i (ji,jj,1) = a_i(ji,jj,1)  / zh
105            ENDIF
106         END DO
107      END DO
108     
109      !-----------------------------------------------------
110      ! ice concentration should not exceed amax
111      !-----------------------------------------------------
112      at_i(:,:) = 0._wp
113      DO jl = 1, jpl
114         at_i(:,:) = a_i(:,:,jl) + at_i(:,:)
115      END DO
116
117      DO jl  = 1, jpl
118         DO jj = 1, jpj
119            DO ji = 1, jpi
120               IF( at_i(ji,jj) > amax .AND. a_i(ji,jj,jl) > 0._wp ) THEN
121                  a_i(ji,jj,jl)  = a_i(ji,jj,jl) * ( 1._wp - ( 1._wp - amax / at_i(ji,jj) ) )
122                  ht_i(ji,jj,jl) = v_i(ji,jj,jl) / a_i(ji,jj,jl)
123               ENDIF
124            END DO
125         END DO
126      END DO
127
128      at_i(:,:) = 0.0
129      DO jl = 1, jpl
130         at_i(:,:) = a_i(:,:,jl) + at_i(:,:)
131      END DO
132
133      ! --------------------------------------
134      ! Final thickness distribution rebinning
135      ! --------------------------------------
136      IF ( jpl > 1 ) CALL lim_itd_th_reb( 1, jpl )
137
138      !-----------------
139      ! zap small values
140      !-----------------
141      CALL lim_var_zapsmall
142
143      !---------------------
144      ! 2.11) Ice salinity
145      !---------------------
146      IF (  num_sal == 2  ) THEN
147         DO jl = 1, jpl
148            DO jj = 1, jpj 
149               DO ji = 1, jpi
150                  zsal            = smv_i(ji,jj,jl)
151                  smv_i(ji,jj,jl) = sm_i(ji,jj,jl) * v_i(ji,jj,jl)
152                  ! salinity stays in bounds
153                  i_ice_switch    = 1._wp - MAX( 0._wp, SIGN( 1._wp, - v_i(ji,jj,jl) ) )
154                  smv_i(ji,jj,jl) = i_ice_switch * MAX( MIN( s_i_max * v_i(ji,jj,jl), smv_i(ji,jj,jl) ), s_i_min * v_i(ji,jj,jl) ) !+ s_i_min * ( 1._wp - i_ice_switch ) * v_i(ji,jj,jl)
155                  ! associated salt flux
156                  sfx_res(ji,jj) = sfx_res(ji,jj) - ( smv_i(ji,jj,jl) - zsal ) * rhoic * r1_rdtice
157               END DO ! ji
158            END DO ! jj
159         END DO !jl
160      ENDIF
161
162      !------------------------------------------------------------------------------
163      ! 2) Corrections to avoid wrong values                                        |
164      !------------------------------------------------------------------------------
165      ! Ice drift
166      !------------
167      DO jj = 2, jpjm1
168         DO ji = 2, jpim1
169            IF ( at_i(ji,jj) == 0._wp ) THEN ! what to do if there is no ice
170               IF ( at_i(ji+1,jj) == 0._wp ) u_ice(ji,jj)   = 0._wp ! right side
171               IF ( at_i(ji-1,jj) == 0._wp ) u_ice(ji-1,jj) = 0._wp ! left side
172               IF ( at_i(ji,jj+1) == 0._wp ) v_ice(ji,jj)   = 0._wp ! upper side
173               IF ( at_i(ji,jj-1) == 0._wp ) v_ice(ji,jj-1) = 0._wp ! bottom side
174            ENDIF
175         END DO
176      END DO
177      !lateral boundary conditions
178      CALL lbc_lnk( u_ice(:,:), 'U', -1. )
179      CALL lbc_lnk( v_ice(:,:), 'V', -1. )
180      !mask velocities
181      u_ice(:,:) = u_ice(:,:) * tmu(:,:)
182      v_ice(:,:) = v_ice(:,:) * tmv(:,:)
183 
184      ! for outputs
185      CALL lim_var_glo2eqv            ! equivalent variables (outputs)
186      CALL lim_var_agg(2)             ! aggregate ice thickness categories
187
188      ! -------------------------------------------------
189      ! Diagnostics
190      ! -------------------------------------------------
191      DO jl  = 1, jpl
192         afx_thd(:,:) = afx_thd(:,:) + ( a_i(:,:,jl) - a_i_b(:,:,jl) ) * r1_rdtice
193      END DO
194      afx_tot = afx_thd + afx_dyn
195
196      d_a_i_thd(:,:,:)   = a_i(:,:,:)   - a_i_b(:,:,:) 
197      d_v_s_thd(:,:,:)   = v_s(:,:,:)   - v_s_b(:,:,:)
198      d_v_i_thd(:,:,:)   = v_i(:,:,:)   - v_i_b(:,:,:) 
199      d_e_s_thd(:,:,:,:) = e_s(:,:,:,:) - e_s_b(:,:,:,:) 
200      d_e_i_thd(:,:,1:nlay_i,:) = e_i(:,:,1:nlay_i,:) - e_i_b(:,:,1:nlay_i,:)
201      !?? d_oa_i_thd(:,:,:)  = oa_i (:,:,:) - oa_i_b (:,:,:)
202      d_smv_i_thd(:,:,:) = 0._wp
203      IF( num_sal == 2 )   d_smv_i_thd(:,:,:) = smv_i(:,:,:) - smv_i_b(:,:,:)
204
205      ! heat content variation (W.m-2)
206      DO jj = 1, jpj
207         DO ji = 1, jpi           
208            diag_heat_dhc(ji,jj) = ( SUM( d_e_i_trp(ji,jj,1:nlay_i,:) + d_e_i_thd(ji,jj,1:nlay_i,:) ) +  & 
209               &                     SUM( d_e_s_trp(ji,jj,1:nlay_s,:) + d_e_s_thd(ji,jj,1:nlay_s,:) )    &
210               &                   ) * unit_fac * r1_rdtice / area(ji,jj)   
211         END DO
212      END DO
213
214      ! conservation test
215      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limupdate2', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
216
217      IF( ln_nicep )   CALL lim_prt( kt, jiindx, jjindx, 2, ' - Final state - ' )   ! control print
218
219      IF(ln_ctl) THEN   ! Control print
220         CALL prt_ctl_info(' ')
221         CALL prt_ctl_info(' - Cell values : ')
222         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
223         CALL prt_ctl(tab2d_1=area       , clinfo1=' lim_update2  : cell area   :')
224         CALL prt_ctl(tab2d_1=at_i       , clinfo1=' lim_update2  : at_i        :')
225         CALL prt_ctl(tab2d_1=vt_i       , clinfo1=' lim_update2  : vt_i        :')
226         CALL prt_ctl(tab2d_1=vt_s       , clinfo1=' lim_update2  : vt_s        :')
227         CALL prt_ctl(tab2d_1=strength   , clinfo1=' lim_update2  : strength    :')
228         CALL prt_ctl(tab2d_1=u_ice      , clinfo1=' lim_update2  : u_ice       :', tab2d_2=v_ice      , clinfo2=' v_ice       :')
229         CALL prt_ctl(tab2d_1=u_ice_b    , clinfo1=' lim_update2  : u_ice_b     :', tab2d_2=v_ice_b    , clinfo2=' v_ice_b     :')
230
231         DO jl = 1, jpl
232            CALL prt_ctl_info(' ')
233            CALL prt_ctl_info(' - Category : ', ivar1=jl)
234            CALL prt_ctl_info('   ~~~~~~~~~~')
235            CALL prt_ctl(tab2d_1=ht_i       (:,:,jl)        , clinfo1= ' lim_update2  : ht_i        : ')
236            CALL prt_ctl(tab2d_1=ht_s       (:,:,jl)        , clinfo1= ' lim_update2  : ht_s        : ')
237            CALL prt_ctl(tab2d_1=t_su       (:,:,jl)        , clinfo1= ' lim_update2  : t_su        : ')
238            CALL prt_ctl(tab2d_1=t_s        (:,:,1,jl)      , clinfo1= ' lim_update2  : t_snow      : ')
239            CALL prt_ctl(tab2d_1=sm_i       (:,:,jl)        , clinfo1= ' lim_update2  : sm_i        : ')
240            CALL prt_ctl(tab2d_1=o_i        (:,:,jl)        , clinfo1= ' lim_update2  : o_i         : ')
241            CALL prt_ctl(tab2d_1=a_i        (:,:,jl)        , clinfo1= ' lim_update2  : a_i         : ')
242            CALL prt_ctl(tab2d_1=a_i_b      (:,:,jl)        , clinfo1= ' lim_update2  : a_i_b       : ')
243            CALL prt_ctl(tab2d_1=d_a_i_thd  (:,:,jl)        , clinfo1= ' lim_update2  : d_a_i_thd   : ')
244            CALL prt_ctl(tab2d_1=v_i        (:,:,jl)        , clinfo1= ' lim_update2  : v_i         : ')
245            CALL prt_ctl(tab2d_1=v_i_b      (:,:,jl)        , clinfo1= ' lim_update2  : v_i_b       : ')
246            CALL prt_ctl(tab2d_1=d_v_i_thd  (:,:,jl)        , clinfo1= ' lim_update2  : d_v_i_thd   : ')
247            CALL prt_ctl(tab2d_1=v_s        (:,:,jl)        , clinfo1= ' lim_update2  : v_s         : ')
248            CALL prt_ctl(tab2d_1=v_s_b      (:,:,jl)        , clinfo1= ' lim_update2  : v_s_b       : ')
249            CALL prt_ctl(tab2d_1=d_v_s_thd  (:,:,jl)        , clinfo1= ' lim_update2  : d_v_s_thd   : ')
250            CALL prt_ctl(tab2d_1=e_i        (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : e_i1        : ')
251            CALL prt_ctl(tab2d_1=e_i_b      (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : e_i1_b      : ')
252            CALL prt_ctl(tab2d_1=d_e_i_thd  (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : de_i1_thd   : ')
253            CALL prt_ctl(tab2d_1=e_i        (:,:,2,jl)/1.0e9, clinfo1= ' lim_update2  : e_i2        : ')
254            CALL prt_ctl(tab2d_1=e_i_b      (:,:,2,jl)/1.0e9, clinfo1= ' lim_update2  : e_i2_b      : ')
255            CALL prt_ctl(tab2d_1=d_e_i_thd  (:,:,2,jl)/1.0e9, clinfo1= ' lim_update2  : de_i2_thd   : ')
256            CALL prt_ctl(tab2d_1=e_s        (:,:,1,jl)      , clinfo1= ' lim_update2  : e_snow      : ')
257            CALL prt_ctl(tab2d_1=e_s_b      (:,:,1,jl)      , clinfo1= ' lim_update2  : e_snow_b    : ')
258            CALL prt_ctl(tab2d_1=d_e_s_thd  (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : d_e_s_thd   : ')
259            CALL prt_ctl(tab2d_1=smv_i      (:,:,jl)        , clinfo1= ' lim_update2  : smv_i       : ')
260            CALL prt_ctl(tab2d_1=smv_i_b    (:,:,jl)        , clinfo1= ' lim_update2  : smv_i_b     : ')
261            CALL prt_ctl(tab2d_1=d_smv_i_thd(:,:,jl)        , clinfo1= ' lim_update2  : d_smv_i_thd : ')
262            CALL prt_ctl(tab2d_1=oa_i       (:,:,jl)        , clinfo1= ' lim_update2  : oa_i        : ')
263            CALL prt_ctl(tab2d_1=oa_i_b     (:,:,jl)        , clinfo1= ' lim_update2  : oa_i_b      : ')
264            CALL prt_ctl(tab2d_1=d_oa_i_thd (:,:,jl)        , clinfo1= ' lim_update2  : d_oa_i_thd  : ')
265
266            DO jk = 1, nlay_i
267               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
268               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_update2  : t_i       : ')
269            END DO
270         END DO
271
272         CALL prt_ctl_info(' ')
273         CALL prt_ctl_info(' - Heat / FW fluxes : ')
274         CALL prt_ctl_info('   ~~~~~~~~~~~~~~~~~~ ')
275         CALL prt_ctl(tab2d_1=sst_m  , clinfo1= ' lim_update2 : sst   : ', tab2d_2=sss_m     , clinfo2= ' sss       : ')
276
277         CALL prt_ctl_info(' ')
278         CALL prt_ctl_info(' - Stresses : ')
279         CALL prt_ctl_info('   ~~~~~~~~~~ ')
280         CALL prt_ctl(tab2d_1=utau       , clinfo1= ' lim_update2 : utau      : ', tab2d_2=vtau       , clinfo2= ' vtau      : ')
281         CALL prt_ctl(tab2d_1=utau_ice   , clinfo1= ' lim_update2 : utau_ice  : ', tab2d_2=vtau_ice   , clinfo2= ' vtau_ice  : ')
282         CALL prt_ctl(tab2d_1=u_oce      , clinfo1= ' lim_update2 : u_oce     : ', tab2d_2=v_oce      , clinfo2= ' v_oce     : ')
283      ENDIF
284   
285      IF( nn_timing == 1 )  CALL timing_stop('limupdate2')
286
287   END SUBROUTINE lim_update2
288#else
289   !!----------------------------------------------------------------------
290   !!   Default option         Empty Module               No sea-ice model
291   !!----------------------------------------------------------------------
292CONTAINS
293   SUBROUTINE lim_update2     ! Empty routine
294   END SUBROUTINE lim_update2
295
296#endif
297
298END MODULE limupdate2
Note: See TracBrowser for help on using the repository browser.