source: branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 5362

Last change on this file since 5362 was 5362, checked in by vancop, 5 years ago

update CLIO forcing to match with new standards

  • Property svn:keywords set to Id
File size: 33.4 KB
Line 
1MODULE sbcice_lim
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim  ***
4   !! Surface module :  update the ocean surface boundary condition over ice
5   !!       &           covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM-3 Sea ice model time-stepping
7   !!=====================================================================
8   !! History :  2.0  ! 2006-12  (M. Vancoppenolle) Original code
9   !!            3.0  ! 2008-02  (C. Talandier)  Surface module from icestp.F90
10   !!             -   ! 2008-04  (G. Madec)  sltyle and lim_ctl routine
11   !!            3.3  ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!            3.4  ! 2011-01  (A Porter)  dynamical allocation
13   !!             -   ! 2012-10  (C. Rousset)  add lim_diahsb
14   !!            3.6  ! 2014-07  (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3' :                                  LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   sbc_ice_lim  : sea-ice model time-stepping and update ocean sbc over ice-covered area
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ice             ! LIM-3: ice variables
25   USE thd_ice         ! LIM-3: thermodynamical variables
26   USE dom_ice         ! LIM-3: ice domain
27
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE sbc_ice         ! Surface boundary condition: ice   fields
30   USE sbcblk_core     ! Surface boundary condition: CORE bulk
31   USE sbcblk_clio     ! Surface boundary condition: CLIO bulk
32   USE sbccpl          ! Surface boundary condition: coupled interface
33   USE albedo          ! ocean & ice albedo
34
35   USE phycst          ! Define parameters for the routines
36   USE eosbn2          ! equation of state
37   USE limdyn          ! Ice dynamics
38   USE limtrp          ! Ice transport
39   USE limthd          ! Ice thermodynamics
40   USE limitd_me       ! Mechanics on ice thickness distribution
41   USE limsbc          ! sea surface boundary condition
42   USE limdiahsb       ! Ice budget diagnostics
43   USE limwri          ! Ice outputs
44   USE limrst          ! Ice restarts
45   USE limupdate1      ! update of global variables
46   USE limupdate2      ! update of global variables
47   USE limvar          ! Ice variables switch
48
49   USE limmsh          ! LIM mesh
50   USE limistate       ! LIM initial state
51   USE limthd_sal      ! LIM ice thermodynamics: salinity
52
53   USE c1d             ! 1D vertical configuration
54   USE lbclnk          ! lateral boundary condition - MPP link
55   USE lib_mpp         ! MPP library
56   USE wrk_nemo        ! work arrays
57   USE timing          ! Timing
58   USE iom             ! I/O manager library
59   USE in_out_manager  ! I/O manager
60   USE prtctl          ! Print control
61   USE lib_fortran     !
62   USE limctl
63
64#if defined key_bdy 
65   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
66#endif
67
68   IMPLICIT NONE
69   PRIVATE
70
71   PUBLIC sbc_ice_lim  ! routine called by sbcmod.F90
72   PUBLIC sbc_lim_init ! routine called by sbcmod.F90
73   
74   !! * Substitutions
75#  include "domzgr_substitute.h90"
76#  include "vectopt_loop_substitute.h90"
77   !!----------------------------------------------------------------------
78   !! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
79   !! $Id$
80   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
81   !!----------------------------------------------------------------------
82CONTAINS
83
84   !!======================================================================
85
86   SUBROUTINE sbc_ice_lim( kt, kblk )
87      !!---------------------------------------------------------------------
88      !!                  ***  ROUTINE sbc_ice_lim  ***
89      !!                   
90      !! ** Purpose :   update the ocean surface boundary condition via the
91      !!                Louvain la Neuve Sea Ice Model time stepping
92      !!
93      !! ** Method  :   ice model time stepping
94      !!              - call the ice dynamics routine
95      !!              - call the ice advection/diffusion routine
96      !!              - call the ice thermodynamics routine
97      !!              - call the routine that computes mass and
98      !!                heat fluxes at the ice/ocean interface
99      !!              - save the outputs
100      !!              - save the outputs for restart when necessary
101      !!
102      !! ** Action  : - time evolution of the LIM sea-ice model
103      !!              - update all sbc variables below sea-ice:
104      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
105      !!---------------------------------------------------------------------
106      INTEGER, INTENT(in) ::   kt      ! ocean time step
107      INTEGER, INTENT(in) ::   kblk    ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
108      !!
109      INTEGER  ::   jl                 ! dummy loop index
110      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_os, zalb_cs  ! ice albedo under overcast/clear sky
111      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_ice          ! mean ice albedo (for coupled)
112      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zutau_ice, zvtau_ice 
113      !!----------------------------------------------------------------------
114
115      IF( nn_timing == 1 )  CALL timing_start('sbc_ice_lim')
116
117      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !  Ice time-step only
118
119         !-----------------------!                                           
120         ! --- Bulk Formulae --- !                                           
121         !-----------------------!
122         u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)      ! mean surface ocean current at ice velocity point
123         v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)      ! (C-grid dynamics :  U- & V-points as the ocean)
124         
125         ! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
126         t_bo(:,:) = ( eos_fzp( sss_m ) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) ) 
127         !                                                                                     
128!!clem         ! Ice albedo
129!!clem         CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
130!!clem         CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os )  ! cloud-sky and overcast-sky ice albedos
131!!
132!!         ! CORE and COUPLED bulk formulations
133!!         SELECT CASE( kblk )
134!!         CASE( jp_core , jp_cpl )
135!!            ! albedo depends on cloud fraction because of non-linear spectral effects
136!!            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
137!!            ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
138!!            ! (zalb_ice) is computed within the bulk routine
139!!clem         END SELECT
140         
141         ! Mask sea ice surface temperature (set to rt0 over land)
142         DO jl = 1, jpl
143            t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
144         END DO
145     
146         ! Bulk formulae  - provides the following fields:
147         ! utau_ice, vtau_ice : surface ice stress                     (U- & V-points)   [N/m2]
148         ! qsr_ice , qns_ice  : solar & non solar heat flux over ice   (T-point)         [W/m2]
149         ! qla_ice            : latent heat flux over ice              (T-point)         [W/m2]
150         ! dqns_ice, dqla_ice : non solar & latent heat sensistivity   (T-point)         [W/m2]
151         ! tprecip , sprecip  : total & solid precipitation            (T-point)         [Kg/m2/s]
152         ! fr1_i0  , fr2_i0   : 1sr & 2nd fraction of qsr penetration in ice             [%]
153         !
154         SELECT CASE( kblk )
155         CASE( jp_clio )                                       ! CLIO bulk formulation
156!!clem            CALL blk_ice_clio( t_su , zalb_cs    , zalb_os    , zalb_ice  ,               &
157!!               &                      utau_ice   , vtau_ice   , qns_ice   , qsr_ice   ,   &
158!!               &                      qla_ice    , dqns_ice   , dqla_ice  ,               &
159!!               &                      tprecip    , sprecip    ,                           &
160!!               &                      fr1_i0     , fr2_i0     , cp_ice_msh, jpl  )
161!!            !         
162!!            IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
163!!               &                                           dqns_ice, qla_ice, dqla_ice, nn_limflx )
164            CALL blk_ice_clio_tau
165
166         CASE( jp_core )                                       ! CORE bulk formulation
167!!clem            CALL blk_ice_core( t_su , u_ice     , v_ice     , zalb_ice   ,               &
168!!clem               &                      utau_ice  , vtau_ice  , qns_ice    , qsr_ice   ,   &
169!!clem               &                      qla_ice   , dqns_ice  , dqla_ice   ,               &
170!!clem               &                      tprecip   , sprecip   ,                            &
171!!clem               &                      fr1_i0    , fr2_i0    , cp_ice_msh, jpl  )
172!!clem            IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
173!!clem               &                                           dqns_ice, qla_ice, dqla_ice, nn_limflx )
174            CALL blk_ice_core_tau
175            !
176         CASE ( jp_cpl )
177           
178            CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )
179
180         END SELECT
181         
182         IF( ln_mixcpl) THEN
183            CALL wrk_alloc( jpi,jpj    , zutau_ice, zvtau_ice)
184            CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
185            utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
186            vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
187            CALL wrk_dealloc( jpi,jpj  , zutau_ice, zvtau_ice)
188         ENDIF
189
190         !                                           !----------------------!
191         !                                           ! LIM-3  time-stepping !
192         !                                           !----------------------!
193         !
194         numit = numit + nn_fsbc                     ! Ice model time step
195         !                                                   
196         CALL sbc_lim_bef                   ! Store previous ice values
197
198         CALL sbc_lim_diag0                 ! set diag of mass, heat and salt fluxes to 0
199         
200         CALL lim_rst_opn( kt )             ! Open Ice restart file
201         !
202         ! ----------------------------------------------
203         ! ice dynamics and transport (except in 1D case)
204         ! ----------------------------------------------
205         IF( .NOT. lk_c1d ) THEN
206           
207            CALL lim_dyn( kt )              ! Ice dynamics    ( rheology/dynamics )
208           
209            CALL lim_trp( kt )              ! Ice transport   ( Advection/diffusion )
210           
211            IF( nn_monocat /= 2 ) CALL lim_itd_me  ! Mechanical redistribution ! (ridging/rafting)
212
213#if defined key_bdy
214            CALL bdy_ice_lim( kt )         ! bdy ice thermo
215            IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermo bdy - ' )
216#endif
217            CALL lim_update1( kt )
218           
219         ENDIF
220         
221         CALL sbc_lim_bef                  ! Store previous ice values
222 
223         ! ----------------------------------------------
224         ! ice thermodynamics
225         ! ----------------------------------------------
226         CALL lim_var_agg(1)
227         
228         ! previous lead fraction and ice volume for flux calculations
229         pfrld(:,:)   = 1._wp - at_i(:,:)
230         phicif(:,:)  = vt_i(:,:)
231         
232         ! Ice albedo
233         CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
234         CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os )  ! cloud-sky and overcast-sky ice albedos
235 
236         SELECT CASE( kblk )
237         CASE( jp_clio )                                       ! CLIO bulk formulation
238            ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
239            ! (zalb_ice) is computed within the bulk routine
240!           CALL blk_ice_clio_flx( t_su , zalb_cs, zalb_os  , zalb_ice, qns_ice   , qsr_ice   ,    &
241!              &                      qla_ice, dqns_ice   , dqla_ice  , tprecip, sprecip    ,  &
242!              &                      fr1_i0     , fr2_i0     , jpl  )
243!           !         
244            CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, zalb_ice )
245            IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
246               &                                           dqns_ice, evap_ice, devap_ice, nn_limflx )
247
248         CASE( jp_core )                                       ! CORE bulk formulation
249            ! albedo depends on cloud fraction because of non-linear spectral effects
250            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
251            CALL blk_ice_core_flx( t_su, zalb_ice )
252            IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
253               &                                           dqns_ice, evap_ice, devap_ice, nn_limflx )
254
255         CASE ( jp_cpl )
256            ! albedo depends on cloud fraction because of non-linear spectral effects
257            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
258            CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su    )
259            IF( nn_limflx == 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
260               &                                           dqns_ice, evap_ice, devap_ice, nn_limflx )
261            ! Latent heat flux is forced to 0 in coupled: it is included in qns (non-solar heat flux)
262            evap_ice  (:,:,:) = 0._wp
263            devap_ice (:,:,:) = 0._wp
264
265         END SELECT
266         CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
267
268         !
269         CALL lim_thd( kt )                         ! Ice thermodynamics
270         
271         CALL lim_update2( kt )                     ! Corrections
272         !
273         CALL lim_sbc_flx( kt )                     ! Update surface ocean mass, heat and salt fluxes
274         !
275         IF(ln_limdiaout) CALL lim_diahsb           ! Diagnostics and outputs
276         
277         CALL lim_wri( 1 )                          ! Ice outputs
278         
279         IF( kt == nit000 .AND. ln_rstart )   &
280            &             CALL iom_close( numrir )  ! close input ice restart file
281         !
282         IF( lrst_ice )   CALL lim_rst_write( kt )  ! Ice restart file
283         !
284         IF( ln_icectl )  CALL lim_ctl( kt )        ! alerts in case of model crash
285         !
286         !
287      ENDIF   ! End sea-ice time step only
288
289      !--------------------------------!
290      ! --- at all ocean time step --- !
291      !--------------------------------!
292      ! Update surface ocean stresses (only in ice-dynamic case)
293      !    otherwise the atm.-ocean stresses are used everywhere
294      IF( ln_limdyn )     CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
295!!gm   remark, the ocean-ice stress is not saved in ice diag call above .....  find a solution!!!
296      !
297      IF( nn_timing == 1 )  CALL timing_stop('sbc_ice_lim')
298      !
299   END SUBROUTINE sbc_ice_lim
300   
301
302   SUBROUTINE sbc_lim_init
303      !!----------------------------------------------------------------------
304      !!                  ***  ROUTINE sbc_lim_init  ***
305      !!
306      !! ** purpose :   Allocate all the dynamic arrays of the LIM-3 modules
307      !!----------------------------------------------------------------------
308      INTEGER :: ierr
309      !!----------------------------------------------------------------------
310      IF(lwp) WRITE(numout,*)
311      IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition' 
312      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM-3) time stepping'
313      !
314                                       ! Open the reference and configuration namelist files and namelist output file
315      CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp ) 
316      CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
317      IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
318
319      CALL ice_run                     ! set some ice run parameters
320      !
321      !                                ! Allocate the ice arrays
322      ierr =        ice_alloc        ()      ! ice variables
323      ierr = ierr + dom_ice_alloc    ()      ! domain
324      ierr = ierr + sbc_ice_alloc    ()      ! surface forcing
325      ierr = ierr + thd_ice_alloc    ()      ! thermodynamics
326      ierr = ierr + lim_itd_me_alloc ()      ! ice thickness distribution - mechanics
327      !
328      IF( lk_mpp    )   CALL mpp_sum( ierr )
329      IF( ierr /= 0 )   CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
330      !
331      !                                ! adequation jpk versus ice/snow layers/categories
332      IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk )   &
333         &      CALL ctl_stop( 'STOP',                          &
334         &     'sbc_lim_init: the 3rd dimension of workspace arrays is too small.',   &
335         &     'use more ocean levels or less ice/snow layers/categories.' )
336      !
337      CALL lim_itd_init                ! ice thickness distribution initialization
338      !
339      CALL lim_thd_init                ! set ice thermodynics parameters
340      !
341      CALL lim_thd_sal_init            ! set ice salinity parameters
342      !
343      CALL lim_msh                     ! ice mesh initialization
344      !
345      CALL lim_itd_me_init             ! ice thickness distribution initialization for mecanical deformation
346      !                                ! Initial sea-ice state
347      IF( .NOT. ln_rstart ) THEN              ! start from rest: sea-ice deduced from sst
348         numit = 0
349         numit = nit000 - 1
350         CALL lim_istate
351      ELSE                                    ! start from a restart file
352         CALL lim_rst_read
353         numit = nit000 - 1
354      ENDIF
355      CALL lim_var_agg(1)
356      CALL lim_var_glo2eqv
357      !
358      CALL lim_sbc_init                 ! ice surface boundary condition   
359      !
360      fr_i(:,:)     = at_i(:,:)         ! initialisation of sea-ice fraction
361      tn_ice(:,:,:) = t_su(:,:,:)       ! initialisation of surface temp for coupled simu
362      !
363      nstart = numit  + nn_fsbc     
364      nitrun = nitend - nit000 + 1 
365      nlast  = numit  + nitrun 
366      !
367      IF( nstock == 0 )   nstock = nlast + 1
368      !
369   END SUBROUTINE sbc_lim_init
370
371
372   SUBROUTINE ice_run
373      !!-------------------------------------------------------------------
374      !!                  ***  ROUTINE ice_run ***
375      !!                 
376      !! ** Purpose :   Definition some run parameter for ice model
377      !!
378      !! ** Method  :   Read the namicerun namelist and check the parameter
379      !!              values called at the first timestep (nit000)
380      !!
381      !! ** input   :   Namelist namicerun
382      !!-------------------------------------------------------------------
383      INTEGER  ::   ios                 ! Local integer output status for namelist read
384      NAMELIST/namicerun/ jpl, nlay_i, nlay_s, cn_icerst_in, cn_icerst_out,   &
385         &                ln_limdyn, rn_amax, ln_limdiahsb, ln_limdiaout, ln_icectl, iiceprt, jiceprt 
386      !!-------------------------------------------------------------------
387      !                   
388      REWIND( numnam_ice_ref )              ! Namelist namicerun in reference namelist : Parameters for ice
389      READ  ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
390901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
391
392      REWIND( numnam_ice_cfg )              ! Namelist namicerun in configuration namelist : Parameters for ice
393      READ  ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
394902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
395      IF(lwm) WRITE ( numoni, namicerun )
396      !
397      !
398      IF(lwp) THEN                        ! control print
399         WRITE(numout,*)
400         WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice'
401         WRITE(numout,*) ' ~~~~~~'
402         WRITE(numout,*) '   number of ice  categories                               = ', jpl
403         WRITE(numout,*) '   number of ice  layers                                   = ', nlay_i
404         WRITE(numout,*) '   number of snow layers                                   = ', nlay_s
405         WRITE(numout,*) '   switch for ice dynamics (1) or not (0)      ln_limdyn   = ', ln_limdyn
406         WRITE(numout,*) '   maximum ice concentration                               = ', rn_amax 
407         WRITE(numout,*) '   Diagnose heat/salt budget or not          ln_limdiahsb  = ', ln_limdiahsb
408         WRITE(numout,*) '   Output   heat/salt budget or not          ln_limdiaout  = ', ln_limdiaout
409         WRITE(numout,*) '   control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_icectl
410         WRITE(numout,*) '   i-index for control prints (ln_icectl=true)             = ', iiceprt
411         WRITE(numout,*) '   j-index for control prints (ln_icectl=true)             = ', jiceprt
412      ENDIF
413      !
414      ! sea-ice timestep and inverse
415      rdt_ice   = nn_fsbc * rdttra(1) 
416      r1_rdtice = 1._wp / rdt_ice 
417
418      ! inverse of nlay_i and nlay_s
419      r1_nlay_i = 1._wp / REAL( nlay_i, wp )
420      r1_nlay_s = 1._wp / REAL( nlay_s, wp )
421      !
422#if defined key_bdy
423      IF( lwp .AND. ln_limdiahsb )  CALL ctl_warn('online conservation check activated but it does not work with BDY')
424#endif
425      !
426   END SUBROUTINE ice_run
427
428
429   SUBROUTINE lim_itd_init
430      !!------------------------------------------------------------------
431      !!                ***  ROUTINE lim_itd_init ***
432      !!
433      !! ** Purpose :   Initializes the ice thickness distribution
434      !! ** Method  :   ...
435      !! ** input   :   Namelist namiceitd
436      !!-------------------------------------------------------------------
437      INTEGER  ::   ios                 ! Local integer output status for namelist read
438      NAMELIST/namiceitd/ nn_catbnd, rn_himean
439      !
440      INTEGER  ::   jl                   ! dummy loop index
441      REAL(wp) ::   zc1, zc2, zc3, zx1   ! local scalars
442      REAL(wp) ::   zhmax, znum, zden, zalpha !
443      !!------------------------------------------------------------------
444      !
445      REWIND( numnam_ice_ref )              ! Namelist namiceitd in reference namelist : Parameters for ice
446      READ  ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 903)
447903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
448
449      REWIND( numnam_ice_cfg )              ! Namelist namiceitd in configuration namelist : Parameters for ice
450      READ  ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 904 )
451904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
452      IF(lwm) WRITE ( numoni, namiceitd )
453      !
454      !
455      IF(lwp) THEN                        ! control print
456         WRITE(numout,*)
457         WRITE(numout,*) 'ice_itd : ice cat distribution'
458         WRITE(numout,*) ' ~~~~~~'
459         WRITE(numout,*) '   shape of ice categories distribution                          nn_catbnd = ', nn_catbnd
460         WRITE(numout,*) '   mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
461      ENDIF
462
463      !----------------------------------
464      !- Thickness categories boundaries
465      !----------------------------------
466      IF(lwp) WRITE(numout,*)
467      IF(lwp) WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
468      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
469
470      hi_max(:) = 0._wp
471
472      SELECT CASE ( nn_catbnd  )       
473                                   !----------------------
474         CASE (1)                  ! tanh function (CICE)
475                                   !----------------------
476         zc1 =  3._wp / REAL( jpl, wp )
477         zc2 = 10._wp * zc1
478         zc3 =  3._wp
479
480         DO jl = 1, jpl
481            zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
482            hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
483         END DO
484
485                                   !----------------------
486         CASE (2)                  ! h^(-alpha) function
487                                   !----------------------
488         zalpha = 0.05             ! exponent of the transform function
489
490         zhmax  = 3.*rn_himean
491
492         DO jl = 1, jpl 
493            znum = jpl * ( zhmax+1 )**zalpha
494            zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
495            hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
496         END DO
497
498      END SELECT
499
500      DO jl = 1, jpl
501         hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
502      END DO
503
504      ! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
505      hi_max(jpl) = 99._wp
506
507      IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
508      IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
509      !
510   END SUBROUTINE lim_itd_init
511
512   
513   SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice,   &
514         &                          pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
515      !!---------------------------------------------------------------------
516      !!                  ***  ROUTINE ice_lim_flx  ***
517      !!                   
518      !! ** Purpose :   update the ice surface boundary condition by averaging and / or
519      !!                redistributing fluxes on ice categories                   
520      !!
521      !! ** Method  :   average then redistribute
522      !!
523      !! ** Action  :   
524      !!---------------------------------------------------------------------
525      INTEGER                   , INTENT(in   ) ::   k_limflx   ! =-1 do nothing; =0 average ;
526                                                                ! =1 average and redistribute ; =2 redistribute
527      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
528      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
529      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
530      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
531      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
532      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
533      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
534      !
535      INTEGER  ::   jl      ! dummy loop index
536      !
537      REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m    ! Mean albedo over all categories
538      REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m    ! Mean temperature over all categories
539      !
540      REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m   ! Mean solar heat flux over all categories
541      REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m   ! Mean non solar heat flux over all categories
542      REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m  ! Mean sublimation over all categories
543      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m   ! Mean d(qns)/dT over all categories
544      REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
545      !!----------------------------------------------------------------------
546
547      IF( nn_timing == 1 )  CALL timing_start('ice_lim_flx')
548      !
549      !
550      SELECT CASE( k_limflx )                              !==  averaged on all ice categories  ==!
551      CASE( 0 , 1 )
552         CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
553         !
554         z_qns_m(:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
555         z_qsr_m(:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
556         z_dqn_m(:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
557         z_evap_m(:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
558         z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
559         DO jl = 1, jpl
560            pdqn_ice(:,:,jl) = z_dqn_m(:,:)
561            pdevap_ice(:,:,jl) = z_devap_m(:,:)
562         END DO
563         !
564         DO jl = 1, jpl
565            pqns_ice(:,:,jl) = z_qns_m(:,:)
566            pqsr_ice(:,:,jl) = z_qsr_m(:,:)
567            pevap_ice(:,:,jl) = z_evap_m(:,:)
568         END DO
569         !
570         CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
571      END SELECT
572
573      SELECT CASE( k_limflx )                              !==  redistribution on all ice categories  ==!
574      CASE( 1 , 2 )
575         CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
576         !
577         zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) ) 
578         ztem_m(:,:) = fice_ice_ave ( ptn_ice  (:,:,:) ) 
579         DO jl = 1, jpl
580            pqns_ice(:,:,jl) = pqns_ice(:,:,jl) + pdqn_ice(:,:,jl) * (ptn_ice(:,:,jl) - ztem_m(:,:))
581            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * (ptn_ice(:,:,jl) - ztem_m(:,:))
582            pqsr_ice(:,:,jl) = pqsr_ice(:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) ) 
583         END DO
584         !
585         CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
586      END SELECT
587      !
588      IF( nn_timing == 1 )  CALL timing_stop('ice_lim_flx')
589      !
590   END SUBROUTINE ice_lim_flx
591
592   SUBROUTINE sbc_lim_bef
593      !!----------------------------------------------------------------------
594      !!                  ***  ROUTINE sbc_lim_bef  ***
595      !!
596      !! ** purpose :  store ice variables at "before" time step
597      !!----------------------------------------------------------------------
598      a_i_b  (:,:,:)   = a_i  (:,:,:)     ! ice area
599      e_i_b  (:,:,:,:) = e_i  (:,:,:,:)   ! ice thermal energy
600      v_i_b  (:,:,:)   = v_i  (:,:,:)     ! ice volume
601      v_s_b  (:,:,:)   = v_s  (:,:,:)     ! snow volume
602      e_s_b  (:,:,:,:) = e_s  (:,:,:,:)   ! snow thermal energy
603      smv_i_b(:,:,:)   = smv_i(:,:,:)     ! salt content
604      oa_i_b (:,:,:)   = oa_i (:,:,:)     ! areal age content
605      u_ice_b(:,:)     = u_ice(:,:)
606      v_ice_b(:,:)     = v_ice(:,:)
607     
608   END SUBROUTINE sbc_lim_bef
609
610   SUBROUTINE sbc_lim_diag0
611      !!----------------------------------------------------------------------
612      !!                  ***  ROUTINE sbc_lim_diag0  ***
613      !!
614      !! ** purpose :  set ice-ocean and ice-atm. fluxes to zeros at the beggining
615      !!               of the time step
616      !!----------------------------------------------------------------------
617      sfx    (:,:) = 0._wp   ;
618      sfx_bri(:,:) = 0._wp   ; 
619      sfx_sni(:,:) = 0._wp   ;   sfx_opw(:,:) = 0._wp
620      sfx_bog(:,:) = 0._wp   ;   sfx_dyn(:,:) = 0._wp
621      sfx_bom(:,:) = 0._wp   ;   sfx_sum(:,:) = 0._wp
622      sfx_res(:,:) = 0._wp
623     
624      wfx_snw(:,:) = 0._wp   ;   wfx_ice(:,:) = 0._wp
625      wfx_sni(:,:) = 0._wp   ;   wfx_opw(:,:) = 0._wp
626      wfx_bog(:,:) = 0._wp   ;   wfx_dyn(:,:) = 0._wp
627      wfx_bom(:,:) = 0._wp   ;   wfx_sum(:,:) = 0._wp
628      wfx_res(:,:) = 0._wp   ;   wfx_sub(:,:) = 0._wp
629      wfx_spr(:,:) = 0._wp   ;   
630     
631      hfx_thd(:,:) = 0._wp   ;   
632      hfx_snw(:,:) = 0._wp   ;   hfx_opw(:,:) = 0._wp
633      hfx_bog(:,:) = 0._wp   ;   hfx_dyn(:,:) = 0._wp
634      hfx_bom(:,:) = 0._wp   ;   hfx_sum(:,:) = 0._wp
635      hfx_res(:,:) = 0._wp   ;   hfx_sub(:,:) = 0._wp
636      hfx_spr(:,:) = 0._wp   ;   hfx_dif(:,:) = 0._wp 
637      hfx_err(:,:) = 0._wp   ;   hfx_err_rem(:,:) = 0._wp
638      hfx_err_dif(:,:) = 0._wp   ;
639
640      afx_tot(:,:) = 0._wp   ;
641      afx_dyn(:,:) = 0._wp   ;   afx_thd(:,:) = 0._wp
642
643      diag_heat(:,:) = 0._wp ;   diag_smvi(:,:) = 0._wp ;
644      diag_vice(:,:) = 0._wp ;   diag_vsnw(:,:) = 0._wp ;
645     
646   END SUBROUTINE sbc_lim_diag0
647
648     
649   FUNCTION fice_cell_ave ( ptab )
650      !!--------------------------------------------------------------------------
651      !! * Compute average over categories, for grid cell (ice covered and free ocean)
652      !!--------------------------------------------------------------------------
653      REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
654      REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
655      INTEGER :: jl ! Dummy loop index
656     
657      fice_cell_ave (:,:) = 0.0_wp
658     
659      DO jl = 1, jpl
660         fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
661      END DO
662     
663   END FUNCTION fice_cell_ave
664   
665   
666   FUNCTION fice_ice_ave ( ptab )
667      !!--------------------------------------------------------------------------
668      !! * Compute average over categories, for ice covered part of grid cell
669      !!--------------------------------------------------------------------------
670      REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
671      REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
672
673      fice_ice_ave (:,:) = 0.0_wp
674      WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
675
676   END FUNCTION fice_ice_ave
677
678
679#else
680   !!----------------------------------------------------------------------
681   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
682   !!----------------------------------------------------------------------
683CONTAINS
684   SUBROUTINE sbc_ice_lim ( kt, kblk )     ! Dummy routine
685      WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
686   END SUBROUTINE sbc_ice_lim
687   SUBROUTINE sbc_lim_init                 ! Dummy routine
688   END SUBROUTINE sbc_lim_init
689#endif
690
691   !!======================================================================
692END MODULE sbcice_lim
Note: See TracBrowser for help on using the repository browser.