New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limhdf.F90 in branches/2015/dev_r5546_CNRS19_HPC_scalability/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5546_CNRS19_HPC_scalability/NEMOGCM/NEMO/LIM_SRC_3/limhdf.F90 @ 6052

Last change on this file since 6052 was 6052, checked in by mcastril, 8 years ago

Added routines in lbclnk to run in serial mode
  • Property svn:keywords set to Id
File size: 19.5 KB
Line 
1MODULE limhdf
2   !!======================================================================
3   !!                    ***  MODULE limhdf   ***
4   !! LIM ice model : horizontal diffusion of sea-ice quantities
5   !!======================================================================
6   !! History :  LIM  !  2000-01 (LIM) Original code
7   !!             -   !  2001-05 (G. Madec, R. Hordoir) opa norm
8   !!            1.0  !  2002-08 (C. Ethe)  F90, free form
9   !!            3.0  !  2015-08 (O. Tintó and M. Castrillo)  added lim_hdf_multiple
10   !!----------------------------------------------------------------------
11#if defined key_lim3
12   !!----------------------------------------------------------------------
13   !!   'key_lim3'                                      LIM3 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   lim_hdf       : diffusion trend on sea-ice variable
16   !!   lim_hdf_init  : initialisation of diffusion trend on sea-ice variable
17   !!----------------------------------------------------------------------
18   USE dom_oce        ! ocean domain
19   USE ice            ! LIM-3: ice variables
20   USE lbclnk         ! lateral boundary condition - MPP exchanges
21   USE lib_mpp        ! MPP library
22   USE wrk_nemo       ! work arrays
23   USE prtctl         ! Print control
24   USE in_out_manager ! I/O manager
25   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   lim_hdf         ! called by lim_trp
31   PUBLIC   lim_hdf_multiple ! called by lim_trp
32   PUBLIC   lim_hdf_init    ! called by sbc_lim_init
33
34   LOGICAL  ::   linit = .TRUE.                             ! initialization flag (set to flase after the 1st call)
35   INTEGER  ::   nn_convfrq                                 !:  convergence check frequency of the Crant-Nicholson scheme
36   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   efact   ! metric coefficient
37
38   !! * Substitution
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE lim_hdf( ptab )
48      !!-------------------------------------------------------------------
49      !!                  ***  ROUTINE lim_hdf  ***
50      !!
51      !! ** purpose :   Compute and add the diffusive trend on sea-ice variables
52      !!
53      !! ** method  :   Second order diffusive operator evaluated using a
54      !!              Cranck-Nicholson time Scheme.
55      !!
56      !! ** Action  :    update ptab with the diffusive contribution
57      !!-------------------------------------------------------------------
58      REAL(wp), DIMENSION(jpi,jpj), INTENT( inout ) ::   ptab    ! Field on which the diffusion is applied
59      !
60      INTEGER                           ::  ji, jj                    ! dummy loop indices
61      INTEGER                           ::  iter, ierr           ! local integers
62      REAL(wp)                          ::  zrlxint, zconv     ! local scalars
63      REAL(wp), POINTER, DIMENSION(:,:) ::  zrlx, zflu, zflv, zdiv0, zdiv, ztab0
64      CHARACTER(lc)                     ::  charout                   ! local character
65      REAL(wp), PARAMETER               ::  zrelax = 0.5_wp           ! relaxation constant for iterative procedure
66      REAL(wp), PARAMETER               ::  zalfa  = 0.5_wp           ! =1.0/0.5/0.0 = implicit/Cranck-Nicholson/explicit
67      INTEGER , PARAMETER               ::  its    = 100              ! Maximum number of iteration
68      !!-------------------------------------------------------------------
69     
70      CALL wrk_alloc( jpi, jpj, zrlx, zflu, zflv, zdiv0, zdiv, ztab0 )
71
72      !                       !==  Initialisation  ==!
73      !
74      IF( linit ) THEN              ! Metric coefficient (compute at the first call and saved in efact)
75         ALLOCATE( efact(jpi,jpj) , STAT=ierr )
76         IF( lk_mpp    )   CALL mpp_sum( ierr )
77         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'lim_hdf : unable to allocate arrays' )
78         DO jj = 2, jpjm1 
79            DO ji = fs_2 , fs_jpim1   ! vector opt.
80               efact(ji,jj) = ( e2u(ji,jj) + e2u(ji-1,jj) + e1v(ji,jj) + e1v(ji,jj-1) ) * r1_e12t(ji,jj)
81            END DO
82         END DO
83         linit = .FALSE.
84      ENDIF
85      !                             ! Time integration parameters
86      !
87      ztab0(:, : ) = ptab(:,:)      ! Arrays initialization
88      zdiv0(:, 1 ) = 0._wp
89      zdiv0(:,jpj) = 0._wp
90      zflu (jpi,:) = 0._wp   
91      zflv (jpi,:) = 0._wp
92      zdiv0(1,  :) = 0._wp
93      zdiv0(jpi,:) = 0._wp
94
95      zconv = 1._wp           !==  horizontal diffusion using a Crant-Nicholson scheme  ==!
96      iter  = 0
97      !
98      DO WHILE( zconv > ( 2._wp * 1.e-04 ) .AND. iter <= its )   ! Sub-time step loop
99         !
100         iter = iter + 1                                 ! incrementation of the sub-time step number
101         !
102         DO jj = 1, jpjm1                                ! diffusive fluxes in U- and V- direction
103            DO ji = 1 , fs_jpim1   ! vector opt.
104               zflu(ji,jj) = pahu(ji,jj) * e2u(ji,jj) * r1_e1u(ji,jj) * ( ptab(ji+1,jj) - ptab(ji,jj) )
105               zflv(ji,jj) = pahv(ji,jj) * e1v(ji,jj) * r1_e2v(ji,jj) * ( ptab(ji,jj+1) - ptab(ji,jj) )
106            END DO
107         END DO
108         !
109         DO jj= 2, jpjm1                                 ! diffusive trend : divergence of the fluxes
110            DO ji = fs_2 , fs_jpim1   ! vector opt.
111               zdiv(ji,jj) = ( zflu(ji,jj) - zflu(ji-1,jj) + zflv(ji,jj) - zflv(ji,jj-1) ) * r1_e12t(ji,jj)
112            END DO
113         END DO
114         !
115         IF( iter == 1 )   zdiv0(:,:) = zdiv(:,:)        ! save the 1st evaluation of the diffusive trend in zdiv0
116         !
117         DO jj = 2, jpjm1                                ! iterative evaluation
118            DO ji = fs_2 , fs_jpim1   ! vector opt.
119               zrlxint = (   ztab0(ji,jj)    &
120                  &       +  rdt_ice * (           zalfa   * ( zdiv(ji,jj) + efact(ji,jj) * ptab(ji,jj) )   &
121                  &                      + ( 1.0 - zalfa ) *   zdiv0(ji,jj) )                               & 
122                  &      ) / ( 1.0 + zalfa * rdt_ice * efact(ji,jj) )
123               zrlx(ji,jj) = ptab(ji,jj) + zrelax * ( zrlxint - ptab(ji,jj) )
124            END DO
125         END DO
126         CALL lbc_lnk( zrlx, 'T', 1. )                   ! lateral boundary condition
127         !
128         IF ( MOD( iter - 1 , nn_convfrq ) == 0 )  THEN    ! convergence test every nn_convfrq iterations (perf. optimization)
129            zconv = 0._wp
130            DO jj = 2, jpjm1
131               DO ji = fs_2, fs_jpim1
132                  zconv = MAX( zconv, ABS( zrlx(ji,jj) - ptab(ji,jj) )  )
133               END DO
134            END DO
135            IF( lk_mpp )   CALL mpp_max( zconv )      ! max over the global domain
136         ENDIF
137         !
138         ptab(:,:) = zrlx(:,:)
139         !
140      END DO                                       ! end of sub-time step loop
141
142      ! -----------------------
143      !!! final step (clem) !!!
144      DO jj = 1, jpjm1                                ! diffusive fluxes in U- and V- direction
145         DO ji = 1 , fs_jpim1   ! vector opt.
146            zflu(ji,jj) = pahu(ji,jj) * e2u(ji,jj) * r1_e1u(ji,jj) * ( ptab(ji+1,jj) - ptab(ji,jj) )
147            zflv(ji,jj) = pahv(ji,jj) * e1v(ji,jj) * r1_e2v(ji,jj) * ( ptab(ji,jj+1) - ptab(ji,jj) )
148         END DO
149      END DO
150      !
151      DO jj= 2, jpjm1                                 ! diffusive trend : divergence of the fluxes
152         DO ji = fs_2 , fs_jpim1   ! vector opt.
153            zdiv(ji,jj) = ( zflu(ji,jj) - zflu(ji-1,jj) + zflv(ji,jj) - zflv(ji,jj-1) ) * r1_e12t(ji,jj)
154            ptab(ji,jj) = ztab0(ji,jj) + 0.5 * ( zdiv(ji,jj) + zdiv0(ji,jj) )
155         END DO
156      END DO
157      CALL lbc_lnk( ptab, 'T', 1. )                   ! lateral boundary condition
158      !!! final step (clem) !!!
159      ! -----------------------
160
161      IF(ln_ctl)   THEN
162         zrlx(:,:) = ptab(:,:) - ztab0(:,:)
163         WRITE(charout,FMT="(' lim_hdf  : zconv =',D23.16, ' iter =',I4,2X)") zconv, iter
164         CALL prt_ctl( tab2d_1=zrlx, clinfo1=charout )
165      ENDIF
166      !
167      CALL wrk_dealloc( jpi, jpj, zrlx, zflu, zflv, zdiv0, zdiv, ztab0 )
168      !
169   END SUBROUTINE lim_hdf
170   
171
172   SUBROUTINE lim_hdf_multiple( ptab , ihdf_vars , jpl , nlay_i )
173      !!-------------------------------------------------------------------
174      !!                  ***  ROUTINE lim_hdf  ***
175      !!
176      !! ** purpose :   Compute and add the diffusive trend on sea-ice variables
177      !!
178      !! ** method  :   Second order diffusive operator evaluated using a
179      !!              Cranck-Nicholson time Scheme.
180      !!
181      !! ** Action  :    update ptab with the diffusive contribution
182      !!-------------------------------------------------------------------
183      INTEGER                           :: jpl, nlay_i, isize, ihdf_vars
184      REAL(wp),  DIMENSION(:,:,:), INTENT( inout ),TARGET ::   ptab    ! Field on which the diffusion is applied
185      REAL(wp), POINTER, DIMENSION(:,:,:)        ::   pahu3D , pahv3D
186      !
187      INTEGER                           ::  ji, jj, jk, jl , jm               ! dummy loop indices
188      INTEGER                           ::  iter, ierr           ! local integers
189      REAL(wp)                          ::  zrlxint     ! local scalars
190      REAL(wp), POINTER , DIMENSION ( : )        :: zconv     ! local scalars
191      REAL(wp), POINTER , DIMENSION(:,:,:) ::  zrlx,zdiv0, ztab0
192      REAL(wp), POINTER , DIMENSION(:,:) ::  zflu, zflv, zdiv
193      CHARACTER(lc)                     ::  charout                   ! local character
194      REAL(wp), PARAMETER               ::  zrelax = 0.5_wp           ! relaxation constant for iterative procedure
195      REAL(wp), PARAMETER               ::  zalfa  = 0.5_wp           ! =1.0/0.5/0.0 = implicit/Cranck-Nicholson/explicit
196      INTEGER , PARAMETER               ::  its    = 100              ! Maximum number of iteration
197      !!-------------------------------------------------------------------
198      TYPE(arrayptr)   , ALLOCATABLE, DIMENSION(:) ::   pt2d_array, zrlx_array
199      CHARACTER(len=1) , ALLOCATABLE, DIMENSION(:) ::   type_array ! define the nature of ptab array grid-points
200      !                                                            ! = T , U , V , F , W and I points
201      REAL(wp)        , ALLOCATABLE, DIMENSION(:)  ::   psgn_array    ! =-1 the sign change across the north fold boundary
202
203     !!---------------------------------------------------------------------
204
205      !                       !==  Initialisation  ==!
206         isize = jpl*(ihdf_vars+nlay_i)
207      ALLOCATE( zconv (isize) )
208      ALLOCATE( pt2d_array(isize) , zrlx_array(isize) )
209      ALLOCATE( type_array(isize) )
210      ALLOCATE( psgn_array(isize) )
211     
212      CALL wrk_alloc( jpi, jpj, isize, zrlx, zdiv0, ztab0 )
213      CALL wrk_alloc( jpi, jpj, zflu, zflv, zdiv )
214      CALL wrk_alloc( jpi, jpj, jpl, pahu3D , pahv3D )
215
216
217      DO jl = 1 , jpl
218         jm = (jl-1)*(ihdf_vars+nlay_i)+1
219         DO jj = 1, jpjm1                 ! NB: has not to be defined on jpj line and jpi row
220            DO ji = 1 , fs_jpim1   ! vector opt.
221               pahu3D(ji,jj,jl) = ( 1._wp - MAX( 0._wp, SIGN( 1._wp, -ptab(ji  ,jj,jm) ) ) )   &
222               &        * ( 1._wp - MAX( 0._wp, SIGN( 1._wp, -ptab(ji+1, jj, jm ) ) ) ) * ahiu(ji,jj)
223               pahv3D(ji,jj,jl) = ( 1._wp - MAX( 0._wp, SIGN( 1._wp, -ptab(ji, jj, jm ) ) ) )   &
224               &        * ( 1._wp - MAX( 0._wp, SIGN( 1._wp,- ptab(ji, jj+1, jm ) ) ) ) * ahiv(ji,jj)
225            END DO
226         END DO
227      END DO
228
229      DO jk= 1 , isize
230         pt2d_array(jk)%pt2d=>ptab(:,:,jk)
231         zrlx_array(jk)%pt2d=>zrlx(:,:,jk)
232         type_array(jk)='T'
233         psgn_array(jk)=1.
234      END DO
235
236      !
237      IF( linit ) THEN              ! Metric coefficient (compute at the first call and saved in efact)
238         ALLOCATE( efact(jpi,jpj) , STAT=ierr )
239         IF( lk_mpp    )   CALL mpp_sum( ierr )
240         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'lim_hdf : unable to allocate arrays' )
241         DO jj = 2, jpjm1
242            DO ji = fs_2 , fs_jpim1   ! vector opt.
243               efact(ji,jj) = ( e2u(ji,jj) + e2u(ji-1,jj) + e1v(ji,jj) + e1v(ji,jj-1) ) * r1_e12t(ji,jj)
244            END DO
245         END DO
246         linit = .FALSE.
247      ENDIF
248      !                             ! Time integration parameters
249      !
250      zflu (jpi,: ) = 0._wp
251      zflv (jpi,: ) = 0._wp
252
253      DO jk=1 , isize
254         ztab0(:, : , jk ) = ptab(:,:,jk)      ! Arrays initialization
255         zdiv0(:, 1 , jk ) = 0._wp
256         zdiv0(:,jpj, jk ) = 0._wp
257         zdiv0(1,  :, jk ) = 0._wp
258         zdiv0(jpi,:, jk ) = 0._wp
259      END DO
260
261      zconv = 1._wp           !==  horizontal diffusion using a Crant-Nicholson scheme  ==!
262      iter  = 0
263      !
264      DO WHILE( MAXVAL(zconv(:)) > ( 2._wp * 1.e-04 ) .AND. iter <= its )   ! Sub-time step loop
265         !
266         iter = iter + 1                                 ! incrementation of the sub-time step number
267         !
268
269         DO jk = 1 , isize
270            jl = (jk-1) /( ihdf_vars+nlay_i)+1
271            IF (zconv(jk) > ( 2._wp * 1.e-04 )) THEN
272               DO jj = 1, jpjm1                                ! diffusive fluxes in U- and V- direction
273                  DO ji = 1 , fs_jpim1   ! vector opt.
274                     zflu(ji,jj) = pahu3D(ji,jj,jl) * e2u(ji,jj) * r1_e1u(ji,jj) * ( ptab(ji+1,jj,jk) - ptab(ji,jj,jk) )
275                     zflv(ji,jj) = pahv3D(ji,jj,jl) * e1v(ji,jj) * r1_e2v(ji,jj) * ( ptab(ji,jj+1,jk) - ptab(ji,jj,jk) )
276                  END DO
277               END DO
278               !
279               DO jj= 2, jpjm1                                 ! diffusive trend : divergence of the fluxes
280                  DO ji = fs_2 , fs_jpim1   ! vector opt.
281                     zdiv(ji,jj) = ( zflu(ji,jj) - zflu(ji-1,jj) + zflv(ji,jj) - zflv(ji,jj-1) ) * r1_e12t(ji,jj)
282                  END DO
283               END DO
284               !
285               IF( iter == 1 )   zdiv0(:,:,jk) = zdiv(:,:)        ! save the 1st evaluation of the diffusive trend in zdiv0
286               !
287               DO jj = 2, jpjm1                                ! iterative evaluation
288                  DO ji = fs_2 , fs_jpim1   ! vector opt.
289                     zrlxint = (   ztab0(ji,jj,jk)    &
290                        &       +  rdt_ice * (           zalfa   * ( zdiv(ji,jj) + efact(ji,jj) * ptab(ji,jj,jk) )   &
291                        &                      + ( 1.0 - zalfa ) *   zdiv0(ji,jj,jk) )                               &
292                        &      ) / ( 1.0 + zalfa * rdt_ice * efact(ji,jj) )
293                     zrlx(ji,jj,jk) = ptab(ji,jj,jk) + zrelax * ( zrlxint - ptab(ji,jj,jk) )
294                  END DO
295               END DO
296            END IF
297
298         END DO
299
300         CALL lbc_lnk_multi( zrlx_array, type_array , psgn_array , isize ) ! Multiple interchange of all the variables
301         !
302         
303         IF ( MOD( iter-1 , nn_convfrq ) == 0 )  THEN   !Convergence test every nn_convfrq iterations (perf. optimization )
304            DO jk=1,isize
305               zconv(jk) = 0._wp                                   ! convergence test
306               DO jj = 2, jpjm1
307                  DO ji = fs_2, fs_jpim1
308                     zconv(jk) = MAX( zconv(jk), ABS( zrlx(ji,jj,jk) - ptab(ji,jj,jk) )  )
309                  END DO
310               END DO
311            END DO
312            IF( lk_mpp ) CALL mpp_max_multiple( zconv , isize )            ! max over the global domain for all the variables
313         ENDIF
314         !
315         DO jk=1,isize
316            ptab(:,:,jk) = zrlx(:,:,jk)
317         END DO
318         !
319      END DO                                       ! end of sub-time step loop
320
321     ! -----------------------
322      !!! final step (clem) !!!
323      DO jk = 1, isize
324         jl = (jk-1) /( ihdf_vars+nlay_i)+1
325         DO jj = 1, jpjm1                                ! diffusive fluxes in U- and V- direction
326            DO ji = 1 , fs_jpim1   ! vector opt.
327               zflu(ji,jj) = pahu3D(ji,jj,jl) * e2u(ji,jj) * r1_e1u(ji,jj) * ( ptab(ji+1,jj,jk) - ptab(ji,jj,jk) )
328               zflv(ji,jj) = pahv3D(ji,jj,jl) * e1v(ji,jj) * r1_e2v(ji,jj) * ( ptab(ji,jj+1,jk) - ptab(ji,jj,jk) )
329            END DO
330         END DO
331         !
332         DO jj= 2, jpjm1                                 ! diffusive trend : divergence of the fluxes
333            DO ji = fs_2 , fs_jpim1   ! vector opt.
334               zdiv(ji,jj) = ( zflu(ji,jj) - zflu(ji-1,jj) + zflv(ji,jj) - zflv(ji,jj-1) ) * r1_e12t(ji,jj)
335               ptab(ji,jj,jk) = ztab0(ji,jj,jk) + 0.5 * ( zdiv(ji,jj) + zdiv0(ji,jj,jk) )
336            END DO
337         END DO
338      END DO
339
340      CALL lbc_lnk_multi( pt2d_array, type_array , psgn_array , isize ) ! Multiple interchange of all the variables
341
342      !!! final step (clem) !!!
343      ! -----------------------
344
345      IF(ln_ctl)   THEN
346         DO jk = 1 , isize
347            zrlx(:,:,jk) = ptab(:,:,jk) - ztab0(:,:,jk)
348            WRITE(charout,FMT="(' lim_hdf  : zconv =',D23.16, ' iter =',I4,2X)") zconv, iter
349            CALL prt_ctl( tab2d_1=zrlx(:,:,jk), clinfo1=charout )
350         END DO
351      ENDIF
352      !
353      CALL wrk_dealloc( jpi, jpj, isize, zrlx, zdiv0, ztab0 )
354      CALL wrk_dealloc( jpi, jpj, zflu, zflv, zdiv )
355      CALL wrk_dealloc( jpi, jpj, jpl, pahu3D , pahv3D )
356
357      DEALLOCATE( zconv )
358      DEALLOCATE( pt2d_array , zrlx_array )
359      DEALLOCATE( type_array )
360      DEALLOCATE( psgn_array )
361      !
362   END SUBROUTINE lim_hdf_multiple
363
364
365   
366   SUBROUTINE lim_hdf_init
367      !!-------------------------------------------------------------------
368      !!                  ***  ROUTINE lim_hdf_init  ***
369      !!
370      !! ** Purpose : Initialisation of horizontal diffusion of sea-ice
371      !!
372      !! ** Method  : Read the namicehdf namelist
373      !!
374      !! ** input   : Namelist namicehdf
375      !!-------------------------------------------------------------------
376      INTEGER  ::   ios                 ! Local integer output status for namelist read
377      NAMELIST/namicehdf/ nn_convfrq 
378      !!-------------------------------------------------------------------
379      !
380      IF(lwp) THEN
381         WRITE(numout,*)
382         WRITE(numout,*) 'lim_hdf : Ice horizontal diffusion'
383         WRITE(numout,*) '~~~~~~~'
384      ENDIF
385      !
386      REWIND( numnam_ice_ref )              ! Namelist namicehdf in reference namelist : Ice horizontal diffusion
387      READ  ( numnam_ice_ref, namicehdf, IOSTAT = ios, ERR = 901)
388901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicehdf in reference namelist', lwp )
389
390      REWIND( numnam_ice_cfg )              ! Namelist namicehdf in configuration namelist : Ice horizontal diffusion
391      READ  ( numnam_ice_cfg, namicehdf, IOSTAT = ios, ERR = 902 )
392902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicehdf in configuration namelist', lwp )
393      IF(lwm) WRITE ( numoni, namicehdf )
394      !
395      IF(lwp) THEN                          ! control print
396         WRITE(numout,*)
397         WRITE(numout,*)'   Namelist of ice parameters for ice horizontal diffusion computation '
398         WRITE(numout,*)'      convergence check frequency of the Crant-Nicholson scheme   nn_convfrq   = ', nn_convfrq
399      ENDIF
400      !
401   END SUBROUTINE lim_hdf_init
402#else
403   !!----------------------------------------------------------------------
404   !!   Default option          Dummy module           NO LIM sea-ice model
405   !!----------------------------------------------------------------------
406#endif
407
408   !!======================================================================
409END MODULE limhdf
Note: See TracBrowser for help on using the repository browser.