New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfbfr.F90 in branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfbfr.F90 @ 5189

Last change on this file since 5189 was 5189, checked in by mathiot, 9 years ago

ISF cleaning branch: simplification and bug correction in hpg_isf, zps_hde_isf, mixed layer definition, slope, diffusion, vertical advection and top friction
  • Property svn:keywords set to Id
File size: 24.8 KB
Line 
1MODULE zdfbfr
2   !!======================================================================
3   !!                       ***  MODULE  zdfbfr  ***
4   !! Ocean physics: Bottom friction
5   !!======================================================================
6   !! History :  OPA  ! 1997-06  (G. Madec, A.-M. Treguier)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.2  ! 2009-09  (A.C.Coward)  Correction to include barotropic contribution
9   !!            3.3  ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
10   !!            3.4  ! 2011-11  (H. Liu) implementation of semi-implicit bottom friction option
11   !!                 ! 2012-06  (H. Liu) implementation of Log Layer bottom friction option
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   zdf_bfr      : update bottom friction coefficient (non-linear bottom friction only)
16   !!   zdf_bfr_init : read in namelist and control the bottom friction parameters.
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE zdf_oce         ! ocean vertical physics variables
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! distributed memory computing
24   USE prtctl          ! Print control
25   USE timing          ! Timing
26   USE wrk_nemo        ! Memory Allocation
27   USE phycst, ONLY: vkarmn
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   zdf_bfr         ! called by step.F90
33   PUBLIC   zdf_bfr_init    ! called by nemogcm.F90
34
35   !                                 !!* Namelist nambfr: bottom friction namelist *
36   INTEGER , PUBLIC ::   nn_bfr       ! = 0/1/2/3 type of bottom friction  (PUBLIC for TAM)
37   REAL(wp), PUBLIC ::   rn_bfri1     ! bottom drag coefficient (linear case)  (PUBLIC for TAM)
38   REAL(wp), PUBLIC ::   rn_bfri2     ! bottom drag coefficient (non linear case) (PUBLIC for TAM)
39   REAL(wp), PUBLIC ::   rn_bfri2_max ! Maximum bottom drag coefficient (non linear case and ln_loglayer=T) (PUBLIC for TAM)
40   REAL(wp), PUBLIC ::   rn_bfeb2     ! background bottom turbulent kinetic energy  [m2/s2] (PUBLIC for TAM)
41   REAL(wp), PUBLIC ::   rn_bfrien    ! local factor to enhance coefficient bfri (PUBLIC for TAM)
42   LOGICAL , PUBLIC ::   ln_bfr2d     ! logical switch for 2D enhancement (PUBLIC for TAM)
43   REAL(wp), PUBLIC ::   rn_tfri1     ! top drag coefficient (linear case)  (PUBLIC for TAM)
44   REAL(wp), PUBLIC ::   rn_tfri2     ! top drag coefficient (non linear case) (PUBLIC for TAM)
45   REAL(wp), PUBLIC ::   rn_tfri2_max ! Maximum top drag coefficient (non linear case and ln_loglayer=T) (PUBLIC for TAM)
46   REAL(wp), PUBLIC ::   rn_tfeb2     ! background top turbulent kinetic energy  [m2/s2] (PUBLIC for TAM)
47   REAL(wp), PUBLIC ::   rn_tfrien    ! local factor to enhance coefficient tfri (PUBLIC for TAM)
48   LOGICAL , PUBLIC ::   ln_tfr2d     ! logical switch for 2D enhancement (PUBLIC for TAM)
49
50   LOGICAL , PUBLIC ::   ln_loglayer  ! switch for log layer bfr coeff. (PUBLIC for TAM)
51   REAL(wp), PUBLIC ::   rn_bfrz0     ! bottom roughness for loglayer bfr coeff (PUBLIC for TAM)
52   REAL(wp), PUBLIC ::   rn_tfrz0     ! bottom roughness for loglayer bfr coeff (PUBLIC for TAM)
53   LOGICAL , PUBLIC ::   ln_bfrimp    ! logical switch for implicit bottom friction
54   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:), PUBLIC ::  bfrcoef2d, tfrcoef2d   ! 2D bottom/top drag coefficient (PUBLIC for TAM)
55
56   !! * Substitutions
57#  include "vectopt_loop_substitute.h90"
58#  include "domzgr_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
61   !! $Id$
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   INTEGER FUNCTION zdf_bfr_alloc()
67      !!----------------------------------------------------------------------
68      !!                ***  FUNCTION zdf_bfr_alloc  ***
69      !!----------------------------------------------------------------------
70      ALLOCATE( bfrcoef2d(jpi,jpj), tfrcoef2d(jpi,jpj), STAT=zdf_bfr_alloc )
71      !
72      IF( lk_mpp             )   CALL mpp_sum ( zdf_bfr_alloc )
73      IF( zdf_bfr_alloc /= 0 )   CALL ctl_warn('zdf_bfr_alloc: failed to allocate arrays.')
74   END FUNCTION zdf_bfr_alloc
75
76
77   SUBROUTINE zdf_bfr( kt )
78      !!----------------------------------------------------------------------
79      !!                   ***  ROUTINE zdf_bfr  ***
80      !!
81      !! ** Purpose :   compute the bottom friction coefficient.
82      !!
83      !! ** Method  :   Calculate and store part of the momentum trend due
84      !!              to bottom friction following the chosen friction type
85      !!              (free-slip, linear, or quadratic). The component
86      !!              calculated here is multiplied by the bottom velocity in
87      !!              dyn_bfr to provide the trend term.
88      !!                The coefficients are updated at each time step only
89      !!              in the quadratic case.
90      !!
91      !! ** Action  :   bfrua , bfrva   bottom friction coefficients
92      !!----------------------------------------------------------------------
93      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
94      !!
95      INTEGER  ::   ji, jj                       ! dummy loop indices
96      INTEGER  ::   ikbt, ikbu, ikbv             ! local integers
97      REAL(wp) ::   zvu, zuv, zecu, zecv, ztmp   ! temporary scalars
98      REAL(wp), POINTER, DIMENSION(:,:) ::  zbfrt, ztfrt
99      !!----------------------------------------------------------------------
100      !
101      IF( nn_timing == 1 )  CALL timing_start('zdf_bfr')
102      !
103      IF( kt == nit000 .AND. lwp ) THEN
104         WRITE(numout,*)
105         WRITE(numout,*) 'zdf_bfr : Set bottom friction coefficient (non-linear case)'
106         WRITE(numout,*) '~~~~~~~~'
107      ENDIF
108      !
109      IF( nn_bfr == 2 ) THEN                 ! quadratic bottom friction only
110         !
111         CALL wrk_alloc( jpi, jpj, zbfrt, ztfrt )
112
113         IF ( ln_loglayer.AND.lk_vvl ) THEN ! "log layer" bottom friction coefficient
114
115            DO jj = 1, jpj
116               DO ji = 1, jpi
117                  ikbt = mbkt(ji,jj)
118!! JC: possible WAD implementation should modify line below if layers vanish
119                  ztmp = tmask(ji,jj,ikbt) * ( vkarmn / LOG( 0.5_wp * fse3t_n(ji,jj,ikbt) / rn_bfrz0 ))**2._wp
120                  zbfrt(ji,jj) = MAX(bfrcoef2d(ji,jj), ztmp)
121                  zbfrt(ji,jj) = MIN(zbfrt(ji,jj), rn_bfri2_max)
122               END DO
123            END DO
124! (ISF)
125            IF ( ln_isfcav ) THEN
126               DO jj = 1, jpj
127                  DO ji = 1, jpi
128                     ikbt = mikt(ji,jj)
129! JC: possible WAD implementation should modify line below if layers vanish
130                     ztmp = (1-tmask(ji,jj,1)) * ( vkarmn / LOG( 0.5_wp * fse3t_n(ji,jj,ikbt) / rn_bfrz0 ))**2._wp
131                     ztfrt(ji,jj) = MAX(tfrcoef2d(ji,jj), ztmp)
132                     ztfrt(ji,jj) = MIN(ztfrt(ji,jj), rn_tfri2_max)
133                  END DO
134               END DO
135            END IF
136         !   
137         ELSE
138            zbfrt(:,:) = bfrcoef2d(:,:)
139            ztfrt(:,:) = tfrcoef2d(:,:)
140         ENDIF
141
142         DO jj = 2, jpjm1
143            DO ji = 2, jpim1
144               ikbu = mbku(ji,jj)         ! ocean bottom level at u- and v-points
145               ikbv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
146               !
147               zvu  = 0.25 * (  vn(ji,jj  ,ikbu) + vn(ji+1,jj  ,ikbu)     &
148                  &           + vn(ji,jj-1,ikbu) + vn(ji+1,jj-1,ikbu)  )
149               zuv  = 0.25 * (  un(ji,jj  ,ikbv) + un(ji-1,jj  ,ikbv)     &
150                  &           + un(ji,jj+1,ikbv) + un(ji-1,jj+1,ikbv)  )
151               !
152               zecu = SQRT(  un(ji,jj,ikbu) * un(ji,jj,ikbu) + zvu*zvu + rn_bfeb2  )
153               zecv = SQRT(  vn(ji,jj,ikbv) * vn(ji,jj,ikbv) + zuv*zuv + rn_bfeb2  )
154               !
155               bfrua(ji,jj) = - 0.5_wp * ( zbfrt(ji,jj) + zbfrt(ji+1,jj  ) ) * zecu
156               bfrva(ji,jj) = - 0.5_wp * ( zbfrt(ji,jj) + zbfrt(ji  ,jj+1) ) * zecv
157               !
158               ! in case of 2 cell water column, we assume each cell feels the top and bottom friction
159               IF ( ln_isfcav ) THEN
160                  IF ( miku(ji,jj) + 1 .GE. mbku(ji,jj) ) THEN
161                     bfrua(ji,jj) = - 0.5_wp * ( ( zbfrt(ji,jj) + zbfrt(ji+1,jj  ) )   &
162                                  &            + ( ztfrt(ji,jj) + ztfrt(ji+1,jj  ) ) ) &
163                                  &          * zecu * (1._wp - umask(ji,jj,1))
164                  END IF
165                  IF ( mikv(ji,jj) + 1 .GE. mbkv(ji,jj) ) THEN
166                     bfrva(ji,jj) = - 0.5_wp * ( ( zbfrt(ji,jj) + zbfrt(ji  ,jj+1) )   &
167                                  &            + ( ztfrt(ji,jj) + ztfrt(ji  ,jj+1) ) ) &
168                                  &          * zecv * (1._wp - vmask(ji,jj,1))
169                  END IF
170               END IF
171            END DO
172         END DO
173         CALL lbc_lnk( bfrua, 'U', 1. )   ;   CALL lbc_lnk( bfrva, 'V', 1. )      ! Lateral boundary condition
174         IF ( ln_isfcav ) THEN
175            DO jj = 2, jpjm1
176               DO ji = 2, jpim1
177                  ! (ISF) ========================================================================
178                  ikbu = miku(ji,jj)         ! ocean bottom level at u- and v-points
179                  ikbv = mikv(ji,jj)         ! (deepest ocean u- and v-points)
180                  !
181                  zvu  = 0.25 * (  vn(ji,jj  ,ikbu) + vn(ji+1,jj  ,ikbu)     &
182                     &           + vn(ji,jj-1,ikbu) + vn(ji+1,jj-1,ikbu)  )
183                  zuv  = 0.25 * (  un(ji,jj  ,ikbv) + un(ji-1,jj  ,ikbv)     &
184                     &           + un(ji,jj+1,ikbv) + un(ji-1,jj+1,ikbv)  )
185              !
186                  zecu = SQRT(  un(ji,jj,ikbu) * un(ji,jj,ikbu) + zvu*zvu + rn_bfeb2 )
187                  zecv = SQRT(  vn(ji,jj,ikbv) * vn(ji,jj,ikbv) + zuv*zuv + rn_bfeb2 )
188              !
189                  tfrua(ji,jj) = - 0.5_wp * ( ztfrt(ji,jj) + ztfrt(ji+1,jj  ) ) * zecu * (1._wp - umask(ji,jj,1))
190                  tfrva(ji,jj) = - 0.5_wp * ( ztfrt(ji,jj) + ztfrt(ji  ,jj+1) ) * zecv * (1._wp - vmask(ji,jj,1))
191              ! (ISF) END ====================================================================
192              ! in case of 2 cell water column, we assume each cell feels the top and bottom friction
193                  IF ( miku(ji,jj) + 1 .GE. mbku(ji,jj) ) THEN
194                     tfrua(ji,jj) = - 0.5_wp * ( ( ztfrt(ji,jj) + ztfrt(ji+1,jj  ) )   &
195                                  &            + ( zbfrt(ji,jj) + zbfrt(ji+1,jj  ) ) ) &
196                                  &          * zecu * (1._wp - umask(ji,jj,1))
197                  END IF
198                  IF ( mikv(ji,jj) + 1 .GE. mbkv(ji,jj) ) THEN
199                     tfrva(ji,jj) = - 0.5_wp * ( ( ztfrt(ji,jj) + ztfrt(ji  ,jj+1) )   &
200                                  &            + ( zbfrt(ji,jj) + zbfrt(ji  ,jj+1) ) ) &
201                                  &          * zecv * (1._wp - vmask(ji,jj,1))
202                  END IF
203               END DO
204            END DO
205            CALL lbc_lnk( tfrua, 'U', 1. )   ;   CALL lbc_lnk( tfrva, 'V', 1. )      ! Lateral boundary condition
206         END IF
207         !
208         !
209         IF(ln_ctl)   CALL prt_ctl( tab2d_1=bfrua, clinfo1=' bfr  - u: ', mask1=umask,        &
210            &                       tab2d_2=bfrva, clinfo2=       ' v: ', mask2=vmask,ovlap=1 )
211         CALL wrk_dealloc( jpi,jpj,zbfrt, ztfrt )
212      ENDIF
213      !
214      IF( nn_timing == 1 )  CALL timing_stop('zdf_bfr')
215      !
216   END SUBROUTINE zdf_bfr
217
218
219   SUBROUTINE zdf_bfr_init
220      !!----------------------------------------------------------------------
221      !!                  ***  ROUTINE zdf_bfr_init  ***
222      !!
223      !! ** Purpose :   Initialization of the bottom friction
224      !!
225      !! ** Method  :   Read the nambfr namelist and check their consistency
226      !!                called at the first timestep (nit000)
227      !!----------------------------------------------------------------------
228      USE iom   ! I/O module for ehanced bottom friction file
229      !!
230      INTEGER   ::   inum         ! logical unit for enhanced bottom friction file
231      INTEGER   ::   ji, jj       ! dummy loop indexes
232      INTEGER   ::   ikbt, ikbu, ikbv   ! temporary integers
233      INTEGER   ::   ictu, ictv         !    -          -
234      INTEGER   ::   ios
235      REAL(wp)  ::   zminbfr, zmaxbfr   ! temporary scalars
236      REAL(wp)  ::   zmintfr, zmaxtfr   ! temporary scalars
237      REAL(wp)  ::   ztmp, zfru, zfrv   !    -         -
238      !!
239      NAMELIST/nambfr/ nn_bfr, rn_bfri1, rn_bfri2, rn_bfri2_max, rn_bfeb2, rn_bfrz0, ln_bfr2d, &
240                    &          rn_tfri1, rn_tfri2, rn_tfri2_max, rn_tfeb2, rn_tfrz0, ln_tfr2d, &
241                    &  rn_bfrien, rn_tfrien, ln_bfrimp, ln_loglayer
242      !!----------------------------------------------------------------------
243      !
244      IF( nn_timing == 1 )  CALL timing_start('zdf_bfr_init')
245      !
246      !                              !* Allocate zdfbfr arrays
247      IF( zdf_bfr_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_bfr_init : unable to allocate arrays' )
248      !
249      !                              !* Parameter control and print
250      !
251      REWIND( numnam_ref )              ! Namelist nambfr in reference namelist : Bottom momentum boundary condition
252      READ  ( numnam_ref, nambfr, IOSTAT = ios, ERR = 901)
253901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambfr in reference namelist', lwp )
254
255      REWIND( numnam_cfg )              ! Namelist nambfr in configuration namelist : Bottom momentum boundary condition
256      READ  ( numnam_cfg, nambfr, IOSTAT = ios, ERR = 902 )
257902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambfr in configuration namelist', lwp )
258      IF(lwm) WRITE ( numond, nambfr )
259      IF(lwp) WRITE(numout,*)
260      IF(lwp) WRITE(numout,*) 'zdf_bfr_init : momentum bottom friction'
261      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
262      IF(lwp) WRITE(numout,*) '   Namelist nam_bfr : set bottom friction parameters'
263      !
264      SELECT CASE (nn_bfr)
265      !
266      CASE( 0 )
267         IF(lwp) WRITE(numout,*) '      free-slip '
268         bfrua(:,:) = 0.e0
269         bfrva(:,:) = 0.e0
270         tfrua(:,:) = 0.e0
271         tfrva(:,:) = 0.e0
272         !
273      CASE( 1 )
274         IF(lwp) WRITE(numout,*) '      linear botton friction'
275         IF(lwp) WRITE(numout,*) '      bottom friction coef.   rn_bfri1  = ', rn_bfri1
276         IF( ln_bfr2d ) THEN
277            IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_bfr2d  = ', ln_bfr2d
278            IF(lwp) WRITE(numout,*) '      coef rn_bfri2 enhancement factor                rn_bfrien  = ',rn_bfrien
279         ENDIF
280         IF(lwp) WRITE(numout,*) '      top    friction coef.   rn_bfri1  = ', rn_bfri1
281         IF( ln_tfr2d ) THEN
282            IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_tfr2d  = ', ln_tfr2d
283            IF(lwp) WRITE(numout,*) '      coef rn_tfri2 enhancement factor                rn_tfrien  = ',rn_tfrien
284         ENDIF
285         !
286         IF(ln_bfr2d) THEN
287            ! bfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
288            CALL iom_open('bfr_coef.nc',inum)
289            CALL iom_get (inum, jpdom_data, 'bfr_coef',bfrcoef2d,1) ! bfrcoef2d is used as tmp array
290            CALL iom_close(inum)
291            bfrcoef2d(:,:) = rn_bfri1 * ( 1 + rn_bfrien * bfrcoef2d(:,:) )
292         ELSE
293            bfrcoef2d(:,:) = rn_bfri1  ! initialize bfrcoef2d to the namelist variable
294         ENDIF
295         !
296         bfrua(:,:) = - bfrcoef2d(:,:)
297         bfrva(:,:) = - bfrcoef2d(:,:)
298         !
299         IF ( ln_isfcav ) THEN
300            IF(ln_tfr2d) THEN
301               ! tfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
302               CALL iom_open('tfr_coef.nc',inum)
303               CALL iom_get (inum, jpdom_data, 'tfr_coef',tfrcoef2d,1) ! tfrcoef2d is used as tmp array
304               CALL iom_close(inum)
305               tfrcoef2d(:,:) = rn_tfri1 * ( 1 + rn_tfrien * tfrcoef2d(:,:) )
306            ELSE
307               tfrcoef2d(:,:) = rn_tfri1  ! initialize tfrcoef2d to the namelist variable
308            ENDIF
309            !
310            tfrua(:,:) = - tfrcoef2d(:,:)
311            tfrva(:,:) = - tfrcoef2d(:,:)
312         END IF
313         !
314      CASE( 2 )
315         IF(lwp) WRITE(numout,*) '      quadratic bottom friction'
316         IF(lwp) WRITE(numout,*) '      friction coef.   rn_bfri2  = ', rn_bfri2
317         IF(lwp) WRITE(numout,*) '      Max. coef. (log case)   rn_bfri2_max  = ', rn_bfri2_max
318         IF(lwp) WRITE(numout,*) '      background tke   rn_bfeb2  = ', rn_bfeb2
319         IF(lwp) WRITE(numout,*) '      log formulation   ln_bfr2d = ', ln_loglayer
320         IF(lwp) WRITE(numout,*) '      bottom roughness  rn_bfrz0 [m] = ', rn_bfrz0
321         IF( rn_bfrz0<=0.e0 ) THEN
322            WRITE(ctmp1,*) '      bottom roughness must be strictly positive'
323            CALL ctl_stop( ctmp1 )
324         ENDIF
325         IF( ln_bfr2d ) THEN
326            IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_bfr2d  = ', ln_bfr2d
327            IF(lwp) WRITE(numout,*) '      coef rn_bfri2 enhancement factor                rn_bfrien  = ',rn_bfrien
328         ENDIF
329         IF(lwp) WRITE(numout,*) '      quadratic top    friction'
330         IF(lwp) WRITE(numout,*) '      friction coef.   rn_bfri2  = ', rn_tfri2
331         IF(lwp) WRITE(numout,*) '      Max. coef. (log case)   rn_tfri2_max  = ', rn_tfri2_max
332         IF(lwp) WRITE(numout,*) '      background tke   rn_tfeb2  = ', rn_tfeb2
333         IF(lwp) WRITE(numout,*) '      log formulation   ln_tfr2d = ', ln_loglayer
334         IF(lwp) WRITE(numout,*) '      bottom roughness  rn_tfrz0 [m] = ', rn_tfrz0
335         IF( rn_tfrz0<=0.e0 ) THEN
336            WRITE(ctmp1,*) '      bottom roughness must be strictly positive'
337            CALL ctl_stop( ctmp1 )
338         ENDIF
339         IF( ln_tfr2d ) THEN
340            IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_tfr2d  = ', ln_tfr2d
341            IF(lwp) WRITE(numout,*) '      coef rn_tfri2 enhancement factor                rn_tfrien  = ',rn_tfrien
342         ENDIF
343         !
344         IF(ln_bfr2d) THEN
345            ! bfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
346            CALL iom_open('bfr_coef.nc',inum)
347            CALL iom_get (inum, jpdom_data, 'bfr_coef',bfrcoef2d,1) ! bfrcoef2d is used as tmp array
348            CALL iom_close(inum)
349            !
350            bfrcoef2d(:,:) = rn_bfri2 * ( 1 + rn_bfrien * bfrcoef2d(:,:) )
351         ELSE
352            bfrcoef2d(:,:) = rn_bfri2  ! initialize bfrcoef2d to the namelist variable
353         ENDIF
354         
355         IF ( ln_isfcav ) THEN
356            IF(ln_tfr2d) THEN
357               ! tfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
358               CALL iom_open('tfr_coef.nc',inum)
359               CALL iom_get (inum, jpdom_data, 'tfr_coef',tfrcoef2d,1) ! bfrcoef2d is used as tmp array
360               CALL iom_close(inum)
361               !
362               tfrcoef2d(:,:) = rn_tfri2 * ( 1 + rn_tfrien * tfrcoef2d(:,:) )
363            ELSE
364               tfrcoef2d(:,:) = rn_tfri2  ! initialize tfrcoef2d to the namelist variable
365            ENDIF
366         END IF
367         !
368         IF ( ln_loglayer.AND.(.NOT.lk_vvl) ) THEN ! set "log layer" bottom friction once for all
369            DO jj = 1, jpj
370               DO ji = 1, jpi
371                  ikbt = mbkt(ji,jj)
372                  ztmp = tmask(ji,jj,ikbt) * ( vkarmn / LOG( 0.5_wp * fse3t_n(ji,jj,ikbt) / rn_bfrz0 ))**2._wp
373                  bfrcoef2d(ji,jj) = MAX(bfrcoef2d(ji,jj), ztmp)
374                  bfrcoef2d(ji,jj) = MIN(bfrcoef2d(ji,jj), rn_bfri2_max)
375               END DO
376            END DO
377            IF ( ln_isfcav ) THEN
378               DO jj = 1, jpj
379                  DO ji = 1, jpi
380                     ikbt = mikt(ji,jj)
381                     ztmp = tmask(ji,jj,ikbt) * ( vkarmn / LOG( 0.5_wp * fse3t_n(ji,jj,ikbt) / rn_tfrz0 ))**2._wp
382                     tfrcoef2d(ji,jj) = MAX(tfrcoef2d(ji,jj), ztmp)
383                     tfrcoef2d(ji,jj) = MIN(tfrcoef2d(ji,jj), rn_tfri2_max)
384                  END DO
385               END DO
386            END IF
387         ENDIF
388         !
389      CASE DEFAULT
390         IF(lwp) WRITE(ctmp1,*) '         bad flag value for nn_bfr = ', nn_bfr
391         CALL ctl_stop( ctmp1 )
392         !
393      END SELECT
394      !
395      IF(lwp) WRITE(numout,*) '      implicit bottom friction switch                ln_bfrimp  = ', ln_bfrimp
396      !
397      !                              ! Make sure ln_zdfexp=.false. when use implicit bfr
398      IF( ln_bfrimp .AND. ln_zdfexp ) THEN
399         IF(lwp) THEN
400            WRITE(numout,*)
401            WRITE(numout,*) 'Implicit bottom friction can only be used when ln_zdfexp=.false.'
402            WRITE(numout,*) '         but you set: ln_bfrimp=.true. and ln_zdfexp=.true.!!!!'
403            WRITE(ctmp1,*)  '         set either ln_zdfexp = .false or ln_bfrimp = .false.'
404            CALL ctl_stop( ctmp1 )
405         END IF
406      END IF
407      !
408      ! Basic stability check on bottom friction coefficient
409      !
410      ictu = 0               ! counter for stability criterion breaches at U-pts
411      ictv = 0               ! counter for stability criterion breaches at V-pts
412      zminbfr =  1.e10_wp    ! initialise tracker for minimum of bottom friction coefficient
413      zmaxbfr = -1.e10_wp    ! initialise tracker for maximum of bottom friction coefficient
414      zmintfr =  1.e10_wp    ! initialise tracker for minimum of bottom friction coefficient
415      zmaxtfr = -1.e10_wp    ! initialise tracker for maximum of bottom friction coefficient
416      !
417      DO jj = 2, jpjm1
418         DO ji = 2, jpim1
419             ikbu = mbku(ji,jj)       ! deepest ocean level at u- and v-points
420             ikbv = mbkv(ji,jj)
421             zfru = 0.5 * fse3u(ji,jj,ikbu) / rdt
422             zfrv = 0.5 * fse3v(ji,jj,ikbv) / rdt
423             IF( ABS( bfrcoef2d(ji,jj) ) > zfru ) THEN
424                IF( ln_ctl ) THEN
425                   WRITE(numout,*) 'BFR ', narea, nimpp+ji, njmpp+jj, ikbu
426                   WRITE(numout,*) 'BFR ', ABS( bfrcoef2d(ji,jj) ), zfru
427                ENDIF
428                ictu = ictu + 1
429             ENDIF
430             IF( ABS( bfrcoef2d(ji,jj) ) > zfrv ) THEN
431                 IF( ln_ctl ) THEN
432                     WRITE(numout,*) 'BFR ', narea, nimpp+ji, njmpp+jj, ikbv
433                     WRITE(numout,*) 'BFR ', bfrcoef2d(ji,jj), zfrv
434                 ENDIF
435                 ictv = ictv + 1
436             ENDIF
437             zminbfr = MIN(  zminbfr, MIN( zfru, ABS( bfrcoef2d(ji,jj) ) )  )
438             zmaxbfr = MAX(  zmaxbfr, MIN( zfrv, ABS( bfrcoef2d(ji,jj) ) )  )
439! (ISF)
440             IF ( ln_isfcav ) THEN
441                ikbu = miku(ji,jj)       ! deepest ocean level at u- and v-points
442                ikbv = mikv(ji,jj)
443                zfru = 0.5 * fse3u(ji,jj,ikbu) / rdt
444                zfrv = 0.5 * fse3v(ji,jj,ikbv) / rdt
445                IF( ABS( tfrcoef2d(ji,jj) ) > zfru ) THEN
446                   IF( ln_ctl ) THEN
447                      WRITE(numout,*) 'BFR ', narea, nimpp+ji, njmpp+jj, ikbu
448                      WRITE(numout,*) 'BFR ', ABS( tfrcoef2d(ji,jj) ), zfru
449                   ENDIF
450                   ictu = ictu + 1
451                ENDIF
452                IF( ABS( tfrcoef2d(ji,jj) ) > zfrv ) THEN
453                   IF( ln_ctl ) THEN
454                      WRITE(numout,*) 'BFR ', narea, nimpp+ji, njmpp+jj, ikbv
455                      WRITE(numout,*) 'BFR ', tfrcoef2d(ji,jj), zfrv
456                   ENDIF
457                   ictv = ictv + 1
458                ENDIF
459                zmintfr = MIN(  zmintfr, MIN( zfru, ABS( tfrcoef2d(ji,jj) ) )  )
460                zmaxtfr = MAX(  zmaxtfr, MIN( zfrv, ABS( tfrcoef2d(ji,jj) ) )  )
461             END IF
462! END ISF
463         END DO
464      END DO
465      IF( lk_mpp ) THEN
466         CALL mpp_sum( ictu )
467         CALL mpp_sum( ictv )
468         CALL mpp_min( zminbfr )
469         CALL mpp_max( zmaxbfr )
470         IF ( ln_isfcav) CALL mpp_min( zmintfr )
471         IF ( ln_isfcav) CALL mpp_max( zmaxtfr )
472      ENDIF
473      IF( .NOT.ln_bfrimp) THEN
474      IF( lwp .AND. ictu + ictv > 0 ) THEN
475         WRITE(numout,*) ' Bottom friction stability check failed at ', ictu, ' U-points '
476         WRITE(numout,*) ' Bottom friction stability check failed at ', ictv, ' V-points '
477         WRITE(numout,*) ' Bottom friction coefficient now ranges from: ', zminbfr, ' to ', zmaxbfr
478         WRITE(numout,*) ' Bottom friction coefficient will be reduced where necessary'
479         IF ( ln_isfcav ) WRITE(numout,*) ' Top friction coefficient now ranges from: ', zmintfr, ' to ', zmaxtfr
480      ENDIF
481      ENDIF
482      !
483      IF( nn_timing == 1 )  CALL timing_stop('zdf_bfr_init')
484      !
485   END SUBROUTINE zdf_bfr_init
486
487   !!======================================================================
488END MODULE zdfbfr
Note: See TracBrowser for help on using the repository browser.