New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcrnf.F90 in branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 5381

Last change on this file since 5381 was 5381, checked in by smasson, 9 years ago
dev_r5218_CNRS17_coupling: continue...
Property svn:keywords set to `Id`
File size: 27.2 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE sbcisf ! PM we could remove it I think
22	USE closea ! closed seas
23	USE fldread ! read input field at current time step
24	USE in_out_manager ! I/O manager
25	USE iom ! I/O module
26	USE lib_mpp ! MPP library
27	USE eosbn2
28	USE wrk_nemo ! Memory allocation
29
30	IMPLICIT NONE
31	PRIVATE
32
33	PUBLIC sbc_rnf ! routine call in sbcmod module
34	PUBLIC sbc_rnf_div ! routine called in sshwzv module
35	PUBLIC sbc_rnf_alloc ! routine call in sbcmod module
36	PUBLIC sbc_rnf_init ! (PUBLIC for TAM)
37	! !!* namsbc_rnf namelist *
38	CHARACTER(len=100), PUBLIC :: cn_dir !: Root directory for location of ssr files
39	LOGICAL , PUBLIC :: ln_rnf_depth !: depth river runoffs attribute specified in a file
40	LOGICAL , PUBLIC :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
41	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
42	LOGICAL , PUBLIC :: ln_rnf_emp !: runoffs into a file to be read or already into precipitation
43	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
44	TYPE(FLD_N) , PUBLIC :: sn_cnf !: information about the runoff mouth file to be read
45	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
46	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
47	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
48	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
49	REAL(wp) , PUBLIC :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
50	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
51	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
52
53	LOGICAL , PUBLIC :: l_rnfcpl = .false. ! runoffs recieved from oasis
54
55	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
56	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
57	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
58	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
59	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
60	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s]
61
62	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
63	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
64	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
65
66	!! * Substitutions
67	# include "domzgr_substitute.h90"
68	!!----------------------------------------------------------------------
69	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
70	!! $Id$
71	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
72	!!----------------------------------------------------------------------
73	CONTAINS
74
75	INTEGER FUNCTION sbc_rnf_alloc()
76	!!----------------------------------------------------------------------
77	!! * ROUTINE sbc_rnf_alloc *
78	!!----------------------------------------------------------------------
79	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
80	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
81	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
82	!
83	IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc )
84	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
85	END FUNCTION sbc_rnf_alloc
86
87
88	SUBROUTINE sbc_rnf( kt )
89	!!----------------------------------------------------------------------
90	!! * ROUTINE sbc_rnf *
91	!!
92	!! ** Purpose : Introduce a climatological run off forcing
93	!!
94	!! ** Method : Set each river mouth with a monthly climatology
95	!! provided from different data.
96	!! CAUTION : upward water flux, runoff forced to be < 0
97	!!
98	!! ** Action : runoff updated runoff field at time-step kt
99	!!----------------------------------------------------------------------
100	INTEGER, INTENT(in) :: kt ! ocean time step
101	!
102	INTEGER :: ji, jj ! dummy loop indices
103	INTEGER :: z_err = 0 ! dummy integer for error handling
104	!!----------------------------------------------------------------------
105	REAL(wp), DIMENSION(:,:), POINTER :: ztfrz ! freezing point used for temperature correction
106	!
107	CALL wrk_alloc( jpi,jpj, ztfrz)
108
109	!
110	IF( kt == nit000 ) CALL sbc_rnf_init ! Read namelist and allocate structures
111
112	! ! ---------------------------------------- !
113	IF( kt /= nit000 ) THEN ! Swap of forcing fields !
114	! ! ---------------------------------------- !
115	rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000
116	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine
117	!
118	ENDIF
119
120	! !-------------------!
121	IF( .NOT. ln_rnf_emp ) THEN ! Update runoff !
122	! !-------------------!
123	!
124	IF( .NOT. l_rnfcpl ) CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
125	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
126	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
127	!
128	! Runoff reduction only associated to the ORCA2_LIM configuration
129	! when reading the NetCDF file runoff_1m_nomask.nc
130	IF( cp_cfg == 'orca' .AND. jp_cfg == 2 .AND. .NOT. l_rnfcpl ) THEN
131	WHERE( 40._wp < gphit(:,:) .AND. gphit(:,:) < 65._wp )
132	sf_rnf(1)%fnow(:,:,1) = 0.85 * sf_rnf(1)%fnow(:,:,1)
133	END WHERE
134	ENDIF
135	!
136	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
137	!
138	IF( .NOT. l_rnfcpl ) rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) ! updated runoff value at time step kt
139	!
140	! ! set temperature & salinity content of runoffs
141	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
142	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
143	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
144	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
145	END WHERE
146	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp ) ! where fwf comes from melting of ice shelves or iceberg
147	ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
148	rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
149	END WHERE
150	ELSE ! use SST as runoffs temperature
151	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
152	ENDIF
153	! ! use runoffs salinity data
154	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
155	! ! else use S=0 for runoffs (done one for all in the init)
156	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
157	ENDIF
158	!
159	ENDIF
160	!
161	! ! ---------------------------------------- !
162	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
163	! ! ---------------------------------------- !
164	IF( ln_rstart .AND. & !* Restart: read in restart file
165	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
166	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
167	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
168	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
169	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
170	ELSE !* no restart: set from nit000 values
171	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
172	rnf_b (:,: ) = rnf (:,: )
173	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
174	ENDIF
175	ENDIF
176	! ! ---------------------------------------- !
177	IF( lrst_oce ) THEN ! Write in the ocean restart file !
178	! ! ---------------------------------------- !
179	IF(lwp) WRITE(numout,*)
180	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
181	& 'at it= ', kt,' date= ', ndastp
182	IF(lwp) WRITE(numout,*) '~~~~'
183	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
184	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
185	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
186	ENDIF
187	CALL wrk_dealloc( jpi,jpj, ztfrz)
188	!
189	END SUBROUTINE sbc_rnf
190
191
192	SUBROUTINE sbc_rnf_div( phdivn )
193	!!----------------------------------------------------------------------
194	!! * ROUTINE sbc_rnf *
195	!!
196	!! ** Purpose : update the horizontal divergence with the runoff inflow
197	!!
198	!! ** Method :
199	!! CAUTION : rnf is positive (inflow) decreasing the
200	!! divergence and expressed in m/s
201	!!
202	!! ** Action : phdivn decreased by the runoff inflow
203	!!----------------------------------------------------------------------
204	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
205	!!
206	INTEGER :: ji, jj, jk ! dummy loop indices
207	REAL(wp) :: zfact ! local scalar
208	!!----------------------------------------------------------------------
209	!
210	zfact = 0.5_wp
211	!
212	IF( ln_rnf_depth ) THEN !== runoff distributed over several levels ==!
213	IF( lk_vvl ) THEN ! variable volume case
214	DO jj = 1, jpj ! update the depth over which runoffs are distributed
215	DO ji = 1, jpi
216	h_rnf(ji,jj) = 0._wp
217	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
218	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
219	END DO
220	! ! apply the runoff input flow
221	DO jk = 1, nk_rnf(ji,jj)
222	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
223	END DO
224	END DO
225	END DO
226	ELSE ! constant volume case : just apply the runoff input flow
227	DO jj = 1, jpj
228	DO ji = 1, jpi
229	DO jk = 1, nk_rnf(ji,jj)
230	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
231	END DO
232	END DO
233	END DO
234	ENDIF
235	ELSE !== runoff put only at the surface ==!
236	IF( lk_vvl ) THEN ! variable volume case
237	h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box
238	ENDIF
239	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
240	ENDIF
241	!
242	END SUBROUTINE sbc_rnf_div
243
244
245	SUBROUTINE sbc_rnf_init
246	!!----------------------------------------------------------------------
247	!! * ROUTINE sbc_rnf_init *
248	!!
249	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
250	!!
251	!! ** Method : - read the runoff namsbc_rnf namelist
252	!!
253	!! ** Action : - read parameters
254	!!----------------------------------------------------------------------
255	CHARACTER(len=32) :: rn_dep_file ! runoff file name
256	INTEGER :: ji, jj, jk ! dummy loop indices
257	INTEGER :: ierror, inum ! temporary integer
258	INTEGER :: ios ! Local integer output status for namelist read
259	!
260	NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
261	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
262	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact
263	!!----------------------------------------------------------------------
264	!
265	! ! ============
266	! ! Namelist
267	! ! ============
268	!
269	REWIND( numnam_ref ) ! Namelist namsbc_rnf in reference namelist : Runoffs
270	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
271	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
272
273	REWIND( numnam_cfg ) ! Namelist namsbc_rnf in configuration namelist : Runoffs
274	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
275	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
276	IF(lwm) WRITE ( numond, namsbc_rnf )
277	!
278	! ! Control print
279	IF(lwp) THEN
280	WRITE(numout,*)
281	WRITE(numout,*) 'sbc_rnf : runoff '
282	WRITE(numout,*) '~~~~~~~ '
283	WRITE(numout,*) ' Namelist namsbc_rnf'
284	WRITE(numout,*) ' runoff in a file to be read ln_rnf_emp = ', ln_rnf_emp
285	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
286	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
287	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
288	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
289	ENDIF
290	!
291	IF( ln_rnf_emp .AND. nn_components == jp_iam_opa ) THEN
292	CALL ctl_stop( 'sbc_rnf_init: ln_rnf_emp must be false in case of SAS-OPA coupling' ) ; RETURN
293	ENDIF
294	! ! ==================
295	! ! Type of runoff
296	! ! ==================
297	! !== allocate runoff arrays
298	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
299	!
300	IF( ln_rnf_emp ) THEN !== runoffs directly provided in the precipitations ==!
301	IF(lwp) WRITE(numout,*)
302	IF(lwp) WRITE(numout,*) ' runoffs directly provided in the precipitations'
303	IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN
304	CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' )
305	ln_rnf_depth = .FALSE. ; ln_rnf_tem = .FALSE. ; ln_rnf_sal = .FALSE.
306	ENDIF
307	!
308	ELSE !== runoffs read in a file : set sf_rnf structure ==!
309	!
310	IF( .NOT. l_rnfcpl ) THEN
311	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create (if required) sf_rnf structure (runoff inflow)
312	IF(lwp) WRITE(numout,*)
313	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
314	IF( ierror > 0 ) THEN
315	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
316	ENDIF
317	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
318	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
319	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
320	ENDIF
321	!
322	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
323	IF(lwp) WRITE(numout,*)
324	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
325	ALLOCATE( sf_t_rnf(1), STAT=ierror )
326	IF( ierror > 0 ) THEN
327	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
328	ENDIF
329	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
330	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
331	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
332	ENDIF
333	!
334	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
335	IF(lwp) WRITE(numout,*)
336	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
337	ALLOCATE( sf_s_rnf(1), STAT=ierror )
338	IF( ierror > 0 ) THEN
339	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
340	ENDIF
341	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
342	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
343	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
344	ENDIF
345	!
346	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
347	IF(lwp) WRITE(numout,*)
348	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
349	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
350	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
351	IF( sn_dep_rnf%cltype == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
352	ENDIF
353	CALL iom_open ( rn_dep_file, inum ) ! open file
354	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
355	CALL iom_close( inum ) ! close file
356	!
357	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
358	DO jj = 1, jpj
359	DO ji = 1, jpi
360	IF( h_rnf(ji,jj) > 0._wp ) THEN
361	jk = 2
362	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; END DO
363	nk_rnf(ji,jj) = jk
364	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
365	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
366	ELSE
367	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
368	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
369	ENDIF
370	END DO
371	END DO
372	DO jj = 1, jpj ! set the associated depth
373	DO ji = 1, jpi
374	h_rnf(ji,jj) = 0._wp
375	DO jk = 1, nk_rnf(ji,jj)
376	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
377	END DO
378	END DO
379	END DO
380	ELSE ! runoffs applied at the surface
381	nk_rnf(:,:) = 1
382	h_rnf (:,:) = fse3t(:,:,1)
383	ENDIF
384	!
385	ENDIF
386	!
387	rnf(:,:) = 0._wp ! runoff initialisation
388	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
389	!
390	! ! ========================
391	! ! River mouth vicinity
392	! ! ========================
393	!
394	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
395	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
396	! ! - set to zero SSS damping (ln_ssr=T)
397	! ! - mixed upstream-centered (ln_traadv_cen2=T)
398	!
399	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
400	& 'be spread through depth by ln_rnf_depth' )
401	!
402	nkrnf = 0 ! Number of level over which Kz increase
403	IF( rn_hrnf > 0._wp ) THEN
404	nkrnf = 2
405	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1 ; END DO
406	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
407	ENDIF
408	IF(lwp) WRITE(numout,*)
409	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
410	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
411	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
412	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
413	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
414	!
415	CALL rnf_mouth ! set river mouth mask
416	!
417	ELSE ! No treatment at river mouths
418	IF(lwp) WRITE(numout,*)
419	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
420	rnfmsk (:,:) = 0._wp
421	rnfmsk_z(:) = 0._wp
422	nkrnf = 0
423	ENDIF
424	!
425	END SUBROUTINE sbc_rnf_init
426
427
428	SUBROUTINE rnf_mouth
429	!!----------------------------------------------------------------------
430	!! * ROUTINE rnf_mouth *
431	!!
432	!! ** Purpose : define the river mouths mask
433	!!
434	!! ** Method : read the river mouth mask (=0/1) in the river runoff
435	!! climatological file. Defined a given vertical structure.
436	!! CAUTION, the vertical structure is hard coded on the
437	!! first 5 levels.
438	!! This fields can be used to:
439	!! - set an upstream advection scheme
440	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
441	!! - increase vertical on the top nn_krnf vertical levels
442	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
443	!! - set to zero SSS restoring flux at river mouth grid points
444	!!
445	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
446	!! rnfmsk_z vertical structure
447	!!----------------------------------------------------------------------
448	INTEGER :: inum ! temporary integers
449	CHARACTER(len=140) :: cl_rnfile ! runoff file name
450	!!----------------------------------------------------------------------
451	!
452	IF(lwp) WRITE(numout,*)
453	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
454	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
455	!
456	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
457	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
458	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
459	ENDIF
460	!
461	! horizontal mask (read in NetCDF file)
462	CALL iom_open ( cl_rnfile, inum ) ! open file
463	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
464	CALL iom_close( inum ) ! close file
465	!
466	IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
467	!
468	rnfmsk_z(:) = 0._wp ! vertical structure
469	rnfmsk_z(1) = 1.0
470	rnfmsk_z(2) = 1.0 ! **********
471	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
472	rnfmsk_z(4) = 0.25 ! **********
473	rnfmsk_z(5) = 0.125
474	!
475	END SUBROUTINE rnf_mouth
476
477	!!======================================================================
478	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

Download in other formats: