New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diahsb.F90 in branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/DIA/diahsb.F90 @ 5956

Last change on this file since 5956 was 5956, checked in by mathiot, 8 years ago

ISF : merged trunk (5936) into branch
  • Property svn:keywords set to Id
File size: 19.9 KB
Line 
1MODULE diahsb
2   !!======================================================================
3   !!                       ***  MODULE  diahsb  ***
4   !! Ocean diagnostics: Heat, salt and volume budgets
5   !!======================================================================
6   !! History :  3.3  ! 2010-09  (M. Leclair)  Original code
7   !!                 ! 2012-10  (C. Rousset)  add iom_put
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dia_hsb       : Diagnose the conservation of ocean heat and salt contents, and volume
12   !!   dia_hsb_rst   : Read or write DIA file in restart file
13   !!   dia_hsb_init  : Initialization of the conservation diagnostic
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE phycst          ! physical constants
18   USE sbc_oce         ! surface thermohaline fluxes
19   USE sbcrnf          ! river runoff
20   USE sbcisf          ! ice shelves
21   USE domvvl          ! vertical scale factors
22   USE traqsr          ! penetrative solar radiation
23   USE trabbc          ! bottom boundary condition
24   USE trabbc          ! bottom boundary condition
25   USE bdy_par         ! (for lk_bdy)
26   USE restart         ! ocean restart
27   !
28   USE iom             ! I/O manager
29   USE in_out_manager  ! I/O manager
30   USE lib_fortran     ! glob_sum
31   USE lib_mpp         ! distributed memory computing library
32   USE timing          ! preformance summary
33   USE wrk_nemo        ! work arrays
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   dia_hsb        ! routine called by step.F90
39   PUBLIC   dia_hsb_init   ! routine called by nemogcm.F90
40   PUBLIC   dia_hsb_rst    ! routine called by step.F90
41
42   LOGICAL, PUBLIC ::   ln_diahsb   !: check the heat and salt budgets
43
44   REAL(wp) ::   surf_tot              ! ocean surface
45   REAL(wp) ::   frc_t, frc_s, frc_v   ! global forcing trends
46   REAL(wp) ::   frc_wn_t, frc_wn_s    ! global forcing trends
47   !
48   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   surf          , ssh_ini          !
49   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   ssh_hc_loc_ini, ssh_sc_loc_ini   !
50   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   hc_loc_ini, sc_loc_ini, e3t_ini  !
51
52   !! * Substitutions
53#  include "domzgr_substitute.h90"
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
57   !! $Id$
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE dia_hsb( kt )
63      !!---------------------------------------------------------------------------
64      !!                  ***  ROUTINE dia_hsb  ***
65      !!     
66      !! ** Purpose: Compute the ocean global heat content, salt content and volume conservation
67      !!
68      !! ** Method : - Compute the deviation of heat content, salt content and volume
69      !!             at the current time step from their values at nit000
70      !!             - Compute the contribution of forcing and remove it from these deviations
71      !!
72      !!---------------------------------------------------------------------------
73      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
74      !
75      INTEGER    ::   ji, jj, jk                  ! dummy loop indice
76      REAL(wp)   ::   zdiff_hc    , zdiff_sc      ! heat and salt content variations
77      REAL(wp)   ::   zdiff_hc1   , zdiff_sc1     !  -         -     -        -
78      REAL(wp)   ::   zdiff_v1    , zdiff_v2      ! volume variation
79      REAL(wp)   ::   zerr_hc1    , zerr_sc1      ! heat and salt content misfit
80      REAL(wp)   ::   zvol_tot                    ! volume
81      REAL(wp)   ::   z_frc_trd_t , z_frc_trd_s   !    -     -
82      REAL(wp)   ::   z_frc_trd_v                 !    -     -
83      REAL(wp)   ::   z_wn_trd_t , z_wn_trd_s     !    -     -
84      REAL(wp)   ::   z_ssh_hc , z_ssh_sc         !    -     -
85      REAL(wp), DIMENSION(:,:), POINTER ::   z2d0, z2d1
86      !!---------------------------------------------------------------------------
87      IF( nn_timing == 1 )   CALL timing_start('dia_hsb')     
88      CALL wrk_alloc( jpi,jpj,   z2d0, z2d1 )
89      !
90      tsn(:,:,:,1) = tsn(:,:,:,1) * tmask(:,:,:) ; tsb(:,:,:,1) = tsb(:,:,:,1) * tmask(:,:,:) ;
91      tsn(:,:,:,2) = tsn(:,:,:,2) * tmask(:,:,:) ; tsb(:,:,:,2) = tsb(:,:,:,2) * tmask(:,:,:) ;
92      ! ------------------------- !
93      ! 1 - Trends due to forcing !
94      ! ------------------------- !
95      z_frc_trd_v = r1_rau0 * glob_sum( - ( emp(:,:) - rnf(:,:) + fwfisf(:,:) ) * surf(:,:) ) ! volume fluxes
96      z_frc_trd_t =           glob_sum( sbc_tsc(:,:,jp_tem) * surf(:,:) )                               ! heat fluxes
97      z_frc_trd_s =           glob_sum( sbc_tsc(:,:,jp_sal) * surf(:,:) )                               ! salt fluxes
98      ! Add runoff    heat & salt input
99      IF( ln_rnf    )   z_frc_trd_t = z_frc_trd_t + glob_sum( rnf_tsc(:,:,jp_tem) * surf(:,:) )
100      IF( ln_rnf_sal)   z_frc_trd_s = z_frc_trd_s + glob_sum( rnf_tsc(:,:,jp_sal) * surf(:,:) )
101      ! Add ice shelf heat & salt input
102      IF( ln_isf    ) z_frc_trd_t = z_frc_trd_t + glob_sum( risf_tsc(:,:,jp_tem) * surf(:,:) )
103      ! Add penetrative solar radiation
104      IF( ln_traqsr )   z_frc_trd_t = z_frc_trd_t + r1_rau0_rcp * glob_sum( qsr     (:,:) * surf(:,:) )
105      ! Add geothermal heat flux
106      IF( ln_trabbc )   z_frc_trd_t = z_frc_trd_t +               glob_sum( qgh_trd0(:,:) * surf(:,:) )
107      !
108      IF( .NOT. lk_vvl ) THEN
109         IF ( ln_isfcav ) THEN
110            DO ji=1,jpi
111               DO jj=1,jpj
112                  z2d0(ji,jj) = surf(ji,jj) * wn(ji,jj,mikt(ji,jj)) * tsb(ji,jj,mikt(ji,jj),jp_tem)
113                  z2d1(ji,jj) = surf(ji,jj) * wn(ji,jj,mikt(ji,jj)) * tsb(ji,jj,mikt(ji,jj),jp_sal)
114               ENDDO
115            ENDDO
116         ELSE
117            z2d0(:,:) = surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_tem)
118            z2d1(:,:) = surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_sal)
119         END IF
120         z_wn_trd_t = - glob_sum( z2d0 ) 
121         z_wn_trd_s = - glob_sum( z2d1 )
122      ENDIF
123
124      frc_v = frc_v + z_frc_trd_v * rdt
125      frc_t = frc_t + z_frc_trd_t * rdt
126      frc_s = frc_s + z_frc_trd_s * rdt
127      !                                          ! Advection flux through fixed surface (z=0)
128      IF( .NOT. lk_vvl ) THEN
129         frc_wn_t = frc_wn_t + z_wn_trd_t * rdt
130         frc_wn_s = frc_wn_s + z_wn_trd_s * rdt
131      ENDIF
132
133      ! ------------------------ !
134      ! 2 -  Content variations !
135      ! ------------------------ !
136      zdiff_v2 = 0._wp
137      zdiff_hc = 0._wp
138      zdiff_sc = 0._wp
139
140      ! volume variation (calculated with ssh)
141      zdiff_v1 = glob_sum( surf(:,:) * ( sshn(:,:) - ssh_ini(:,:) ) )
142
143      ! heat & salt content variation (associated with ssh)
144      IF( .NOT. lk_vvl ) THEN
145         IF ( ln_isfcav ) THEN
146            DO ji = 1, jpi
147               DO jj = 1, jpj
148                  z2d0(ji,jj) = surf(ji,jj) * ( tsn(ji,jj,mikt(ji,jj),jp_tem) * sshn(ji,jj) - ssh_hc_loc_ini(ji,jj) ) 
149                  z2d1(ji,jj) = surf(ji,jj) * ( tsn(ji,jj,mikt(ji,jj),jp_sal) * sshn(ji,jj) - ssh_sc_loc_ini(ji,jj) ) 
150               END DO
151            END DO
152         ELSE
153            z2d0(:,:) = surf(:,:) * ( tsn(:,:,1,jp_tem) * sshn(:,:) - ssh_hc_loc_ini(:,:) ) 
154            z2d1(:,:) = surf(:,:) * ( tsn(:,:,1,jp_sal) * sshn(:,:) - ssh_sc_loc_ini(:,:) ) 
155         END IF
156         z_ssh_hc = glob_sum( z2d0 ) 
157         z_ssh_sc = glob_sum( z2d1 ) 
158      ENDIF
159
160      DO jk = 1, jpkm1
161         ! volume variation (calculated with scale factors)
162         zdiff_v2 = zdiff_v2 + glob_sum( surf(:,:) * tmask(:,:,jk) &
163            &                           * ( fse3t_n(:,:,jk) - e3t_ini(:,:,jk) ) )
164         ! heat content variation
165         zdiff_hc = zdiff_hc + glob_sum(  surf(:,:) * tmask(:,:,jk) & 
166            &                           * ( fse3t_n(:,:,jk) * tsn(:,:,jk,jp_tem) - hc_loc_ini(:,:,jk) ) )
167         ! salt content variation
168         zdiff_sc = zdiff_sc + glob_sum(  surf(:,:) * tmask(:,:,jk)   &
169            &                           * ( fse3t_n(:,:,jk) * tsn(:,:,jk,jp_sal) - sc_loc_ini(:,:,jk) ) )
170      ENDDO
171
172      ! Substract forcing from heat content, salt content and volume variations
173      zdiff_v1 = zdiff_v1 - frc_v
174      IF( lk_vvl )   zdiff_v2 = zdiff_v2 - frc_v
175      zdiff_hc = zdiff_hc - frc_t
176      zdiff_sc = zdiff_sc - frc_s
177      IF( .NOT. lk_vvl ) THEN
178         zdiff_hc1 = zdiff_hc + z_ssh_hc 
179         zdiff_sc1 = zdiff_sc + z_ssh_sc
180         zerr_hc1  = z_ssh_hc - frc_wn_t
181         zerr_sc1  = z_ssh_sc - frc_wn_s
182      ENDIF
183
184      ! ----------------------- !
185      ! 3 - Diagnostics writing !
186      ! ----------------------- !
187      zvol_tot = 0._wp                    ! total ocean volume (calculated with scale factors)
188      DO jk = 1, jpkm1
189         zvol_tot  = zvol_tot + glob_sum( surf(:,:) * tmask(:,:,jk) * fse3t_n(:,:,jk) )
190      END DO
191
192!!gm to be added ?
193!      IF( .NOT. lk_vvl ) THEN            ! fixed volume, add the ssh contribution
194!        zvol_tot = zvol_tot + glob_sum( surf(:,:) * sshn(:,:) )
195!      ENDIF
196!!gm end
197
198      IF( lk_vvl ) THEN
199        CALL iom_put( 'bgtemper' , zdiff_hc / zvol_tot )              ! Temperature variation (C)
200        CALL iom_put( 'bgsaline' , zdiff_sc / zvol_tot )              ! Salinity    variation (psu)
201        CALL iom_put( 'bgheatco' , zdiff_hc * 1.e-20 * rau0 * rcp )   ! Heat content variation (1.e20 J)
202        CALL iom_put( 'bgsaltco' , zdiff_sc * 1.e-9    )              ! Salt content variation (psu*km3)
203        CALL iom_put( 'bgvolssh' , zdiff_v1 * 1.e-9    )              ! volume ssh variation (km3) 
204        CALL iom_put( 'bgvole3t' , zdiff_v2 * 1.e-9    )              ! volume e3t variation (km3) 
205        CALL iom_put( 'bgfrcvol' , frc_v    * 1.e-9    )              ! vol - surface forcing (km3)
206        CALL iom_put( 'bgfrctem' , frc_t / zvol_tot    )              ! hc  - surface forcing (C)
207        CALL iom_put( 'bgfrcsal' , frc_s / zvol_tot    )              ! sc  - surface forcing (psu)
208      ELSE
209        CALL iom_put( 'bgtemper' , zdiff_hc1 / zvol_tot)              ! Heat content variation (C)
210        CALL iom_put( 'bgsaline' , zdiff_sc1 / zvol_tot)              ! Salt content variation (psu)
211        CALL iom_put( 'bgheatco' , zdiff_hc1 * 1.e-20 * rau0 * rcp )  ! Heat content variation (1.e20 J)
212        CALL iom_put( 'bgsaltco' , zdiff_sc1 * 1.e-9   )              ! Salt content variation (psu*km3)
213        CALL iom_put( 'bgvolssh' , zdiff_v1  * 1.e-9   )              ! volume ssh variation (km3) 
214        CALL iom_put( 'bgfrcvol' , frc_v    * 1.e-9    )              ! vol - surface forcing (km3)
215        CALL iom_put( 'bgfrctem' , frc_t / zvol_tot    )              ! hc  - surface forcing (C)
216        CALL iom_put( 'bgfrcsal' , frc_s / zvol_tot    )              ! sc  - surface forcing (psu)
217        CALL iom_put( 'bgmistem' , zerr_hc1 / zvol_tot )              ! hc  - error due to free surface (C)
218        CALL iom_put( 'bgmissal' , zerr_sc1 / zvol_tot )              ! sc  - error due to free surface (psu)
219      ENDIF
220      !
221      IF( lrst_oce )   CALL dia_hsb_rst( kt, 'WRITE' )
222
223      CALL wrk_dealloc( jpi,jpj,   z2d0, z2d1 )
224
225      IF( nn_timing == 1 )   CALL timing_stop('dia_hsb')
226      !
227   END SUBROUTINE dia_hsb
228
229
230   SUBROUTINE dia_hsb_rst( kt, cdrw )
231     !!---------------------------------------------------------------------
232     !!                   ***  ROUTINE limdia_rst  ***
233     !!                     
234     !! ** Purpose :   Read or write DIA file in restart file
235     !!
236     !! ** Method  :   use of IOM library
237     !!----------------------------------------------------------------------
238     INTEGER         , INTENT(in) ::   kt     ! ocean time-step
239     CHARACTER(len=*), INTENT(in) ::   cdrw   ! "READ"/"WRITE" flag
240     !
241     INTEGER ::   ji, jj, jk   ! dummy loop indices
242     INTEGER ::   id1          ! local integers
243     !!----------------------------------------------------------------------
244     !
245     IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
246        IF( ln_rstart ) THEN                   !* Read the restart file
247           !id1 = iom_varid( numror, 'frc_vol'  , ldstop = .FALSE. )
248           !
249           IF(lwp) WRITE(numout,*) '~~~~~~~'
250           IF(lwp) WRITE(numout,*) ' dia_hsb_rst at it= ', kt,' date= ', ndastp
251           IF(lwp) WRITE(numout,*) '~~~~~~~'
252           CALL iom_get( numror, 'frc_v', frc_v )
253           CALL iom_get( numror, 'frc_t', frc_t )
254           CALL iom_get( numror, 'frc_s', frc_s )
255           IF( .NOT. lk_vvl ) THEN
256              CALL iom_get( numror, 'frc_wn_t', frc_wn_t )
257              CALL iom_get( numror, 'frc_wn_s', frc_wn_s )
258           ENDIF
259           CALL iom_get( numror, jpdom_autoglo, 'ssh_ini', ssh_ini )
260           CALL iom_get( numror, jpdom_autoglo, 'e3t_ini', e3t_ini )
261           CALL iom_get( numror, jpdom_autoglo, 'hc_loc_ini', hc_loc_ini )
262           CALL iom_get( numror, jpdom_autoglo, 'sc_loc_ini', sc_loc_ini )
263           IF( .NOT. lk_vvl ) THEN
264              CALL iom_get( numror, jpdom_autoglo, 'ssh_hc_loc_ini', ssh_hc_loc_ini )
265              CALL iom_get( numror, jpdom_autoglo, 'ssh_sc_loc_ini', ssh_sc_loc_ini )
266           ENDIF
267       ELSE
268          IF(lwp) WRITE(numout,*) '~~~~~~~'
269          IF(lwp) WRITE(numout,*) ' dia_hsb at initial state '
270          IF(lwp) WRITE(numout,*) '~~~~~~~'
271          ssh_ini(:,:) = sshn(:,:)                                       ! initial ssh
272          DO jk = 1, jpk
273             e3t_ini   (:,:,jk) = fse3t_n(:,:,jk)                        ! initial vertical scale factors
274             hc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_tem) * fse3t_n(:,:,jk)   ! initial heat content
275             sc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_sal) * fse3t_n(:,:,jk)   ! initial salt content
276          END DO
277          frc_v = 0._wp                                           ! volume       trend due to forcing
278          frc_t = 0._wp                                           ! heat content   -    -   -    -   
279          frc_s = 0._wp                                           ! salt content   -    -   -    -       
280          IF( .NOT. lk_vvl ) THEN
281             IF ( ln_isfcav ) THEN
282                DO ji=1,jpi
283                   DO jj=1,jpj
284                      ssh_hc_loc_ini(ji,jj) = tsn(ji,jj,mikt(ji,jj),jp_tem) * sshn(ji,jj)   ! initial heat content in ssh
285                      ssh_sc_loc_ini(ji,jj) = tsn(ji,jj,mikt(ji,jj),jp_sal) * sshn(ji,jj)   ! initial salt content in ssh
286                   ENDDO
287                ENDDO
288             ELSE
289                ssh_hc_loc_ini(:,:) = tsn(:,:,1,jp_tem) * sshn(:,:)   ! initial heat content in ssh
290                ssh_sc_loc_ini(:,:) = tsn(:,:,1,jp_sal) * sshn(:,:)   ! initial salt content in ssh
291             END IF
292             frc_wn_t = 0._wp                                       ! initial heat content misfit due to free surface
293             frc_wn_s = 0._wp                                       ! initial salt content misfit due to free surface
294          ENDIF
295       ENDIF
296
297     ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
298        !                                   ! -------------------
299        IF(lwp) WRITE(numout,*) '~~~~~~~'
300        IF(lwp) WRITE(numout,*) ' dia_hsb_rst at it= ', kt,' date= ', ndastp
301        IF(lwp) WRITE(numout,*) '~~~~~~~'
302
303        CALL iom_rstput( kt, nitrst, numrow, 'frc_v'   , frc_v     )
304        CALL iom_rstput( kt, nitrst, numrow, 'frc_t'   , frc_t     )
305        CALL iom_rstput( kt, nitrst, numrow, 'frc_s'   , frc_s     )
306        IF( .NOT. lk_vvl ) THEN
307           CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_t', frc_wn_t )
308           CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_s', frc_wn_s )
309        ENDIF
310        CALL iom_rstput( kt, nitrst, numrow, 'ssh_ini', ssh_ini )
311        CALL iom_rstput( kt, nitrst, numrow, 'e3t_ini', e3t_ini )
312        CALL iom_rstput( kt, nitrst, numrow, 'hc_loc_ini', hc_loc_ini )
313        CALL iom_rstput( kt, nitrst, numrow, 'sc_loc_ini', sc_loc_ini )
314        IF( .NOT. lk_vvl ) THEN
315           CALL iom_rstput( kt, nitrst, numrow, 'ssh_hc_loc_ini', ssh_hc_loc_ini )
316           CALL iom_rstput( kt, nitrst, numrow, 'ssh_sc_loc_ini', ssh_sc_loc_ini )
317        ENDIF
318        !
319     ENDIF
320     !
321   END SUBROUTINE dia_hsb_rst
322
323
324   SUBROUTINE dia_hsb_init
325      !!---------------------------------------------------------------------------
326      !!                  ***  ROUTINE dia_hsb  ***
327      !!     
328      !! ** Purpose: Initialization for the heat salt volume budgets
329      !!
330      !! ** Method : Compute initial heat content, salt content and volume
331      !!
332      !! ** Action : - Compute initial heat content, salt content and volume
333      !!             - Initialize forcing trends
334      !!             - Compute coefficients for conversion
335      !!---------------------------------------------------------------------------
336      INTEGER ::   jk       ! dummy loop indice
337      INTEGER ::   ierror   ! local integer
338      INTEGER ::   ios
339      !
340      NAMELIST/namhsb/ ln_diahsb
341      !!----------------------------------------------------------------------
342
343      IF(lwp) THEN
344         WRITE(numout,*)
345         WRITE(numout,*) 'dia_hsb_init : check the heat and salt budgets'
346         WRITE(numout,*) '~~~~~~~~ '
347      ENDIF
348
349      REWIND( numnam_ref )              ! Namelist namhsb in reference namelist
350      READ  ( numnam_ref, namhsb, IOSTAT = ios, ERR = 901)
351901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namhsb in reference namelist', lwp )
352
353      REWIND( numnam_cfg )              ! Namelist namhsb in configuration namelist
354      READ  ( numnam_cfg, namhsb, IOSTAT = ios, ERR = 902 )
355902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namhsb in configuration namelist', lwp )
356      IF(lwm) WRITE ( numond, namhsb )
357
358      !
359      IF(lwp) THEN                   ! Control print
360         WRITE(numout,*)
361         WRITE(numout,*) 'dia_hsb_init : check the heat and salt budgets'
362         WRITE(numout,*) '~~~~~~~~~~~~'
363         WRITE(numout,*) '   Namelist namhsb : set hsb parameters'
364         WRITE(numout,*) '      Switch for hsb diagnostic (T) or not (F)  ln_diahsb  = ', ln_diahsb
365         WRITE(numout,*)
366      ENDIF
367
368      IF( .NOT. ln_diahsb )   RETURN
369         !      IF( .NOT. lk_mpp_rep ) &
370         !        CALL ctl_stop (' Your global mpp_sum if performed in single precision - 64 bits -', &
371         !             &         ' whereas the global sum to be precise must be done in double precision ',&
372         !             &         ' please add key_mpp_rep')
373
374      ! ------------------- !
375      ! 1 - Allocate memory !
376      ! ------------------- !
377      ALLOCATE( hc_loc_ini(jpi,jpj,jpk), sc_loc_ini(jpi,jpj,jpk), &
378         &      e3t_ini(jpi,jpj,jpk), surf(jpi,jpj),  ssh_ini(jpi,jpj), STAT=ierror )
379      IF( ierror > 0 ) THEN
380         CALL ctl_stop( 'dia_hsb: unable to allocate hc_loc_ini' )   ;   RETURN
381      ENDIF
382
383      IF(.NOT. lk_vvl ) ALLOCATE( ssh_hc_loc_ini(jpi,jpj), ssh_sc_loc_ini(jpi,jpj),STAT=ierror )
384      IF( ierror > 0 ) THEN
385         CALL ctl_stop( 'dia_hsb: unable to allocate hc_loc_ini' )   ;   RETURN
386      ENDIF
387
388      ! ----------------------------------------------- !
389      ! 2 - Time independant variables and file opening !
390      ! ----------------------------------------------- !
391      IF(lwp) WRITE(numout,*) "dia_hsb: heat salt volume budgets activated"
392      IF(lwp) WRITE(numout,*) '~~~~~~~'
393      surf(:,:) = e1t(:,:) * e2t(:,:) * tmask_i(:,:)      ! masked surface grid cell area
394      surf_tot  = glob_sum( surf(:,:) )                                       ! total ocean surface area
395
396      IF( lk_bdy ) CALL ctl_warn( 'dia_hsb does not take open boundary fluxes into account' )         
397      !
398      ! ---------------------------------- !
399      ! 4 - initial conservation variables !
400      ! ---------------------------------- !
401      CALL dia_hsb_rst( nit000, 'READ' )  !* read or initialize all required files
402      !
403   END SUBROUTINE dia_hsb_init
404
405   !!======================================================================
406END MODULE diahsb
Note: See TracBrowser for help on using the repository browser.