source: branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 5122

Last change on this file since 5122 was 5122, checked in by vancop, 6 years ago

fixes to verify SETTE tests. Evt ok, except SAS (no solver) and ORCA_AGRIF_LIM (compiler crash)

  • Property svn:keywords set to Id
File size: 31.1 KB
Line 
1MODULE sbcice_lim
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim  ***
4   !! Surface module :  update the ocean surface boundary condition over ice
5   !!       &           covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM-3 Sea ice model time-stepping
7   !!=====================================================================
8   !! History :  2.0  ! 2006-12  (M. Vancoppenolle) Original code
9   !!            3.0  ! 2008-02  (C. Talandier)  Surface module from icestp.F90
10   !!             -   ! 2008-04  (G. Madec)  sltyle and lim_ctl routine
11   !!            3.3  ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!            3.4  ! 2011-01  (A Porter)  dynamical allocation
13   !!             -   ! 2012-10  (C. Rousset)  add lim_diahsb
14   !!            3.6  ! 2014-07  (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3' :                                  LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   sbc_ice_lim  : sea-ice model time-stepping and update ocean sbc over ice-covered area
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ice             ! LIM-3: ice variables
25   USE thd_ice         ! LIM-3: thermodynamical variables
26   USE dom_ice         ! LIM-3: ice domain
27
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE sbc_ice         ! Surface boundary condition: ice   fields
30   USE sbcblk_core     ! Surface boundary condition: CORE bulk
31   USE sbcblk_clio     ! Surface boundary condition: CLIO bulk
32   USE sbccpl          ! Surface boundary condition: coupled interface
33   USE albedo          ! ocean & ice albedo
34
35   USE phycst          ! Define parameters for the routines
36   USE eosbn2          ! equation of state
37   USE limdyn          ! Ice dynamics
38   USE limtrp          ! Ice transport
39   USE limthd          ! Ice thermodynamics
40   USE limitd_me       ! Mechanics on ice thickness distribution
41   USE limsbc          ! sea surface boundary condition
42   USE limdiahsb       ! Ice budget diagnostics
43   USE limwri          ! Ice outputs
44   USE limrst          ! Ice restarts
45   USE limupdate1      ! update of global variables
46   USE limupdate2      ! update of global variables
47   USE limvar          ! Ice variables switch
48
49   USE limmsh          ! LIM mesh
50   USE limistate       ! LIM initial state
51   USE limthd_sal      ! LIM ice thermodynamics: salinity
52
53   USE c1d             ! 1D vertical configuration
54   USE lbclnk          ! lateral boundary condition - MPP link
55   USE lib_mpp         ! MPP library
56   USE wrk_nemo        ! work arrays
57   USE timing          ! Timing
58   USE iom             ! I/O manager library
59   USE in_out_manager  ! I/O manager
60   USE prtctl          ! Print control
61   USE lib_fortran     !
62   USE limctl
63
64#if defined key_bdy 
65   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
66#endif
67
68   IMPLICIT NONE
69   PRIVATE
70
71   PUBLIC sbc_ice_lim  ! routine called by sbcmod.F90
72   PUBLIC sbc_lim_init ! routine called by sbcmod.F90
73   
74   !! * Substitutions
75#  include "domzgr_substitute.h90"
76#  include "vectopt_loop_substitute.h90"
77   !!----------------------------------------------------------------------
78   !! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
79   !! $Id$
80   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
81   !!----------------------------------------------------------------------
82CONTAINS
83
84   !!======================================================================
85
86   SUBROUTINE sbc_ice_lim( kt, kblk )
87      !!---------------------------------------------------------------------
88      !!                  ***  ROUTINE sbc_ice_lim  ***
89      !!                   
90      !! ** Purpose :   update the ocean surface boundary condition via the
91      !!                Louvain la Neuve Sea Ice Model time stepping
92      !!
93      !! ** Method  :   ice model time stepping
94      !!              - call the ice dynamics routine
95      !!              - call the ice advection/diffusion routine
96      !!              - call the ice thermodynamics routine
97      !!              - call the routine that computes mass and
98      !!                heat fluxes at the ice/ocean interface
99      !!              - save the outputs
100      !!              - save the outputs for restart when necessary
101      !!
102      !! ** Action  : - time evolution of the LIM sea-ice model
103      !!              - update all sbc variables below sea-ice:
104      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
105      !!---------------------------------------------------------------------
106      INTEGER, INTENT(in) ::   kt      ! ocean time step
107      INTEGER, INTENT(in) ::   kblk    ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
108      !!
109      INTEGER  ::   jl                 ! dummy loop index
110      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_os, zalb_cs  ! ice albedo under overcast/clear sky
111      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_ice          ! mean ice albedo (for coupled)
112      !!----------------------------------------------------------------------
113
114      IF( nn_timing == 1 )  CALL timing_start('sbc_ice_lim')
115
116      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !  Ice time-step only
117         !-----------------------!                                           
118         ! --- Bulk Formulae --- !                                           
119         !-----------------------!
120         u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)      ! mean surface ocean current at ice velocity point
121         v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)      ! (C-grid dynamics :  U- & V-points as the ocean)
122         
123         ! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
124         t_bo(:,:) = ( eos_fzp( sss_m ) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) ) 
125         !                                                                                     
126         ! Ice albedo
127         CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
128         CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os )  ! cloud-sky and overcast-sky ice albedos
129
130         ! CORE and COUPLED bulk formulations
131         SELECT CASE( kblk )
132         CASE( jp_core , jp_cpl )
133
134            ! albedo depends on cloud fraction because of non-linear spectral effects
135            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
136            ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
137            ! (zalb_ice) is computed within the bulk routine
138           
139         END SELECT
140         
141         ! Mask sea ice surface temperature (set to rt0 over land)
142         DO jl = 1, jpl
143            t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
144         END DO
145     
146         ! Bulk formulae  - provides the following fields:
147         ! utau_ice, vtau_ice : surface ice stress                     (U- & V-points)   [N/m2]
148         ! qsr_ice , qns_ice  : solar & non solar heat flux over ice   (T-point)         [W/m2]
149         ! qla_ice            : latent heat flux over ice              (T-point)         [W/m2]
150         ! dqns_ice, dqla_ice : non solar & latent heat sensistivity   (T-point)         [W/m2]
151         ! tprecip , sprecip  : total & solid precipitation            (T-point)         [Kg/m2/s]
152         ! fr1_i0  , fr2_i0   : 1sr & 2nd fraction of qsr penetration in ice             [%]
153         !
154         SELECT CASE( kblk )
155         CASE( jp_clio )                                       ! CLIO bulk formulation
156            CALL blk_ice_clio( t_su , zalb_cs    , zalb_os    , zalb_ice  ,               &
157               &                      utau_ice   , vtau_ice   , qns_ice   , qsr_ice   ,   &
158               &                      qla_ice    , dqns_ice   , dqla_ice  ,               &
159               &                      tprecip    , sprecip    ,                           &
160               &                      fr1_i0     , fr2_i0     , cp_ice_msh, jpl  )
161            !         
162            IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
163               &                                           dqns_ice, qla_ice, dqla_ice, nn_limflx )
164
165         CASE( jp_core )                                       ! CORE bulk formulation
166            CALL blk_ice_core( t_su , u_ice     , v_ice     , zalb_ice   ,               &
167               &                      utau_ice  , vtau_ice  , qns_ice    , qsr_ice   ,   &
168               &                      qla_ice   , dqns_ice  , dqla_ice   ,               &
169               &                      tprecip   , sprecip   ,                            &
170               &                      fr1_i0    , fr2_i0    , cp_ice_msh, jpl  )
171               !
172            IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
173               &                                           dqns_ice, qla_ice, dqla_ice, nn_limflx )
174            !
175         CASE ( jp_cpl )
176           
177            CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )
178
179         END SELECT
180         
181         !------------------------------!
182         ! --- LIM-3 main time-step --- !
183         !------------------------------!
184         numit = numit + nn_fsbc                     ! Ice model time step
185         !                                                   
186         CALL sbc_lim_update                ! Store previous ice values
187
188         CALL sbc_lim_diag0                 ! set diag of mass, heat and salt fluxes to 0
189         
190         CALL lim_rst_opn( kt )             ! Open Ice restart file
191         !
192         ! ----------------------------------------------
193         ! ice dynamics and transport (except in 1D case)
194         ! ----------------------------------------------
195         IF( .NOT. lk_c1d ) THEN
196           
197            CALL lim_dyn( kt )              ! Ice dynamics    ( rheology/dynamics )
198           
199            CALL lim_trp( kt )              ! Ice transport   ( Advection/diffusion )
200           
201            IF( nn_monocat /= 2 ) CALL lim_itd_me  ! Mechanical redistribution ! (ridging/rafting)
202
203#if defined key_bdy
204            CALL lim_var_glo2eqv
205            CALL bdy_ice_lim( kt )         ! bdy ice thermo
206            CALL lim_var_zapsmall
207            CALL lim_var_agg(1)
208            IF( ln_nicep )   CALL lim_prt( kt, jiindx, jjindx, 1, ' - ice thermo bdy - ' )
209#endif
210            CALL lim_update1( kt )
211           
212         ENDIF
213         
214         CALL sbc_lim_update                ! Store previous ice values
215 
216         ! ----------------------------------------------
217         ! ice thermodynamics
218         ! ----------------------------------------------
219         CALL lim_var_glo2eqv
220         CALL lim_var_agg(1)
221         
222         ! previous lead fraction and ice volume for flux calculations
223         pfrld(:,:)   = 1._wp - at_i(:,:)
224         phicif(:,:)  = vt_i(:,:)
225         
226         SELECT CASE( kblk )
227         CASE ( jp_cpl )
228            CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su    )
229            IF( nn_limflx == 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
230               &                                           dqns_ice, qla_ice, dqla_ice, nn_limflx )
231            ! Latent heat flux is forced to 0 in coupled: it is included in qns (non-solar heat flux)
232            qla_ice  (:,:,:) = 0._wp
233            dqla_ice (:,:,:) = 0._wp
234         END SELECT
235         !
236         CALL lim_thd( kt )                         ! Ice thermodynamics
237         
238         CALL lim_update2( kt )                     ! Corrections
239         !
240         CALL lim_sbc_flx( kt )                     ! Update surface ocean mass, heat and salt fluxes
241         !
242         IF(ln_limdiaout) CALL lim_diahsb           ! Diagnostics and outputs
243         
244         CALL lim_wri( 1 )                          ! Ice outputs
245         
246         IF( kt == nit000 .AND. ln_rstart )   &
247            &             CALL iom_close( numrir )  ! close input ice restart file
248         !
249         IF( lrst_ice )   CALL lim_rst_write( kt )  ! Ice restart file
250         CALL lim_var_glo2eqv                       ! ???
251         !
252         IF( ln_nicep )   CALL lim_ctl( kt )        ! alerts in case of model crash
253         !
254         CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
255         !
256      ENDIF   ! End sea-ice time step only
257
258      !--------------------------------!
259      ! --- at all ocean time step --- !
260      !--------------------------------!
261      ! Update surface ocean stresses (only in ice-dynamic case)
262      !    otherwise the atm.-ocean stresses are used everywhere
263      IF( ln_limdyn )     CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
264!!gm   remark, the ocean-ice stress is not saved in ice diag call above .....  find a solution!!!
265      !
266      IF( nn_timing == 1 )  CALL timing_stop('sbc_ice_lim')
267      !
268   END SUBROUTINE sbc_ice_lim
269   
270
271   SUBROUTINE sbc_lim_init
272      !!----------------------------------------------------------------------
273      !!                  ***  ROUTINE sbc_lim_init  ***
274      !!
275      !! ** purpose :   Allocate all the dynamic arrays of the LIM-3 modules
276      !!----------------------------------------------------------------------
277      INTEGER :: ierr
278      !!----------------------------------------------------------------------
279      IF(lwp) WRITE(numout,*)
280      IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition' 
281      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM-3) time stepping'
282      !
283                                       ! Open the reference and configuration namelist files and namelist output file
284      CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp ) 
285      CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
286      IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
287
288      CALL ice_run                     ! set some ice run parameters
289      !
290      !                                ! Allocate the ice arrays
291      ierr =        ice_alloc        ()      ! ice variables
292      ierr = ierr + dom_ice_alloc    ()      ! domain
293      ierr = ierr + sbc_ice_alloc    ()      ! surface forcing
294      ierr = ierr + thd_ice_alloc    ()      ! thermodynamics
295      ierr = ierr + lim_itd_me_alloc ()      ! ice thickness distribution - mechanics
296      !
297      IF( lk_mpp    )   CALL mpp_sum( ierr )
298      IF( ierr /= 0 )   CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
299      !
300      !                                ! adequation jpk versus ice/snow layers/categories
301      IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk )   &
302         &      CALL ctl_stop( 'STOP',                          &
303         &     'sbc_lim_init: the 3rd dimension of workspace arrays is too small.',   &
304         &     'use more ocean levels or less ice/snow layers/categories.' )
305      !
306      CALL lim_itd_init                ! ice thickness distribution initialization
307      !
308      CALL lim_thd_init                ! set ice thermodynics parameters
309      !
310      CALL lim_thd_sal_init            ! set ice salinity parameters
311      !
312      CALL lim_msh                     ! ice mesh initialization
313      !
314      CALL lim_itd_me_init             ! ice thickness distribution initialization for mecanical deformation
315      !                                ! Initial sea-ice state
316      IF( .NOT. ln_rstart ) THEN              ! start from rest: sea-ice deduced from sst
317         numit = 0
318         numit = nit000 - 1
319         CALL lim_istate
320      ELSE                                    ! start from a restart file
321         CALL lim_rst_read
322         numit = nit000 - 1
323      ENDIF
324      CALL lim_var_agg(1)
325      CALL lim_var_glo2eqv
326      !
327      CALL lim_sbc_init                 ! ice surface boundary condition   
328      !
329      fr_i(:,:)     = at_i(:,:)         ! initialisation of sea-ice fraction
330      tn_ice(:,:,:) = t_su(:,:,:)       ! initialisation of surface temp for coupled simu
331      !
332      nstart = numit  + nn_fsbc     
333      nitrun = nitend - nit000 + 1 
334      nlast  = numit  + nitrun 
335      !
336      IF( nstock == 0 )   nstock = nlast + 1
337      !
338   END SUBROUTINE sbc_lim_init
339
340
341   SUBROUTINE ice_run
342      !!-------------------------------------------------------------------
343      !!                  ***  ROUTINE ice_run ***
344      !!                 
345      !! ** Purpose :   Definition some run parameter for ice model
346      !!
347      !! ** Method  :   Read the namicerun namelist and check the parameter
348      !!              values called at the first timestep (nit000)
349      !!
350      !! ** input   :   Namelist namicerun
351      !!-------------------------------------------------------------------
352      INTEGER  ::   ios                 ! Local integer output status for namelist read
353      NAMELIST/namicerun/ jpl, nlay_i, nlay_s, cn_icerst_in, cn_icerst_out,   &
354         &                ln_limdyn, rn_amax, ln_nicep, ln_limdiahsb, ln_limdiaout
355      !!-------------------------------------------------------------------
356      !                   
357      REWIND( numnam_ice_ref )              ! Namelist namicerun in reference namelist : Parameters for ice
358      READ  ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
359901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
360
361      REWIND( numnam_ice_cfg )              ! Namelist namicerun in configuration namelist : Parameters for ice
362      READ  ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
363902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
364      IF(lwm) WRITE ( numoni, namicerun )
365      !
366      !
367      IF(lwp) THEN                        ! control print
368         WRITE(numout,*)
369         WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice'
370         WRITE(numout,*) ' ~~~~~~'
371         WRITE(numout,*) '   number of ice  categories                               = ', jpl
372         WRITE(numout,*) '   number of ice  layers                                   = ', nlay_i
373         WRITE(numout,*) '   number of snow layers                                   = ', nlay_s
374         WRITE(numout,*) '   switch for ice dynamics (1) or not (0)      ln_limdyn   = ', ln_limdyn
375         WRITE(numout,*) '   maximum ice concentration                               = ', rn_amax 
376         WRITE(numout,*) '   Several ice points in the ice or not in ocean.output    = ', ln_nicep
377         WRITE(numout,*) '   Diagnose heat/salt budget or not          ln_limdiahsb  = ', ln_limdiahsb
378         WRITE(numout,*) '   Output   heat/salt budget or not          ln_limdiaout  = ', ln_limdiaout
379      ENDIF
380      !
381      !IF( lk_mpp .AND. ln_nicep ) THEN
382      !   ln_nicep = .FALSE.
383      !   CALL ctl_warn( 'ice_run : specific control print for LIM3 desactivated with MPI' )
384      !ENDIF
385      IF( ln_nicep ) THEN      ! control print at a given point
386         jiindx = 15    ;   jjindx =  44
387         IF(lwp) WRITE(numout,*) ' The debugging point is : jiindx : ',jiindx, ' jjindx : ',jjindx
388      ENDIF
389      !
390      ! sea-ice timestep and inverse
391      rdt_ice   = nn_fsbc * rdttra(1) 
392      r1_rdtice = 1._wp / rdt_ice 
393
394      ! inverse of nlay_i and nlay_s
395      r1_nlay_i = 1._wp / REAL( nlay_i, wp )
396      r1_nlay_s = 1._wp / REAL( nlay_s, wp )
397      !
398   END SUBROUTINE ice_run
399
400
401   SUBROUTINE lim_itd_init
402      !!------------------------------------------------------------------
403      !!                ***  ROUTINE lim_itd_init ***
404      !!
405      !! ** Purpose :   Initializes the ice thickness distribution
406      !! ** Method  :   ...
407      !! ** input   :   Namelist namiceitd
408      !!-------------------------------------------------------------------
409      INTEGER  ::   ios                 ! Local integer output status for namelist read
410      NAMELIST/namiceitd/ nn_catbnd, rn_himean
411      !
412      INTEGER  ::   jl                   ! dummy loop index
413      REAL(wp) ::   zc1, zc2, zc3, zx1   ! local scalars
414      REAL(wp) ::   zhmax, znum, zden, zalpha !
415      !!------------------------------------------------------------------
416      !
417      REWIND( numnam_ice_ref )              ! Namelist namiceitd in reference namelist : Parameters for ice
418      READ  ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 903)
419903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
420
421      REWIND( numnam_ice_cfg )              ! Namelist namiceitd in configuration namelist : Parameters for ice
422      READ  ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 904 )
423904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
424      IF(lwm) WRITE ( numoni, namiceitd )
425      !
426      !
427      IF(lwp) THEN                        ! control print
428         WRITE(numout,*)
429         WRITE(numout,*) 'ice_itd : ice cat distribution'
430         WRITE(numout,*) ' ~~~~~~'
431         WRITE(numout,*) '   shape of ice categories distribution                          nn_catbnd = ', nn_catbnd
432         WRITE(numout,*) '   mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
433      ENDIF
434
435      !----------------------------------
436      !- Thickness categories boundaries
437      !----------------------------------
438      IF(lwp) WRITE(numout,*)
439      IF(lwp) WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
440      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
441
442      hi_max(:) = 0._wp
443
444      SELECT CASE ( nn_catbnd  )       
445                                   !----------------------
446         CASE (1)                  ! tanh function (CICE)
447                                   !----------------------
448         zc1 =  3._wp / REAL( jpl, wp )
449         zc2 = 10._wp * zc1
450         zc3 =  3._wp
451
452         DO jl = 1, jpl
453            zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
454            hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
455         END DO
456
457                                   !----------------------
458         CASE (2)                  ! h^(-alpha) function
459                                   !----------------------
460         zalpha = 0.05             ! exponent of the transform function
461
462         zhmax  = 3.*rn_himean
463
464         DO jl = 1, jpl 
465            znum = jpl * ( zhmax+1 )**zalpha
466            zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
467            hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
468         END DO
469
470      END SELECT
471
472      DO jl = 1, jpl
473         hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
474      END DO
475
476      ! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
477      hi_max(jpl) = 99._wp
478
479      IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
480      IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
481      !
482   END SUBROUTINE lim_itd_init
483
484   
485   SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice,   &
486         &                          pdqn_ice, pqla_ice, pdql_ice, k_limflx )
487      !!---------------------------------------------------------------------
488      !!                  ***  ROUTINE ice_lim_flx  ***
489      !!                   
490      !! ** Purpose :   update the ice surface boundary condition by averaging and / or
491      !!                redistributing fluxes on ice categories                   
492      !!
493      !! ** Method  :   average then redistribute
494      !!
495      !! ** Action  :   
496      !!---------------------------------------------------------------------
497      INTEGER                   , INTENT(in   ) ::   k_limflx   ! =-1 do nothing; =0 average ;
498                                                                ! =1 average and redistribute ; =2 redistribute
499      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
500      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
501      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
502      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
503      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
504      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqla_ice   ! latent heat flux
505      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdql_ice   ! latent heat flux sensitivity
506      !
507      INTEGER  ::   jl      ! dummy loop index
508      !
509      REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m    ! Mean albedo over all categories
510      REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m    ! Mean temperature over all categories
511      !
512      REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m   ! Mean solar heat flux over all categories
513      REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m   ! Mean non solar heat flux over all categories
514      REAL(wp), POINTER, DIMENSION(:,:) :: z_qla_m   ! Mean latent heat flux over all categories
515      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m   ! Mean d(qns)/dT over all categories
516      REAL(wp), POINTER, DIMENSION(:,:) :: z_dql_m   ! Mean d(qla)/dT over all categories
517      !!----------------------------------------------------------------------
518
519      IF( nn_timing == 1 )  CALL timing_start('ice_lim_flx')
520      !
521      !
522      SELECT CASE( k_limflx )                              !==  averaged on all ice categories  ==!
523      CASE( 0 , 1 )
524         CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_qla_m, z_dqn_m, z_dql_m)
525         !
526         z_qns_m(:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
527         z_qsr_m(:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
528         z_dqn_m(:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
529         z_qla_m(:,:) = fice_ice_ave ( pqla_ice (:,:,:) )
530         z_dql_m(:,:) = fice_ice_ave ( pdql_ice (:,:,:) )
531         DO jl = 1, jpl
532            pdqn_ice(:,:,jl) = z_dqn_m(:,:)
533            pdql_ice(:,:,jl) = z_dql_m(:,:)
534         END DO
535         !
536         DO jl = 1, jpl
537            pqns_ice(:,:,jl) = z_qns_m(:,:)
538            pqsr_ice(:,:,jl) = z_qsr_m(:,:)
539            pqla_ice(:,:,jl) = z_qla_m(:,:)
540         END DO
541         !
542         CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_qla_m, z_dqn_m, z_dql_m)
543      END SELECT
544
545      SELECT CASE( k_limflx )                              !==  redistribution on all ice categories  ==!
546      CASE( 1 , 2 )
547         CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
548         !
549         zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) ) 
550         ztem_m(:,:) = fice_ice_ave ( ptn_ice  (:,:,:) ) 
551         DO jl = 1, jpl
552            pqns_ice(:,:,jl) = pqns_ice(:,:,jl) + pdqn_ice(:,:,jl) * (ptn_ice(:,:,jl) - ztem_m(:,:))
553            pqla_ice(:,:,jl) = pqla_ice(:,:,jl) + pdql_ice(:,:,jl) * (ptn_ice(:,:,jl) - ztem_m(:,:))
554            pqsr_ice(:,:,jl) = pqsr_ice(:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) ) 
555         END DO
556         !
557         CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
558      END SELECT
559      !
560      IF( nn_timing == 1 )  CALL timing_stop('ice_lim_flx')
561      !
562   END SUBROUTINE ice_lim_flx
563
564   SUBROUTINE sbc_lim_update
565      !!----------------------------------------------------------------------
566      !!                  ***  ROUTINE sbc_lim_update  ***
567      !!
568      !! ** purpose :  store ice variables at "before" time step
569      !!----------------------------------------------------------------------
570      a_i_b  (:,:,:)   = a_i  (:,:,:)     ! ice area
571      e_i_b  (:,:,:,:) = e_i  (:,:,:,:)   ! ice thermal energy
572      v_i_b  (:,:,:)   = v_i  (:,:,:)     ! ice volume
573      v_s_b  (:,:,:)   = v_s  (:,:,:)     ! snow volume
574      e_s_b  (:,:,:,:) = e_s  (:,:,:,:)   ! snow thermal energy
575      smv_i_b(:,:,:)   = smv_i(:,:,:)     ! salt content
576      oa_i_b (:,:,:)   = oa_i (:,:,:)     ! areal age content
577      u_ice_b(:,:)     = u_ice(:,:)
578      v_ice_b(:,:)     = v_ice(:,:)
579     
580   END SUBROUTINE sbc_lim_update
581
582   SUBROUTINE sbc_lim_diag0
583      !!----------------------------------------------------------------------
584      !!                  ***  ROUTINE sbc_lim_diag0  ***
585      !!
586      !! ** purpose :  set ice-ocean and ice-atm. fluxes to zeros at the beggining
587      !!               of the time step
588      !!----------------------------------------------------------------------
589      sfx    (:,:) = 0._wp   ;
590      sfx_bri(:,:) = 0._wp   ; 
591      sfx_sni(:,:) = 0._wp   ;   sfx_opw(:,:) = 0._wp
592      sfx_bog(:,:) = 0._wp   ;   sfx_dyn(:,:) = 0._wp
593      sfx_bom(:,:) = 0._wp   ;   sfx_sum(:,:) = 0._wp
594      sfx_res(:,:) = 0._wp
595     
596      wfx_snw(:,:) = 0._wp   ;   wfx_ice(:,:) = 0._wp
597      wfx_sni(:,:) = 0._wp   ;   wfx_opw(:,:) = 0._wp
598      wfx_bog(:,:) = 0._wp   ;   wfx_dyn(:,:) = 0._wp
599      wfx_bom(:,:) = 0._wp   ;   wfx_sum(:,:) = 0._wp
600      wfx_res(:,:) = 0._wp   ;   wfx_sub(:,:) = 0._wp
601      wfx_spr(:,:) = 0._wp   ;   
602     
603      hfx_in (:,:) = 0._wp   ;   hfx_out(:,:) = 0._wp
604      hfx_thd(:,:) = 0._wp   ;   
605      hfx_snw(:,:) = 0._wp   ;   hfx_opw(:,:) = 0._wp
606      hfx_bog(:,:) = 0._wp   ;   hfx_dyn(:,:) = 0._wp
607      hfx_bom(:,:) = 0._wp   ;   hfx_sum(:,:) = 0._wp
608      hfx_res(:,:) = 0._wp   ;   hfx_sub(:,:) = 0._wp
609      hfx_spr(:,:) = 0._wp   ;   hfx_dif(:,:) = 0._wp 
610      hfx_err(:,:) = 0._wp   ;   hfx_err_rem(:,:) = 0._wp
611
612      afx_tot(:,:) = 0._wp   ;
613      afx_dyn(:,:) = 0._wp   ;   afx_thd(:,:) = 0._wp
614
615      diag_heat_dhc(:,:) = 0._wp ;
616     
617   END SUBROUTINE sbc_lim_diag0
618     
619   FUNCTION fice_cell_ave ( ptab )
620      !!--------------------------------------------------------------------------
621      !! * Compute average over categories, for grid cell (ice covered and free ocean)
622      !!--------------------------------------------------------------------------
623      REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
624      REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
625      INTEGER :: jl ! Dummy loop index
626     
627      fice_cell_ave (:,:) = 0.0_wp
628     
629      DO jl = 1, jpl
630         fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
631      END DO
632     
633   END FUNCTION fice_cell_ave
634   
635   
636   FUNCTION fice_ice_ave ( ptab )
637      !!--------------------------------------------------------------------------
638      !! * Compute average over categories, for ice covered part of grid cell
639      !!--------------------------------------------------------------------------
640      REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
641      REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
642
643      fice_ice_ave (:,:) = 0.0_wp
644      WHERE ( at_i (:,:) .GT. 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
645
646   END FUNCTION fice_ice_ave
647
648
649#else
650   !!----------------------------------------------------------------------
651   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
652   !!----------------------------------------------------------------------
653CONTAINS
654   SUBROUTINE sbc_ice_lim ( kt, kblk )     ! Dummy routine
655      WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
656   END SUBROUTINE sbc_ice_lim
657   SUBROUTINE sbc_lim_init                 ! Dummy routine
658   END SUBROUTINE sbc_lim_init
659#endif
660
661   !!======================================================================
662END MODULE sbcice_lim
Note: See TracBrowser for help on using the repository browser.