source: branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 5357

Last change on this file since 5357 was 5357, checked in by clem, 5 years ago

LIM3: change the interface between the ice and atm for both coupled and forced modes. Some work still needs to be done to deal with sublimation in coupled mode.

  • Property svn:keywords set to Id
File size: 31.1 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting                   
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   sbc_init       : read namsbc namelist
20   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
21   !!----------------------------------------------------------------------
22   USE oce              ! ocean dynamics and tracers
23   USE dom_oce          ! ocean space and time domain
24   USE phycst           ! physical constants
25   USE sbc_oce          ! Surface boundary condition: ocean fields
26   USE sbc_ice          ! Surface boundary condition: ice fields
27   USE sbcdcy           ! surface boundary condition: diurnal cycle
28   USE sbcssm           ! surface boundary condition: sea-surface mean variables
29   USE sbcapr           ! surface boundary condition: atmospheric pressure
30   USE sbcana           ! surface boundary condition: analytical formulation
31   USE sbcflx           ! surface boundary condition: flux formulation
32   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
33   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
34   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
35   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
36   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
37   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
38   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
39   USE sbccpl           ! surface boundary condition: coupled florulation
40   USE cpl_oasis3       ! OASIS routines for coupling
41   USE sbcssr           ! surface boundary condition: sea surface restoring
42   USE sbcrnf           ! surface boundary condition: runoffs
43   USE sbcisf           ! surface boundary condition: ice shelf
44   USE sbcfwb           ! surface boundary condition: freshwater budget
45   USE closea           ! closed sea
46   USE icbstp           ! Icebergs!
47
48   USE prtctl           ! Print control                    (prt_ctl routine)
49   USE iom              ! IOM library
50   USE in_out_manager   ! I/O manager
51   USE lib_mpp          ! MPP library
52   USE timing           ! Timing
53   USE sbcwave          ! Wave module
54
55   IMPLICIT NONE
56   PRIVATE
57
58   PUBLIC   sbc        ! routine called by step.F90
59   PUBLIC   sbc_init   ! routine called by opa.F90
60   
61   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
62     
63   !! * Substitutions
64#  include "domzgr_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
67   !! $Id$
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE sbc_init
73      !!---------------------------------------------------------------------
74      !!                    ***  ROUTINE sbc_init ***
75      !!
76      !! ** Purpose :   Initialisation of the ocean surface boundary computation
77      !!
78      !! ** Method  :   Read the namsbc namelist and set derived parameters
79      !!                Call init routines for all other SBC modules that have one
80      !!
81      !! ** Action  : - read namsbc parameters
82      !!              - nsbc: type of sbc
83      !!----------------------------------------------------------------------
84      INTEGER ::   icpt   ! local integer
85      !!
86      NAMELIST/namsbc/ nn_fsbc   , ln_ana    , ln_flx, ln_blk_clio, ln_blk_core, ln_mixcpl,   &
87         &             ln_blk_mfs, ln_apr_dyn, nn_ice, nn_ice_embd, ln_dm2dc   , ln_rnf   ,   &
88         &             ln_ssr    , nn_isf    , nn_fwb, ln_cdgw    , ln_wave    , ln_sdw   ,   &
89         &             nn_lsm    , nn_limflx , nn_components, ln_cpl
90      INTEGER  ::   ios
91      INTEGER  ::   ierr, ierr0, ierr1, ierr2, ierr3, jpm
92      LOGICAL  ::   ll_purecpl
93      !!----------------------------------------------------------------------
94
95      IF(lwp) THEN
96         WRITE(numout,*)
97         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
98         WRITE(numout,*) '~~~~~~~~ '
99      ENDIF
100
101      REWIND( numnam_ref )              ! Namelist namsbc in reference namelist : Surface boundary
102      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
103901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
104
105      REWIND( numnam_cfg )              ! Namelist namsbc in configuration namelist : Parameters of the run
106      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
107902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
108      IF(lwm) WRITE ( numond, namsbc )
109
110      !                          ! overwrite namelist parameter using CPP key information
111      IF( Agrif_Root() ) THEN                ! AGRIF zoom
112        IF( lk_lim2 )   nn_ice      = 2
113        IF( lk_lim3 )   nn_ice      = 3
114        IF( lk_cice )   nn_ice      = 4
115      ENDIF
116      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
117          ln_ana      = .TRUE.   
118          nn_ice      =   0
119      ENDIF
120
121      IF(lwp) THEN               ! Control print
122         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
123         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
124         WRITE(numout,*) '           Type of sbc : '
125         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
126         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
127         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
128         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
129         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
130         WRITE(numout,*) '              forced-coupled mixed formulation           ln_mixcpl   = ', ln_mixcpl
131         WRITE(numout,*) '              coupled    formulation                     ln_cpl      = ', ln_cpl
132         WRITE(numout,*) '              OASIS coupling (with atm or sas)           lk_oasis    = ', lk_oasis
133         WRITE(numout,*) '              components of your executable              nn_components = ', nn_components
134         WRITE(numout,*) '              Multicategory heat flux formulation (LIM3) nn_limflx   = ', nn_limflx
135         WRITE(numout,*) '           Misc. options of sbc : '
136         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
137         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
138         WRITE(numout,*) '              ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd = ', nn_ice_embd
139         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
140         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
141         WRITE(numout,*) '              iceshelf formulation                       nn_isf      = ', nn_isf
142         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
143         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
144         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
145         WRITE(numout,*) '              n. of iterations if land-sea-mask applied  nn_lsm      = ', nn_lsm
146      ENDIF
147
148      ! LIM3 Multi-category heat flux formulation
149      SELECT CASE ( nn_limflx)
150      CASE ( -1 )
151         IF(lwp) WRITE(numout,*) '              Use of per-category fluxes (nn_limflx = -1) '
152      CASE ( 0  )
153         IF(lwp) WRITE(numout,*) '              Average per-category fluxes (nn_limflx = 0) ' 
154      CASE ( 1  )
155         IF(lwp) WRITE(numout,*) '              Average then redistribute per-category fluxes (nn_limflx = 1) '
156      CASE ( 2  )
157         IF(lwp) WRITE(numout,*) '              Redistribute a single flux over categories (nn_limflx = 2) '
158      END SELECT
159      !
160#if defined key_top && ! defined key_offline
161      ltrcdm2dc = (ln_dm2dc .AND. ln_blk_core .AND. nn_ice==2)
162      IF( ltrcdm2dc )THEN
163         IF(lwp)THEN
164            WRITE(numout,*)"analytical diurnal cycle, core bulk formulation and LIM2 use: "
165            WRITE(numout,*)"Diurnal cycle on physics but not in passive tracers"
166         ENDIF
167      ENDIF
168#else
169      ltrcdm2dc =  .FALSE.
170#endif
171
172      IF ( nn_components /= jp_iam_nemo .AND. .NOT. lk_oasis )   &
173         &      CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
174      IF ( ln_cpl .AND. .NOT. lk_oasis )    &
175         &      CALL ctl_stop( 'STOP', 'sbc_init : OASIS-coupled atmosphere model, but key_oasis3 disabled' )
176      IF( ln_mixcpl .AND. .NOT. lk_oasis )    &
177         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires the cpp key key_oasis3' )
178      IF( ln_mixcpl .AND. nn_components /= jp_iam_nemo )    &
179         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) is not yet working with sas-opa coupling via oasis' )
180
181      !
182      !                              ! allocate sbc arrays
183      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
184
185      !                          ! Checks:
186      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
187         ln_rnf_mouth  = .false.                     
188         IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' )
189         nkrnf         = 0
190         rnf     (:,:) = 0.0_wp
191         rnf_b   (:,:) = 0.0_wp
192         rnfmsk  (:,:) = 0.0_wp
193         rnfmsk_z(:)   = 0.0_wp
194      ENDIF
195      IF( nn_isf .EQ. 0 ) THEN                      ! no specific treatment in vicinity of ice shelf
196         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
197         fwfisf  (:,:) = 0.0_wp
198         fwfisf_b(:,:) = 0.0_wp
199      END IF
200      IF( nn_ice == 0 .AND. nn_components /= jp_iam_opa )   fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero
201
202      sfx(:,:) = 0.0_wp                            ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero)
203                                                   ! only if sea-ice is present
204 
205      fmmflx(:,:) = 0.0_wp                        ! freezing-melting array initialisation
206     
207      taum(:,:) = 0.0_wp                           ! Initialise taum for use in gls in case of reduced restart
208
209      !                                            ! restartability   
210      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. ln_cpl ) )   &
211         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
212      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. ln_cpl ) )   &
213         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or ln_cpl' )
214      IF( nn_ice == 4 .AND. lk_agrif )   &
215         &   CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' )
216      IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 )   &
217         &   CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' )
218      IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) )   &
219         &   WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3'
220      IF( ( nn_ice == 3 ) .AND. ( ln_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) )   &
221         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
222      IF( ( nn_ice == 3 ) .AND. ( .NOT. ln_cpl ) .AND. ( nn_limflx == 2 ) )   &
223         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' )
224
225      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
226
227      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) )   &
228         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
229     
230      IF ( ln_wave ) THEN
231      !Activated wave module but neither drag nor stokes drift activated
232         IF ( .NOT.(ln_cdgw .OR. ln_sdw) )   THEN
233            CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' )
234      !drag coefficient read from wave model definable only with mfs bulk formulae and core
235         ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) )       THEN       
236             CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
237         ENDIF
238      ELSE
239      IF ( ln_cdgw .OR. ln_sdw  )                                         & 
240         &   CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but     &
241         & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ')
242      ENDIF 
243     
244      !                          ! Choice of the Surface Boudary Condition (set nsbc)
245      ll_purecpl = ln_cpl .AND. .NOT. ln_mixcpl
246      !
247      icpt = 0
248      IF( ln_ana          ) THEN   ;   nsbc = jp_ana    ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
249      IF( ln_flx          ) THEN   ;   nsbc = jp_flx    ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
250      IF( ln_blk_clio     ) THEN   ;   nsbc = jp_clio   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
251      IF( ln_blk_core     ) THEN   ;   nsbc = jp_core   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
252      IF( ln_blk_mfs      ) THEN   ;   nsbc = jp_mfs    ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk       formulation
253      IF( ll_purecpl      ) THEN   ;   nsbc = jp_cpl    ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled    formulation
254      IF( cp_cfg == 'gyre') THEN   ;   nsbc = jp_gyre                       ;   ENDIF       ! GYRE analytical formulation
255      IF( nn_components == jp_iam_opa ) THEN   ;   nsbc = jp_none  ; icpt = icpt + 1 ;   ENDIF       ! opa coupling via SAS module
256      IF( lk_esopa        )            nsbc = jp_esopa                                      ! esopa test, ALL formulations
257      !
258      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
259         WRITE(numout,*)
260         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
261         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
262         WRITE(numout,*) '                     We stop'
263         nstop = nstop + 1
264      ENDIF
265      IF(lwp) THEN
266         WRITE(numout,*)
267         IF( nsbc == jp_esopa )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
268         IF( nsbc == jp_gyre  )   WRITE(numout,*) '              GYRE analytical formulation'
269         IF( nsbc == jp_ana   )   WRITE(numout,*) '              analytical formulation'
270         IF( nsbc == jp_flx   )   WRITE(numout,*) '              flux formulation'
271         IF( nsbc == jp_clio  )   WRITE(numout,*) '              CLIO bulk formulation'
272         IF( nsbc == jp_core  )   WRITE(numout,*) '              CORE bulk formulation'
273         IF( nsbc == jp_cpl   )   WRITE(numout,*) '              pure coupled formulation'
274         IF( nsbc == jp_mfs   )   WRITE(numout,*) '              MFS Bulk formulation'
275         IF( nsbc == jp_none  )   WRITE(numout,*) '              OPA coupled to SAS via oasis'
276         IF( ln_mixcpl        )   WRITE(numout,*) '              + forced-coupled mixed formulation'
277         IF( nn_components/= 0 )  WRITE(numout,*) '              + OASIS coupled SAS'
278      ENDIF
279      !
280      IF( lk_oasis         )   CALL sbc_cpl_init (nn_ice)   ! OASIS initialisation. must be done before: (1) first time step
281      !                                                     !                                            (2) the use of nn_fsbc
282
283!     nn_fsbc initialization if OPA-SAS coupling via OASIS
284!     sas model time step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
285      IF ( nn_components /= jp_iam_nemo ) THEN
286
287         IF ( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
288         IF ( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
289         !
290         IF(lwp)THEN
291            WRITE(numout,*)
292            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
293            WRITE(numout,*)
294         ENDIF
295      ENDIF
296
297      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
298          MOD( nstock             , nn_fsbc) /= 0 ) THEN
299         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
300            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
301         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
302      ENDIF
303      !
304      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
305         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
306      !
307      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
308         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
309
310
311      IF( nn_components /= jp_iam_sas )   &
312         &                     CALL sbc_ssm_init               ! Sea-surface mean fields initialisation
313      !
314      IF( ln_ssr           )   CALL sbc_ssr_init               ! Sea-Surface Restoring initialisation
315      !
316      IF( nn_ice == 3      )   CALL sbc_lim_init               ! LIM3 initialisation
317
318      IF( nn_ice == 4      )   CALL cice_sbc_init( nsbc )      ! CICE initialisation
319     
320   END SUBROUTINE sbc_init
321
322
323   SUBROUTINE sbc( kt )
324      !!---------------------------------------------------------------------
325      !!                    ***  ROUTINE sbc  ***
326      !!             
327      !! ** Purpose :   provide at each time-step the ocean surface boundary
328      !!                condition (momentum, heat and freshwater fluxes)
329      !!
330      !! ** Method  :   blah blah  to be written ?????????
331      !!                CAUTION : never mask the surface stress field (tke sbc)
332      !!
333      !! ** Action  : - set the ocean surface boundary condition at before and now
334      !!                time step, i.e. 
335      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
336      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
337      !!              - updte the ice fraction : fr_i
338      !!----------------------------------------------------------------------
339      INTEGER, INTENT(in) ::   kt       ! ocean time step
340      !!---------------------------------------------------------------------
341      !
342      IF( nn_timing == 1 )  CALL timing_start('sbc')
343      !
344      !                                            ! ---------------------------------------- !
345      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
346         !                                         ! ---------------------------------------- !
347         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
348         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
349         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
350         ! The 3D heat content due to qsr forcing is treated in traqsr
351         ! qsr_b (:,:) = qsr (:,:)
352         emp_b(:,:) = emp(:,:)
353         sfx_b(:,:) = sfx(:,:)
354      ENDIF
355      !                                            ! ---------------------------------------- !
356      !                                            !        forcing field computation         !
357      !                                            ! ---------------------------------------- !
358      !
359      IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
360                                                         ! (caution called before sbc_ssm)
361      !
362      IF( nn_components /= jp_iam_sas ) CALL sbc_ssm( kt )         ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
363      !                                                  ! averaged over nf_sbc time-step
364
365      IF (ln_wave) CALL sbc_wave( kt )
366                                                   !==  sbc formulation  ==!
367                                                           
368      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
369      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
370      CASE( jp_gyre  )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
371      CASE( jp_ana   )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
372      CASE( jp_flx   )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
373      CASE( jp_clio  )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
374      CASE( jp_core  )   
375         IF( nn_components == jp_iam_sas ) &
376            &                CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
377                             CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
378                                                                        ! from oce: sea surface variables (sst_m, sss_m,  ssu_m,  ssv_m)
379      CASE( jp_cpl   )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
380                                                                        !
381      CASE( jp_mfs   )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
382      CASE( jp_none  ) 
383         IF( nn_components == jp_iam_opa ) &
384                             CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
385      CASE( jp_esopa )                               
386                             CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
387                             CALL sbc_gyre    ( kt )                    !
388                             CALL sbc_flx     ( kt )                    !
389                             CALL sbc_blk_clio( kt )                    !
390                             CALL sbc_blk_core( kt )                    !
391                             CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
392      END SELECT
393
394      IF( ln_mixcpl )        CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation
395
396
397      !                                            !==  Misc. Options  ==!
398     
399      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
400      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
401      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
402      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
403      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
404      END SELECT                                             
405
406      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
407
408      IF( nn_isf   /= 0  )   CALL sbc_isf( kt )                    ! compute iceshelves
409
410      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
411 
412      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
413
414      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
415
416      IF( nn_closea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
417      !                                                           ! (update freshwater fluxes)
418!RBbug do not understand why see ticket 667
419!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
420      CALL lbc_lnk( emp, 'T', 1. )
421      !
422      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
423         !                                             ! ---------------------------------------- !
424         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
425            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
426            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
427            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
428            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
429            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
430            ! The 3D heat content due to qsr forcing is treated in traqsr
431            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
432            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
433            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
434            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
435               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
436            ELSE
437               sfx_b (:,:) = sfx(:,:)
438            ENDIF
439         ELSE                                                   !* no restart: set from nit000 values
440            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
441            utau_b(:,:) = utau(:,:) 
442            vtau_b(:,:) = vtau(:,:)
443            qns_b (:,:) = qns (:,:)
444            emp_b (:,:) = emp(:,:)
445            sfx_b (:,:) = sfx(:,:)
446         ENDIF
447      ENDIF
448      !                                                ! ---------------------------------------- !
449      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
450         !                                             ! ---------------------------------------- !
451         IF(lwp) WRITE(numout,*)
452         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
453            &                    'at it= ', kt,' date= ', ndastp
454         IF(lwp) WRITE(numout,*) '~~~~'
455         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
456         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
457         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
458         ! The 3D heat content due to qsr forcing is treated in traqsr
459         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
460         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
461         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx  )
462      ENDIF
463
464      !                                                ! ---------------------------------------- !
465      !                                                !        Outputs and control print         !
466      !                                                ! ---------------------------------------- !
467      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
468         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
469         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux 
470                                                                ! (includes virtual salt flux beneath ice
471                                                                ! in linear free surface case)
472         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
473         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
474         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
475         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
476         IF( nn_ice > 0 .OR. nn_components == jp_iam_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
477         CALL iom_put( "taum"  , taum       )                   ! wind stress module
478         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
479      ENDIF
480      !
481      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
482      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
483      !
484      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
485         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
486         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
487         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf  - : ', mask1=tmask, ovlap=1 )
488         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
489         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
490         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
491         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
492         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
493         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
494            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
495      ENDIF
496
497      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
498      !
499      IF( nn_timing == 1 )  CALL timing_stop('sbc')
500      !
501   END SUBROUTINE sbc
502
503
504   SUBROUTINE sbc_final
505      !!---------------------------------------------------------------------
506      !!                    ***  ROUTINE sbc_final  ***
507      !!
508      !! ** Purpose :   Finalize CICE (if used)
509      !!---------------------------------------------------------------------
510      !
511      IF( nn_ice == 4 )   CALL cice_sbc_final
512      !
513   END SUBROUTINE sbc_final
514
515   !!======================================================================
516END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.