New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 5189

Last change on this file since 5189 was 5189, checked in by mathiot, 9 years ago

ISF cleaning branch: simplification and bug correction in hpg_isf, zps_hde_isf, mixed layer definition, slope, diffusion, vertical advection and top friction
  • Property svn:keywords set to Id
File size: 16.8 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   defined key_ldfslp   ||   defined key_esopa
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE trc_oce         ! share passive tracers/Ocean variables
24   USE zdf_oce         ! ocean vertical physics
25   USE ldftra_oce      ! ocean active tracers: lateral physics
26   USE ldfslp          ! iso-neutral slopes
27   USE diaptr          ! poleward transport diagnostics
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O library
30   USE phycst          ! physical constants
31   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
32   USE wrk_nemo        ! Memory Allocation
33   USE timing          ! Timing
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_ldf_iso   ! routine called by step.F90
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "ldftra_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_ldf_iso( kt, kit000, cdtype, pgu, pgv,              &
52      &                                pgui, pgvi,                    &
53      &                                ptb, pta, kjpt, pahtb0 )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE tra_ldf_iso  ***
56      !!
57      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
58      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
59      !!      add it to the general trend of tracer equation.
60      !!
61      !! ** Method  :   The horizontal component of the lateral diffusive trends
62      !!      is provided by a 2nd order operator rotated along neural or geopo-
63      !!      tential surfaces to which an eddy induced advection can be added
64      !!      It is computed using before fields (forward in time) and isopyc-
65      !!      nal or geopotential slopes computed in routine ldfslp.
66      !!
67      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
68      !!      ========    with partial cell update if ln_zps=T.
69      !!
70      !!      2nd part :  horizontal fluxes of the lateral mixing operator
71      !!      ========   
72      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
73      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
74      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
75      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
76      !!      take the horizontal divergence of the fluxes:
77      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
78      !!      Add this trend to the general trend (ta,sa):
79      !!         ta = ta + difft
80      !!
81      !!      3rd part: vertical trends of the lateral mixing operator
82      !!      ========  (excluding the vertical flux proportional to dk[t] )
83      !!      vertical fluxes associated with the rotated lateral mixing:
84      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
85      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
86      !!      take the horizontal divergence of the fluxes:
87      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
88      !!      Add this trend to the general trend (ta,sa):
89      !!         pta = pta + difft
90      !!
91      !! ** Action :   Update pta arrays with the before rotated diffusion
92      !!----------------------------------------------------------------------
93      USE oce     , ONLY:   zftu => ua       , zftv  => va         ! (ua,va) used as workspace
94      !
95      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
96      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
97      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
98      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
99      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu , pgv    ! tracer gradient at pstep levels
100      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgui, pgvi   ! tracer gradient at pstep levels
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
102      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
103      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
104      !
105      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
106      INTEGER  ::  ikt
107      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
108      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
109      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
110      REAL(wp), POINTER, DIMENSION(:,:  ) ::  zdkt, zdk1t, z2d
111      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zdit, zdjt , ztfw 
112      !!----------------------------------------------------------------------
113      !
114      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
115      !
116      CALL wrk_alloc( jpi, jpj,      zdkt, zdk1t, z2d  ) 
117      CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt , ztfw ) 
118      !
119
120      IF( kt == kit000 )  THEN
121         IF(lwp) WRITE(numout,*)
122         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
123         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
124      ENDIF
125      !
126      !                                                          ! ===========
127      DO jn = 1, kjpt                                            ! tracer loop
128         !                                                       ! ===========
129         !                                               
130         !!----------------------------------------------------------------------
131         !!   I - masked horizontal derivative
132         !!----------------------------------------------------------------------
133         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
134         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
135         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
136         !!end
137
138         ! Horizontal tracer gradient
139         DO jk = 1, jpkm1
140            DO jj = 1, jpjm1
141               DO ji = 1, fs_jpim1   ! vector opt.
142                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
143                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
144               END DO
145            END DO
146         END DO
147
148         ! partial cell correction
149         IF( ln_zps ) THEN      ! partial steps correction at the last ocean level
150            DO jj = 1, jpjm1
151               DO ji = 1, fs_jpim1   ! vector opt.
152! IF useless if zpshde defines pgu everywhere
153                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
154                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
155               END DO
156            END DO
157         ENDIF
158         IF( ln_zps .AND. ln_isfcav ) THEN      ! partial steps correction at the first wet level beneath a cavity
159            DO jj = 1, jpjm1
160               DO ji = 1, fs_jpim1   ! vector opt.
161                  IF (miku(ji,jj) > 1) zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
162                  IF (mikv(ji,jj) > 1) zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
163               END DO
164            END DO
165         END IF
166
167         !!----------------------------------------------------------------------
168         !!   II - horizontal trend  (full)
169         !!----------------------------------------------------------------------
170!CDIR PARALLEL DO PRIVATE( zdk1t )
171         !                                                ! ===============
172         DO jk = 1, jpkm1                                 ! Horizontal slab
173            !                                             ! ===============
174            ! 1. Vertical tracer gradient at level jk and jk+1
175            ! ------------------------------------------------
176            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
177            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * wmask(:,:,jk+1)
178            !
179            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)
180            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * wmask(:,:,jk)
181            ENDIF
182
183            ! 2. Horizontal fluxes
184            ! --------------------   
185            DO jj = 1 , jpjm1
186               DO ji = 1, fs_jpim1   ! vector opt.
187                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * re2u_e1u(ji,jj) * fse3u_n(ji,jj,jk)
188                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * re1v_e2v(ji,jj) * fse3v_n(ji,jj,jk)
189                  !
190                  zmsku = 1. / MAX(  wmask(ji+1,jj,jk  ) + wmask(ji,jj,jk+1)   &
191                     &             + wmask(ji+1,jj,jk+1) + wmask(ji,jj,jk  ), 1. )
192                  !
193                  zmskv = 1. / MAX(  wmask(ji,jj+1,jk  ) + wmask(ji,jj,jk+1)   &
194                     &             + wmask(ji,jj+1,jk+1) + wmask(ji,jj,jk  ), 1. )
195                  !
196                  zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
197                  zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
198                  !
199                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
200                     &              + zcof1 * (  zdkt (ji+1,jj  ) + zdk1t(ji,jj)      &
201                     &                         + zdk1t(ji+1,jj  ) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
202                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
203                     &              + zcof2 * (  zdkt (ji  ,jj+1) + zdk1t(ji,jj)      &
204                     &                         + zdk1t(ji  ,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
205               END DO
206            END DO
207
208            ! II.4 Second derivative (divergence) and add to the general trend
209            ! ----------------------------------------------------------------
210            DO jj = 2 , jpjm1
211               DO ji = fs_2, fs_jpim1   ! vector opt.
212                  zbtr = 1.0 / ( e12t(ji,jj) * fse3t_n(ji,jj,jk) )
213                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
214                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
215               END DO
216            END DO
217            !                                          ! ===============
218         END DO                                        !   End of slab 
219         !                                             ! ===============
220         !
221         ! "Poleward" diffusive heat or salt transports (T-S case only)
222         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
223            ! note sign is reversed to give down-gradient diffusive transports (#1043)
224            IF( jn == jp_tem)   htr_ldf(:) = ptr_sj( -zftv(:,:,:) )
225            IF( jn == jp_sal)   str_ldf(:) = ptr_sj( -zftv(:,:,:) )
226         ENDIF
227 
228         IF( iom_use("udiff_heattr") .OR. iom_use("vdiff_heattr") ) THEN
229           !
230           IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
231               z2d(:,:) = 0._wp 
232               DO jk = 1, jpkm1
233                  DO jj = 2, jpjm1
234                     DO ji = fs_2, fs_jpim1   ! vector opt.
235                        z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
236                     END DO
237                  END DO
238               END DO
239               z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
240               CALL lbc_lnk( z2d, 'U', -1. )
241               CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
242               !
243               z2d(:,:) = 0._wp 
244               DO jk = 1, jpkm1
245                  DO jj = 2, jpjm1
246                     DO ji = fs_2, fs_jpim1   ! vector opt.
247                        z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
248                     END DO
249                  END DO
250               END DO
251               z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
252               CALL lbc_lnk( z2d, 'V', -1. )
253               CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
254            END IF
255            !
256         ENDIF
257
258         !!----------------------------------------------------------------------
259         !!   III - vertical trend of T & S (extra diagonal terms only)
260         !!----------------------------------------------------------------------
261         
262         ! Local constant initialization
263         ! -----------------------------
264         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
265         
266         ! Vertical fluxes
267         ! ---------------
268         
269         ! Surface and bottom vertical fluxes set to zero
270         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
271         
272         ! interior (2=<jk=<jpk-1)
273         DO jk = 2, jpkm1
274            DO jj = 2, jpjm1
275               DO ji = fs_2, fs_jpim1   ! vector opt.
276                  zcoef0 = - fsahtw(ji,jj,jk) * wmask(ji,jj,jk)
277                  !
278                  zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
279                     &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
280                  zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
281                     &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
282                  !
283                  zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
284                  zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
285                  !
286                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
287                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
288                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
289                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
290               END DO
291            END DO
292         END DO
293         
294         
295         ! I.5 Divergence of vertical fluxes added to the general tracer trend
296         ! -------------------------------------------------------------------
297         DO jk = 1, jpkm1
298            DO jj = 2, jpjm1
299               DO ji = fs_2, fs_jpim1   ! vector opt.
300                  zbtr = 1.0 / ( e12t(ji,jj) * fse3t_n(ji,jj,jk) )
301                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
302                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
303               END DO
304            END DO
305         END DO
306         !
307      END DO
308      !
309      CALL wrk_dealloc( jpi, jpj,      zdkt, zdk1t, z2d  ) 
310      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt , ztfw ) 
311      !
312      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
313      !
314   END SUBROUTINE tra_ldf_iso
315
316#else
317   !!----------------------------------------------------------------------
318   !!   default option :   Dummy code   NO rotation of the diffusive tensor
319   !!----------------------------------------------------------------------
320CONTAINS
321   SUBROUTINE tra_ldf_iso( kt, kit000,cdtype, pgu, pgv, pgui, pgvi, ptb, pta, kjpt, pahtb0 )      ! Empty routine
322      INTEGER:: kt, kit000
323      CHARACTER(len=3) ::   cdtype
324      REAL, DIMENSION(:,:,:) ::   pgu, pgv, pgui, pgvi    ! tracer gradient at pstep levels
325      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
326      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt, kit000, cdtype,   &
327         &                       pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
328   END SUBROUTINE tra_ldf_iso
329#endif
330
331   !!==============================================================================
332END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.