New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

limsbc.F90 in branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

Context Navigation

source: branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/LIM_SRC_3/limsbc.F90 @ 5370

Last change on this file since 5370 was 5370, checked in by clem, 9 years ago
correct output of the solar and non-solar fluxes received by the ice/ocean system
Property svn:keywords set to `Id`
File size: 21.5 KB

Rev	Line
[888]	1	MODULE limsbc
	2	!!======================================================================
	3	!! * MODULE limsbc *
	4	!! computation of the flux at the sea ice/ocean interface
	5	!!======================================================================
[2528]	6	!! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code
	7	!! 3.0 ! 2008-03 (C. Tallandier) surface module
	8	!! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling
	9	!! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea
	10	!! ! + simplification of the ice-ocean stress calculation
[3625]	11	!! 3.4 ! 2011-02 (G. Madec) dynamical allocation
[4161]	12	!! - ! 2012 (D. Iovino) salt flux change
	13	!! - ! 2012-05 (C. Rousset) add penetration solar flux
[3625]	14	!! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass
[888]	15	!!----------------------------------------------------------------------
	16	#if defined key_lim3
	17	!!----------------------------------------------------------------------
	18	!! 'key_lim3' LIM 3.0 sea-ice model
	19	!!----------------------------------------------------------------------
[2715]	20	!! lim_sbc_alloc : allocate the limsbc arrays
	21	!! lim_sbc_init : initialisation
	22	!! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface
	23	!! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface
[888]	24	!!----------------------------------------------------------------------
	25	USE par_oce ! ocean parameters
[4299]	26	USE phycst ! physical constants
[888]	27	USE dom_oce ! ocean domain
[4299]	28	USE ice ! LIM sea-ice variables
[888]	29	USE sbc_ice ! Surface boundary condition: sea-ice fields
	30	USE sbc_oce ! Surface boundary condition: ocean fields
[4299]	31	USE sbccpl
[5352]	32	USE oce , ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass
[2528]	33	USE albedo ! albedo parameters
[4299]	34	USE lbclnk ! ocean lateral boundary condition - MPP exchanges
[2715]	35	USE lib_mpp ! MPP library
[3294]	36	USE wrk_nemo ! work arrays
[4299]	37	USE in_out_manager ! I/O manager
[888]	38	USE prtctl ! Print control
[4299]	39	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
[5123]	40	USE traqsr ! add penetration of solar flux in the calculation of heat budget
[4688]	41	USE iom
	42	USE domvvl ! Variable volume
[5123]	43	USE limctl
[5167]	44	USE limcons
[888]	45
	46	IMPLICIT NONE
	47	PRIVATE
	48
[5123]	49	PUBLIC lim_sbc_init ! called by sbc_lim_init
[2715]	50	PUBLIC lim_sbc_flx ! called by sbc_ice_lim
	51	PUBLIC lim_sbc_tau ! called by sbc_ice_lim
[888]	52
[2715]	53	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2]
	54	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s]
	55	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice)
[1526]	56
[888]	57	!! * Substitutions
	58	# include "vectopt_loop_substitute.h90"
[4614]	59	# include "domzgr_substitute.h90"
[888]	60	!!----------------------------------------------------------------------
[4161]	61	!! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
[1146]	62	!! $Id$
[2528]	63	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
[888]	64	!!----------------------------------------------------------------------
	65	CONTAINS
	66
[2715]	67	INTEGER FUNCTION lim_sbc_alloc()
	68	!!-------------------------------------------------------------------
	69	!! * ROUTINE lim_sbc_alloc *
	70	!!-------------------------------------------------------------------
	71	ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , &
	72	& sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc)
	73	!
	74	IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc )
	75	IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays')
	76	END FUNCTION lim_sbc_alloc
	77
	78
[918]	79	SUBROUTINE lim_sbc_flx( kt )
	80	!!-------------------------------------------------------------------
	81	!! * ROUTINE lim_sbc_flx *
	82	!!
	83	!! ** Purpose : Update the surface ocean boundary condition for heat
	84	!! salt and mass over areas where sea-ice is non-zero
	85	!!
	86	!! ** Action : - computes the heat and freshwater/salt fluxes
	87	!! at the ice-ocean interface.
	88	!! - Update the ocean sbc
	89	!!
[1037]	90	!! ** Outputs : - qsr : sea heat flux: solar
	91	!! - qns : sea heat flux: non solar
	92	!! - emp : freshwater budget: volume flux
[3625]	93	!! - sfx : salt flux
[1037]	94	!! - fr_i : ice fraction
	95	!! - tn_ice : sea-ice surface temperature
[5357]	96	!! - alb_ice : sea-ice albedo (only useful in coupled mode)
[888]	97	!!
	98	!! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
	99	!! Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
[4990]	100	!! These refs are now obsolete since everything has been revised
[5123]	101	!! The ref should be Rousset et al., 2015
[888]	102	!!---------------------------------------------------------------------
[5357]	103	INTEGER, INTENT(in) :: kt ! number of iteration
	104	INTEGER :: ji, jj, jl, jk ! dummy loop indices
	105	REAL(wp) :: zqmass ! Heat flux associated with mass exchange ice->ocean (W.m-2)
	106	REAL(wp) :: zqsr ! New solar flux received by the ocean
[4990]	107	!
	108	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_cs, zalb_os ! 2D/3D workspace
[888]	109	!!---------------------------------------------------------------------
[921]	110
[4688]	111	! make calls for heat fluxes before it is modified
[5370]	112	IF( iom_use('qsr_oce') ) CALL iom_put( "qsr_oce" , qsr_oce(:,:) * pfrld(:,:) ) ! solar flux at ocean surface
	113	IF( iom_use('qns_oce') ) CALL iom_put( "qns_oce" , qns_oce(:,:) * pfrld(:,:) + qemp_oce(:,:) ) ! non-solar flux at ocean surface
	114	IF( iom_use('qsr_ice') ) CALL iom_put( "qsr_ice" , SUM( qsr_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) ) ! solar flux at ice surface
	115	IF( iom_use('qns_ice') ) CALL iom_put( "qns_ice" , SUM( qns_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) + qemp_ice(:,:) ) ! non-solar flux at ice surface
	116	IF( iom_use('qtr_ice') ) CALL iom_put( "qtr_ice" , SUM( ftr_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) ) ! solar flux transmitted thru ice
	117	IF( iom_use('qt_oce' ) ) CALL iom_put( "qt_oce" , ( qsr_oce(:,:) + qns_oce(:,:) ) * pfrld(:,:) + qemp_oce(:,:) )
	118	IF( iom_use('qt_ice' ) ) CALL iom_put( "qt_ice" , SUM( ( qns_ice(:,:,:) + qsr_ice(:,:,:) ) &
	119	& * a_i_b(:,:,:), dim=3 ) + qemp_ice(:,:) )
[4688]	120
[888]	121	! pfrld is the lead fraction at the previous time step (actually between TRP and THD)
	122	DO jj = 1, jpj
	123	DO ji = 1, jpi
	124
[4688]	125	!------------------------------------------!
	126	! heat flux at the ocean surface !
	127	!------------------------------------------!
[5357]	128	! Solar heat flux reaching the ocean = zqsr (W.m-2)
[4688]	129	!---------------------------------------------------
[5357]	130	zqsr = qsr_tot(ji,jj)
	131	DO jl = 1, jpl
	132	zqsr = zqsr - a_i_b(ji,jj,jl) * ( qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) )
	133	END DO
[888]	134
[4688]	135	! Total heat flux reaching the ocean = hfx_out (W.m-2)
	136	!---------------------------------------------------
[5357]	137	zqmass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC)
	138	hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr
[4161]	139
[5146]	140	! Add the residual from heat diffusion equation (W.m-2)
	141	!-------------------------------------------------------
	142	hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj)
	143
[4688]	144	! New qsr and qns used to compute the oceanic heat flux at the next time step
	145	!---------------------------------------------------
[5357]	146	qsr(ji,jj) = zqsr
	147	qns(ji,jj) = hfx_out(ji,jj) - zqsr
[888]	148
[4688]	149	!------------------------------------------!
	150	! mass flux at the ocean surface !
	151	!------------------------------------------!
[888]	152	! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED)
	153	! -------------------------------------------------------------------------------------
	154	! The idea of this approach is that the system that we consider is the ICE-OCEAN system
	155	! Thus FW flux = External ( E-P+snow melt)
	156	! Salt flux = Exchanges in the ice-ocean system then converted into FW
	157	! Associated to Ice formation AND Ice melting
	158	! Even if i see Ice melting as a FW and SALT flux
	159	!
[4688]	160	! mass flux from ice/ocean
[4765]	161	wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) &
	162	+ wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj)
[2528]	163
[4688]	164	! mass flux at the ocean/ice interface
[5187]	165	fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) ) * r1_rdtice ! F/M mass flux save at least for biogeochemical model
[5357]	166	emp(ji,jj) = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange)
[3625]	167
[888]	168	END DO
	169	END DO
	170
[3625]	171	!------------------------------------------!
	172	! salt flux at the ocean surface !
	173	!------------------------------------------!
[4765]	174	sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:) &
	175	& + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:)
[3625]	176
[4688]	177	!-------------------------------------------------------------!
	178	! mass of snow and ice per unit area for embedded sea-ice !
	179	!-------------------------------------------------------------!
	180	IF( nn_ice_embd /= 0 ) THEN
	181	! save mass from the previous ice time step
	182	snwice_mass_b(:,:) = snwice_mass(:,:)
	183	! new mass per unit area
[5123]	184	snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) )
[4688]	185	! time evolution of snow+ice mass
[3625]	186	snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice
	187	ENDIF
[921]	188
[888]	189	!-----------------------------------------------!
	190	! Storing the transmitted variables !
	191	!-----------------------------------------------!
[1037]	192	fr_i (:,:) = at_i(:,:) ! Sea-ice fraction
[888]	193	tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature
	194
[5357]	195	!------------------------------------------------------------------------!
	196	! Snow/ice albedo (only if sent to coupler, useless in forced mode) !
	197	!------------------------------------------------------------------------!
	198	CALL wrk_alloc( jpi, jpj, jpl, zalb_cs, zalb_os )
	199	CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
	200	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
	201	CALL wrk_dealloc( jpi, jpj, jpl, zalb_cs, zalb_os )
[4990]	202
[5167]	203	! conservation test
	204	IF( ln_limdiahsb ) CALL lim_cons_final( 'limsbc' )
[4688]	205
[5167]	206	! control prints
	207	IF( ln_icectl ) CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' )
	208
[888]	209	IF(ln_ctl) THEN
[918]	210	CALL prt_ctl( tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ' )
[3625]	211	CALL prt_ctl( tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=sfx , clinfo2=' sfx : ' )
[1037]	212	CALL prt_ctl( tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ' )
[918]	213	CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl )
[921]	214	ENDIF
[4990]	215
[918]	216	END SUBROUTINE lim_sbc_flx
[888]	217
[2528]	218
	219	SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce )
	220	!!-------------------------------------------------------------------
	221	!! * ROUTINE lim_sbc_tau *
	222	!!
	223	!! ** Purpose : Update the ocean surface stresses due to the ice
	224	!!
	225	!! ** Action : * at each ice time step (every nn_fsbc time step):
	226	!! - compute the modulus of ice-ocean relative velocity
	227	!! (rhoCd) at T-point (C-grid) or I-point (B-grid)
	228	!! tmod_io = rhoco * \| U_ice-U_oce \|
	229	!! - update the modulus of stress at ocean surface
	230	!! taum = frld * taum + (1-frld) * tmod_io * \| U_ice-U_oce \|
	231	!! * at each ocean time step (every kt):
	232	!! compute linearized ice-ocean stresses as
	233	!! Utau = tmod_io * \| U_ice - pU_oce \|
	234	!! using instantaneous current ocean velocity (usually before)
	235	!!
	236	!! NB: - ice-ocean rotation angle no more allowed
	237	!! - here we make an approximation: taum is only computed every ice time step
	238	!! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
	239	!! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
	240	!!
	241	!! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
	242	!! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
	243	!!---------------------------------------------------------------------
	244	INTEGER , INTENT(in) :: kt ! ocean time-step index
	245	REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents
	246	!!
	247	INTEGER :: ji, jj ! dummy loop indices
	248	REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar
	249	REAL(wp) :: zat_v, zvtau_ice, zv_t ! - -
[2715]	250	!!---------------------------------------------------------------------
	251	!
[2528]	252	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step)
	253	DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point)
	254	DO ji = fs_2, fs_jpim1
	255	! ! 2*(U_ice-U_oce) at T-point
	256	zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)
	257	zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1)
	258	! ! \|U_ice-U_oce\|^2
	259	zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t )
	260	! ! update the ocean stress modulus
	261	taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt
	262	tmod_io(ji,jj) = rhoco * SQRT( zmodt ) ! rhoco * \|U_ice-U_oce\| at T-point
	263	END DO
	264	END DO
	265	CALL lbc_lnk( taum, 'T', 1. ) ; CALL lbc_lnk( tmod_io, 'T', 1. )
	266	!
	267	utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step
	268	vtau_oce(:,:) = vtau(:,:)
	269	!
	270	ENDIF
[2715]	271	!
	272	! !== every ocean time-step ==!
	273	!
[2528]	274	DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle
	275	DO ji = fs_2, fs_jpim1 ! Vect. Opt.
	276	zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points
	277	zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp
	278	! ! linearized quadratic drag formulation
	279	zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) )
	280	zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) )
	281	! ! stresses at the ocean surface
	282	utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
	283	vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
	284	END DO
	285	END DO
	286	CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition
	287	!
	288	IF(ln_ctl) CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau : ', mask1=umask, &
	289	& tab2d_2=vtau, clinfo2=' vtau : ' , mask2=vmask )
	290	!
	291	END SUBROUTINE lim_sbc_tau
	292
[2715]	293
	294	SUBROUTINE lim_sbc_init
	295	!!-------------------------------------------------------------------
	296	!! * ROUTINE lim_sbc_init *
	297	!!
	298	!! ** Purpose : Preparation of the file ice_evolu for the output of
	299	!! the temporal evolution of key variables
	300	!!
	301	!! ** input : Namelist namicedia
	302	!!-------------------------------------------------------------------
[4299]	303	INTEGER :: ji, jj, jk ! dummy loop indices
[3625]	304	REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar
[2715]	305	IF(lwp) WRITE(numout,*)
	306	IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition'
	307	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ '
	308
	309	! ! allocate lim_sbc array
	310	IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' )
	311	!
	312	soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case
	313	sice_0(:,:) = sice
	314	!
	315	IF( cp_cfg == "orca" ) THEN ! decrease ocean & ice reference salinities in the Baltic sea
	316	WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. &
	317	& 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp )
	318	soce_0(:,:) = 4._wp
	319	sice_0(:,:) = 2._wp
	320	END WHERE
	321	ENDIF
[4161]	322	!
[4205]	323	IF( .NOT. ln_rstart ) THEN
	324	! ! embedded sea ice
	325	IF( nn_ice_embd /= 0 ) THEN ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass
[5123]	326	snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) )
[4205]	327	snwice_mass_b(:,:) = snwice_mass(:,:)
	328	ELSE
	329	snwice_mass (:,:) = 0.0_wp ! no mass exchanges
	330	snwice_mass_b(:,:) = 0.0_wp ! no mass exchanges
	331	ENDIF
	332	IF( nn_ice_embd == 2 ) THEN ! full embedment (case 2) deplete the initial ssh below sea-ice area
	333	sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0
	334	sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0
[4302]	335	#if defined key_vvl
	336	! key_vvl necessary? clem: yes for compilation purpose
[4301]	337	DO jk = 1,jpkm1 ! adjust initial vertical scale factors
	338	fse3t_n(:,:,jk) = e3t_0(:,:,jk)( 1._wp + sshn(:,:)tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
	339	fse3t_b(:,:,jk) = e3t_0(:,:,jk)( 1._wp + sshb(:,:)tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
	340	ENDDO
	341	fse3t_a(:,:,:) = fse3t_b(:,:,:)
	342	! Reconstruction of all vertical scale factors at now and before time
	343	! steps
	344	! =============================================================================
	345	! Horizontal scale factor interpolations
	346	! --------------------------------------
	347	CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3u_b(:,:,:), 'U' )
	348	CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3v_b(:,:,:), 'V' )
	349	CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3u_n(:,:,:), 'U' )
	350	CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3v_n(:,:,:), 'V' )
	351	CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3f_n(:,:,:), 'F' )
	352	! Vertical scale factor interpolations
	353	! ------------------------------------
	354	CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3w_n (:,:,:), 'W' )
	355	CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3uw_n(:,:,:), 'UW' )
	356	CALL dom_vvl_interpol( fse3v_n(:,:,:), fse3vw_n(:,:,:), 'VW' )
	357	CALL dom_vvl_interpol( fse3u_b(:,:,:), fse3uw_b(:,:,:), 'UW' )
	358	CALL dom_vvl_interpol( fse3v_b(:,:,:), fse3vw_b(:,:,:), 'VW' )
	359	! t- and w- points depth
	360	! ----------------------
	361	fsdept_n(:,:,1) = 0.5_wp * fse3w_n(:,:,1)
	362	fsdepw_n(:,:,1) = 0.0_wp
	363	fsde3w_n(:,:,1) = fsdept_n(:,:,1) - sshn(:,:)
	364	DO jk = 2, jpk
	365	fsdept_n(:,:,jk) = fsdept_n(:,:,jk-1) + fse3w_n(:,:,jk)
	366	fsdepw_n(:,:,jk) = fsdepw_n(:,:,jk-1) + fse3t_n(:,:,jk-1)
	367	fsde3w_n(:,:,jk) = fsdept_n(:,:,jk ) - sshn (:,:)
	368	END DO
	369	#endif
[4205]	370	ENDIF
	371	ENDIF ! .NOT. ln_rstart
[2715]	372	!
[4161]	373
[2715]	374	END SUBROUTINE lim_sbc_init
	375
[888]	376	#else
	377	!!----------------------------------------------------------------------
	378	!! Default option : Dummy module NO LIM 3.0 sea-ice model
	379	!!----------------------------------------------------------------------
	380	CONTAINS
	381	SUBROUTINE lim_sbc ! Dummy routine
	382	END SUBROUTINE lim_sbc
	383	#endif
	384
	385	!!======================================================================
	386	END MODULE limsbc

Note: See TracBrowser for help on using the repository browser.

Download in other formats: