| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !! 3.6 ! 2014-11 (P. Mathiot, C. Harris) add ice shelves melting |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | !! sbc_init : read namsbc namelist |
|---|
| 20 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 21 | !!---------------------------------------------------------------------- |
|---|
| 22 | USE oce ! ocean dynamics and tracers |
|---|
| 23 | USE dom_oce ! ocean space and time domain |
|---|
| 24 | USE phycst ! physical constants |
|---|
| 25 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 26 | USE trc_oce ! shared ocean-passive tracers variables |
|---|
| 27 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 28 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 29 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 30 | USE sbcapr ! surface boundary condition: atmospheric pressure |
|---|
| 31 | USE sbcana ! surface boundary condition: analytical formulation |
|---|
| 32 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 33 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 34 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 35 | USE sbcblk_mfs ! surface boundary condition: bulk formulation : MFS |
|---|
| 36 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 37 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 38 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 39 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 40 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 41 | USE cpl_oasis3 ! OASIS routines for coupling |
|---|
| 42 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 43 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 44 | USE sbcisf ! surface boundary condition: ice shelf |
|---|
| 45 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 46 | USE closea ! closed sea |
|---|
| 47 | USE icbstp ! Icebergs! |
|---|
| 48 | |
|---|
| 49 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 50 | USE iom ! IOM library |
|---|
| 51 | USE in_out_manager ! I/O manager |
|---|
| 52 | USE lib_mpp ! MPP library |
|---|
| 53 | USE timing ! Timing |
|---|
| 54 | USE sbcwave ! Wave module |
|---|
| 55 | USE bdy_par ! Require lk_bdy |
|---|
| 56 | |
|---|
| 57 | USE diurnal_bulk, ONLY: & |
|---|
| 58 | & ln_diurnal_only |
|---|
| 59 | |
|---|
| 60 | IMPLICIT NONE |
|---|
| 61 | PRIVATE |
|---|
| 62 | |
|---|
| 63 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 64 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 65 | |
|---|
| 66 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 67 | |
|---|
| 68 | !! * Substitutions |
|---|
| 69 | # include "domzgr_substitute.h90" |
|---|
| 70 | !!---------------------------------------------------------------------- |
|---|
| 71 | !! NEMO/OPA 4.0 , NEMO-consortium (2011) |
|---|
| 72 | !! $Id$ |
|---|
| 73 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | CONTAINS |
|---|
| 76 | |
|---|
| 77 | SUBROUTINE sbc_init |
|---|
| 78 | !!--------------------------------------------------------------------- |
|---|
| 79 | !! *** ROUTINE sbc_init *** |
|---|
| 80 | !! |
|---|
| 81 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 82 | !! |
|---|
| 83 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 84 | !! Call init routines for all other SBC modules that have one |
|---|
| 85 | !! |
|---|
| 86 | !! ** Action : - read namsbc parameters |
|---|
| 87 | !! - nsbc: type of sbc |
|---|
| 88 | !!---------------------------------------------------------------------- |
|---|
| 89 | INTEGER :: icpt ! local integer |
|---|
| 90 | !! |
|---|
| 91 | NAMELIST/namsbc/ nn_fsbc , ln_ana , ln_flx, ln_blk_clio, ln_blk_core, ln_mixcpl, & |
|---|
| 92 | & ln_blk_mfs, ln_apr_dyn, nn_ice, nn_ice_embd, ln_dm2dc , ln_rnf , & |
|---|
| 93 | & ln_ssr , nn_isf , nn_fwb, ln_cdgw , ln_wave , ln_sdw , & |
|---|
| 94 | & nn_lsm , nn_limflx , nn_components, ln_cpl |
|---|
| 95 | INTEGER :: ios |
|---|
| 96 | INTEGER :: ierr, ierr0, ierr1, ierr2, ierr3, jpm |
|---|
| 97 | LOGICAL :: ll_purecpl |
|---|
| 98 | !!---------------------------------------------------------------------- |
|---|
| 99 | |
|---|
| 100 | IF(lwp) THEN |
|---|
| 101 | WRITE(numout,*) |
|---|
| 102 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 103 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 104 | ENDIF |
|---|
| 105 | |
|---|
| 106 | REWIND( numnam_ref ) ! Namelist namsbc in reference namelist : Surface boundary |
|---|
| 107 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 108 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp ) |
|---|
| 109 | |
|---|
| 110 | REWIND( numnam_cfg ) ! Namelist namsbc in configuration namelist : Parameters of the run |
|---|
| 111 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 112 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp ) |
|---|
| 113 | IF(lwm) WRITE ( numond, namsbc ) |
|---|
| 114 | |
|---|
| 115 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 116 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 117 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 118 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 119 | IF( lk_cice ) nn_ice = 4 |
|---|
| 120 | ENDIF |
|---|
| 121 | IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration |
|---|
| 122 | ln_ana = .TRUE. |
|---|
| 123 | nn_ice = 0 |
|---|
| 124 | ENDIF |
|---|
| 125 | |
|---|
| 126 | IF(lwp) THEN ! Control print |
|---|
| 127 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 128 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 129 | WRITE(numout,*) ' Type of sbc : ' |
|---|
| 130 | WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana |
|---|
| 131 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 132 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 133 | WRITE(numout,*) ' CORE bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 134 | WRITE(numout,*) ' MFS bulk formulation ln_blk_mfs = ', ln_blk_mfs |
|---|
| 135 | WRITE(numout,*) ' ocean-atmosphere coupled formulation ln_cpl = ', ln_cpl |
|---|
| 136 | WRITE(numout,*) ' forced-coupled mixed formulation ln_mixcpl = ', ln_mixcpl |
|---|
| 137 | WRITE(numout,*) ' OASIS coupling (with atm or sas) lk_oasis = ', lk_oasis |
|---|
| 138 | WRITE(numout,*) ' components of your executable nn_components = ', nn_components |
|---|
| 139 | WRITE(numout,*) ' Multicategory heat flux formulation (LIM3) nn_limflx = ', nn_limflx |
|---|
| 140 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 141 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 142 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 143 | WRITE(numout,*) ' ice-ocean embedded/levitating (=0/1/2) nn_ice_embd = ', nn_ice_embd |
|---|
| 144 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 145 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 146 | WRITE(numout,*) ' iceshelf formulation nn_isf = ', nn_isf |
|---|
| 147 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 148 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 149 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 150 | WRITE(numout,*) ' n. of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 151 | ENDIF |
|---|
| 152 | |
|---|
| 153 | ! LIM3 Multi-category heat flux formulation |
|---|
| 154 | SELECT CASE ( nn_limflx) |
|---|
| 155 | CASE ( -1 ) |
|---|
| 156 | IF(lwp) WRITE(numout,*) ' Use of per-category fluxes (nn_limflx = -1) ' |
|---|
| 157 | CASE ( 0 ) |
|---|
| 158 | IF(lwp) WRITE(numout,*) ' Average per-category fluxes (nn_limflx = 0) ' |
|---|
| 159 | CASE ( 1 ) |
|---|
| 160 | IF(lwp) WRITE(numout,*) ' Average then redistribute per-category fluxes (nn_limflx = 1) ' |
|---|
| 161 | CASE ( 2 ) |
|---|
| 162 | IF(lwp) WRITE(numout,*) ' Redistribute a single flux over categories (nn_limflx = 2) ' |
|---|
| 163 | END SELECT |
|---|
| 164 | ! |
|---|
| 165 | IF ( nn_components /= jp_iam_nemo .AND. .NOT. lk_oasis ) & |
|---|
| 166 | & CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 167 | IF ( nn_components == jp_iam_opa .AND. ln_cpl ) & |
|---|
| 168 | & CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' ) |
|---|
| 169 | IF ( nn_components == jp_iam_opa .AND. ln_mixcpl ) & |
|---|
| 170 | & CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 171 | IF ( ln_cpl .AND. .NOT. lk_oasis ) & |
|---|
| 172 | & CALL ctl_stop( 'STOP', 'sbc_init : OASIS-coupled atmosphere model, but key_oasis3 disabled' ) |
|---|
| 173 | IF( ln_mixcpl .AND. .NOT. lk_oasis ) & |
|---|
| 174 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires the cpp key key_oasis3' ) |
|---|
| 175 | IF( ln_mixcpl .AND. .NOT. ln_cpl ) & |
|---|
| 176 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires ln_cpl = T' ) |
|---|
| 177 | IF( ln_mixcpl .AND. nn_components /= jp_iam_nemo ) & |
|---|
| 178 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) is not yet working with sas-opa coupling via oasis' ) |
|---|
| 179 | |
|---|
| 180 | ! ! allocate sbc arrays |
|---|
| 181 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 182 | |
|---|
| 183 | ! ! Checks: |
|---|
| 184 | IF( nn_isf .EQ. 0 ) THEN ! variable initialisation if no ice shelf |
|---|
| 185 | IF( sbc_isf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' ) |
|---|
| 186 | fwfisf (:,:) = 0.0_wp ; fwfisf_b (:,:) = 0.0_wp |
|---|
| 187 | risf_tsc(:,:,:) = 0.0_wp ; risf_tsc_b(:,:,:) = 0.0_wp |
|---|
| 188 | rdivisf = 0.0_wp |
|---|
| 189 | END IF |
|---|
| 190 | IF( nn_ice == 0 .AND. nn_components /= jp_iam_opa ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero |
|---|
| 191 | |
|---|
| 192 | sfx(:,:) = 0.0_wp ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero) |
|---|
| 193 | ! only if sea-ice is present |
|---|
| 194 | |
|---|
| 195 | fmmflx(:,:) = 0.0_wp ! freezing-melting array initialisation |
|---|
| 196 | |
|---|
| 197 | taum(:,:) = 0.0_wp ! Initialise taum for use in gls in case of reduced restart |
|---|
| 198 | |
|---|
| 199 | ! ! restartability |
|---|
| 200 | IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. ln_cpl ) ) & |
|---|
| 201 | & CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 202 | IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. ln_cpl ) ) & |
|---|
| 203 | & CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or ln_cpl' ) |
|---|
| 204 | IF( nn_ice == 4 .AND. lk_agrif ) & |
|---|
| 205 | & CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 206 | IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 ) & |
|---|
| 207 | & CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' ) |
|---|
| 208 | IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) ) & |
|---|
| 209 | & WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3' |
|---|
| 210 | IF( ( nn_ice == 3 ) .AND. ( ln_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) ) & |
|---|
| 211 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' ) |
|---|
| 212 | IF( ( nn_ice == 3 ) .AND. ( .NOT. ln_cpl ) .AND. ( nn_limflx == 2 ) ) & |
|---|
| 213 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' ) |
|---|
| 214 | |
|---|
| 215 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 216 | |
|---|
| 217 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) .AND. nn_components /= jp_iam_opa ) & |
|---|
| 218 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 219 | |
|---|
| 220 | IF ( ln_wave ) THEN |
|---|
| 221 | !Activated wave module but neither drag nor stokes drift activated |
|---|
| 222 | IF ( .NOT.(ln_cdgw .OR. ln_sdw) ) THEN |
|---|
| 223 | CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' ) |
|---|
| 224 | !drag coefficient read from wave model definable only with mfs bulk formulae and core |
|---|
| 225 | ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) ) THEN |
|---|
| 226 | CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core') |
|---|
| 227 | ENDIF |
|---|
| 228 | ELSE |
|---|
| 229 | IF ( ln_cdgw .OR. ln_sdw ) & |
|---|
| 230 | & CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but & |
|---|
| 231 | & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ') |
|---|
| 232 | ENDIF |
|---|
| 233 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 234 | ll_purecpl = ln_cpl .AND. .NOT. ln_mixcpl |
|---|
| 235 | ! |
|---|
| 236 | icpt = 0 |
|---|
| 237 | IF( ln_ana ) THEN ; nsbc = jp_ana ; icpt = icpt + 1 ; ENDIF ! analytical formulation |
|---|
| 238 | IF( ln_flx ) THEN ; nsbc = jp_flx ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 239 | IF( ln_blk_clio ) THEN ; nsbc = jp_clio ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 240 | IF( ln_blk_core ) THEN ; nsbc = jp_core ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 241 | IF( ln_blk_mfs ) THEN ; nsbc = jp_mfs ; icpt = icpt + 1 ; ENDIF ! MFS bulk formulation |
|---|
| 242 | IF( ll_purecpl ) THEN ; nsbc = jp_purecpl ; icpt = icpt + 1 ; ENDIF ! Pure Coupled formulation |
|---|
| 243 | IF( cp_cfg == 'gyre') THEN ; nsbc = jp_gyre ; ENDIF ! GYRE analytical formulation |
|---|
| 244 | IF( nn_components == jp_iam_opa ) & |
|---|
| 245 | & THEN ; nsbc = jp_none ; icpt = icpt + 1 ; ENDIF ! opa coupling via SAS module |
|---|
| 246 | IF( lk_esopa ) nsbc = jp_esopa ! esopa test, ALL formulations |
|---|
| 247 | ! |
|---|
| 248 | IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN |
|---|
| 249 | WRITE(numout,*) |
|---|
| 250 | WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option ' |
|---|
| 251 | WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)' |
|---|
| 252 | WRITE(numout,*) ' We stop' |
|---|
| 253 | nstop = nstop + 1 |
|---|
| 254 | ENDIF |
|---|
| 255 | IF(lwp) THEN |
|---|
| 256 | WRITE(numout,*) |
|---|
| 257 | IF( nsbc == jp_esopa ) WRITE(numout,*) ' ESOPA test All surface boundary conditions' |
|---|
| 258 | IF( nsbc == jp_gyre ) WRITE(numout,*) ' GYRE analytical formulation' |
|---|
| 259 | IF( nsbc == jp_ana ) WRITE(numout,*) ' analytical formulation' |
|---|
| 260 | IF( nsbc == jp_flx ) WRITE(numout,*) ' flux formulation' |
|---|
| 261 | IF( nsbc == jp_clio ) WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 262 | IF( nsbc == jp_core ) WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 263 | IF( nsbc == jp_purecpl ) WRITE(numout,*) ' pure coupled formulation' |
|---|
| 264 | IF( nsbc == jp_mfs ) WRITE(numout,*) ' MFS Bulk formulation' |
|---|
| 265 | IF( nsbc == jp_none ) WRITE(numout,*) ' OPA coupled to SAS via oasis' |
|---|
| 266 | IF( ln_mixcpl ) WRITE(numout,*) ' + forced-coupled mixed formulation' |
|---|
| 267 | IF( nn_components/= jp_iam_nemo ) & |
|---|
| 268 | & WRITE(numout,*) ' + OASIS coupled SAS' |
|---|
| 269 | ENDIF |
|---|
| 270 | ! |
|---|
| 271 | IF( lk_oasis ) CALL sbc_cpl_init (nn_ice) ! OASIS initialisation. must be done before: (1) first time step |
|---|
| 272 | ! ! (2) the use of nn_fsbc |
|---|
| 273 | |
|---|
| 274 | ! nn_fsbc initialization if OPA-SAS coupling via OASIS |
|---|
| 275 | ! sas model time step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly |
|---|
| 276 | IF ( nn_components /= jp_iam_nemo ) THEN |
|---|
| 277 | |
|---|
| 278 | IF ( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt) |
|---|
| 279 | IF ( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt) |
|---|
| 280 | ! |
|---|
| 281 | IF(lwp)THEN |
|---|
| 282 | WRITE(numout,*) |
|---|
| 283 | WRITE(numout,*)" OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc |
|---|
| 284 | WRITE(numout,*) |
|---|
| 285 | ENDIF |
|---|
| 286 | ENDIF |
|---|
| 287 | |
|---|
| 288 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 289 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 290 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 291 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 292 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 293 | ENDIF |
|---|
| 294 | ! |
|---|
| 295 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 296 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 297 | ! |
|---|
| 298 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 299 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 300 | |
|---|
| 301 | CALL sbc_ssm_init ! Sea-surface mean fields initialisation |
|---|
| 302 | ! |
|---|
| 303 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialisation |
|---|
| 304 | ! |
|---|
| 305 | CALL sbc_rnf_init ! Runof initialisation |
|---|
| 306 | ! |
|---|
| 307 | IF( nn_ice == 3 ) CALL sbc_lim_init ! LIM3 initialisation |
|---|
| 308 | |
|---|
| 309 | IF( nn_ice == 4 ) CALL cice_sbc_init( nsbc ) ! CICE initialisation |
|---|
| 310 | |
|---|
| 311 | END SUBROUTINE sbc_init |
|---|
| 312 | |
|---|
| 313 | |
|---|
| 314 | SUBROUTINE sbc( kt ) |
|---|
| 315 | !!--------------------------------------------------------------------- |
|---|
| 316 | !! *** ROUTINE sbc *** |
|---|
| 317 | !! |
|---|
| 318 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 319 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 320 | !! |
|---|
| 321 | !! ** Method : blah blah to be written ????????? |
|---|
| 322 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 323 | !! |
|---|
| 324 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 325 | !! time step, i.e. |
|---|
| 326 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 327 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 328 | !! - updte the ice fraction : fr_i |
|---|
| 329 | !!---------------------------------------------------------------------- |
|---|
| 330 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 331 | !!--------------------------------------------------------------------- |
|---|
| 332 | ! |
|---|
| 333 | IF( nn_timing == 1 ) CALL timing_start('sbc') |
|---|
| 334 | ! |
|---|
| 335 | ! ! ---------------------------------------- ! |
|---|
| 336 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 337 | ! ! ---------------------------------------- ! |
|---|
| 338 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 339 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 340 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 341 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 342 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 343 | emp_b(:,:) = emp(:,:) |
|---|
| 344 | sfx_b(:,:) = sfx(:,:) |
|---|
| 345 | ENDIF |
|---|
| 346 | ! ! ---------------------------------------- ! |
|---|
| 347 | ! ! forcing field computation ! |
|---|
| 348 | ! ! ---------------------------------------- ! |
|---|
| 349 | ! |
|---|
| 350 | IF ( .NOT. lk_bdy ) then |
|---|
| 351 | IF( ln_apr_dyn ) CALL sbc_apr( kt ) ! atmospheric pressure provided at kt+0.5*nn_fsbc |
|---|
| 352 | ENDIF |
|---|
| 353 | ! (caution called before sbc_ssm) |
|---|
| 354 | ! |
|---|
| 355 | IF( nn_components /= jp_iam_sas ) CALL sbc_ssm( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 356 | ! ! averaged over nf_sbc time-step |
|---|
| 357 | |
|---|
| 358 | IF (ln_wave) CALL sbc_wave( kt ) |
|---|
| 359 | !== sbc formulation ==! |
|---|
| 360 | |
|---|
| 361 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 362 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 363 | CASE( jp_gyre ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration |
|---|
| 364 | CASE( jp_ana ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc |
|---|
| 365 | CASE( jp_flx ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 366 | CASE( jp_clio ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 367 | CASE( jp_core ) |
|---|
| 368 | IF( nn_components == jp_iam_sas ) & |
|---|
| 369 | & CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: SAS receiving fields from OPA |
|---|
| 370 | CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 371 | ! from oce: sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 372 | CASE( jp_purecpl ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! pure coupled formulation |
|---|
| 373 | ! |
|---|
| 374 | CASE( jp_mfs ) ; CALL sbc_blk_mfs ( kt ) ! bulk formulation : MFS for the ocean |
|---|
| 375 | CASE( jp_none ) |
|---|
| 376 | IF( nn_components == jp_iam_opa ) & |
|---|
| 377 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: OPA receiving fields from SAS |
|---|
| 378 | CASE( jp_esopa ) |
|---|
| 379 | CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations |
|---|
| 380 | CALL sbc_gyre ( kt ) ! |
|---|
| 381 | CALL sbc_flx ( kt ) ! |
|---|
| 382 | CALL sbc_blk_clio( kt ) ! |
|---|
| 383 | CALL sbc_blk_core( kt ) ! |
|---|
| 384 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! |
|---|
| 385 | END SELECT |
|---|
| 386 | |
|---|
| 387 | IF( ln_mixcpl ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! forced-coupled mixed formulation after forcing |
|---|
| 388 | |
|---|
| 389 | |
|---|
| 390 | ! !== Misc. Options ==! |
|---|
| 391 | |
|---|
| 392 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 393 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 394 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 395 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 396 | CASE( 4 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 397 | END SELECT |
|---|
| 398 | |
|---|
| 399 | IF( ln_icebergs ) CALL icb_stp( kt ) ! compute icebergs |
|---|
| 400 | |
|---|
| 401 | IF( nn_isf /= 0 ) CALL sbc_isf( kt ) ! compute iceshelves |
|---|
| 402 | |
|---|
| 403 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 404 | |
|---|
| 405 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 406 | |
|---|
| 407 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 408 | |
|---|
| 409 | ! treatment of closed sea in the model domain |
|---|
| 410 | ! (update freshwater fluxes) |
|---|
| 411 | ! Should not be ran if ln_diurnal_only |
|---|
| 412 | IF( .NOT.(ln_diurnal_only) .AND. (nn_closea == 1) ) CALL sbc_clo( kt ) |
|---|
| 413 | |
|---|
| 414 | !RBbug do not understand why see ticket 667 |
|---|
| 415 | !clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why. |
|---|
| 416 | CALL lbc_lnk( emp, 'T', 1. ) |
|---|
| 417 | ! |
|---|
| 418 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 419 | ! ! ---------------------------------------- ! |
|---|
| 420 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 421 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 422 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 423 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 424 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 425 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 426 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 427 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 428 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b ) ! before freshwater flux (T-point) |
|---|
| 429 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 430 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 431 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b ) ! before salt flux (T-point) |
|---|
| 432 | ELSE |
|---|
| 433 | sfx_b (:,:) = sfx(:,:) |
|---|
| 434 | ENDIF |
|---|
| 435 | ELSE !* no restart: set from nit000 values |
|---|
| 436 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 437 | utau_b(:,:) = utau(:,:) |
|---|
| 438 | vtau_b(:,:) = vtau(:,:) |
|---|
| 439 | qns_b (:,:) = qns (:,:) |
|---|
| 440 | emp_b (:,:) = emp(:,:) |
|---|
| 441 | sfx_b (:,:) = sfx(:,:) |
|---|
| 442 | ENDIF |
|---|
| 443 | ENDIF |
|---|
| 444 | ! ! ---------------------------------------- ! |
|---|
| 445 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 446 | ! ! ---------------------------------------- ! |
|---|
| 447 | IF(lwp) WRITE(numout,*) |
|---|
| 448 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 449 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 450 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 451 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 452 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 453 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 454 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 455 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 456 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 457 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx ) |
|---|
| 458 | ENDIF |
|---|
| 459 | |
|---|
| 460 | ! ! ---------------------------------------- ! |
|---|
| 461 | ! ! Outputs and control print ! |
|---|
| 462 | ! ! ---------------------------------------- ! |
|---|
| 463 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 464 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 465 | CALL iom_put( "saltflx", sfx ) ! downward salt flux |
|---|
| 466 | ! (includes virtual salt flux beneath ice |
|---|
| 467 | ! in linear free surface case) |
|---|
| 468 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 469 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 470 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 471 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 472 | IF( nn_ice > 0 .OR. nn_components == jp_iam_opa ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 473 | CALL iom_put( "taum" , taum ) ! wind stress module |
|---|
| 474 | CALL iom_put( "wspd" , wndm ) ! wind speed module over free ocean or leads in presence of sea-ice |
|---|
| 475 | ENDIF |
|---|
| 476 | ! |
|---|
| 477 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 478 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 479 | ! |
|---|
| 480 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 481 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 482 | CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 483 | CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 484 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 485 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 486 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 487 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 488 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 489 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 490 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 491 | ENDIF |
|---|
| 492 | |
|---|
| 493 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 494 | ! |
|---|
| 495 | IF( nn_timing == 1 ) CALL timing_stop('sbc') |
|---|
| 496 | ! |
|---|
| 497 | END SUBROUTINE sbc |
|---|
| 498 | |
|---|
| 499 | |
|---|
| 500 | SUBROUTINE sbc_final |
|---|
| 501 | !!--------------------------------------------------------------------- |
|---|
| 502 | !! *** ROUTINE sbc_final *** |
|---|
| 503 | !! |
|---|
| 504 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 505 | !!--------------------------------------------------------------------- |
|---|
| 506 | ! |
|---|
| 507 | IF( nn_ice == 4 ) CALL cice_sbc_final |
|---|
| 508 | ! |
|---|
| 509 | END SUBROUTINE sbc_final |
|---|
| 510 | |
|---|
| 511 | !!====================================================================== |
|---|
| 512 | END MODULE sbcmod |
|---|
