New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsed.F90 @ 5206

Last change on this file since 5206 was 5206, checked in by cetlod, 9 years ago

First improvment of diurnal cycle for passive tracers, see ticket #1484
File size: 21.8 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11#if defined key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_sed        :  Compute loss of organic matter in the sediments
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE p4zrem          !  Remineralisation of organic matter
24   USE p4zsbc          !  External source of nutrients
25   USE p4zint          !  interpolation and computation of various fields
26   USE iom             !  I/O manager
27   USE prtctl_trc      !  print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_sed   
33
34   !! * Module variables
35   REAL(wp) :: r1_rday                  !: inverse of rday
36
37   INTEGER ::  numnit 
38
39
40   !!* Substitution
41#  include "top_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
44   !! $Header:$
45   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE p4z_sed( kt, jnt )
50      !!---------------------------------------------------------------------
51      !!                     ***  ROUTINE p4z_sed  ***
52      !!
53      !! ** Purpose :   Compute loss of organic matter in the sediments. This
54      !!              is by no way a sediment model. The loss is simply
55      !!              computed to balance the inout from rivers and dust
56      !!
57      !! ** Method  : - ???
58      !!---------------------------------------------------------------------
59      !
60      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
61      INTEGER  ::   ji, jj, jk, ikt
62#if ! defined key_sed
63      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
64      REAL(wp) ::   zrivalk, zrivsil, zrivno3
65#endif
66      REAL(wp) ::  zwflux, zfminus, zfplus
67      REAL(wp) ::  zlim, zfact, zfactcal
68      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit
69      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep, zwstpoc
70      REAL(wp) ::  ztrfer, ztrpo4, zwdust, zlight
71      REAL(wp) ::  zrdenittot, zsdenittot, znitrpottot
72      !
73      CHARACTER (len=25) :: charout
74      REAL(wp), POINTER, DIMENSION(:,:  ) :: zpdep, zsidep, zwork1, zwork2, zwork3, zwork4
75      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zironice, zbureff
76      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsbio3, zwsbio4, zwscal
77      REAL(wp), POINTER, DIMENSION(:,:,:) :: znitrpot, zirondep, zsoufer
78      !!---------------------------------------------------------------------
79      !
80      IF( nn_timing == 1 )  CALL timing_start('p4z_sed')
81      !
82      IF( kt == nittrc000 .AND. jnt == 1 )  THEN
83         r1_rday  = 1. / rday
84         IF( ln_check_mass .AND. lwp)  &
85           &  CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
86      ENDIF
87      !
88      ! Allocate temporary workspace
89      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
90      CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
91      CALL wrk_alloc( jpi, jpj, jpk, znitrpot, zsoufer )
92
93      zdenit2d(:,:) = 0.e0
94      zbureff (:,:) = 0.e0
95      zwork1  (:,:) = 0.e0
96      zwork2  (:,:) = 0.e0
97      zwork3  (:,:) = 0.e0
98      zwork4  (:,:) = 0.e0
99
100      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
101      ! ----------------------------------------------------
102      IF( ln_ironice ) THEN 
103         !                                             
104         CALL wrk_alloc( jpi, jpj, zironice )
105         !                                             
106         DO jj = 1, jpj
107            DO ji = 1, jpi
108               zdep    = rfact2 / fse3t(ji,jj,1)
109               zwflux  = fmmflx(ji,jj) / 1000._wp
110               zfminus = MIN( 0._wp, -zwflux ) * trn(ji,jj,1,jpfer) * zdep
111               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
112               zironice(ji,jj) =  zfplus + zfminus
113            END DO
114         END DO
115         !
116         trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + zironice(:,:) 
117         !
118         IF( lk_iomput .AND. jnt == nrdttrc .AND. iom_use( "Ironice" ) )   &
119            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
120         !
121         CALL wrk_dealloc( jpi, jpj, zironice )
122         !                                             
123      ENDIF
124
125      ! Add the external input of nutrients from dust deposition
126      ! ----------------------------------------------------------
127      IF( ln_dust ) THEN
128         !                                             
129         CALL wrk_alloc( jpi, jpj,      zpdep, zsidep )
130         CALL wrk_alloc( jpi, jpj, jpk, zirondep      )
131         !                                              ! Iron and Si deposition at the surface
132         IF( ln_solub ) THEN
133            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
134         ELSE
135            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
136         ENDIF
137         zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 28.1 
138         zpdep (:,:) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 31. / po4r 
139         !                                              ! Iron solubilization of particles in the water column
140         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
141         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
142         DO jk = 2, jpkm1
143            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -fsdept(:,:,jk) / 540. )
144         END DO
145         !                                              ! Iron solubilization of particles in the water column
146         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + zpdep   (:,:)
147         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + zsidep  (:,:)
148         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + zirondep(:,:,:) 
149         !
150         IF( lk_iomput ) THEN
151            IF( jnt == nrdttrc ) THEN
152                IF( iom_use( "Irondep" ) )   &
153                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
154                IF( iom_use( "pdust" ) )   &
155                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
156            ENDIF
157         ELSE                                   
158            IF( ln_diatrc )  &
159              &  trc2d(:,:,jp_pcs0_2d + 11) = zirondep(:,:,1) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1)
160         ENDIF
161         CALL wrk_dealloc( jpi, jpj,      zpdep, zsidep )
162         CALL wrk_dealloc( jpi, jpj, jpk, zirondep      )
163         !                                             
164      ENDIF
165     
166      ! Add the external input of nutrients from river
167      ! ----------------------------------------------------------
168      IF( ln_river ) THEN
169         DO jj = 1, jpj
170            DO ji = 1, jpi
171               DO jk = 1, nk_rnf(ji,jj)
172                  trn(ji,jj,jk,jppo4) = trn(ji,jj,jk,jppo4) +  rivdip(ji,jj) * rfact2
173                  trn(ji,jj,jk,jpno3) = trn(ji,jj,jk,jpno3) +  rivdin(ji,jj) * rfact2
174                  trn(ji,jj,jk,jpfer) = trn(ji,jj,jk,jpfer) +  rivdic(ji,jj) * 5.e-5 * rfact2
175                  trn(ji,jj,jk,jpsil) = trn(ji,jj,jk,jpsil) +  rivdsi(ji,jj) * rfact2
176                  trn(ji,jj,jk,jpdic) = trn(ji,jj,jk,jpdic) +  rivdic(ji,jj) * rfact2
177                  trn(ji,jj,jk,jptal) = trn(ji,jj,jk,jptal) +  ( rivalk(ji,jj) - rno3 * rivdin(ji,jj) ) * rfact2
178               ENDDO
179            ENDDO
180         ENDDO
181      ENDIF
182     
183      ! Add the external input of nutrients from nitrogen deposition
184      ! ----------------------------------------------------------
185      IF( ln_ndepo ) THEN
186         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + nitdep(:,:) * rfact2
187         trn(:,:,1,jptal) = trn(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
188      ENDIF
189
190      ! Add the external input of iron from sediment mobilization
191      ! ------------------------------------------------------
192      IF( ln_ironsed ) THEN
193         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
194         !
195         IF( lk_iomput .AND. jnt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
196            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
197      ENDIF
198
199      ! Add the external input of iron from hydrothermal vents
200      ! ------------------------------------------------------
201      IF( ln_hydrofe ) THEN
202         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
203         !
204         IF( lk_iomput .AND. jnt == nrdttrc .AND. iom_use( "HYDR" ) )   &
205            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
206      ENDIF
207
208      ! OA: Warning, the following part is necessary, especially with Kriest
209      ! to avoid CFL problems above the sediments
210      ! --------------------------------------------------------------------
211      DO jj = 1, jpj
212         DO ji = 1, jpi
213            ikt  = mbkt(ji,jj)
214            zdep = fse3t(ji,jj,ikt) / xstep
215            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
216            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
217            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
218         END DO
219      END DO
220
221#if ! defined key_sed
222      ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
223      ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
224      ! -------------------------------------------------------
225      DO jj = 1, jpj
226         DO ji = 1, jpi
227           IF( tmask(ji,jj,1) == 1 ) THEN
228              ikt = mbkt(ji,jj)
229# if defined key_kriest
230              zflx =    trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)    * 1E3 * 1E6 / 1E4
231# else
232              zflx = (  trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
233                &     + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
234#endif
235              zflx  = LOG10( MAX( 1E-3, zflx ) )
236              zo2   = LOG10( MAX( 10. , trn(ji,jj,ikt,jpoxy) * 1E6 ) )
237              zno3  = LOG10( MAX( 1.  , trn(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
238              zdep  = LOG10( fsdepw(ji,jj,ikt+1) )
239              zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
240              &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
241              zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
242              !
243              zflx = (  trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
244                &     + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
245              zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
246           ENDIF
247         END DO
248      END DO 
249
250      ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
251      ! First, the total loss is computed.
252      ! The factor for calcite comes from the alkalinity effect
253      ! -------------------------------------------------------------
254      DO jj = 1, jpj
255         DO ji = 1, jpi
256            IF( tmask(ji,jj,1) == 1 ) THEN
257               ikt = mbkt(ji,jj) 
258# if defined key_kriest
259               zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwscal (ji,jj)
260               zwork2(ji,jj) = trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)
261# else
262               zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
263               zwork2(ji,jj) = trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
264# endif
265               ! For calcite, burial efficiency is made a function of saturation
266               zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
267               zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
268               zwork3(ji,jj) = trn(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
269            ENDIF
270         END DO
271      END DO
272      zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
273      zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
274      zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
275#endif
276
277      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
278      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
279      ! ------------------------------------------------------
280#if ! defined key_sed
281      zrivsil =  1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn )
282#endif
283
284      DO jj = 1, jpj
285         DO ji = 1, jpi
286            ikt  = mbkt(ji,jj)
287            zdep = xstep / fse3t(ji,jj,ikt)
288            zws4 = zwsbio4(ji,jj) * zdep
289            zwsc = zwscal (ji,jj) * zdep
290# if defined key_kriest
291            zsiloss = trn(ji,jj,ikt,jpgsi) * zws4
292# else
293            zsiloss = trn(ji,jj,ikt,jpgsi) * zwsc
294# endif
295            zcaloss = trn(ji,jj,ikt,jpcal) * zwsc
296            !
297            trn(ji,jj,ikt,jpgsi) = trn(ji,jj,ikt,jpgsi) - zsiloss
298            trn(ji,jj,ikt,jpcal) = trn(ji,jj,ikt,jpcal) - zcaloss
299#if ! defined key_sed
300            trn(ji,jj,ikt,jpsil) = trn(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
301            zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
302            zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
303            zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn )
304            trn(ji,jj,ikt,jptal) =  trn(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
305            trn(ji,jj,ikt,jpdic) =  trn(ji,jj,ikt,jpdic) + zcaloss * zrivalk
306#endif
307         END DO
308      END DO
309
310      DO jj = 1, jpj
311         DO ji = 1, jpi
312            ikt     = mbkt(ji,jj)
313            zdep    = xstep / fse3t(ji,jj,ikt)
314            zws4 = zwsbio4(ji,jj) * zdep
315            zws3 = zwsbio3(ji,jj) * zdep
316            zrivno3 = 1. - zbureff(ji,jj)
317# if ! defined key_kriest
318            trn(ji,jj,ikt,jpgoc) = trn(ji,jj,ikt,jpgoc) - trn(ji,jj,ikt,jpgoc) * zws4
319            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
320            trn(ji,jj,ikt,jpbfe) = trn(ji,jj,ikt,jpbfe) - trn(ji,jj,ikt,jpbfe) * zws4
321            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
322            zwstpoc              =  trn(ji,jj,ikt,jpgoc) * zws4 + trn(ji,jj,ikt,jppoc) * zws3 
323# else
324            trn(ji,jj,ikt,jpnum) = trn(ji,jj,ikt,jpnum) - trn(ji,jj,ikt,jpnum) * zws4
325            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
326            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
327            zwstpoc = trn(ji,jj,ikt,jppoc) * zws3 
328# endif
329
330#if ! defined key_sed
331            ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification
332            ! in the sediments and just above the sediments. Not very clever, but simpliest option.
333            zpdenit  = MIN( 0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
334            z1pdenit = zwstpoc * zrivno3 - zpdenit
335            zolimit = MIN( ( trn(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
336            zdenitt = MIN(  0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) )
337            trn(ji,jj,ikt,jpdoc) = trn(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt
338            trn(ji,jj,ikt,jppo4) = trn(ji,jj,ikt,jppo4) + zpdenit + zolimit + zdenitt
339            trn(ji,jj,ikt,jpnh4) = trn(ji,jj,ikt,jpnh4) + zpdenit + zolimit + zdenitt
340            trn(ji,jj,ikt,jpno3) = trn(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt)
341            trn(ji,jj,ikt,jpoxy) = trn(ji,jj,ikt,jpoxy) - zolimit * o2ut
342            trn(ji,jj,ikt,jptal) = trn(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * (zpdenit + zdenitt) )
343            trn(ji,jj,ikt,jpdic) = trn(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt
344            zwork4(ji,jj) = rdenit * zpdenit * fse3t(ji,jj,ikt)
345#endif
346         END DO
347      END DO
348
349      ! Nitrogen fixation process
350      ! Small source iron from particulate inorganic iron
351      !-----------------------------------
352      DO jk = 1, jpkm1
353         DO jj = 1, jpj
354            DO ji = 1, jpi
355               !                      ! Potential nitrogen fixation dependant on temperature and iron
356               zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
357               IF( zlim <= 0.2 )   zlim = 0.01
358#if defined key_degrad
359               zfact = zlim * rfact2 * facvol(ji,jj,jk)
360#else
361               zfact = zlim * rfact2
362#endif
363               ztrfer = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
364               ztrpo4 = trn  (ji,jj,jk,jppo4) / ( concnnh4   + trn  (ji,jj,jk,jppo4) ) 
365               zlight =  ( 1.- EXP( -etot_ndcy(ji,jj,jk) / diazolight ) ) 
366               znitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday )   &
367                 &         *  zfact * MIN( ztrfer, ztrpo4 ) * zlight
368               zsoufer(ji,jj,jk) = zlight * 2E-11 / (2E-11 + biron(ji,jj,jk))
369            END DO
370         END DO
371      END DO
372
373      ! Nitrogen change due to nitrogen fixation
374      ! ----------------------------------------
375      DO jk = 1, jpkm1
376         DO jj = 1, jpj
377            DO ji = 1, jpi
378               zfact = znitrpot(ji,jj,jk) * nitrfix
379               trn(ji,jj,jk,jpnh4) = trn(ji,jj,jk,jpnh4) +             zfact
380               trn(ji,jj,jk,jptal) = trn(ji,jj,jk,jptal) + rno3      * zfact
381               trn(ji,jj,jk,jpoxy) = trn(ji,jj,jk,jpoxy) + o2nit     * zfact 
382               trn(ji,jj,jk,jppo4) = trn(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trn(ji,jj,jk,jppo4) ) &
383               &                     * 0.002 * trn(ji,jj,jk,jpdoc) * rfact2 / rday
384               trn(ji,jj,jk,jpfer) = trn(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
385           END DO
386         END DO
387      END DO
388
389      ! Global budget of N SMS : denitrification in the water column and in the sediment
390      !                          nitrogen fixation by the diazotrophs
391      ! --------------------------------------------------------------------------------
392      zrdenittot   = glob_sum ( denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
393      zsdenittot   = glob_sum ( zwork4(:,:)   * e1e2t(:,:) )
394      znitrpottot  = glob_sum ( znitrpot(:,:,:) * nitrfix              * cvol(:,:,:) )
395      zfact = 1.e+3 * rfact2r * rno3 * 14. / 1.e12 * ryyss   ! conversion molC/l/kt ----> TgN/m3/year
396      !
397      IF( ln_check_mass .AND. ( kt == nitend .AND. jnt == nrdttrc ) .AND. ( lwp )  )  &
398         &  WRITE(numnit,9100) ndastp, znitrpottot * zfact  , &
399         &                             zrdenittot  * zfact  , &
400         &                             zsdenittot  * zfact
401      !
402      IF( lk_iomput ) THEN
403         IF( jnt == nrdttrc ) THEN
404            zfact = 1.e+3 * rfact2r * rno3  !  conversion from molC/l/kt  to molN/m3/s
405            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix"  , znitrpot(:,:,:) * nitrfix * zfact * tmask(:,:,:) )  ! nitrogen fixation
406            IF( iom_use("Sdenit" ) ) CALL iom_put( "Sdenit", zwork4(:,:) * zfact * tmask(:,:,1) )  ! Nitrate reduction in the sediments
407            IF( iom_use("tnfix"  ) ) CALL iom_put( "tnfix"  , znitrpottot * zfact  )               ! Global  nitrogen fixation
408            IF( iom_use("tdenit" ) ) CALL iom_put( "tdenit" , zrdenittot  * zfact  )               ! Total denitrification
409            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
410               zwork1(:,:) = 0.
411               DO jk = 1, jpkm1
412                 zwork1(:,:) = zwork1(:,:) + znitrpot(:,:,jk) * nitrfix * zfact * fse3t(:,:,jk) * tmask(:,:,jk)
413               ENDDO
414               CALL iom_put( "INTNFIX" , zwork1 ) 
415            ENDIF
416         ENDIF
417      ELSE
418         IF( ln_diatrc )  &
419            &  trc2d(:,:,jp_pcs0_2d + 12) = znitrpot(:,:,1) * nitrfix * rno3 * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1)
420      ENDIF
421      !
422      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
423         WRITE(charout, fmt="('sed ')")
424         CALL prt_ctl_trc_info(charout)
425         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
426      ENDIF
427      !
428      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
429      CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
430      CALL wrk_dealloc( jpi, jpj, jpk, znitrpot, zsoufer )
431      !
432      IF( nn_timing == 1 )  CALL timing_stop('p4z_sed')
433      !
434 9100  FORMAT(i8,3f10.5)
435      !
436   END SUBROUTINE p4z_sed
437
438#else
439   !!======================================================================
440   !!  Dummy module :                                   No PISCES bio-model
441   !!======================================================================
442CONTAINS
443   SUBROUTINE p4z_sed                         ! Empty routine
444   END SUBROUTINE p4z_sed
445#endif 
446
447   !!======================================================================
448END MODULE  p4zsed
Note: See TracBrowser for help on using the repository browser.