New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2015/dev_r5656_Met_Office_3_diurnalSST/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2015/dev_r5656_Met_Office_3_diurnalSST/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 5676

Last change on this file since 5676 was 5676, checked in by jwhile, 9 years ago
Adding cool skin and warm layer + associated modifications
Property svn:keywords set to `Id`
File size: 40.9 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!!----------------------------------------------------------------------
33
34	!!----------------------------------------------------------------------
35	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36	!! nemo_init : initialization of the NEMO system
37	!! nemo_ctl : initialisation of the contol print
38	!! nemo_closefile : close remaining open files
39	!! nemo_alloc : dynamical allocation
40	!! nemo_partition : calculate MPP domain decomposition
41	!! factorise : calculate the factors of the no. of MPI processes
42	!!----------------------------------------------------------------------
43	USE step_oce ! module used in the ocean time stepping module
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	#if defined key_nemocice_decomp
49	USE ice_domain_size, only: nx_global, ny_global
50	#endif
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE bdyini ! open boundary cond. setting (bdy_init routine)
53	USE bdydta ! open boundary cond. setting (bdy_dta_init routine)
54	USE bdytides ! open boundary cond. setting (bdytide_init routine)
55	USE istate ! initial state setting (istate_init routine)
56	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
57	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
58	USE zdfini ! vertical physics setting (zdf_init routine)
59	USE phycst ! physical constant (par_cst routine)
60	USE trdini ! dyn/tra trends initialization (trd_init routine)
61	USE asminc ! assimilation increments
62	USE asmbkg ! writing out state trajectory
63	USE diaptr ! poleward transports (dia_ptr_init routine)
64	USE diadct ! sections transports (dia_dct_init routine)
65	USE diaobs ! Observation diagnostics (dia_obs_init routine)
66	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
67	USE step ! NEMO time-stepping (stp routine)
68	USE icbini ! handle bergs, initialisation
69	USE icbstp ! handle bergs, calving, themodynamics and transport
70	USE cpl_oasis3 ! OASIS3 coupling
71	USE c1d ! 1D configuration
72	USE step_c1d ! Time stepping loop for the 1D configuration
73	USE dyndmp ! Momentum damping
74	#if defined key_top
75	USE trcini ! passive tracer initialisation
76	#endif
77	USE lib_mpp ! distributed memory computing
78	USE diurnal_bulk ! diurnal bulk SST
79	#if defined key_iomput
80	USE xios
81	#endif
82	USE sbctide, ONLY: lk_tide
83	USE crsini ! initialise grid coarsening utility
84	USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
85	USE sbc_oce, ONLY: lk_oasis
86	USE stopar
87	USE stopts
88
89	IMPLICIT NONE
90	PRIVATE
91
92	PUBLIC nemo_gcm ! called by model.F90
93	PUBLIC nemo_init ! needed by AGRIF
94	PUBLIC nemo_alloc ! needed by TAM
95
96	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
97
98	!!----------------------------------------------------------------------
99	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
100	!! $Id$
101	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
102	!!----------------------------------------------------------------------
103	CONTAINS
104
105	SUBROUTINE nemo_gcm
106	!!----------------------------------------------------------------------
107	!! * ROUTINE nemo_gcm *
108	!!
109	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
110	!! curvilinear mesh on the sphere.
111	!!
112	!! ** Method : - model general initialization
113	!! - launch the time-stepping (stp routine)
114	!! - finalize the run by closing files and communications
115	!!
116	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
117	!! Madec, 2008, internal report, IPSL.
118	!!----------------------------------------------------------------------
119	INTEGER :: istp ! time step index
120	!!----------------------------------------------------------------------
121	!
122	#if defined key_agrif
123	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
124	#endif
125
126	! !-----------------------!
127	CALL nemo_init !== Initialisations ==!
128	! !-----------------------!
129	#if defined key_agrif
130	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
131	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
132	# if defined key_top
133	CALL Agrif_Declare_Var_top ! " " " " " TOP
134	# endif
135	# if defined key_lim2
136	CALL Agrif_Declare_Var_lim2 ! " " " " " LIM
137	# endif
138	#endif
139	! check that all process are still there... If some process have an error,
140	! they will never enter in step and other processes will wait until the end of the cpu time!
141	IF( lk_mpp ) CALL mpp_max( nstop )
142
143	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
144
145	! !-----------------------!
146	! !== time stepping ==!
147	! !-----------------------!
148	istp = nit000
149	#if defined key_c1d
150	DO WHILE ( istp <= nitend .AND. nstop == 0 )
151	CALL stp_c1d( istp )
152	istp = istp + 1
153	END DO
154	#else
155	IF( lk_asminc ) THEN
156	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
157	IF( ln_asmdin ) THEN ! Direct initialization
158	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
159	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
160	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
161	ENDIF
162	ENDIF
163
164	#if defined key_agrif
165	CALL Agrif_Regrid()
166	#endif
167
168	DO WHILE ( istp <= nitend .AND. nstop == 0 )
169	#if defined key_agrif
170	CALL stp ! AGRIF: time stepping
171	#else
172	IF ( .NOT. ln_diurnal_only ) THEN
173	CALL stp( istp ) ! standard time stepping
174	ELSE
175	CALL stp_diurnal( istp ) ! time step only the diurnal SST
176	ENDIF
177	#endif
178	istp = istp + 1
179	IF( lk_mpp ) CALL mpp_max( nstop )
180	END DO
181	#endif
182
183	IF( lk_diaobs ) CALL dia_obs_wri
184	!
185	IF( ln_icebergs ) CALL icb_end( nitend )
186
187	! !------------------------!
188	! !== finalize the run ==!
189	! !------------------------!
190	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
191	!
192	IF( nstop /= 0 .AND. lwp ) THEN ! error print
193	WRITE(numout,cform_err)
194	WRITE(numout,*) nstop, ' error have been found'
195	ENDIF
196	!
197	#if defined key_agrif
198	IF( .NOT. Agrif_Root() ) THEN
199	CALL Agrif_ParentGrid_To_ChildGrid()
200	IF( lk_diaobs ) CALL dia_obs_wri
201	IF( nn_timing == 1 ) CALL timing_finalize
202	CALL Agrif_ChildGrid_To_ParentGrid()
203	ENDIF
204	#endif
205	IF( nn_timing == 1 ) CALL timing_finalize
206	!
207	CALL nemo_closefile
208	!
209	#if defined key_iomput
210	CALL xios_finalize ! end mpp communications with xios
211	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
212	#else
213	IF( lk_oasis ) THEN
214	CALL cpl_finalize ! end coupling and mpp communications with OASIS
215	ELSE
216	IF( lk_mpp ) CALL mppstop ! end mpp communications
217	ENDIF
218	#endif
219	!
220	END SUBROUTINE nemo_gcm
221
222
223	SUBROUTINE nemo_init
224	!!----------------------------------------------------------------------
225	!! * ROUTINE nemo_init *
226	!!
227	!! ** Purpose : initialization of the NEMO GCM
228	!!----------------------------------------------------------------------
229	INTEGER :: ji ! dummy loop indices
230	INTEGER :: ilocal_comm ! local integer
231	INTEGER :: ios
232	CHARACTER(len=80), DIMENSION(16) :: cltxt
233	!
234	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
235	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
236	& nn_bench, nn_timing
237	NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
238	& jpizoom, jpjzoom, jperio, ln_use_jattr
239	!!----------------------------------------------------------------------
240	!
241	cltxt = ''
242	cxios_context = 'nemo'
243	!
244	! ! Open reference namelist and configuration namelist files
245	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
246	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
247	!
248	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints & Benchmark
249	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
250	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
251
252	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist : Control prints & Benchmark
253	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
254	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
255
256	!
257	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints & Benchmark
258	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
259	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
260
261	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
262	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
263	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
264
265	! Force values for AGRIF zoom (cf. agrif_user.F90)
266	#if defined key_agrif
267	IF( .NOT. Agrif_Root() ) THEN
268	jpiglo = nbcellsx + 2 + 2*nbghostcells
269	jpjglo = nbcellsy + 2 + 2*nbghostcells
270	jpi = ( jpiglo-2jpreci + (jpni-1+0) ) / jpni + 2jpreci
271	jpj = ( jpjglo-2jprecj + (jpnj-1+0) ) / jpnj + 2jprecj
272	jpidta = jpiglo
273	jpjdta = jpjglo
274	jpizoom = 1
275	jpjzoom = 1
276	nperio = 0
277	jperio = 0
278	ln_use_jattr = .false.
279	ENDIF
280	#endif
281	!
282	! !--------------------------------------------!
283	! ! set communicator & select the local node !
284	! ! NB: mynode also opens output.namelist.dyn !
285	! ! on unit number numond on first proc !
286	! !--------------------------------------------!
287	#if defined key_iomput
288	IF( Agrif_Root() ) THEN
289	IF( lk_oasis ) THEN
290	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
291	CALL xios_initialize( "not used",local_comm=ilocal_comm ) ! send nemo communicator to xios
292	ELSE
293	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) ! nemo local communicator given by xios
294	ENDIF
295	ENDIF
296	! Nodes selection (control print return in cltxt)
297	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
298	#else
299	IF( lk_oasis ) THEN
300	IF( Agrif_Root() ) THEN
301	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
302	ENDIF
303	! Nodes selection (control print return in cltxt)
304	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
305	ELSE
306	ilocal_comm = 0
307	! Nodes selection (control print return in cltxt)
308	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
309	ENDIF
310	#endif
311	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
312
313	lwm = (narea == 1) ! control of output namelists
314	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
315
316	IF(lwm) THEN
317	! write merged namelists from earlier to output namelist now that the
318	! file has been opened in call to mynode. nammpp has already been
319	! written in mynode (if lk_mpp_mpi)
320	WRITE( numond, namctl )
321	WRITE( numond, namcfg )
322	ENDIF
323
324	! If dimensions of processor grid weren't specified in the namelist file
325	! then we calculate them here now that we have our communicator size
326	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
327	#if defined key_mpp_mpi
328	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
329	#else
330	jpni = 1
331	jpnj = 1
332	jpnij = jpni*jpnj
333	#endif
334	END IF
335
336	! Calculate domain dimensions given calculated jpni and jpnj
337	! This used to be done in par_oce.F90 when they were parameters rather
338	! than variables
339	IF( Agrif_Root() ) THEN
340	#if defined key_nemocice_decomp
341	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
342	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
343	#else
344	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
345	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
346	#endif
347	ENDIF
348	jpk = jpkdta ! third dim
349	#if defined key_agrif
350	! simple trick to use same vertical grid as parent
351	! but different number of levels:
352	! Save maximum number of levels in jpkdta, then define all vertical grids
353	! with this number.
354	! Suppress once vertical online interpolation is ok
355	IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
356	#endif
357	jpim1 = jpi-1 ! inner domain indices
358	jpjm1 = jpj-1 ! " "
359	jpkm1 = jpk-1 ! " "
360	jpij = jpi*jpj ! jpi x j
361
362	IF(lwp) THEN ! open listing units
363	!
364	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
365	!
366	WRITE(numout,*)
367	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
368	WRITE(numout,*) ' NEMO team'
369	WRITE(numout,*) ' Ocean General Circulation Model'
370	WRITE(numout,*) ' version 3.6 (2015) '
371	WRITE(numout,*)
372	WRITE(numout,*)
373	DO ji = 1, SIZE(cltxt)
374	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
375	END DO
376	WRITE(numout,cform_aaa) ! Flag AAAAAAA
377	!
378	ENDIF
379
380	! Now we know the dimensions of the grid and numout has been set we can
381	! allocate arrays
382	CALL nemo_alloc()
383
384	! !-------------------------------!
385	! ! NEMO general initialization !
386	! !-------------------------------!
387
388	CALL nemo_ctl ! Control prints & Benchmark
389
390	! ! Domain decomposition
391	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
392	ELSE ; CALL mpp_init2 ! eliminate land processors
393	ENDIF
394	!
395	IF( nn_timing == 1 ) CALL timing_init
396	!
397	! ! General initialization
398	CALL phy_cst ! Physical constants
399	CALL eos_init ! Equation of state
400	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
401	CALL dom_cfg ! Domain configuration
402	CALL dom_init ! Domain
403
404	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
405
406	IF( ln_ctl ) CALL prt_ctl_init ! Print control
407
408	CALL diurnal_sst_bulk_init ! diurnal sst
409	IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin
410
411	! IF ln_diurnal_only, then we only want a subset of the initialisation routines
412	IF ( ln_diurnal_only ) THEN
413	CALL istate_init ! ocean initial state (Dynamics and tracers)
414	CALL sbc_init ! Forcings : surface module
415	CALL tra_qsr_init ! penetrative solar radiation qsr
416	IF( lk_diaobs ) THEN ! Observation & model comparison
417	CALL dia_obs_init ! Initialize observational data
418	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
419	ENDIF
420	! ! Assimilation increments
421	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
422
423	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
424	RETURN
425	ENDIF
426
427	CALL istate_init ! ocean initial state (Dynamics and tracers)
428
429	IF( lk_tide ) CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics
430
431	CALL sbc_init ! Forcings : surface module (clem: moved here for bdy purpose)
432
433	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
434	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
435	IF( lk_bdy .AND. lk_tide ) &
436	& CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing
437
438	CALL dyn_nept_init ! simplified form of Neptune effect
439	!
440	IF( ln_crs ) CALL crs_init ! Domain initialization of coarsened grid
441	!
442	! Ocean physics
443	! ! Vertical physics
444	CALL zdf_init ! namelist read
445	CALL zdf_bfr_init ! bottom friction
446	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
447	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
448	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
449	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
450	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
451	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
452	& CALL zdf_ddm_init ! double diffusive mixing
453	! ! Lateral physics
454	CALL ldf_tra_init ! Lateral ocean tracer physics
455	CALL ldf_dyn_init ! Lateral ocean momentum physics
456	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
457
458	! ! Active tracers
459	CALL tra_qsr_init ! penetrative solar radiation qsr
460	CALL tra_bbc_init ! bottom heat flux
461	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
462	CALL tra_dmp_init ! internal damping trends- tracers
463	CALL tra_adv_init ! horizontal & vertical advection
464	CALL tra_ldf_init ! lateral mixing
465	CALL tra_zdf_init ! vertical mixing and after tracer fields
466
467	! ! Dynamics
468	IF( lk_c1d ) CALL dyn_dmp_init ! internal damping trends- momentum
469	CALL dyn_adv_init ! advection (vector or flux form)
470	CALL dyn_vor_init ! vorticity term including Coriolis
471	CALL dyn_ldf_init ! lateral mixing
472	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
473	CALL dyn_zdf_init ! vertical diffusion
474	CALL dyn_spg_init ! surface pressure gradient
475
476	! ! Misc. options
477	IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 ) CALL cla_init ! Cross Land Advection
478	CALL icb_init( rdt, nit000) ! initialise icebergs instance
479	CALL sto_par_init ! Stochastic parametrization
480	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
481
482	#if defined key_top
483	! ! Passive tracers
484	CALL trc_init
485	#endif
486	! ! Diagnostics
487	IF( lk_floats ) CALL flo_init ! drifting Floats
488	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
489	CALL dia_ptr_init ! Poleward TRansports initialization
490	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
491	CALL dia_hsb_init ! heat content, salt content and volume budgets
492	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
493	IF( lk_diaobs ) THEN ! Observation & model comparison
494	CALL dia_obs_init ! Initialize observational data
495	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
496	ENDIF
497
498	! ! Assimilation increments
499	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
500	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
501	!
502	END SUBROUTINE nemo_init
503
504
505	SUBROUTINE nemo_ctl
506	!!----------------------------------------------------------------------
507	!! * ROUTINE nemo_ctl *
508	!!
509	!! ** Purpose : control print setting
510	!!
511	!! ** Method : - print namctl information and check some consistencies
512	!!----------------------------------------------------------------------
513	!
514	IF(lwp) THEN ! control print
515	WRITE(numout,*)
516	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
517	WRITE(numout,*) '~~~~~~~ '
518	WRITE(numout,*) ' Namelist namctl'
519	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
520	WRITE(numout,*) ' level of print nn_print = ', nn_print
521	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
522	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
523	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
524	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
525	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
526	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
527	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
528	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
529	ENDIF
530	!
531	nprint = nn_print ! convert DOCTOR namelist names into OLD names
532	nictls = nn_ictls
533	nictle = nn_ictle
534	njctls = nn_jctls
535	njctle = nn_jctle
536	isplt = nn_isplt
537	jsplt = nn_jsplt
538	nbench = nn_bench
539
540	IF(lwp) THEN ! control print
541	WRITE(numout,*)
542	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
543	WRITE(numout,*) '~~~~~~~ '
544	WRITE(numout,*) ' Namelist namcfg'
545	WRITE(numout,*) ' configuration name cp_cfg = ', TRIM(cp_cfg)
546	WRITE(numout,*) ' configuration zoom name cp_cfz = ', TRIM(cp_cfz)
547	WRITE(numout,*) ' configuration resolution jp_cfg = ', jp_cfg
548	WRITE(numout,*) ' 1st lateral dimension ( >= jpi ) jpidta = ', jpidta
549	WRITE(numout,*) ' 2nd " " ( >= jpj ) jpjdta = ', jpjdta
550	WRITE(numout,*) ' 3nd " " jpkdta = ', jpkdta
551	WRITE(numout,*) ' 1st dimension of global domain in i jpiglo = ', jpiglo
552	WRITE(numout,*) ' 2nd - - in j jpjglo = ', jpjglo
553	WRITE(numout,*) ' left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
554	WRITE(numout,*) ' left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
555	WRITE(numout,*) ' lateral cond. type (between 0 and 6) jperio = ', jperio
556	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
557	ENDIF
558	! ! Parameter control
559	!
560	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
561	IF( lk_mpp .AND. jpnij > 1 ) THEN
562	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
563	ELSE
564	IF( isplt == 1 .AND. jsplt == 1 ) THEN
565	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
566	& ' - the print control will be done over the whole domain' )
567	ENDIF
568	ijsplt = isplt * jsplt ! total number of processors ijsplt
569	ENDIF
570	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
571	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
572	!
573	! ! indices used for the SUM control
574	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
575	lsp_area = .FALSE.
576	ELSE ! print control done over a specific area
577	lsp_area = .TRUE.
578	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
579	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
580	nictls = 1
581	ENDIF
582	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
583	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
584	nictle = jpiglo
585	ENDIF
586	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
587	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
588	njctls = 1
589	ENDIF
590	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
591	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
592	njctle = jpjglo
593	ENDIF
594	ENDIF
595	ENDIF
596	!
597	IF( nbench == 1 ) THEN ! Benchmark
598	SELECT CASE ( cp_cfg )
599	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
600	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
601	& ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
602	END SELECT
603	ENDIF
604	!
605	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
606	& 'f2003 standard. ' , &
607	& 'Compile with key_nosignedzero enabled' )
608	!
609	END SUBROUTINE nemo_ctl
610
611
612	SUBROUTINE nemo_closefile
613	!!----------------------------------------------------------------------
614	!! * ROUTINE nemo_closefile *
615	!!
616	!! ** Purpose : Close the files
617	!!----------------------------------------------------------------------
618	!
619	IF( lk_mpp ) CALL mppsync
620	!
621	CALL iom_close ! close all input/output files managed by iom_*
622	!
623	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
624	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
625	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
626	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
627	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
628	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
629	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
630	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
631	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
632	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
633	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
634	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
635	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
636
637	!
638	numout = 6 ! redefine numout in case it is used after this point...
639	!
640	END SUBROUTINE nemo_closefile
641
642
643	SUBROUTINE nemo_alloc
644	!!----------------------------------------------------------------------
645	!! * ROUTINE nemo_alloc *
646	!!
647	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
648	!!
649	!! ** Method :
650	!!----------------------------------------------------------------------
651	USE diawri , ONLY: dia_wri_alloc
652	USE dom_oce , ONLY: dom_oce_alloc
653	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
654	USE ldftra_oce, ONLY: ldftra_oce_alloc
655	USE trc_oce , ONLY: trc_oce_alloc
656	#if defined key_diadct
657	USE diadct , ONLY: diadct_alloc
658	#endif
659	#if defined key_bdy
660	USE bdy_oce , ONLY: bdy_oce_alloc
661	#endif
662	!
663	INTEGER :: ierr
664	!!----------------------------------------------------------------------
665	!
666	ierr = oce_alloc () ! ocean
667	ierr = ierr + dia_wri_alloc ()
668	ierr = ierr + dom_oce_alloc () ! ocean domain
669	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
670	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
671	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
672	!
673	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
674	!
675	#if defined key_diadct
676	ierr = ierr + diadct_alloc () !
677	#endif
678	#if defined key_bdy
679	ierr = ierr + bdy_oce_alloc () ! bdy masks (incl. initialization)
680	#endif
681	!
682	IF( lk_mpp ) CALL mpp_sum( ierr )
683	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
684	!
685	END SUBROUTINE nemo_alloc
686
687
688	SUBROUTINE nemo_partition( num_pes )
689	!!----------------------------------------------------------------------
690	!! * ROUTINE nemo_partition *
691	!!
692	!! ** Purpose :
693	!!
694	!! ** Method :
695	!!----------------------------------------------------------------------
696	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
697	!
698	INTEGER, PARAMETER :: nfactmax = 20
699	INTEGER :: nfact ! The no. of factors returned
700	INTEGER :: ierr ! Error flag
701	INTEGER :: ji
702	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
703	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
704	!!----------------------------------------------------------------------
705	!
706	ierr = 0
707	!
708	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
709	!
710	IF( nfact <= 1 ) THEN
711	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
712	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
713	jpnj = 1
714	jpni = num_pes
715	ELSE
716	! Search through factors for the pair that are closest in value
717	mindiff = 1000000
718	imin = 1
719	DO ji = 1, nfact-1, 2
720	idiff = ABS( ifact(ji) - ifact(ji+1) )
721	IF( idiff < mindiff ) THEN
722	mindiff = idiff
723	imin = ji
724	ENDIF
725	END DO
726	jpnj = ifact(imin)
727	jpni = ifact(imin + 1)
728	ENDIF
729	!
730	jpnij = jpni*jpnj
731	!
732	END SUBROUTINE nemo_partition
733
734
735	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
736	!!----------------------------------------------------------------------
737	!! * ROUTINE factorise *
738	!!
739	!! ** Purpose : return the prime factors of n.
740	!! knfax factors are returned in array kfax which is of
741	!! maximum dimension kmaxfax.
742	!! ** Method :
743	!!----------------------------------------------------------------------
744	INTEGER , INTENT(in ) :: kn, kmaxfax
745	INTEGER , INTENT( out) :: kerr, knfax
746	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
747	!
748	INTEGER :: ifac, jl, inu
749	INTEGER, PARAMETER :: ntest = 14
750	INTEGER, DIMENSION(ntest) :: ilfax
751	!!----------------------------------------------------------------------
752	! lfax contains the set of allowed factors.
753	ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
754
755	! Clear the error flag and initialise output vars
756	kerr = 0
757	kfax = 1
758	knfax = 0
759
760	! Find the factors of n.
761	IF( kn == 1 ) GOTO 20
762
763	! nu holds the unfactorised part of the number.
764	! knfax holds the number of factors found.
765	! l points to the allowed factor list.
766	! ifac holds the current factor.
767
768	inu = kn
769	knfax = 0
770
771	DO jl = ntest, 1, -1
772	!
773	ifac = ilfax(jl)
774	IF( ifac > inu ) CYCLE
775
776	! Test whether the factor will divide.
777
778	IF( MOD(inu,ifac) == 0 ) THEN
779	!
780	knfax = knfax + 1 ! Add the factor to the list
781	IF( knfax > kmaxfax ) THEN
782	kerr = 6
783	write (,) 'FACTOR: insufficient space in factor array ', knfax
784	return
785	ENDIF
786	kfax(knfax) = ifac
787	! Store the other factor that goes with this one
788	knfax = knfax + 1
789	kfax(knfax) = inu / ifac
790	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
791	ENDIF
792	!
793	END DO
794
795	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
796	!
797	END SUBROUTINE factorise
798
799	#if defined key_mpp_mpi
800
801	SUBROUTINE nemo_northcomms
802	!!======================================================================
803	!! * ROUTINE nemo_northcomms *
804	!! nemo_northcomms : Setup for north fold exchanges with explicit
805	!! point-to-point messaging
806	!!=====================================================================
807	!!----------------------------------------------------------------------
808	!!
809	!! ** Purpose : Initialization of the northern neighbours lists.
810	!!----------------------------------------------------------------------
811	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
812	!! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
813	!!----------------------------------------------------------------------
814
815	INTEGER :: sxM, dxM, sxT, dxT, jn
816	INTEGER :: njmppmax
817
818	njmppmax = MAXVAL( njmppt )
819
820	!initializes the north-fold communication variables
821	isendto(:) = 0
822	nsndto = 0
823
824	!if I am a process in the north
825	IF ( njmpp == njmppmax ) THEN
826	!sxM is the first point (in the global domain) needed to compute the
827	!north-fold for the current process
828	sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
829	!dxM is the last point (in the global domain) needed to compute the
830	!north-fold for the current process
831	dxM = jpiglo - nimppt(narea) + 2
832
833	!loop over the other north-fold processes to find the processes
834	!managing the points belonging to the sxT-dxT range
835
836	DO jn = 1, jpni
837	!sxT is the first point (in the global domain) of the jn
838	!process
839	sxT = nfiimpp(jn, jpnj)
840	!dxT is the last point (in the global domain) of the jn
841	!process
842	dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
843	IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
844	nsndto = nsndto + 1
845	isendto(nsndto) = jn
846	ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
847	nsndto = nsndto + 1
848	isendto(nsndto) = jn
849	ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
850	nsndto = nsndto + 1
851	isendto(nsndto) = jn
852	END IF
853	END DO
854	nfsloop = 1
855	nfeloop = nlci
856	DO jn = 2,jpni-1
857	IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
858	IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
859	nfsloop = nldi
860	ENDIF
861	IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
862	nfeloop = nlei
863	ENDIF
864	ENDIF
865	END DO
866
867	ENDIF
868	l_north_nogather = .TRUE.
869	END SUBROUTINE nemo_northcomms
870	#else
871	SUBROUTINE nemo_northcomms ! Dummy routine
872	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
873	END SUBROUTINE nemo_northcomms
874	#endif
875
876	!!======================================================================
877	END MODULE nemogcm
878
879

Note: See TracBrowser for help on using the repository browser.

Download in other formats: