New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in branches/2015/dev_r5171_CNRS_LIM3_seaicebgc/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2015/dev_r5171_CNRS_LIM3_seaicebgc/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsed.F90 @ 5184

Last change on this file since 5184 was 5184, checked in by vancop, 9 years ago

TOP ice routines
File size: 20.4 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11#if defined key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_sed        :  Compute loss of organic matter in the sediments
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE p4zrem          !  Remineralisation of organic matter
24   USE p4zsbc          !  External source of nutrients
25   USE p4zint          !  interpolation and computation of various fields
26   USE iom             !  I/O manager
27   USE prtctl_trc      !  print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_sed   
33
34   !! * Module variables
35   REAL(wp) :: r1_rday                  !: inverse of rday
36
37   INTEGER ::  numnit 
38
39
40   !!* Substitution
41#  include "top_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
44   !! $Header:$
45   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE p4z_sed( kt, jnt )
50      !!---------------------------------------------------------------------
51      !!                     ***  ROUTINE p4z_sed  ***
52      !!
53      !! ** Purpose :   Compute loss of organic matter in the sediments. This
54      !!              is by no way a sediment model. The loss is simply
55      !!              computed to balance the inout from rivers and dust
56      !!
57      !! ** Method  : - ???
58      !!---------------------------------------------------------------------
59      !
60      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
61      INTEGER  ::   ji, jj, jk, ikt
62#if ! defined key_sed
63      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
64      REAL(wp) ::   zrivalk, zrivsil, zrivno3
65#endif
66      REAL(wp) ::  zwflux, zfminus, zfplus
67      REAL(wp) ::  zlim, zfact, zfactcal
68      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit
69      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep, zwstpoc
70      REAL(wp) ::  ztrfer, ztrpo4, zwdust, zlight
71      REAL(wp) ::  zrdenittot, zsdenittot, znitrpottot
72      !
73      CHARACTER (len=25) :: charout
74      REAL(wp), POINTER, DIMENSION(:,:  ) :: zpdep, zsidep, zwork1, zwork2, zwork3, zwork4
75      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zbureff
76      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsbio3, zwsbio4, zwscal
77      REAL(wp), POINTER, DIMENSION(:,:,:) :: znitrpot, zirondep, zsoufer
78      !!---------------------------------------------------------------------
79      !
80      IF( nn_timing == 1 )  CALL timing_start('p4z_sed')
81      !
82      IF( kt == nittrc000 .AND. jnt == 1 )  THEN
83         r1_rday  = 1. / rday
84         IF( ln_check_mass .AND. lwp)  &
85           &  CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
86      ENDIF
87      !
88      ! Allocate temporary workspace
89      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
90      CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
91      CALL wrk_alloc( jpi, jpj, jpk, znitrpot, zsoufer )
92
93      zdenit2d(:,:) = 0.e0
94      zbureff (:,:) = 0.e0
95      zwork1  (:,:) = 0.e0
96      zwork2  (:,:) = 0.e0
97      zwork3  (:,:) = 0.e0
98      zwork4  (:,:) = 0.e0
99
100      ! Add the external input of nutrients from dust deposition
101      ! ----------------------------------------------------------
102      IF( ln_dust ) THEN
103         !                                             
104         CALL wrk_alloc( jpi, jpj,      zpdep, zsidep )
105         CALL wrk_alloc( jpi, jpj, jpk, zirondep      )
106         !                                              ! Iron and Si deposition at the surface
107         IF( ln_solub ) THEN
108            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
109         ELSE
110            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
111         ENDIF
112         zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 28.1 
113         zpdep (:,:) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 31. / po4r 
114         !                                              ! Iron solubilization of particles in the water column
115         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
116         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
117         DO jk = 2, jpkm1
118            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -fsdept(:,:,jk) / 540. )
119         END DO
120         !                                              ! Iron solubilization of particles in the water column
121         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + zpdep   (:,:)
122         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + zsidep  (:,:)
123         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + zirondep(:,:,:) 
124         !
125         IF( lk_iomput ) THEN
126            IF( jnt == nrdttrc ) THEN
127                IF( iom_use( "Irondep" ) )   &
128                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
129                IF( iom_use( "pdust" ) )   &
130                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
131            ENDIF
132         ELSE                                   
133            IF( ln_diatrc )  &
134              &  trc2d(:,:,jp_pcs0_2d + 11) = zirondep(:,:,1) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1)
135         ENDIF
136         CALL wrk_dealloc( jpi, jpj,      zpdep, zsidep )
137         CALL wrk_dealloc( jpi, jpj, jpk, zirondep      )
138         !                                             
139      ENDIF
140     
141      ! Add the external input of nutrients from river
142      ! ----------------------------------------------------------
143      IF( ln_river ) THEN
144         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + rivdip(:,:) * rfact2
145         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + rivdin(:,:) * rfact2
146         trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + rivdic(:,:) * 5.e-5 * rfact2
147         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + rivdsi(:,:) * rfact2
148         trn(:,:,1,jpdic) = trn(:,:,1,jpdic) + rivdic(:,:) * rfact2
149         trn(:,:,1,jptal) = trn(:,:,1,jptal) + ( rivalk(:,:) - rno3 * rivdin(:,:) ) * rfact2
150      ENDIF
151     
152      ! Add the external input of nutrients from nitrogen deposition
153      ! ----------------------------------------------------------
154      IF( ln_ndepo ) THEN
155         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + nitdep(:,:) * rfact2
156         trn(:,:,1,jptal) = trn(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
157      ENDIF
158
159      ! Add the external input of iron from sediment mobilization
160      ! ------------------------------------------------------
161      IF( ln_ironsed ) THEN
162         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
163         !
164         IF( lk_iomput .AND. jnt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
165            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
166      ENDIF
167
168      ! Add the external input of iron from hydrothermal vents
169      ! ------------------------------------------------------
170      IF( ln_hydrofe ) THEN
171         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
172         !
173         IF( lk_iomput .AND. jnt == nrdttrc .AND. iom_use( "HYDR" ) )   &
174            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
175      ENDIF
176
177      ! OA: Warning, the following part is necessary, especially with Kriest
178      ! to avoid CFL problems above the sediments
179      ! --------------------------------------------------------------------
180      DO jj = 1, jpj
181         DO ji = 1, jpi
182            ikt  = mbkt(ji,jj)
183            zdep = fse3t(ji,jj,ikt) / xstep
184            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
185            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
186            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
187         END DO
188      END DO
189
190#if ! defined key_sed
191      ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
192      ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
193      ! -------------------------------------------------------
194      DO jj = 1, jpj
195         DO ji = 1, jpi
196           IF( tmask(ji,jj,1) == 1 ) THEN
197              ikt = mbkt(ji,jj)
198# if defined key_kriest
199              zflx =    trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)    * 1E3 * 1E6 / 1E4
200# else
201              zflx = (  trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
202                &     + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
203#endif
204              zflx  = LOG10( MAX( 1E-3, zflx ) )
205              zo2   = LOG10( MAX( 10. , trn(ji,jj,ikt,jpoxy) * 1E6 ) )
206              zno3  = LOG10( MAX( 1.  , trn(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
207              zdep  = LOG10( fsdepw(ji,jj,ikt+1) )
208              zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
209              &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
210              zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
211              !
212              zflx = (  trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
213                &     + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
214              zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
215           ENDIF
216         END DO
217      END DO 
218
219      ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
220      ! First, the total loss is computed.
221      ! The factor for calcite comes from the alkalinity effect
222      ! -------------------------------------------------------------
223      DO jj = 1, jpj
224         DO ji = 1, jpi
225            IF( tmask(ji,jj,1) == 1 ) THEN
226               ikt = mbkt(ji,jj) 
227# if defined key_kriest
228               zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwscal (ji,jj)
229               zwork2(ji,jj) = trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)
230# else
231               zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
232               zwork2(ji,jj) = trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
233# endif
234               ! For calcite, burial efficiency is made a function of saturation
235               zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
236               zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
237               zwork3(ji,jj) = trn(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
238            ENDIF
239         END DO
240      END DO
241      zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
242      zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
243      zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
244#endif
245
246      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
247      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
248      ! ------------------------------------------------------
249#if ! defined key_sed
250      zrivsil =  1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn )
251#endif
252
253      DO jj = 1, jpj
254         DO ji = 1, jpi
255            ikt  = mbkt(ji,jj)
256            zdep = xstep / fse3t(ji,jj,ikt)
257            zws4 = zwsbio4(ji,jj) * zdep
258            zwsc = zwscal (ji,jj) * zdep
259# if defined key_kriest
260            zsiloss = trn(ji,jj,ikt,jpgsi) * zws4
261# else
262            zsiloss = trn(ji,jj,ikt,jpgsi) * zwsc
263# endif
264            zcaloss = trn(ji,jj,ikt,jpcal) * zwsc
265            !
266            trn(ji,jj,ikt,jpgsi) = trn(ji,jj,ikt,jpgsi) - zsiloss
267            trn(ji,jj,ikt,jpcal) = trn(ji,jj,ikt,jpcal) - zcaloss
268#if ! defined key_sed
269            trn(ji,jj,ikt,jpsil) = trn(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
270            zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
271            zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
272            zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn )
273            trn(ji,jj,ikt,jptal) =  trn(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
274            trn(ji,jj,ikt,jpdic) =  trn(ji,jj,ikt,jpdic) + zcaloss * zrivalk
275#endif
276         END DO
277      END DO
278
279      DO jj = 1, jpj
280         DO ji = 1, jpi
281            ikt     = mbkt(ji,jj)
282            zdep    = xstep / fse3t(ji,jj,ikt)
283            zws4 = zwsbio4(ji,jj) * zdep
284            zws3 = zwsbio3(ji,jj) * zdep
285            zrivno3 = 1. - zbureff(ji,jj)
286# if ! defined key_kriest
287            trn(ji,jj,ikt,jpgoc) = trn(ji,jj,ikt,jpgoc) - trn(ji,jj,ikt,jpgoc) * zws4
288            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
289            trn(ji,jj,ikt,jpbfe) = trn(ji,jj,ikt,jpbfe) - trn(ji,jj,ikt,jpbfe) * zws4
290            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
291            zwstpoc              =  trn(ji,jj,ikt,jpgoc) * zws4 + trn(ji,jj,ikt,jppoc) * zws3 
292# else
293            trn(ji,jj,ikt,jpnum) = trn(ji,jj,ikt,jpnum) - trn(ji,jj,ikt,jpnum) * zws4
294            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
295            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
296            zwstpoc = trn(ji,jj,ikt,jppoc) * zws3 
297# endif
298
299#if ! defined key_sed
300            ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification
301            ! in the sediments and just above the sediments. Not very clever, but simpliest option.
302            zpdenit  = MIN( 0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
303            z1pdenit = zwstpoc * zrivno3 - zpdenit
304            zolimit = MIN( ( trn(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
305            zdenitt = MIN(  0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) )
306            trn(ji,jj,ikt,jpdoc) = trn(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt
307            trn(ji,jj,ikt,jppo4) = trn(ji,jj,ikt,jppo4) + zpdenit + zolimit + zdenitt
308            trn(ji,jj,ikt,jpnh4) = trn(ji,jj,ikt,jpnh4) + zpdenit + zolimit + zdenitt
309            trn(ji,jj,ikt,jpno3) = trn(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt)
310            trn(ji,jj,ikt,jpoxy) = trn(ji,jj,ikt,jpoxy) - zolimit * o2ut
311            trn(ji,jj,ikt,jptal) = trn(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * (zpdenit + zdenitt) )
312            trn(ji,jj,ikt,jpdic) = trn(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt
313            zwork4(ji,jj) = rdenit * zpdenit * fse3t(ji,jj,ikt)
314#endif
315         END DO
316      END DO
317
318      ! Nitrogen fixation process
319      ! Small source iron from particulate inorganic iron
320      !-----------------------------------
321      DO jk = 1, jpkm1
322         DO jj = 1, jpj
323            DO ji = 1, jpi
324               !                      ! Potential nitrogen fixation dependant on temperature and iron
325               zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
326               IF( zlim <= 0.2 )   zlim = 0.01
327#if defined key_degrad
328               zfact = zlim * rfact2 * facvol(ji,jj,jk)
329#else
330               zfact = zlim * rfact2
331#endif
332               ztrfer = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
333               ztrpo4 = trn  (ji,jj,jk,jppo4) / ( concnnh4   + trn  (ji,jj,jk,jppo4) ) 
334               zlight =  ( 1.- EXP( -etot(ji,jj,jk) / diazolight ) ) 
335               znitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday )   &
336                 &         *  zfact * MIN( ztrfer, ztrpo4 ) * zlight
337               zsoufer(ji,jj,jk) = zlight * 2E-11 / (2E-11 + biron(ji,jj,jk))
338            END DO
339         END DO
340      END DO
341
342      ! Nitrogen change due to nitrogen fixation
343      ! ----------------------------------------
344      DO jk = 1, jpkm1
345         DO jj = 1, jpj
346            DO ji = 1, jpi
347               zfact = znitrpot(ji,jj,jk) * nitrfix
348               trn(ji,jj,jk,jpnh4) = trn(ji,jj,jk,jpnh4) +             zfact
349               trn(ji,jj,jk,jptal) = trn(ji,jj,jk,jptal) + rno3      * zfact
350               trn(ji,jj,jk,jpoxy) = trn(ji,jj,jk,jpoxy) + o2nit     * zfact 
351               trn(ji,jj,jk,jppo4) = trn(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trn(ji,jj,jk,jppo4) ) &
352               &                     * 0.002 * trn(ji,jj,jk,jpdoc) * rfact2 / rday
353               trn(ji,jj,jk,jpfer) = trn(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
354           END DO
355         END DO
356      END DO
357
358      ! Global budget of N SMS : denitrification in the water column and in the sediment
359      !                          nitrogen fixation by the diazotrophs
360      ! --------------------------------------------------------------------------------
361      zrdenittot   = glob_sum ( denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
362      zsdenittot   = glob_sum ( zwork4(:,:)   * e1e2t(:,:) )
363      znitrpottot  = glob_sum ( znitrpot(:,:,:) * nitrfix              * cvol(:,:,:) )
364      zfact = 1.e+3 * rfact2r * rno3 * 14. / 1.e12 * ryyss   ! conversion molC/l/kt ----> TgN/m3/year
365      !
366      IF( ln_check_mass .AND. ( kt == nitend .AND. jnt == nrdttrc ) .AND. ( lwp )  )  &
367         &  WRITE(numnit,9100) ndastp, znitrpottot * zfact  , &
368         &                             zrdenittot  * zfact  , &
369         &                             zsdenittot  * zfact
370      !
371      IF( lk_iomput ) THEN
372         IF( jnt == nrdttrc ) THEN
373            zfact = 1.e+3 * rfact2r * rno3  !  conversion from molC/l/kt  to molN/m3/s
374            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix"  , znitrpot(:,:,:) * nitrfix * zfact * tmask(:,:,:) )  ! nitrogen fixation
375            IF( iom_use("Sdenit" ) ) CALL iom_put( "Sdenit", zwork4(:,:) * zfact * tmask(:,:,1) )  ! Nitrate reduction in the sediments
376            IF( iom_use("tnfix"  ) ) CALL iom_put( "tnfix"  , znitrpottot * zfact  )               ! Global  nitrogen fixation
377            IF( iom_use("tdenit" ) ) CALL iom_put( "tdenit" , zrdenittot  * zfact  )               ! Total denitrification
378            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
379               zwork1(:,:) = 0.
380               DO jk = 1, jpkm1
381                 zwork1(:,:) = zwork1(:,:) + znitrpot(:,:,jk) * nitrfix * zfact * fse3t(:,:,jk) * tmask(:,:,jk)
382               ENDDO
383               CALL iom_put( "INTNFIX" , zwork1 ) 
384            ENDIF
385         ENDIF
386      ELSE
387         IF( ln_diatrc )  &
388            &  trc2d(:,:,jp_pcs0_2d + 12) = znitrpot(:,:,1) * nitrfix * rno3 * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1)
389      ENDIF
390      !
391      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
392         WRITE(charout, fmt="('sed ')")
393         CALL prt_ctl_trc_info(charout)
394         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
395      ENDIF
396      !
397      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
398      CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
399      CALL wrk_dealloc( jpi, jpj, jpk, znitrpot, zsoufer )
400      !
401      IF( nn_timing == 1 )  CALL timing_stop('p4z_sed')
402      !
403 9100  FORMAT(i8,3f10.5)
404      !
405   END SUBROUTINE p4z_sed
406
407#else
408   !!======================================================================
409   !!  Dummy module :                                   No PISCES bio-model
410   !!======================================================================
411CONTAINS
412   SUBROUTINE p4z_sed                         ! Empty routine
413   END SUBROUTINE p4z_sed
414#endif 
415
416   !!======================================================================
417END MODULE  p4zsed
Note: See TracBrowser for help on using the repository browser.