New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/2015/dev_r5721_CNRS9_NOC3_LDF/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5721_CNRS9_NOC3_LDF/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 5758

Last change on this file since 5758 was 5737, checked in by gm, 9 years ago

#1593: LDF-ADV, step I: Phasing of horizontal scale factors correct 2

  • Property svn:keywords set to Id
File size: 32.7 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trc_oce        ! share passive tracers/Ocean variables
25   USE trd_oce        ! trends: ocean variables
26   USE trdtra         ! tracers trends
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE diaptr         ! poleward transport diagnostics
29   !
30   USE lib_mpp        ! MPP library
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE in_out_manager ! I/O manager
33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_adv_tvd        ! routine called by traadv.F90
41   PUBLIC   tra_adv_tvd_zts    ! routine called by traadv.F90
42
43   LOGICAL ::   l_trd   ! flag to compute trends
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
56      &                                       ptb, ptn, pta, kjpt )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE tra_adv_tvd  ***
59      !!
60      !! **  Purpose :   Compute the now trend due to total advection of
61      !!       tracers and add it to the general trend of tracer equations
62      !!
63      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
64      !!       corrected flux (monotonic correction)
65      !!       note: - this advection scheme needs a leap-frog time scheme
66      !!
67      !! ** Action : - update (pta) with the now advective tracer trends
68      !!             - save the trends
69      !!----------------------------------------------------------------------
70      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
71      !
72      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
73      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
76      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
77      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
80      !
81      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices
82      INTEGER  ::   ik 
83      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
84      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
85      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
88      !!----------------------------------------------------------------------
89      !
90      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
91      !
92      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
93      !
94      IF( kt == kit000 )  THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
98         !
99         l_trd = .FALSE.
100         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
101      ENDIF
102      !
103      IF( l_trd )  THEN
104         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
105         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
106      ENDIF
107      !
108      zwi(:,:,:) = 0.e0 ; 
109      !
110      !                                                          ! ===========
111      DO jn = 1, kjpt                                            ! tracer loop
112         !                                                       ! ===========
113         ! 1. Bottom and k=1 value : flux set to zero
114         ! ----------------------------------
115         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
116         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
117         
118         zwz(:,:,1  ) = 0._wp
119         ! 2. upstream advection with initial mass fluxes & intermediate update
120         ! --------------------------------------------------------------------
121         ! upstream tracer flux in the i and j direction
122         DO jk = 1, jpkm1
123            DO jj = 1, jpjm1
124               DO ji = 1, fs_jpim1   ! vector opt.
125                  ! upstream scheme
126                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
127                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
128                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
129                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
130                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
131                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
132               END DO
133            END DO
134         END DO
135
136         ! upstream tracer flux in the k direction
137         ! Interior value
138         DO jk = 2, jpkm1
139            DO jj = 1, jpj
140               DO ji = 1, jpi
141                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
142                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
143                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
144               END DO
145            END DO
146         END DO
147         ! Surface value
148         IF( lk_vvl ) THEN   
149            IF ( ln_isfcav ) THEN
150               DO jj = 1, jpj
151                  DO ji = 1, jpi
152                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable
153                  END DO
154               END DO
155            ELSE
156               zwz(:,:,1) = 0.e0          ! volume variable
157            END IF
158         ELSE               
159            IF ( ln_isfcav ) THEN
160               DO jj = 1, jpj
161                  DO ji = 1, jpi
162                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
163                  END DO
164               END DO   
165            ELSE
166               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
167            END IF
168         ENDIF
169
170         ! total advective trend
171         DO jk = 1, jpkm1
172            z2dtt = p2dt(jk)
173            DO jj = 2, jpjm1
174               DO ji = fs_2, fs_jpim1   ! vector opt.
175                  zbtr = 1. / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) )
176                  ! total intermediate advective trends
177                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
178                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
179                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
180                  ! update and guess with monotonic sheme
181                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra   * tmask(ji,jj,jk)
182                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
183               END DO
184            END DO
185         END DO
186         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
187         CALL lbc_lnk( zwi, 'T', 1. ) 
188
189         !                                 ! trend diagnostics (contribution of upstream fluxes)
190         IF( l_trd )  THEN 
191            ! store intermediate advective trends
192            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
193         END IF
194         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
195         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
196           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
197           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
198         ENDIF
199
200         ! 3. antidiffusive flux : high order minus low order
201         ! --------------------------------------------------
202         ! antidiffusive flux on i and j
203         DO jk = 1, jpkm1
204            DO jj = 1, jpjm1
205               DO ji = 1, fs_jpim1   ! vector opt.
206                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
207                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
208               END DO
209            END DO
210         END DO
211     
212         ! antidiffusive flux on k
213         ! Interior value
214         DO jk = 2, jpkm1                   
215            DO jj = 1, jpj
216               DO ji = 1, jpi
217                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
218               END DO
219            END DO
220         END DO
221         ! surface value
222         IF ( ln_isfcav ) THEN
223            DO jj = 1, jpj
224               DO ji = 1, jpi
225                  zwz(ji,jj,mikt(ji,jj)) = 0.e0
226               END DO
227            END DO
228         ELSE
229            zwz(:,:,1) = 0.e0
230         END IF
231         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
232         CALL lbc_lnk( zwz, 'W',  1. )
233
234         ! 4. monotonicity algorithm
235         ! -------------------------
236         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
237
238
239         ! 5. final trend with corrected fluxes
240         ! ------------------------------------
241         DO jk = 1, jpkm1
242            DO jj = 2, jpjm1
243               DO ji = fs_2, fs_jpim1   ! vector opt. 
244                  zbtr = 1. / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) )
245                  ! total advective trends
246                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
247                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
248                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
249                  ! add them to the general tracer trends
250                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra * tmask(ji,jj,jk)
251               END DO
252            END DO
253         END DO
254
255         !                                 ! trend diagnostics (contribution of upstream fluxes)
256         IF( l_trd )  THEN
257            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
258            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
259            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
260           
261            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
262            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
263            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
264         END IF
265         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
266         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
267           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
268           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
269         ENDIF
270         !
271      END DO
272      !
273                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
274      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
275      !
276      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
277      !
278   END SUBROUTINE tra_adv_tvd
279
280
281   SUBROUTINE tra_adv_tvd_zts ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
282      &                                       ptb, ptn, pta, kjpt )
283      !!----------------------------------------------------------------------
284      !!                  ***  ROUTINE tra_adv_tvd_zts  ***
285      !!
286      !! **  Purpose :   Compute the now trend due to total advection of
287      !!       tracers and add it to the general trend of tracer equations
288      !!
289      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
290      !!       corrected flux (monotonic correction). This version use sub-
291      !!       timestepping for the vertical advection which increases stability
292      !!       when vertical metrics are small.
293      !!       note: - this advection scheme needs a leap-frog time scheme
294      !!
295      !! ** Action : - update (pta) with the now advective tracer trends
296      !!             - save the trends
297      !!----------------------------------------------------------------------
298      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
299      !
300      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
301      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
302      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
303      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
304      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
305      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
306      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
307      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
308      !
309      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
310      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
311      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
312      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
313      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
314      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
315      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
316      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
317      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
318      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
319      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwx_sav , zwy_sav
320      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz, zhdiv, zwz_sav, zwzts
321      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
322      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrs
323      !!----------------------------------------------------------------------
324      !
325      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd_zts')
326      !
327      CALL wrk_alloc( jpi, jpj, zwx_sav, zwy_sav )
328      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zhdiv, zwz_sav, zwzts )
329      CALL wrk_alloc( jpi, jpj, jpk, 3, ztrs )
330      !
331      IF( kt == kit000 )  THEN
332         IF(lwp) WRITE(numout,*)
333         IF(lwp) WRITE(numout,*) 'tra_adv_tvd_zts : TVD ZTS advection scheme on ', cdtype
334         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
335      ENDIF
336      !
337      l_trd = .FALSE.
338      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
339      !
340      IF( l_trd )  THEN
341         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
342         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
343      ENDIF
344      !
345      zwi(:,:,:) = 0._wp
346      z_rzts = 1._wp / REAL( jnzts, wp )
347      zr_p2dt(:) = 1._wp / p2dt(:)
348      !
349      !                                                          ! ===========
350      DO jn = 1, kjpt                                            ! tracer loop
351         !                                                       ! ===========
352         ! 1. Bottom value : flux set to zero
353         ! ----------------------------------
354         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
355         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
356
357         ! 2. upstream advection with initial mass fluxes & intermediate update
358         ! --------------------------------------------------------------------
359         ! upstream tracer flux in the i and j direction
360         DO jk = 1, jpkm1
361            DO jj = 1, jpjm1
362               DO ji = 1, fs_jpim1   ! vector opt.
363                  ! upstream scheme
364                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
365                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
366                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
367                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
368                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
369                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
370               END DO
371            END DO
372         END DO
373
374         ! upstream tracer flux in the k direction
375         ! Interior value
376         DO jk = 2, jpkm1
377            DO jj = 1, jpj
378               DO ji = 1, jpi
379                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
380                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
381                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
382               END DO
383            END DO
384         END DO
385         ! Surface value
386         IF( lk_vvl ) THEN
387            IF ( ln_isfcav ) THEN
388               DO jj = 1, jpj
389                  DO ji = 1, jpi
390                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable +    isf
391                  END DO
392               END DO
393            ELSE
394               zwz(:,:,1) = 0.e0                              ! volume variable + no isf
395            END IF
396         ELSE
397            IF ( ln_isfcav ) THEN
398               DO jj = 1, jpj
399                  DO ji = 1, jpi
400                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface +    isf
401                  END DO
402               END DO
403            ELSE
404               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)                                               ! linear free surface + no isf
405            END IF
406         ENDIF
407
408         ! total advective trend
409         DO jk = 1, jpkm1
410            z2dtt = p2dt(jk)
411            DO jj = 2, jpjm1
412               DO ji = fs_2, fs_jpim1   ! vector opt.
413                  zbtr = 1._wp / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) )
414                  ! total intermediate advective trends
415                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
416                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
417                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
418                  ! update and guess with monotonic sheme
419                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
420                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
421               END DO
422            END DO
423         END DO
424         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
425         CALL lbc_lnk( zwi, 'T', 1. ) 
426
427         !                                 ! trend diagnostics (contribution of upstream fluxes)
428         IF( l_trd )  THEN 
429            ! store intermediate advective trends
430            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
431         END IF
432         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
433         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
434           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
435           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
436         ENDIF
437
438         ! 3. antidiffusive flux : high order minus low order
439         ! --------------------------------------------------
440         ! antidiffusive flux on i and j
441
442
443         DO jk = 1, jpkm1
444
445            DO jj = 1, jpjm1
446               DO ji = 1, fs_jpim1   ! vector opt.
447                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
448                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
449
450                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
451                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
452               END DO
453            END DO
454
455            DO jj = 2, jpjm1         ! partial horizontal divergence
456               DO ji = fs_2, fs_jpim1
457                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
458                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
459               END DO
460            END DO
461
462            DO jj = 1, jpjm1
463               DO ji = 1, fs_jpim1   ! vector opt.
464                  zwx(ji,jj,jk) = zwx(ji,jj,jk)  - zwx_sav(ji,jj)
465                  zwy(ji,jj,jk) = zwy(ji,jj,jk)  - zwy_sav(ji,jj)
466               END DO
467            END DO
468         END DO
469     
470         ! antidiffusive flux on k
471         zwz(:,:,1) = 0._wp        ! Surface value
472         zwz_sav(:,:,:) = zwz(:,:,:)
473         !
474         ztrs(:,:,:,1) = ptb(:,:,:,jn)
475         zwzts(:,:,:) = 0._wp
476
477         DO jl = 1, jnzts                   ! Start of sub timestepping loop
478
479            IF( jl == 1 ) THEN              ! Euler forward to kick things off
480              jtb = 1   ;   jtn = 1   ;   jta = 2
481              zts(:) = p2dt(:) * z_rzts
482              jtaken = MOD( jnzts + 1 , 2)  ! Toggle to collect every second flux
483                                            ! starting at jl =1 if jnzts is odd;
484                                            ! starting at jl =2 otherwise
485            ELSEIF( jl == 2 ) THEN          ! First leapfrog step
486              jtb = 1   ;   jtn = 2   ;   jta = 3
487              zts(:) = 2._wp * p2dt(:) * z_rzts
488            ELSE                            ! Shuffle pointers for subsequent leapfrog steps
489              jtb = MOD(jtb,3) + 1
490              jtn = MOD(jtn,3) + 1
491              jta = MOD(jta,3) + 1
492            ENDIF
493            DO jk = 2, jpkm1          ! Interior value
494               DO jj = 2, jpjm1
495                  DO ji = fs_2, fs_jpim1
496                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) )
497                     IF( jtaken == 0 ) zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk)*zts(jk)           ! Accumulate time-weighted vertcal flux
498                  END DO
499               END DO
500            END DO
501
502            jtaken = MOD( jtaken + 1 , 2 )
503
504            DO jk = 2, jpkm1          ! Interior value
505               DO jj = 2, jpjm1
506                  DO ji = fs_2, fs_jpim1
507                     zbtr = 1._wp / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) )
508                     ! total advective trends
509                     ztra = - zbtr * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
510                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb) + zts(jk) * ztra
511                  END DO
512               END DO
513            END DO
514
515         END DO
516
517         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
518            DO jj = 2, jpjm1
519               DO ji = fs_2, fs_jpim1
520                  zwz(ji,jj,jk) = zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk)
521               END DO
522            END DO
523         END DO
524         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
525         CALL lbc_lnk( zwz, 'W',  1. )
526
527         ! 4. monotonicity algorithm
528         ! -------------------------
529         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
530
531
532         ! 5. final trend with corrected fluxes
533         ! ------------------------------------
534         DO jk = 1, jpkm1
535            DO jj = 2, jpjm1
536               DO ji = fs_2, fs_jpim1   ! vector opt. 
537                  zbtr = 1. / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) )
538                  ! total advective trends
539                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
540                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
541                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
542                  ! add them to the general tracer trends
543                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
544               END DO
545            END DO
546         END DO
547
548         !                                 ! trend diagnostics (contribution of upstream fluxes)
549         IF( l_trd )  THEN
550            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
551            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
552            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
553           
554            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
555            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
556            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
557         END IF
558         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
559         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
560           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
561           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
562         ENDIF
563         !
564      END DO
565      !
566                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz, zhdiv, zwz_sav, zwzts )
567                   CALL wrk_dealloc( jpi, jpj, jpk, 3, ztrs )
568                   CALL wrk_dealloc( jpi, jpj, zwx_sav, zwy_sav )
569      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
570      !
571      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd_zts')
572      !
573   END SUBROUTINE tra_adv_tvd_zts
574
575
576   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
577      !!---------------------------------------------------------------------
578      !!                    ***  ROUTINE nonosc  ***
579      !!     
580      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
581      !!       scheme and the before field by a nonoscillatory algorithm
582      !!
583      !! **  Method  :   ... ???
584      !!       warning : pbef and paft must be masked, but the boundaries
585      !!       conditions on the fluxes are not necessary zalezak (1979)
586      !!       drange (1995) multi-dimensional forward-in-time and upstream-
587      !!       in-space based differencing for fluid
588      !!----------------------------------------------------------------------
589      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
590      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
591      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
592      !
593      INTEGER  ::   ji, jj, jk   ! dummy loop indices
594      INTEGER  ::   ikm1         ! local integer
595      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
596      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
597      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
598      !!----------------------------------------------------------------------
599      !
600      IF( nn_timing == 1 )  CALL timing_start('nonosc')
601      !
602      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
603      !
604      zbig  = 1.e+40_wp
605      zrtrn = 1.e-15_wp
606      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
607
608      ! Search local extrema
609      ! --------------------
610      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
611      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
612         &        paft * tmask - zbig * ( 1._wp - tmask )  )
613      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
614         &        paft * tmask + zbig * ( 1._wp - tmask )  )
615
616      DO jk = 1, jpkm1
617         ikm1 = MAX(jk-1,1)
618         z2dtt = p2dt(jk)
619         DO jj = 2, jpjm1
620            DO ji = fs_2, fs_jpim1   ! vector opt.
621
622               ! search maximum in neighbourhood
623               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
624                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
625                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
626                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
627
628               ! search minimum in neighbourhood
629               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
630                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
631                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
632                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
633
634               ! positive part of the flux
635               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
636                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
637                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
638
639               ! negative part of the flux
640               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
641                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
642                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
643
644               ! up & down beta terms
645               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
646               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
647               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
648            END DO
649         END DO
650      END DO
651      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
652
653      ! 3. monotonic flux in the i & j direction (paa & pbb)
654      ! ----------------------------------------
655      DO jk = 1, jpkm1
656         DO jj = 2, jpjm1
657            DO ji = fs_2, fs_jpim1   ! vector opt.
658               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
659               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
660               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
661               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
662
663               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
664               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
665               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
666               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
667
668      ! monotonic flux in the k direction, i.e. pcc
669      ! -------------------------------------------
670               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
671               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
672               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
673               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
674            END DO
675         END DO
676      END DO
677      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
678      !
679      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
680      !
681      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
682      !
683   END SUBROUTINE nonosc
684
685   !!======================================================================
686END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.