New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 5299

Last change on this file since 5299 was 5299, checked in by smasson, 9 years ago

dev_r5218_CNRS17_coupling: bugfixes
  • Property svn:keywords set to Id
File size: 11.6 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! surface boundary condition: ocean fields
17   USE sbcapr          ! surface boundary condition: atmospheric pressure
18   USE eosbn2          ! equation of state and related derivatives
19   !
20   USE in_out_manager  ! I/O manager
21   USE prtctl          ! Print control
22   USE iom             ! IOM library
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   sbc_ssm         ! routine called by step.F90
28   PUBLIC   sbc_ssm_init    ! routine called by sbcmod.F90
29
30   LOGICAL, SAVE  ::   l_ssm_mean = .FALSE.       ! keep track of whether means have been read
31                                                  ! from restart file
32   
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE sbc_ssm( kt )
43      !!---------------------------------------------------------------------
44      !!                     ***  ROUTINE sbc_oce  ***
45      !!                     
46      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
47      !!                condition computation
48      !!               
49      !! ** Method  :   compute mean surface velocity (2 components at U and
50      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
51      !!      the periode (kt - nn_fsbc) to kt
52      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
53      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
54      !!---------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kt   ! ocean time step
56      !
57      INTEGER  ::   ji, jj               ! loop index
58      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
59      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
60      !!---------------------------------------------------------------------
61     
62      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
63      DO jj = 1, jpj
64         DO ji = 1, jpi
65            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
66            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
67         END DO
68      END DO
69      !
70      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
71         !                                                ! ---------------------------------------- !
72         ssu_m(:,:) = ub(:,:,1)
73         ssv_m(:,:) = vb(:,:,1)
74         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
75         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
76         ENDIF
77         sss_m(:,:) = zts(:,:,jp_sal)
78         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
79         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
80         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
81         ENDIF
82         !
83         IF( lk_vvl )   fse3t_m(:,:) = fse3t_n(:,:,1)
84         !
85      ELSE
86         !                                                ! ----------------------------------------------- !
87         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
88            !                                             ! ----------------------------------------------- !
89            IF(lwp) WRITE(numout,*)
90            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
91            zcoef = REAL( nn_fsbc - 1, wp )
92            ssu_m(:,:) = zcoef * ub(:,:,1)
93            ssv_m(:,:) = zcoef * vb(:,:,1)
94            IF( ln_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
95            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
96            ENDIF
97            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
98            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
99            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
100            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
101            ENDIF
102            !
103            IF( lk_vvl )   fse3t_m(:,:) = zcoef * fse3t_n(:,:,1)
104            !                                             ! ---------------------------------------- !
105         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
106            !                                             ! ---------------------------------------- !
107            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
108            ssv_m(:,:) = 0.e0
109            sst_m(:,:) = 0.e0
110            sss_m(:,:) = 0.e0
111            ssh_m(:,:) = 0.e0
112            IF( lk_vvl )   fse3t_m(:,:) = 0.e0
113         ENDIF
114         !                                                ! ---------------------------------------- !
115         !                                                !        Cumulate at each time step        !
116         !                                                ! ---------------------------------------- !
117         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
118         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
119         IF( ln_useCT )  THEN    ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
120         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
121         ENDIF
122         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
123         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
124         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
125         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
126         ENDIF
127         !
128         IF( lk_vvl )   fse3t_m(:,:) = fse3t_m(:,:) + fse3t_n(:,:,1)
129
130         !                                                ! ---------------------------------------- !
131         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
132            !                                             ! ---------------------------------------- !
133            zcoef = 1. / REAL( nn_fsbc, wp )
134            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
135            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
136            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
137            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
138            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
139            IF( lk_vvl )   fse3t_m(:,:) = fse3t_m(:,:) * zcoef   ! mean vertical scale factor [m]
140            !
141         ENDIF
142         !                                                ! ---------------------------------------- !
143         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
144            !                                             ! ---------------------------------------- !
145            IF(lwp) WRITE(numout,*)
146            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
147               &                    'at it= ', kt,' date= ', ndastp
148            IF(lwp) WRITE(numout,*) '~~~~~~~'
149            zf_sbc = REAL( nn_fsbc, wp )
150            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
151            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
152            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
153            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
154            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
155            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
156            IF( lk_vvl ) THEN
157               CALL iom_rstput( kt, nitrst, numrow, 'fse3t_m'  , fse3t_m(:,:)  )
158            END IF
159            !
160         ENDIF
161         !
162      ENDIF
163      !
164   END SUBROUTINE sbc_ssm
165
166   SUBROUTINE sbc_ssm_init
167      !!----------------------------------------------------------------------
168      !!                  ***  ROUTINE sbc_ssm_init  ***
169      !!
170      !! ** Purpose :   Initialisation of the sbc data
171      !!
172      !! ** Action  : - read parameters
173      !!----------------------------------------------------------------------
174      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
175      !!----------------------------------------------------------------------
176
177      IF( nn_fsbc == 1 ) THEN
178         !
179         IF(lwp) WRITE(numout,*)
180         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
181         IF(lwp) WRITE(numout,*) '~~~~~~~ '
182         !
183      ELSE
184         !               
185         IF(lwp) WRITE(numout,*)
186         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
187         IF(lwp) WRITE(numout,*) '~~~~~~~ '
188         !
189         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
190            l_ssm_mean = .TRUE.
191            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
192            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
193            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
194            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
195            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
196            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
197            IF( lk_vvl ) CALL iom_get( numror, jpdom_autoglo, 'fse3t_m', fse3t_m(:,:) )
198            !
199            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
200               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
201                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
202               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
203               ssu_m(:,:) = zcoef * ssu_m(:,:) 
204               ssv_m(:,:) = zcoef * ssv_m(:,:)
205               sst_m(:,:) = zcoef * sst_m(:,:)
206               sss_m(:,:) = zcoef * sss_m(:,:)
207               ssh_m(:,:) = zcoef * ssh_m(:,:)
208               IF( lk_vvl ) fse3t_m(:,:) = zcoef * fse3t_m(:,:)
209            ELSE
210               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
211            ENDIF
212         ENDIF
213      ENDIF
214      !
215   END SUBROUTINE sbc_ssm_init
216
217   !!======================================================================
218END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.