| 1 | MODULE step |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE step *** |
|---|
| 4 | !! Time-stepping : manager of the ocean, tracer and ice time stepping |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 (G. Madec) Original code |
|---|
| 7 | !! - ! 1991-11 (G. Madec) |
|---|
| 8 | !! - ! 1992-06 (M. Imbard) add a first output record |
|---|
| 9 | !! - ! 1996-04 (G. Madec) introduction of dynspg |
|---|
| 10 | !! - ! 1996-04 (M.A. Foujols) introduction of passive tracer |
|---|
| 11 | !! 8.0 ! 1997-06 (G. Madec) new architecture of call |
|---|
| 12 | !! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface |
|---|
| 13 | !! - ! 1999-02 (G. Madec, N. Grima) hpg implicit |
|---|
| 14 | !! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions |
|---|
| 15 | !! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking |
|---|
| 16 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 17 | !! - ! 2005-01 (C. Ethe) Add the KPP closure scheme |
|---|
| 18 | !! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls |
|---|
| 19 | !! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 20 | !! - ! 2006-07 (S. Masson) restart using iom |
|---|
| 21 | !! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate |
|---|
| 22 | !! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl |
|---|
| 23 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 24 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA |
|---|
| 25 | !! 3.4 ! 2011-04 (G. Madec, C. Ethe) Merge of dtatem and dtasal |
|---|
| 26 | !! ! 2012-07 (J. Simeon, G. Madec, C. Ethe) Online coarsening of outputs |
|---|
| 27 | !! 3.7 ! 2014-04 (F. Roquet, G. Madec) New equations of state |
|---|
| 28 | !!---------------------------------------------------------------------- |
|---|
| 29 | |
|---|
| 30 | !!---------------------------------------------------------------------- |
|---|
| 31 | !! stp : OPA system time-stepping |
|---|
| 32 | !!---------------------------------------------------------------------- |
|---|
| 33 | USE step_oce ! time stepping definition modules |
|---|
| 34 | USE iom |
|---|
| 35 | |
|---|
| 36 | IMPLICIT NONE |
|---|
| 37 | PRIVATE |
|---|
| 38 | |
|---|
| 39 | PUBLIC stp ! called by opa.F90 |
|---|
| 40 | |
|---|
| 41 | !! * Substitutions |
|---|
| 42 | # include "domzgr_substitute.h90" |
|---|
| 43 | !!gm # include "zdfddm_substitute.h90" |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | !! NEMO/OPA 3.7 , NEMO Consortium (2014) |
|---|
| 46 | !! $Id$ |
|---|
| 47 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | CONTAINS |
|---|
| 50 | |
|---|
| 51 | #if defined key_agrif |
|---|
| 52 | SUBROUTINE stp( ) |
|---|
| 53 | INTEGER :: kstp ! ocean time-step index |
|---|
| 54 | #else |
|---|
| 55 | SUBROUTINE stp( kstp ) |
|---|
| 56 | INTEGER, INTENT(in) :: kstp ! ocean time-step index |
|---|
| 57 | #endif |
|---|
| 58 | !!---------------------------------------------------------------------- |
|---|
| 59 | !! *** ROUTINE stp *** |
|---|
| 60 | !! |
|---|
| 61 | !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.) |
|---|
| 62 | !! - Time stepping of LIM (dynamic and thermodynamic eqs.) |
|---|
| 63 | !! - Tme stepping of TRC (passive tracer eqs.) |
|---|
| 64 | !! |
|---|
| 65 | !! ** Method : -1- Update forcings and data |
|---|
| 66 | !! -2- Update ocean physics |
|---|
| 67 | !! -3- Compute the t and s trends |
|---|
| 68 | !! -4- Update t and s |
|---|
| 69 | !! -5- Compute the momentum trends |
|---|
| 70 | !! -6- Update the horizontal velocity |
|---|
| 71 | !! -7- Compute the diagnostics variables (rd,N2, div,cur,w) |
|---|
| 72 | !! -8- Outputs and diagnostics |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | INTEGER :: jk ! dummy loop indice |
|---|
| 75 | INTEGER :: indic ! error indicator if < 0 |
|---|
| 76 | INTEGER :: kcall ! optional integer argument (dom_vvl_sf_nxt) |
|---|
| 77 | !! --------------------------------------------------------------------- |
|---|
| 78 | |
|---|
| 79 | #if defined key_agrif |
|---|
| 80 | kstp = nit000 + Agrif_Nb_Step() |
|---|
| 81 | ! IF ( Agrif_Root() .and. lwp) Write(*,*) '---' |
|---|
| 82 | ! IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp |
|---|
| 83 | IF ( kstp == (nit000 + 1) ) lk_agrif_fstep = .FALSE. |
|---|
| 84 | # if defined key_iomput |
|---|
| 85 | IF( Agrif_Nbstepint() == 0 ) CALL iom_swap( "nemo" ) |
|---|
| 86 | # endif |
|---|
| 87 | #endif |
|---|
| 88 | indic = 0 ! reset to no error condition |
|---|
| 89 | IF( kstp == nit000 ) THEN |
|---|
| 90 | CALL iom_init( "nemo" ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS) |
|---|
| 91 | IF( ln_crs ) CALL iom_init( "nemo_crs" ) ! initialize context for coarse grid |
|---|
| 92 | ENDIF |
|---|
| 93 | |
|---|
| 94 | IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 95 | CALL iom_setkt( kstp - nit000 + 1, "nemo" ) ! say to iom that we are at time step kstp |
|---|
| 96 | IF( ln_crs ) CALL iom_setkt( kstp - nit000 + 1, "nemo_crs" ) ! say to iom that we are at time step kstp |
|---|
| 97 | |
|---|
| 98 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 99 | ! Update data, open boundaries, surface boundary condition (including sea-ice) |
|---|
| 100 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 101 | IF( lk_tide ) CALL sbc_tide( kstp ) |
|---|
| 102 | IF( lk_bdy ) CALL bdy_dta ( kstp, time_offset=+1 ) ! update dynamic & tracer data at open boundaries |
|---|
| 103 | |
|---|
| 104 | CALL sbc ( kstp ) ! Sea Boundary Condition (including sea-ice) |
|---|
| 105 | ! clem: moved here for bdy ice purpose |
|---|
| 106 | |
|---|
| 107 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 108 | ! Ocean physics update (ua, va, tsa used as workspace) |
|---|
| 109 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 110 | ! THERMODYNAMICS |
|---|
| 111 | CALL eos_rab( tsb, rab_b ) ! before local thermal/haline expension ratio at T-points |
|---|
| 112 | CALL eos_rab( tsn, rab_n ) ! now local thermal/haline expension ratio at T-points |
|---|
| 113 | CALL bn2 ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency |
|---|
| 114 | CALL bn2 ( tsn, rab_n, rn2 ) ! now Brunt-Vaisala frequency |
|---|
| 115 | ! |
|---|
| 116 | ! VERTICAL PHYSICS |
|---|
| 117 | CALL zdf_bfr( kstp ) ! bottom friction (if quadratic) |
|---|
| 118 | ! ! Vertical eddy viscosity and diffusivity coefficients |
|---|
| 119 | IF( lk_zdfric ) CALL zdf_ric( kstp ) ! Richardson number dependent Kz |
|---|
| 120 | IF( lk_zdftke ) CALL zdf_tke( kstp ) ! TKE closure scheme for Kz |
|---|
| 121 | IF( lk_zdfgls ) CALL zdf_gls( kstp ) ! GLS closure scheme for Kz |
|---|
| 122 | IF( lk_zdfkpp ) CALL zdf_kpp( kstp ) ! KPP closure scheme for Kz |
|---|
| 123 | IF( lk_zdfcst ) THEN ! Constant Kz (reset avt, avm[uv] to the background value) |
|---|
| 124 | avt (:,:,:) = rn_avt0 * tmask(:,:,:) |
|---|
| 125 | avmu(:,:,:) = rn_avm0 * umask(:,:,:) |
|---|
| 126 | avmv(:,:,:) = rn_avm0 * vmask(:,:,:) |
|---|
| 127 | ENDIF |
|---|
| 128 | IF( ln_rnf_mouth ) THEN ! increase diffusivity at rivers mouths |
|---|
| 129 | DO jk = 2, nkrnf ; avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk) ; END DO |
|---|
| 130 | ENDIF |
|---|
| 131 | IF( ln_zdfevd ) CALL zdf_evd( kstp ) ! enhanced vertical eddy diffusivity |
|---|
| 132 | |
|---|
| 133 | IF( lk_zdftmx ) CALL zdf_tmx( kstp ) ! tidal vertical mixing |
|---|
| 134 | |
|---|
| 135 | IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) & |
|---|
| 136 | & CALL zdf_ddm( kstp ) ! double diffusive mixing |
|---|
| 137 | |
|---|
| 138 | CALL zdf_mxl( kstp ) ! mixed layer depth |
|---|
| 139 | |
|---|
| 140 | ! write TKE or GLS information in the restart file |
|---|
| 141 | IF( lrst_oce .AND. lk_zdftke ) CALL tke_rst( kstp, 'WRITE' ) |
|---|
| 142 | IF( lrst_oce .AND. lk_zdfgls ) CALL gls_rst( kstp, 'WRITE' ) |
|---|
| 143 | ! |
|---|
| 144 | ! LATERAL PHYSICS |
|---|
| 145 | ! |
|---|
| 146 | IF( lk_ldfslp ) THEN ! slope of lateral mixing |
|---|
| 147 | CALL eos( tsb, rhd, gdept_0(:,:,:) ) ! before in situ density |
|---|
| 148 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 149 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & ! |
|---|
| 150 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
|---|
| 151 | IF( ln_traldf_grif ) THEN ! before slope for Griffies operator |
|---|
| 152 | CALL ldf_slp_grif( kstp ) |
|---|
| 153 | ELSE |
|---|
| 154 | CALL ldf_slp( kstp, rhd, rn2b ) ! before slope for Madec operator |
|---|
| 155 | ENDIF |
|---|
| 156 | ENDIF |
|---|
| 157 | #if defined key_traldf_c2d |
|---|
| 158 | IF( lk_traldf_eiv ) CALL ldf_eiv( kstp ) ! eddy induced velocity coefficient |
|---|
| 159 | #endif |
|---|
| 160 | |
|---|
| 161 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 162 | ! Ocean dynamics : hdiv, rot, ssh, e3, wn |
|---|
| 163 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 164 | CALL ssh_nxt ( kstp ) ! after ssh (includes call to div_cur) |
|---|
| 165 | IF( lk_vvl ) CALL dom_vvl_sf_nxt( kstp ) ! after vertical scale factors |
|---|
| 166 | CALL wzv ( kstp ) ! now cross-level velocity |
|---|
| 167 | |
|---|
| 168 | IF( lk_dynspg_ts ) THEN |
|---|
| 169 | ! In case the time splitting case, update almost all momentum trends here: |
|---|
| 170 | ! Note that the computation of vertical velocity above, hence "after" sea level |
|---|
| 171 | ! is necessary to compute momentum advection for the rhs of barotropic loop: |
|---|
| 172 | CALL eos ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation |
|---|
| 173 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 174 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & ! |
|---|
| 175 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
|---|
| 176 | |
|---|
| 177 | ua(:,:,:) = 0.e0 ! set dynamics trends to zero |
|---|
| 178 | va(:,:,:) = 0.e0 |
|---|
| 179 | IF( ln_asmiau .AND. & |
|---|
| 180 | & ln_dyninc ) CALL dyn_asm_inc ( kstp ) ! apply dynamics assimilation increment |
|---|
| 181 | IF( lk_bdy ) CALL bdy_dyn3d_dmp( kstp ) ! bdy damping trends |
|---|
| 182 | CALL dyn_adv ( kstp ) ! advection (vector or flux form) |
|---|
| 183 | CALL dyn_vor ( kstp ) ! vorticity term including Coriolis |
|---|
| 184 | CALL dyn_ldf ( kstp ) ! lateral mixing |
|---|
| 185 | #if defined key_agrif |
|---|
| 186 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momentum sponge |
|---|
| 187 | #endif |
|---|
| 188 | CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 189 | CALL dyn_spg( kstp, indic ) ! surface pressure gradient |
|---|
| 190 | |
|---|
| 191 | ua_sv(:,:,:) = ua(:,:,:) ! Save trends (barotropic trend has been fully updated at this stage) |
|---|
| 192 | va_sv(:,:,:) = va(:,:,:) |
|---|
| 193 | |
|---|
| 194 | CALL div_cur( kstp ) ! Horizontal divergence & Relative vorticity (2nd call in time-split case) |
|---|
| 195 | IF( lk_vvl ) CALL dom_vvl_sf_nxt( kstp, kcall=2 ) ! after vertical scale factors (update depth average component) |
|---|
| 196 | CALL wzv ( kstp ) ! now cross-level velocity |
|---|
| 197 | ENDIF |
|---|
| 198 | |
|---|
| 199 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 200 | ! diagnostics and outputs (ua, va, tsa used as workspace) |
|---|
| 201 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 202 | IF( lk_floats ) CALL flo_stp( kstp ) ! drifting Floats |
|---|
| 203 | IF( lk_diahth ) CALL dia_hth( kstp ) ! Thermocline depth (20 degres isotherm depth) |
|---|
| 204 | IF( .NOT. lk_cpl ) CALL dia_fwb( kstp ) ! Fresh water budget diagnostics |
|---|
| 205 | IF( ln_diaptr ) CALL dia_ptr( kstp ) ! Poleward TRansports diagnostics |
|---|
| 206 | IF( lk_diadct ) CALL dia_dct( kstp ) ! Transports |
|---|
| 207 | IF( lk_diaar5 ) CALL dia_ar5( kstp ) ! ar5 diag |
|---|
| 208 | IF( lk_diaharm ) CALL dia_harm( kstp ) ! Tidal harmonic analysis |
|---|
| 209 | CALL dia_wri( kstp ) ! ocean model: outputs |
|---|
| 210 | ! |
|---|
| 211 | IF( ln_crs ) CALL crs_fld( kstp ) ! ocean model: online field coarsening & output |
|---|
| 212 | |
|---|
| 213 | |
|---|
| 214 | #if defined key_top |
|---|
| 215 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 216 | ! Passive Tracer Model |
|---|
| 217 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 218 | CALL trc_stp( kstp ) ! time-stepping |
|---|
| 219 | #endif |
|---|
| 220 | |
|---|
| 221 | |
|---|
| 222 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 223 | ! Active tracers (ua, va used as workspace) |
|---|
| 224 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 225 | tsa(:,:,:,:) = 0.e0 ! set tracer trends to zero |
|---|
| 226 | |
|---|
| 227 | IF( ln_asmiau .AND. & |
|---|
| 228 | & ln_trainc ) CALL tra_asm_inc( kstp ) ! apply tracer assimilation increment |
|---|
| 229 | CALL tra_sbc ( kstp ) ! surface boundary condition |
|---|
| 230 | IF( ln_traqsr ) CALL tra_qsr ( kstp ) ! penetrative solar radiation qsr |
|---|
| 231 | IF( ln_trabbc ) CALL tra_bbc ( kstp ) ! bottom heat flux |
|---|
| 232 | IF( lk_trabbl ) CALL tra_bbl ( kstp ) ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 233 | IF( ln_tradmp ) CALL tra_dmp ( kstp ) ! internal damping trends |
|---|
| 234 | IF( lk_bdy ) CALL bdy_tra_dmp( kstp ) ! bdy damping trends |
|---|
| 235 | CALL tra_adv ( kstp ) ! horizontal & vertical advection |
|---|
| 236 | IF( lk_zdfkpp ) CALL tra_kpp ( kstp ) ! KPP non-local tracer fluxes |
|---|
| 237 | CALL tra_ldf ( kstp ) ! lateral mixing |
|---|
| 238 | #if defined key_agrif |
|---|
| 239 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra ! tracers sponge |
|---|
| 240 | #endif |
|---|
| 241 | CALL tra_zdf ( kstp ) ! vertical mixing and after tracer fields |
|---|
| 242 | |
|---|
| 243 | IF( ln_dynhpg_imp ) THEN ! semi-implicit hpg (time stepping then eos) |
|---|
| 244 | IF( ln_zdfnpc ) CALL tra_npc( kstp ) ! update after fields by non-penetrative convection |
|---|
| 245 | CALL tra_nxt( kstp ) ! tracer fields at next time step |
|---|
| 246 | CALL eos ( tsa, rhd, rhop, fsdept_n(:,:,:) ) ! Time-filtered in situ density for hpg computation |
|---|
| 247 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 248 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & ! |
|---|
| 249 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
|---|
| 250 | ELSE ! centered hpg (eos then time stepping) |
|---|
| 251 | IF ( .NOT. lk_dynspg_ts ) THEN ! eos already called in time-split case |
|---|
| 252 | CALL eos ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation |
|---|
| 253 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 254 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & ! |
|---|
| 255 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
|---|
| 256 | ENDIF |
|---|
| 257 | IF( ln_zdfnpc ) CALL tra_npc( kstp ) ! update after fields by non-penetrative convection |
|---|
| 258 | CALL tra_nxt( kstp ) ! tracer fields at next time step |
|---|
| 259 | ENDIF |
|---|
| 260 | |
|---|
| 261 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 262 | ! Dynamics (tsa used as workspace) |
|---|
| 263 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 264 | IF( lk_dynspg_ts ) THEN |
|---|
| 265 | ! revert to previously computed momentum tendencies |
|---|
| 266 | ! (not using ua, va as temporary arrays during tracers' update could avoid that) |
|---|
| 267 | ua(:,:,:) = ua_sv(:,:,:) |
|---|
| 268 | va(:,:,:) = va_sv(:,:,:) |
|---|
| 269 | ! Revert now divergence and rotational to previously computed ones |
|---|
| 270 | !(needed because of the time swap in div_cur, at the beginning of each time step) |
|---|
| 271 | hdivn(:,:,:) = hdivb(:,:,:) |
|---|
| 272 | rotn(:,:,:) = rotb(:,:,:) |
|---|
| 273 | |
|---|
| 274 | CALL dyn_bfr( kstp ) ! bottom friction |
|---|
| 275 | CALL dyn_zdf( kstp ) ! vertical diffusion |
|---|
| 276 | ELSE |
|---|
| 277 | ua(:,:,:) = 0.e0 ! set dynamics trends to zero |
|---|
| 278 | va(:,:,:) = 0.e0 |
|---|
| 279 | |
|---|
| 280 | IF( ln_asmiau .AND. & |
|---|
| 281 | & ln_dyninc ) CALL dyn_asm_inc( kstp ) ! apply dynamics assimilation increment |
|---|
| 282 | IF( ln_bkgwri ) CALL asm_bkg_wri( kstp ) ! output background fields |
|---|
| 283 | IF( lk_bdy ) CALL bdy_dyn3d_dmp(kstp ) ! bdy damping trends |
|---|
| 284 | CALL dyn_adv( kstp ) ! advection (vector or flux form) |
|---|
| 285 | CALL dyn_vor( kstp ) ! vorticity term including Coriolis |
|---|
| 286 | CALL dyn_ldf( kstp ) ! lateral mixing |
|---|
| 287 | #if defined key_agrif |
|---|
| 288 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momemtum sponge |
|---|
| 289 | #endif |
|---|
| 290 | CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 291 | CALL dyn_bfr( kstp ) ! bottom friction |
|---|
| 292 | CALL dyn_zdf( kstp ) ! vertical diffusion |
|---|
| 293 | CALL dyn_spg( kstp, indic ) ! surface pressure gradient |
|---|
| 294 | ENDIF |
|---|
| 295 | CALL dyn_nxt( kstp ) ! lateral velocity at next time step |
|---|
| 296 | |
|---|
| 297 | CALL ssh_swp( kstp ) ! swap of sea surface height |
|---|
| 298 | IF( lk_vvl ) CALL dom_vvl_sf_swp( kstp ) ! swap of vertical scale factors |
|---|
| 299 | |
|---|
| 300 | IF( ln_diahsb ) CALL dia_hsb( kstp ) ! - ML - global conservation diagnostics |
|---|
| 301 | IF( lk_diaobs ) CALL dia_obs( kstp ) ! obs-minus-model (assimilation) diagnostics (call after dynamics update) |
|---|
| 302 | |
|---|
| 303 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 304 | ! Control and restarts |
|---|
| 305 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 306 | CALL stp_ctl( kstp, indic ) |
|---|
| 307 | IF( indic < 0 ) THEN |
|---|
| 308 | CALL ctl_stop( 'step: indic < 0' ) |
|---|
| 309 | CALL dia_wri_state( 'output.abort', kstp ) |
|---|
| 310 | ENDIF |
|---|
| 311 | IF( kstp == nit000 ) THEN |
|---|
| 312 | CALL iom_close( numror ) ! close input ocean restart file |
|---|
| 313 | IF(lwm) CALL FLUSH ( numond ) ! flush output namelist oce |
|---|
| 314 | IF( lwm.AND.numoni /= -1 ) CALL FLUSH ( numoni ) ! flush output namelist ice |
|---|
| 315 | ENDIF |
|---|
| 316 | IF( lrst_oce ) CALL rst_write ( kstp ) ! write output ocean restart file |
|---|
| 317 | |
|---|
| 318 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 319 | ! Coupled mode |
|---|
| 320 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 321 | IF( lk_cpl ) CALL sbc_cpl_snd( kstp ) ! coupled mode : field exchanges |
|---|
| 322 | ! |
|---|
| 323 | #if defined key_iomput |
|---|
| 324 | IF( kstp == nitend .OR. indic < 0 ) THEN |
|---|
| 325 | CALL iom_context_finalize( "nemo" ) ! needed for XIOS+AGRIF |
|---|
| 326 | IF( ln_crs ) CALL iom_context_finalize( "nemo_crs" ) ! |
|---|
| 327 | ENDIF |
|---|
| 328 | #endif |
|---|
| 329 | ! |
|---|
| 330 | IF( nn_timing == 1 .AND. kstp == nit000 ) CALL timing_reset |
|---|
| 331 | ! |
|---|
| 332 | END SUBROUTINE stp |
|---|
| 333 | |
|---|
| 334 | !!====================================================================== |
|---|
| 335 | END MODULE step |
|---|
