New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 5226

Last change on this file since 5226 was 5226, checked in by cetlod, 9 years ago

NEMOGCM_dev_r5204_CNRS_PISCES_dcy : minor bugs correction

  • Property svn:keywords set to Id
File size: 28.1 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting                   
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   sbc_init       : read namsbc namelist
20   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
21   !!----------------------------------------------------------------------
22   USE oce              ! ocean dynamics and tracers
23   USE dom_oce          ! ocean space and time domain
24   USE phycst           ! physical constants
25   USE sbc_oce          ! Surface boundary condition: ocean fields
26   USE trc_oce          ! shared ocean-passive tracers variables
27   USE sbc_ice          ! Surface boundary condition: ice fields
28   USE sbcdcy           ! surface boundary condition: diurnal cycle
29   USE sbcssm           ! surface boundary condition: sea-surface mean variables
30   USE sbcapr           ! surface boundary condition: atmospheric pressure
31   USE sbcana           ! surface boundary condition: analytical formulation
32   USE sbcflx           ! surface boundary condition: flux formulation
33   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
34   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
35   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
36   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
37   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
38   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
39   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
40   USE sbccpl           ! surface boundary condition: coupled florulation
41   USE sbcssr           ! surface boundary condition: sea surface restoring
42   USE sbcrnf           ! surface boundary condition: runoffs
43   USE sbcisf           ! surface boundary condition: ice shelf
44   USE sbcfwb           ! surface boundary condition: freshwater budget
45   USE closea           ! closed sea
46   USE icbstp           ! Icebergs!
47
48   USE prtctl           ! Print control                    (prt_ctl routine)
49   USE iom              ! IOM library
50   USE in_out_manager   ! I/O manager
51   USE lib_mpp          ! MPP library
52   USE timing           ! Timing
53   USE sbcwave          ! Wave module
54
55   IMPLICIT NONE
56   PRIVATE
57
58   PUBLIC   sbc        ! routine called by step.F90
59   PUBLIC   sbc_init   ! routine called by opa.F90
60   
61   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
62     
63   !! * Substitutions
64#  include "domzgr_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
67   !! $Id$
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE sbc_init
73      !!---------------------------------------------------------------------
74      !!                    ***  ROUTINE sbc_init ***
75      !!
76      !! ** Purpose :   Initialisation of the ocean surface boundary computation
77      !!
78      !! ** Method  :   Read the namsbc namelist and set derived parameters
79      !!                Call init routines for all other SBC modules that have one
80      !!
81      !! ** Action  : - read namsbc parameters
82      !!              - nsbc: type of sbc
83      !!----------------------------------------------------------------------
84      INTEGER ::   icpt   ! local integer
85      !!
86      NAMELIST/namsbc/ nn_fsbc   , ln_ana    , ln_flx,  ln_blk_clio, ln_blk_core,           &
87         &             ln_blk_mfs, ln_apr_dyn, nn_ice,  nn_ice_embd, ln_dm2dc   , ln_rnf,   &
88         &             ln_ssr    ,  nn_isf , nn_fwb    , ln_cdgw , ln_wave , ln_sdw, nn_lsm, nn_limflx
89      INTEGER  ::   ios
90      !!----------------------------------------------------------------------
91
92      IF(lwp) THEN
93         WRITE(numout,*)
94         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
95         WRITE(numout,*) '~~~~~~~~ '
96      ENDIF
97
98      REWIND( numnam_ref )              ! Namelist namsbc in reference namelist : Surface boundary
99      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
100901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
101
102      REWIND( numnam_cfg )              ! Namelist namsbc in configuration namelist : Parameters of the run
103      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
104902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
105      IF(lwm) WRITE ( numond, namsbc )
106
107      !                          ! overwrite namelist parameter using CPP key information
108      IF( Agrif_Root() ) THEN                ! AGRIF zoom
109        IF( lk_lim2 )   nn_ice      = 2
110        IF( lk_lim3 )   nn_ice      = 3
111        IF( lk_cice )   nn_ice      = 4
112      ENDIF
113      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
114          ln_ana      = .TRUE.   
115          nn_ice      =   0
116      ENDIF
117     
118      IF(lwp) THEN               ! Control print
119         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
120         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
121         WRITE(numout,*) '           Type of sbc : '
122         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
123         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
124         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
125         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
126         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
127         WRITE(numout,*) '              coupled    formulation (T if key_oasis3)   lk_cpl      = ', lk_cpl
128         WRITE(numout,*) '              Multicategory heat flux formulation (LIM3) nn_limflx   = ', nn_limflx
129         WRITE(numout,*) '           Misc. options of sbc : '
130         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
131         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
132         WRITE(numout,*) '              ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd = ', nn_ice_embd
133         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
134         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
135         WRITE(numout,*) '              iceshelf formulation                       nn_isf      = ', nn_isf
136         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
137         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
138         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
139         WRITE(numout,*) '              n. of iterations if land-sea-mask applied  nn_lsm      = ', nn_lsm
140      ENDIF
141
142      ! LIM3 Multi-category heat flux formulation
143      SELECT CASE ( nn_limflx)
144      CASE ( -1 )
145         IF(lwp) WRITE(numout,*) '              Use of per-category fluxes (nn_limflx = -1) '
146      CASE ( 0  )
147         IF(lwp) WRITE(numout,*) '              Average per-category fluxes (nn_limflx = 0) ' 
148      CASE ( 1  )
149         IF(lwp) WRITE(numout,*) '              Average then redistribute per-category fluxes (nn_limflx = 1) '
150      CASE ( 2  )
151         IF(lwp) WRITE(numout,*) '              Redistribute a single flux over categories (nn_limflx = 2) '
152      END SELECT
153      !
154      !                              ! allocate sbc arrays
155      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
156
157      !                          ! Checks:
158      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
159         ln_rnf_mouth  = .false.                     
160         IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' )
161         nkrnf         = 0
162         rnf     (:,:) = 0.0_wp
163         rnf_b   (:,:) = 0.0_wp
164         rnfmsk  (:,:) = 0.0_wp
165         rnfmsk_z(:)   = 0.0_wp
166      ENDIF
167      IF( nn_isf .EQ. 0 ) THEN                      ! no specific treatment in vicinity of ice shelf
168         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
169         fwfisf  (:,:) = 0.0_wp
170         fwfisf_b(:,:) = 0.0_wp
171      END IF
172      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
173
174      sfx(:,:) = 0.0_wp                            ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero)
175                                                   ! only if sea-ice is present
176 
177      fmmflx(:,:) = 0.0_wp                        ! freezing-melting array initialisation
178     
179      taum(:,:) = 0.0_wp                           ! Initialise taum for use in gls in case of reduced restart
180
181      !                                            ! restartability   
182      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
183          MOD( nstock             , nn_fsbc) /= 0 ) THEN
184         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
185            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
186         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
187      ENDIF
188      !
189      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
190         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
191      !
192      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
193         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
194      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) )   &
195         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' )
196      IF( nn_ice == 4 .AND. lk_agrif )   &
197         &   CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' )
198      IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 )   &
199         &   CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' )
200      IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) )   &
201         &   WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3'
202      IF( ( nn_ice == 3 ) .AND. ( lk_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) )   &
203         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
204      IF( ( nn_ice == 3 ) .AND. ( .NOT. lk_cpl ) .AND. ( nn_limflx == 2 ) )   &
205         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' )
206
207      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
208
209      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) )   &
210         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
211     
212      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
213         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
214
215      IF ( ln_wave ) THEN
216      !Activated wave module but neither drag nor stokes drift activated
217         IF ( .NOT.(ln_cdgw .OR. ln_sdw) )   THEN
218            CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' )
219      !drag coefficient read from wave model definable only with mfs bulk formulae and core
220         ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) )       THEN       
221             CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
222         ENDIF
223      ELSE
224      IF ( ln_cdgw .OR. ln_sdw  )                                         & 
225         &   CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but     &
226         & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ')
227      ENDIF 
228     
229      !                          ! Choice of the Surface Boudary Condition (set nsbc)
230      icpt = 0
231      IF( ln_ana          ) THEN   ;   nsbc = jp_ana    ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
232      IF( ln_flx          ) THEN   ;   nsbc = jp_flx    ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
233      IF( ln_blk_clio     ) THEN   ;   nsbc = jp_clio   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
234      IF( ln_blk_core     ) THEN   ;   nsbc = jp_core   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
235      IF( ln_blk_mfs      ) THEN   ;   nsbc = jp_mfs    ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk       formulation
236      IF( lk_cpl          ) THEN   ;   nsbc = jp_cpl    ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
237      IF( cp_cfg == 'gyre') THEN   ;   nsbc = jp_gyre                       ;   ENDIF       ! GYRE analytical formulation
238      IF( lk_esopa        )            nsbc = jp_esopa                                      ! esopa test, ALL formulations
239      !
240      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
241         WRITE(numout,*)
242         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
243         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
244         WRITE(numout,*) '                     We stop'
245         nstop = nstop + 1
246      ENDIF
247      IF(lwp) THEN
248         WRITE(numout,*)
249         IF( nsbc == jp_esopa )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
250         IF( nsbc == jp_gyre  )   WRITE(numout,*) '              GYRE analytical formulation'
251         IF( nsbc == jp_ana   )   WRITE(numout,*) '              analytical formulation'
252         IF( nsbc == jp_flx   )   WRITE(numout,*) '              flux formulation'
253         IF( nsbc == jp_clio  )   WRITE(numout,*) '              CLIO bulk formulation'
254         IF( nsbc == jp_core  )   WRITE(numout,*) '              CORE bulk formulation'
255         IF( nsbc == jp_cpl   )   WRITE(numout,*) '              coupled formulation'
256         IF( nsbc == jp_mfs   )   WRITE(numout,*) '              MFS Bulk formulation'
257      ENDIF
258      !
259                               CALL sbc_ssm_init               ! Sea-surface mean fields initialisation
260      !
261      IF( ln_ssr           )   CALL sbc_ssr_init               ! Sea-Surface Restoring initialisation
262      !
263      IF( ln_rnf           )   CALL sbc_rnf_init               ! Runof initialisation
264      !
265      IF( nn_ice == 3      )   CALL sbc_lim_init               ! LIM3 initialisation
266
267      IF( nn_ice == 4      )   CALL cice_sbc_init( nsbc )      ! CICE initialisation
268      !
269      IF( nsbc   == jp_cpl )   CALL sbc_cpl_init (nn_ice)      ! OASIS initialisation. must be done before first time step
270     
271      l_trcdm2dc = lk_top .AND. ( ln_dm2dc .OR. ( lk_cpl .AND. n_cpl_qsr /= 1 ) ) 
272      IF( l_trcdm2dc .AND. lwp ) THEN
273            WRITE(numout,*) "Coupling with passive tracers and used of diurnal cycle !!!!! "
274            WRITE(numout,*) "Computation of a daily mean shortwave for some biogeochemical models"
275      ENDIF
276
277   END SUBROUTINE sbc_init
278
279
280   SUBROUTINE sbc( kt )
281      !!---------------------------------------------------------------------
282      !!                    ***  ROUTINE sbc  ***
283      !!             
284      !! ** Purpose :   provide at each time-step the ocean surface boundary
285      !!                condition (momentum, heat and freshwater fluxes)
286      !!
287      !! ** Method  :   blah blah  to be written ?????????
288      !!                CAUTION : never mask the surface stress field (tke sbc)
289      !!
290      !! ** Action  : - set the ocean surface boundary condition at before and now
291      !!                time step, i.e. 
292      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
293      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
294      !!              - updte the ice fraction : fr_i
295      !!----------------------------------------------------------------------
296      INTEGER, INTENT(in) ::   kt       ! ocean time step
297      !!---------------------------------------------------------------------
298      !
299      IF( nn_timing == 1 )  CALL timing_start('sbc')
300      !
301      !                                            ! ---------------------------------------- !
302      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
303         !                                         ! ---------------------------------------- !
304         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
305         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
306         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
307         ! The 3D heat content due to qsr forcing is treated in traqsr
308         ! qsr_b (:,:) = qsr (:,:)
309         emp_b(:,:) = emp(:,:)
310         sfx_b(:,:) = sfx(:,:)
311      ENDIF
312      !                                            ! ---------------------------------------- !
313      !                                            !        forcing field computation         !
314      !                                            ! ---------------------------------------- !
315      !
316      IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
317                                                         ! (caution called before sbc_ssm)
318      !
319      CALL sbc_ssm( kt )                                 ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
320      !                                                  ! averaged over nf_sbc time-step
321
322      IF (ln_wave) CALL sbc_wave( kt )
323                                                   !==  sbc formulation  ==!
324                                                           
325      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
326      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
327      CASE( jp_gyre  )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
328      CASE( jp_ana   )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
329      CASE( jp_flx   )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
330      CASE( jp_clio  )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
331      CASE( jp_core  )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
332      CASE( jp_cpl   )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
333      CASE( jp_mfs   )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
334      CASE( jp_esopa )                               
335                             CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
336                             CALL sbc_gyre    ( kt )                    !
337                             CALL sbc_flx     ( kt )                    !
338                             CALL sbc_blk_clio( kt )                    !
339                             CALL sbc_blk_core( kt )                    !
340                             CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
341      END SELECT
342
343      !                                            !==  Misc. Options  ==!
344     
345      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
346      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
347      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
348      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
349      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
350      END SELECT                                             
351
352      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
353
354      IF( nn_isf   /= 0  )   CALL sbc_isf( kt )                    ! compute iceshelves
355
356      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
357 
358      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
359
360      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
361
362      IF( nn_closea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
363      !                                                           ! (update freshwater fluxes)
364!RBbug do not understand why see ticket 667
365      !clem-bugsal CALL lbc_lnk( emp, 'T', 1. )
366      !
367      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
368         !                                             ! ---------------------------------------- !
369         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
370            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
371            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
372            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
373            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
374            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
375            ! The 3D heat content due to qsr forcing is treated in traqsr
376            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
377            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
378            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
379            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
380               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
381            ELSE
382               sfx_b (:,:) = sfx(:,:)
383            ENDIF
384         ELSE                                                   !* no restart: set from nit000 values
385            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
386            utau_b(:,:) = utau(:,:) 
387            vtau_b(:,:) = vtau(:,:)
388            qns_b (:,:) = qns (:,:)
389            emp_b (:,:) = emp(:,:)
390            sfx_b (:,:) = sfx(:,:)
391         ENDIF
392      ENDIF
393      !                                                ! ---------------------------------------- !
394      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
395         !                                             ! ---------------------------------------- !
396         IF(lwp) WRITE(numout,*)
397         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
398            &                    'at it= ', kt,' date= ', ndastp
399         IF(lwp) WRITE(numout,*) '~~~~'
400         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
401         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
402         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
403         ! The 3D heat content due to qsr forcing is treated in traqsr
404         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
405         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
406         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx )
407      ENDIF
408
409      !                                                ! ---------------------------------------- !
410      !                                                !        Outputs and control print         !
411      !                                                ! ---------------------------------------- !
412      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
413         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
414         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux 
415                                                                ! (includes virtual salt flux beneath ice
416                                                                ! in linear free surface case)
417         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
418         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
419         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
420         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
421         IF( l_trcdm2dc ) CALL iom_put( "qsr_mean" ,       qsr_mean  )                   ! daily mean solar heat flux
422         IF( nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
423         CALL iom_put( "taum"  , taum       )                   ! wind stress module
424         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
425      ENDIF
426      !
427      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
428      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
429      !
430      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
431         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
432         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
433         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf  - : ', mask1=tmask, ovlap=1 )
434         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
435         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
436         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
437         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
438         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
439         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
440            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
441      ENDIF
442
443      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
444      !
445      IF( nn_timing == 1 )  CALL timing_stop('sbc')
446      !
447   END SUBROUTINE sbc
448
449
450   SUBROUTINE sbc_final
451      !!---------------------------------------------------------------------
452      !!                    ***  ROUTINE sbc_final  ***
453      !!
454      !! ** Purpose :   Finalize CICE (if used)
455      !!---------------------------------------------------------------------
456      !
457      IF( nn_ice == 4 )   CALL cice_sbc_final
458      !
459   END SUBROUTINE sbc_final
460
461   !!======================================================================
462END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.