New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcrnf.F90 in branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 5330

Last change on this file since 5330 was 5330, checked in by cetlod, 9 years ago
NEMOGCM_dev_r5204_CNRS_PISCES_dcy : move the call of sbc_rnf_init from sbcrnf to sbcmod
Property svn:keywords set to `Id`
File size: 30.8 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE sbcisf ! PM we could remove it I think
22	USE closea ! closed seas
23	USE fldread ! read input field at current time step
24	USE in_out_manager ! I/O manager
25	USE iom ! I/O module
26	USE lib_mpp ! MPP library
27	USE eosbn2
28	USE wrk_nemo ! Memory allocation
29
30	IMPLICIT NONE
31	PRIVATE
32
33	PUBLIC sbc_rnf ! routine call in sbcmod module
34	PUBLIC sbc_rnf_div ! routine called in sshwzv module
35	PUBLIC sbc_rnf_alloc ! routine call in sbcmod module
36	PUBLIC sbc_rnf_init ! (PUBLIC for TAM)
37	! !!* namsbc_rnf namelist *
38	CHARACTER(len=100), PUBLIC :: cn_dir !: Root directory for location of ssr files
39	LOGICAL , PUBLIC :: ln_rnf_depth !: depth river runoffs attribute specified in a file
40	LOGICAL :: ln_rnf_depth_ini !: depth river runoffs computed at the initialisation
41	REAL(wp) :: rn_rnf_max !: maximum value of the runoff climatologie ( ln_rnf_depth_ini = .true )
42	REAL(wp) :: rn_dep_max !: depth over which runoffs is spread ( ln_rnf_depth_ini = .true )
43	INTEGER :: nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44	LOGICAL , PUBLIC :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
45	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
46	LOGICAL , PUBLIC :: ln_rnf_emp !: runoffs into a file to be read or already into precipitation
47	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
48	TYPE(FLD_N) , PUBLIC :: sn_cnf !: information about the runoff mouth file to be read
49	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
50	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
51	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
52	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
53	REAL(wp) , PUBLIC :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
54	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
55	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
56
57	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
58	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
59	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
60	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
61	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
62	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s]
63
64	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
65	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
66	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
67
68	!! * Substitutions
69	# include "domzgr_substitute.h90"
70	!!----------------------------------------------------------------------
71	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
72	!! $Id$
73	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
74	!!----------------------------------------------------------------------
75	CONTAINS
76
77	INTEGER FUNCTION sbc_rnf_alloc()
78	!!----------------------------------------------------------------------
79	!! * ROUTINE sbc_rnf_alloc *
80	!!----------------------------------------------------------------------
81	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
82	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
83	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
84	!
85	IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc )
86	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
87	END FUNCTION sbc_rnf_alloc
88
89
90	SUBROUTINE sbc_rnf( kt )
91	!!----------------------------------------------------------------------
92	!! * ROUTINE sbc_rnf *
93	!!
94	!! ** Purpose : Introduce a climatological run off forcing
95	!!
96	!! ** Method : Set each river mouth with a monthly climatology
97	!! provided from different data.
98	!! CAUTION : upward water flux, runoff forced to be < 0
99	!!
100	!! ** Action : runoff updated runoff field at time-step kt
101	!!----------------------------------------------------------------------
102	INTEGER, INTENT(in) :: kt ! ocean time step
103	!
104	INTEGER :: ji, jj ! dummy loop indices
105	INTEGER :: z_err = 0 ! dummy integer for error handling
106	!!----------------------------------------------------------------------
107	REAL(wp), DIMENSION(:,:), POINTER :: ztfrz ! freezing point used for temperature correction
108	!
109	CALL wrk_alloc( jpi,jpj, ztfrz)
110
111	! ! ---------------------------------------- !
112	IF( kt /= nit000 ) THEN ! Swap of forcing fields !
113	! ! ---------------------------------------- !
114	rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000
115	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine
116	!
117	ENDIF
118
119	! !-------------------!
120	IF( .NOT. ln_rnf_emp ) THEN ! Update runoff !
121	! !-------------------!
122	!
123	CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
124	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
125	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
126	!
127	! Runoff reduction only associated to the ORCA2_LIM configuration
128	! when reading the NetCDF file runoff_1m_nomask.nc
129	IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN
130	WHERE( 40._wp < gphit(:,:) .AND. gphit(:,:) < 65._wp )
131	sf_rnf(1)%fnow(:,:,1) = 0.85 * sf_rnf(1)%fnow(:,:,1)
132	END WHERE
133	ENDIF
134	!
135	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
136	!
137	rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) ! updated runoff value at time step kt
138	!
139	! ! set temperature & salinity content of runoffs
140	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
141	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
142	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
143	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
144	END WHERE
145	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp ) ! where fwf comes from melting of ice shelves or iceberg
146	ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
147	rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
148	END WHERE
149	ELSE ! use SST as runoffs temperature
150	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
151	ENDIF
152	! ! use runoffs salinity data
153	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
154	! ! else use S=0 for runoffs (done one for all in the init)
155	IF ( ANY( rnf(:,:) < 0._wp ) ) z_err=1
156	IF(lk_mpp) CALL mpp_sum(z_err)
157	IF( z_err > 0 ) CALL ctl_stop( 'sbc_rnf : negative runnoff values exist' )
158	!
159	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
160	ENDIF
161	!
162	ENDIF
163	!
164	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
165	! ! ---------------------------------------- !
166	IF( ln_rstart .AND. & !* Restart: read in restart file
167	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
168	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
169	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
170	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
171	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
172	ELSE !* no restart: set from nit000 values
173	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
174	rnf_b (:,: ) = rnf (:,: )
175	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
176	ENDIF
177	ENDIF
178	! ! ---------------------------------------- !
179	IF( lrst_oce ) THEN ! Write in the ocean restart file !
180	! ! ---------------------------------------- !
181	IF(lwp) WRITE(numout,*)
182	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
183	& 'at it= ', kt,' date= ', ndastp
184	IF(lwp) WRITE(numout,*) '~~~~'
185	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
186	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
187	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
188	ENDIF
189	CALL wrk_dealloc( jpi,jpj, ztfrz)
190	!
191	END SUBROUTINE sbc_rnf
192
193
194	SUBROUTINE sbc_rnf_div( phdivn )
195	!!----------------------------------------------------------------------
196	!! * ROUTINE sbc_rnf *
197	!!
198	!! ** Purpose : update the horizontal divergence with the runoff inflow
199	!!
200	!! ** Method :
201	!! CAUTION : rnf is positive (inflow) decreasing the
202	!! divergence and expressed in m/s
203	!!
204	!! ** Action : phdivn decreased by the runoff inflow
205	!!----------------------------------------------------------------------
206	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
207	!!
208	INTEGER :: ji, jj, jk ! dummy loop indices
209	REAL(wp) :: zfact ! local scalar
210	!!----------------------------------------------------------------------
211	!
212	zfact = 0.5_wp
213	!
214	IF( ln_rnf_depth ) THEN !== runoff distributed over several levels ==!
215	IF( lk_vvl ) THEN ! variable volume case
216	DO jj = 1, jpj ! update the depth over which runoffs are distributed
217	DO ji = 1, jpi
218	h_rnf(ji,jj) = 0._wp
219	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
220	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
221	END DO
222	! ! apply the runoff input flow
223	DO jk = 1, nk_rnf(ji,jj)
224	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
225	END DO
226	END DO
227	END DO
228	ELSE ! constant volume case : just apply the runoff input flow
229	DO jj = 1, jpj
230	DO ji = 1, jpi
231	DO jk = 1, nk_rnf(ji,jj)
232	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
233	END DO
234	END DO
235	END DO
236	ENDIF
237	ELSE !== runoff put only at the surface ==!
238	IF( lk_vvl ) THEN ! variable volume case
239	h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box
240	ENDIF
241	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
242	ENDIF
243	!
244	END SUBROUTINE sbc_rnf_div
245
246
247	SUBROUTINE sbc_rnf_init
248	!!----------------------------------------------------------------------
249	!! * ROUTINE sbc_rnf_init *
250	!!
251	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
252	!!
253	!! ** Method : - read the runoff namsbc_rnf namelist
254	!!
255	!! ** Action : - read parameters
256	!!----------------------------------------------------------------------
257	CHARACTER(len=32) :: rn_dep_file ! runoff file name
258	INTEGER :: ji, jj, jk, jm ! dummy loop indices
259	INTEGER :: ierror, inum ! temporary integer
260	INTEGER :: ios ! Local integer output status for namelist read
261	INTEGER :: nbrec ! temporary integer
262	REAL(wp) :: zacoef
263	REAL(wp), DIMENSION(12) :: zrec ! times records
264	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl
265	REAL(wp), DIMENSION(:,: ), ALLOCATABLE :: zrnf
266	!
267	NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
268	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
269	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact, &
270	& ln_rnf_depth_ini , rn_dep_max , rn_rnf_max, nn_rnf_depth_file
271	!!----------------------------------------------------------------------
272	!
273	! ! ============
274	! ! Namelist
275	! ! ============
276	!
277	REWIND( numnam_ref ) ! Namelist namsbc_rnf in reference namelist : Runoffs
278	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
279	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
280
281	REWIND( numnam_cfg ) ! Namelist namsbc_rnf in configuration namelist : Runoffs
282	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
283	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
284	IF(lwm) WRITE ( numond, namsbc_rnf )
285	!
286	! ! Control print
287	IF(lwp) THEN
288	WRITE(numout,*)
289	WRITE(numout,*) 'sbc_rnf : runoff '
290	WRITE(numout,*) '~~~~~~~ '
291	WRITE(numout,*) ' Namelist namsbc_rnf'
292	WRITE(numout,*) ' runoff in a file to be read ln_rnf_emp = ', ln_rnf_emp
293	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
294	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
295	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
296	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
297	ENDIF
298	!
299	! ! ==================
300	! ! Type of runoff
301	! ! ==================
302	! !== allocate runoff arrays
303	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
304	!
305	IF( ln_rnf_emp ) THEN !== runoffs directly provided in the precipitations ==!
306	IF(lwp) WRITE(numout,*)
307	IF(lwp) WRITE(numout,*) ' runoffs directly provided in the precipitations'
308	IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal .OR. ln_rnf_depth_ini ) THEN
309	CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' )
310	ln_rnf_depth = .FALSE. ; ln_rnf_tem = .FALSE. ; ln_rnf_sal = .FALSE. ; ln_rnf_depth_ini = .FALSE.
311	ENDIF
312	!
313	ELSE !== runoffs read in a file : set sf_rnf structure ==!
314	!
315	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
316	IF(lwp) WRITE(numout,*)
317	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
318	IF( ierror > 0 ) THEN
319	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
320	ENDIF
321	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
322	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
323	! ! fill sf_rnf with the namelist (sn_rnf) and control print
324	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
325	!
326	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
327	IF(lwp) WRITE(numout,*)
328	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
329	ALLOCATE( sf_t_rnf(1), STAT=ierror )
330	IF( ierror > 0 ) THEN
331	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
332	ENDIF
333	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
334	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
335	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
336	ENDIF
337	!
338	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
339	IF(lwp) WRITE(numout,*)
340	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
341	ALLOCATE( sf_s_rnf(1), STAT=ierror )
342	IF( ierror > 0 ) THEN
343	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
344	ENDIF
345	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
346	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
347	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
348	ENDIF
349	!
350	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
351	IF(lwp) WRITE(numout,*)
352	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
353	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
354	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
355	IF( sn_dep_rnf%cltype == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
356	ENDIF
357	CALL iom_open ( rn_dep_file, inum ) ! open file
358	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
359	CALL iom_close( inum ) ! close file
360	!
361	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
362	DO jj = 1, jpj
363	DO ji = 1, jpi
364	IF( h_rnf(ji,jj) > 0._wp ) THEN
365	jk = 2
366	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; END DO
367	nk_rnf(ji,jj) = jk
368	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
369	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
370	ELSE
371	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
372	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
373	ENDIF
374	END DO
375	END DO
376	DO jj = 1, jpj ! set the associated depth
377	DO ji = 1, jpi
378	h_rnf(ji,jj) = 0._wp
379	DO jk = 1, nk_rnf(ji,jj)
380	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
381	END DO
382	END DO
383	END DO
384	!
385	ELSE IF( ln_rnf_depth_ini ) THEN ! runoffs applied at the surface
386	!
387	IF(lwp) WRITE(numout,*)
388	IF(lwp) WRITE(numout,*) ' depth of runoff computed once from max value of runoff'
389	IF(lwp) WRITE(numout,*) ' max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
390	IF(lwp) WRITE(numout,*) ' depth over which runoffs is spread rn_dep_max = ', rn_dep_max
391	IF(lwp) WRITE(numout,*) ' create (=1) a runoff depth file or not (=0) nn_rnf_depth_file = ', nn_rnf_depth_file
392
393	CALL iom_open( TRIM( sn_rnf%clname ), inum ) ! open runoff file
394	CALL iom_gettime( inum, zrec, kntime=nbrec)
395	ALLOCATE( zrnfcl(jpi,jpj,nbrec) ) ; ALLOCATE( zrnf(jpi,jpj) )
396	DO jm = 1, nbrec
397	CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
398	END DO
399	CALL iom_close( inum )
400	zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 ) ! maximum value in time
401	DEALLOCATE( zrnfcl )
402	!
403	h_rnf(:,:) = 1.
404	!
405	zacoef = rn_dep_max / rn_rnf_max ! coef of linear relation between runoff and its depth (150m for max of runoff)
406	!
407	WHERE( zrnf(:,:) > 0._wp ) h_rnf(:,:) = zacoef * zrnf(:,:) ! compute depth for all runoffs
408	!
409	DO jj = 1, jpj ! take in account min depth of ocean rn_hmin
410	DO ji = 1, jpi
411	IF( zrnf(ji,jj) > 0._wp ) THEN
412	jk = mbkt(ji,jj)
413	h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
414	ENDIF
415	END DO
416	END DO
417	!
418	nk_rnf(:,:) = 0 ! number of levels on which runoffs are distributed
419	DO jj = 1, jpj
420	DO ji = 1, jpi
421	IF( zrnf(ji,jj) > 0._wp ) THEN
422	jk = 2
423	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; END DO
424	nk_rnf(ji,jj) = jk
425	ELSE
426	nk_rnf(ji,jj) = 1
427	ENDIF
428	END DO
429	END DO
430	!
431	DEALLOCATE( zrnf )
432	!
433	DO jj = 1, jpj ! set the associated depth
434	DO ji = 1, jpi
435	h_rnf(ji,jj) = 0._wp
436	DO jk = 1, nk_rnf(ji,jj)
437	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
438	END DO
439	END DO
440	END DO
441	!
442	IF( nn_rnf_depth_file == 1 ) THEN ! save output nb levels for runoff
443	IF(lwp) WRITE(numout,*) ' create runoff depht file'
444	CALL iom_open ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
445	CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
446	CALL iom_close ( inum )
447	ENDIF
448	ELSE ! runoffs applied at the surface
449	nk_rnf(:,:) = 1
450	h_rnf (:,:) = fse3t(:,:,1)
451	ENDIF
452	!
453	ENDIF
454	!
455	rnf(:,:) = 0._wp ! runoff initialisation
456	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
457	!
458	! ! ========================
459	! ! River mouth vicinity
460	! ! ========================
461	!
462	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
463	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
464	! ! - set to zero SSS damping (ln_ssr=T)
465	! ! - mixed upstream-centered (ln_traadv_cen2=T)
466	!
467	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
468	& 'be spread through depth by ln_rnf_depth' )
469	!
470	nkrnf = 0 ! Number of level over which Kz increase
471	IF( rn_hrnf > 0._wp ) THEN
472	nkrnf = 2
473	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1 ; END DO
474	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
475	ENDIF
476	IF(lwp) WRITE(numout,*)
477	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
478	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
479	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
480	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
481	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
482	!
483	CALL rnf_mouth ! set river mouth mask
484	!
485	ELSE ! No treatment at river mouths
486	IF(lwp) WRITE(numout,*)
487	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
488	rnfmsk (:,:) = 0._wp
489	rnfmsk_z(:) = 0._wp
490	nkrnf = 0
491	ENDIF
492	!
493	END SUBROUTINE sbc_rnf_init
494
495
496	SUBROUTINE rnf_mouth
497	!!----------------------------------------------------------------------
498	!! * ROUTINE rnf_mouth *
499	!!
500	!! ** Purpose : define the river mouths mask
501	!!
502	!! ** Method : read the river mouth mask (=0/1) in the river runoff
503	!! climatological file. Defined a given vertical structure.
504	!! CAUTION, the vertical structure is hard coded on the
505	!! first 5 levels.
506	!! This fields can be used to:
507	!! - set an upstream advection scheme
508	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
509	!! - increase vertical on the top nn_krnf vertical levels
510	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
511	!! - set to zero SSS restoring flux at river mouth grid points
512	!!
513	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
514	!! rnfmsk_z vertical structure
515	!!----------------------------------------------------------------------
516	INTEGER :: inum ! temporary integers
517	CHARACTER(len=140) :: cl_rnfile ! runoff file name
518	!!----------------------------------------------------------------------
519	!
520	IF(lwp) WRITE(numout,*)
521	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
522	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
523	!
524	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
525	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
526	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
527	ENDIF
528	!
529	! horizontal mask (read in NetCDF file)
530	CALL iom_open ( cl_rnfile, inum ) ! open file
531	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
532	CALL iom_close( inum ) ! close file
533	!
534	IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
535	!
536	rnfmsk_z(:) = 0._wp ! vertical structure
537	rnfmsk_z(1) = 1.0
538	rnfmsk_z(2) = 1.0 ! **********
539	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
540	rnfmsk_z(4) = 0.25 ! **********
541	rnfmsk_z(5) = 0.125
542	!
543	END SUBROUTINE rnf_mouth
544
545	!!======================================================================
546	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

Download in other formats: