New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 5189

Last change on this file since 5189 was 5189, checked in by mathiot, 9 years ago

ISF cleaning branch: simplification and bug correction in hpg_isf, zps_hde_isf, mixed layer definition, slope, diffusion, vertical advection and top friction
  • Property svn:keywords set to Id
File size: 24.9 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE phycst          ! physical constants
20   USE eosbn2          ! ocean equation of state
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! MPP library
24   USE wrk_nemo        ! Memory allocation
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   zps_hde     ! routine called by step.F90
31   PUBLIC   zps_hde_isf ! routine called by step.F90
32
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35#  include "vectopt_loop_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
38   !! $Id$
39   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
44      &                          prd, pgru, pgrv    )
45      !!----------------------------------------------------------------------
46      !!                     ***  ROUTINE zps_hde  ***
47      !!                   
48      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
49      !!      at u- and v-points with a linear interpolation for z-coordinate
50      !!      with partial steps.
51      !!
52      !! ** Method  :   In z-coord with partial steps, scale factors on last
53      !!      levels are different for each grid point, so that T, S and rd
54      !!      points are not at the same depth as in z-coord. To have horizontal
55      !!      gradients again, we interpolate T and S at the good depth :
56      !!      Linear interpolation of T, S   
57      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
58      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
59      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
60      !!         This formulation computes the two cases:
61      !!                 CASE 1                   CASE 2 
62      !!         k-1  ___ ___________   k-1   ___ ___________
63      !!                    Ti  T~                  T~  Ti+1
64      !!                  _____                        _____
65      !!         k        |   |Ti+1     k           Ti |   |
66      !!                  |   |____                ____|   |
67      !!              ___ |   |   |           ___  |   |   |
68      !!                 
69      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
70      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
71      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
72      !!          or
73      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
74      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
75      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
76      !!          Idem for di(s) and dj(s)         
77      !!
78      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
79      !!      depth zh from interpolated T and S for the different formulations
80      !!      of the equation of state (eos).
81      !!      Gradient formulation for rho :
82      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
83      !!
84      !! ** Action  : compute for top interfaces
85      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
86      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
87      !!----------------------------------------------------------------------
88      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
89      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
90      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
91      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
92      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
93      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
94      !
95      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
96      INTEGER  ::   iku, ikv, ikum1, ikvm1   ! partial step level (ocean bottom level) at u- and v-points
97      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv  ! temporary scalars
98      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
99      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
100      !!----------------------------------------------------------------------
101      !
102      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde')
103      !
104      pgtu(:,:,:)=0.0_wp ; pgtv(:,:,:)=0.0_wp ;
105      zti (:,:,:)=0.0_wp ; ztj (:,:,:)=0.0_wp ;
106      zhi (:,:  )=0.0_wp ; zhj (:,:  )=0.0_wp ;
107      !
108      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
109         !
110         DO jj = 1, jpjm1
111            DO ji = 1, jpim1
112               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
113               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
114               ze3wu = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
115               ze3wv = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
116               !
117               ! i- direction
118               IF( ze3wu >= 0._wp ) THEN      ! case 1
119                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
120                  ! interpolated values of tracers
121                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
122                  ! gradient of  tracers
123                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
124               ELSE                           ! case 2
125                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
126                  ! interpolated values of tracers
127                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
128                  ! gradient of tracers
129                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
130               ENDIF
131               !
132               ! j- direction
133               IF( ze3wv >= 0._wp ) THEN      ! case 1
134                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
135                  ! interpolated values of tracers
136                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
137                  ! gradient of tracers
138                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
139               ELSE                           ! case 2
140                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
141                  ! interpolated values of tracers
142                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
143                  ! gradient of tracers
144                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
145               ENDIF
146            END DO
147         END DO
148         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
149         !
150      END DO
151
152      ! horizontal derivative of density anomalies (rd)
153      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
154         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
155         DO jj = 1, jpjm1
156            DO ji = 1, jpim1
157               iku = mbku(ji,jj)
158               ikv = mbkv(ji,jj)
159               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
160               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
161               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)     ! i-direction: case 1
162               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)     ! -     -      case 2
163               ENDIF
164               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)     ! j-direction: case 1
165               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)     ! -     -      case 2
166               ENDIF
167            END DO
168         END DO
169
170         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
171         ! step and store it in  zri, zrj for each  case
172         CALL eos( zti, zhi, zri ) 
173         CALL eos( ztj, zhj, zrj )
174
175         ! Gradient of density at the last level
176         DO jj = 1, jpjm1
177            DO ji = 1, jpim1
178               iku = mbku(ji,jj)
179               ikv = mbkv(ji,jj)
180               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
181               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
182               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
183               ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
184               ENDIF
185               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
186               ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
187               ENDIF
188            END DO
189         END DO
190         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
191         !
192      END IF
193      !
194      IF( nn_timing == 1 )  CALL timing_stop( 'zps_hde')
195      !
196   END SUBROUTINE zps_hde
197   !
198   SUBROUTINE zps_hde_isf( kt, kjpt, pta, pgtu, pgtv, pgtui, pgtvi,  &
199      &                          prd, pgru, pgrv, pgrui, pgrvi )
200      !!----------------------------------------------------------------------
201      !!                     ***  ROUTINE zps_hde  ***
202      !!                   
203      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
204      !!      at u- and v-points with a linear interpolation for z-coordinate
205      !!      with partial steps.
206      !!
207      !! ** Method  :   In z-coord with partial steps, scale factors on last
208      !!      levels are different for each grid point, so that T, S and rd
209      !!      points are not at the same depth as in z-coord. To have horizontal
210      !!      gradients again, we interpolate T and S at the good depth :
211      !!      Linear interpolation of T, S   
212      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
213      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
214      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
215      !!         This formulation computes the two cases:
216      !!                 CASE 1                   CASE 2 
217      !!         k-1  ___ ___________   k-1   ___ ___________
218      !!                    Ti  T~                  T~  Ti+1
219      !!                  _____                        _____
220      !!         k        |   |Ti+1     k           Ti |   |
221      !!                  |   |____                ____|   |
222      !!              ___ |   |   |           ___  |   |   |
223      !!                 
224      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
225      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
226      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
227      !!          or
228      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
229      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
230      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
231      !!          Idem for di(s) and dj(s)         
232      !!
233      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
234      !!      depth zh from interpolated T and S for the different formulations
235      !!      of the equation of state (eos).
236      !!      Gradient formulation for rho :
237      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
238      !!
239      !! ** Action  : compute for top and bottom interfaces
240      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
241      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
242      !!              - pmru, pmrv, pmrui, pmrvi: horizontal sum of rho at u- & v- point (used in dynhpg with vvl)
243      !!              - pgzu, pgzv, pgzui, pgzvi: horizontal gradient of z at u- and v- point (used in dynhpg with vvl)
244      !!              - pge3ru, pge3rv, pge3rui, pge3rvi: horizontal gradient of rho weighted by local e3w at u- & v-points
245      !!----------------------------------------------------------------------
246      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
247      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
248      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
249      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
250      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtui, pgtvi  ! hor. grad. of stra at u- & v-pts (ISF)
251      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
252      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv      ! hor. grad of prd at u- & v-pts (bottom)
253      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi      ! hor. grad of prd at u- & v-pts (top)
254      !
255      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
256      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
257      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv, zdzwu, zdzwv, zdzwuip1, zdzwvjp1  ! temporary scalars
258      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
259      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
260      !!----------------------------------------------------------------------
261      !
262      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde_isf')
263      !
264      pgtu (:,:,:)=0.0_wp ; pgtv(:,:,:) =0.0_wp ;
265      pgtui(:,:,:)=0.0_wp ; pgtvi(:,:,:)=0.0_wp ;
266      zti  (:,:,:)=0.0_wp ; ztj  (:,:,:)=0.0_wp ;
267      zhi  (:,:  )=0.0_wp ; zhj  (:,:  )=0.0_wp ;
268      !
269      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
270         !
271         DO jj = 1, jpjm1
272            DO ji = 1, jpim1
273               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
274               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
275               ze3wu = gdept_0(ji+1,jj,iku) - gdept_0(ji,jj,iku)
276               ze3wv = gdept_0(ji,jj+1,ikv) - gdept_0(ji,jj,ikv)
277               !
278               ! i- direction
279               IF( ze3wu >= 0._wp ) THEN      ! case 1
280                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
281                  ! interpolated values of tracers
282                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
283                  ! gradient of  tracers
284                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
285               ELSE                           ! case 2
286                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
287                  ! interpolated values of tracers
288                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
289                  ! gradient of tracers
290                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
291               ENDIF
292               !
293               ! j- direction
294               IF( ze3wv >= 0._wp ) THEN      ! case 1
295                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
296                  ! interpolated values of tracers
297                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
298                  ! gradient of tracers
299                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
300               ELSE                           ! case 2
301                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
302                  ! interpolated values of tracers
303                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
304                  ! gradient of tracers
305                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
306               ENDIF
307            END DO
308         END DO
309         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
310         !
311      END DO
312
313      ! horizontal derivative of density anomalies (rd)
314      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
315         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
316         !
317         DO jj = 1, jpjm1
318            DO ji = 1, jpim1
319               iku = mbku(ji,jj)
320               ikv = mbkv(ji,jj)
321               ze3wu = gdept_0(ji+1,jj,iku) - gdept_0(ji,jj,iku)
322               ze3wv = gdept_0(ji,jj+1,ikv) - gdept_0(ji,jj,ikv)
323
324               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji+1,jj,iku) + ze3wu    ! i-direction: case 1
325               ELSE                        ;   zhi(ji,jj) = fsdept(ji  ,jj,iku) - ze3wu    ! -     -      case 2
326               ENDIF
327               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv) + ze3wv    ! j-direction: case 1
328               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv) - ze3wv    ! -     -      case 2
329               ENDIF
330
331            END DO
332         END DO
333
334         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
335         ! step and store it in  zri, zrj for each  case
336         CALL eos( zti, zhi, zri )
337         CALL eos( ztj, zhj, zrj )
338
339         ! Gradient of density at the last level
340         DO jj = 1, jpjm1
341            DO ji = 1, jpim1
342               iku = mbku(ji,jj)
343               ikv = mbkv(ji,jj)
344               ze3wu = gdept_0(ji+1,jj,iku) - gdept_0(ji,jj,iku)
345               ze3wv = gdept_0(ji,jj+1,ikv) - gdept_0(ji,jj,ikv)
346
347               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
348               ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
349               ENDIF
350               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
351               ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
352               ENDIF
353            END DO
354         END DO
355         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
356         !
357      END IF
358         ! (ISH)  compute grui and gruvi
359      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
360         DO jj = 1, jpjm1
361            DO ji = 1, jpim1
362               iku = miku(ji,jj)   ;  ikup1 = miku(ji,jj) + 1
363               ikv = mikv(ji,jj)   ;  ikvp1 = mikv(ji,jj) + 1
364               !
365               ! (ISF) case partial step top and bottom in adjacent cell in vertical
366               ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
367               ! in this case e3w(i,j) - e3w(i,j+1) is not the distance between Tj~ and Tj
368               ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
369               ze3wu  =  gdept_0(ji,jj,iku) - gdept_0(ji+1,jj,iku)
370               ze3wv  =  gdept_0(ji,jj,ikv) - gdept_0(ji,jj+1,ikv) 
371               ! i- direction
372               IF( ze3wu >= 0._wp ) THEN      ! case 1
373                  zmaxu = ze3wu / fse3w(ji+1,jj,iku+1)
374                  ! interpolated values of tracers
375                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,iku+1,jn) - pta(ji+1,jj,iku,jn) )
376                  ! gradient of tracers
377                  pgtui(ji,jj,jn) = umask(ji,jj,iku) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
378               ELSE                           ! case 2
379                  zmaxu = - ze3wu / fse3w(ji,jj,iku+1)
380                  ! interpolated values of tracers
381                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,iku+1,jn) - pta(ji,jj,iku,jn) )
382                  ! gradient of  tracers
383                  pgtui(ji,jj,jn) = umask(ji,jj,iku) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
384               ENDIF
385               !
386               ! j- direction
387               IF( ze3wv >= 0._wp ) THEN      ! case 1
388                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv+1)
389                  ! interpolated values of tracers
390                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikv+1,jn) - pta(ji,jj+1,ikv,jn) )
391                  ! gradient of tracers
392                  pgtvi(ji,jj,jn) = vmask(ji,jj,ikv) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
393               ELSE                           ! case 2
394                  zmaxv =  - ze3wv / fse3w(ji,jj,ikv+1)
395                  ! interpolated values of tracers
396                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikv+1,jn) - pta(ji,jj,ikv,jn) )
397                  ! gradient of tracers
398                  pgtvi(ji,jj,jn) = vmask(ji,jj,ikv) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
399               ENDIF
400            END DO!!
401         END DO!!
402         CALL lbc_lnk( pgtui(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtvi(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
403         !
404      END DO
405
406      ! horizontal derivative of density anomalies (rd)
407      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
408         pgrui(:,:)  =0.0_wp ; pgrvi(:,:)  =0.0_wp ;
409         DO jj = 1, jpjm1
410            DO ji = 1, jpim1
411               iku = miku(ji,jj)
412               ikv = mikv(ji,jj)
413               ze3wu  =  gdept_0(ji,jj,iku) - gdept_0(ji+1,jj,iku)
414               ze3wv  =  gdept_0(ji,jj,ikv) - gdept_0(ji,jj+1,ikv) 
415
416               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji+1,jj,iku) + ze3wu    ! i-direction: case 1
417               ELSE                        ;   zhi(ji,jj) = fsdept(ji  ,jj,iku) - ze3wu    ! -     -      case 2
418               ENDIF
419
420               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv) + ze3wv    ! j-direction: case 1
421               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv) - ze3wv    ! -     -      case 2
422               ENDIF
423
424            END DO
425         END DO
426
427         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
428         ! step and store it in  zri, zrj for each  case
429         CALL eos( zti, zhi, zri ) 
430         CALL eos( ztj, zhj, zrj )
431
432         ! Gradient of density at the last level
433         DO jj = 1, jpjm1
434            DO ji = 1, jpim1
435               iku = miku(ji,jj) ; ikup1 = miku(ji,jj) + 1
436               ikv = mikv(ji,jj) ; ikvp1 = mikv(ji,jj) + 1
437               ze3wu  =  gdept_0(ji,jj,iku) - gdept_0(ji+1,jj,iku)
438               ze3wv  =  gdept_0(ji,jj,ikv) - gdept_0(ji,jj+1,ikv) 
439
440               IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = umask(ji,jj,iku) * ( zri(ji  ,jj      ) - prd(ji,jj,iku) )          ! i: 1
441               ELSE                      ; pgrui(ji,jj) = umask(ji,jj,iku) * ( prd(ji+1,jj  ,iku) - zri(ji,jj    ) )      ! i: 2
442               ENDIF
443
444               IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = vmask(ji,jj,ikv) * ( zrj(ji  ,jj      ) - prd(ji,jj,ikv) ) ! j: 1
445               ELSE                      ; pgrvi(ji,jj) = vmask(ji,jj,ikv) * ( prd(ji  ,jj+1,ikv) - zrj(ji,jj    ) ) ! j: 2
446               ENDIF
447
448            END DO
449         END DO
450         CALL lbc_lnk( pgrui   , 'U', -1. )   ;   CALL lbc_lnk( pgrvi   , 'V', -1. )   ! Lateral boundary conditions
451         !
452      END IF 
453      !
454      IF( nn_timing == 1 )  CALL timing_stop( 'zps_hde_isf')
455      !
456   END SUBROUTINE zps_hde_isf
457   !!======================================================================
458END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.