New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_lap_blp.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/DYN/dynldf_lap_blp.F90 @ 5845

Last change on this file since 5845 was 5845, checked in by gm, 8 years ago

#1613: vvl by default: suppression of domzgr_substitute.h90

  • Property svn:keywords set to Id
File size: 8.7 KB
Line 
1MODULE dynldf_lap_blp
2   !!======================================================================
3   !!                   ***  MODULE  dynldf_lap_blp  ***
4   !! Ocean dynamics:  lateral viscosity trend (laplacian and bilaplacian)
5   !!======================================================================
6   !! History :  OPA  ! 1990-09 (G. Madec) Original code
7   !!            4.0  ! 1991-11 (G. Madec)
8   !!            6.0  ! 1996-01 (G. Madec) statement function for e3 and ahm
9   !!   NEMO     1.0  ! 2002-06 (G. Madec)  F90: Free form and module
10   !!             -   ! 2004-08 (C. Talandier) New trends organization
11   !!            3.7  ! 2014-01  (F. Lemarie, G. Madec)  restructuration/simplification of ahm specification,
12   !!                 !                                  add velocity dependent coefficient and optional read in file
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   dyn_ldf_lap   : update the momentum trend with the lateral viscosity using an iso-level   laplacian operator
17   !!   dyn_ldf_blp   : update the momentum trend with the lateral viscosity using an iso-level bilaplacian operator
18   !!----------------------------------------------------------------------
19   USE oce            ! ocean dynamics and tracers
20   USE dom_oce        ! ocean space and time domain
21   USE ldfdyn         ! lateral diffusion: eddy viscosity coef.
22   USE ldfslp         ! iso-neutral slopes
23   USE zdf_oce        ! ocean vertical physics
24   !
25   USE in_out_manager ! I/O manager
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27   USE wrk_nemo       ! Memory Allocation
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC dyn_ldf_lap  ! called by dynldf.F90
34   PUBLIC dyn_ldf_blp  ! called by dynldf.F90
35
36   !! * Substitutions
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
40   !! $Id$
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE dyn_ldf_lap( kt, pub, pvb, pua, pva, kpass )
46      !!----------------------------------------------------------------------
47      !!                     ***  ROUTINE dyn_ldf_lap  ***
48      !!                       
49      !! ** Purpose :   Compute the before horizontal momentum diffusive
50      !!      trend and add it to the general trend of momentum equation.
51      !!
52      !! ** Method  :   The Laplacian operator apply on horizontal velocity is
53      !!      writen as :   grad_h( ahmt div_h(U )) - curl_h( ahmf curl_z(U) )
54      !!
55      !! ** Action : - pua, pva increased by the harmonic operator applied on pub, pvb.
56      !!----------------------------------------------------------------------
57      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
58      INTEGER                         , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
59      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pub, pvb   ! before velocity  [m/s]
60      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pua, pva   ! velocity trend   [m/s2]
61      !
62      INTEGER  ::   ji, jj, jk   ! dummy loop indices
63      REAL(wp) ::   zsign        ! local scalars
64      REAL(wp) ::   zua, zva     ! local scalars
65      REAL(wp), POINTER, DIMENSION(:,:) ::  zcur, zdiv
66      !!----------------------------------------------------------------------
67      !
68      IF( kt == nit000 .AND. lwp ) THEN
69         WRITE(numout,*)
70         WRITE(numout,*) 'dyn_ldf : iso-level harmonic (laplacian) operator, pass=', kpass
71         WRITE(numout,*) '~~~~~~~ '
72      ENDIF
73      !
74      IF( nn_timing == 1 )   CALL timing_start('dyn_ldf_lap')
75      !
76      CALL wrk_alloc( jpi, jpj, zcur, zdiv ) 
77      !
78      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign
79      ELSE                    ;   zsign = -1._wp      !  (eddy viscosity coef. >0)
80      ENDIF
81      !
82      !                                                ! ===============
83      DO jk = 1, jpkm1                                 ! Horizontal slab
84         !                                             ! ===============
85         DO jj = 2, jpj
86            DO ji = fs_2, jpi   ! vector opt.
87               !                                      ! ahm * e3 * curl  (computed from 1 to jpim1/jpjm1)
88               zcur(ji-1,jj-1) = ahmf(ji-1,jj-1,jk) * e3f_n(ji-1,jj-1,jk) * r1_e1e2f(ji-1,jj-1)      &
89                  &     * (  e2v(ji  ,jj-1) * pvb(ji  ,jj-1,jk) - e2v(ji-1,jj-1) * pvb(ji-1,jj-1,jk)                &
90                  &        - e1u(ji-1,jj  ) * pub(ji-1,jj  ,jk) + e1u(ji-1,jj-1) * pub(ji-1,jj-1,jk)  ) * fmask(ji-1,jj-1,jk)
91               !                                      ! ahm * div        (computed from 2 to jpi/jpj)
92               zdiv(ji,jj)     = ahmt(ji,jj,jk) / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) )                     * tmask(ji,jj,jk)    &
93                  &     * (  e2u(ji,jj)*e3u_n(ji,jj,jk) * pub(ji,jj,jk) - e2u(ji-1,jj)*e3u_n(ji-1,jj,jk) * pub(ji-1,jj,jk)    &
94                  &        + e1v(ji,jj)*e3v_n(ji,jj,jk) * pvb(ji,jj,jk) - e1v(ji,jj-1)*e3v_n(ji,jj-1,jk) * pvb(ji,jj-1,jk)  )
95            END DO 
96         END DO 
97         !
98         DO jj = 2, jpjm1                             ! - curl( curl) + grad( div )
99            DO ji = fs_2, fs_jpim1   ! vector opt.
100               pua(ji,jj,jk) = pua(ji,jj,jk) + zsign * (                                                   &
101                  &              - ( zcur(ji  ,jj) - zcur(ji,jj-1) ) /  ( e2u(ji,jj) * e3u_n(ji,jj,jk) )   &
102                  &              + ( zdiv(ji+1,jj) - zdiv(ji,jj  ) ) * r1_e1u(ji,jj)                     )
103                  !
104               pva(ji,jj,jk) = pva(ji,jj,jk) + zsign * (                                                   &
105                  &                ( zcur(ji,jj  ) - zcur(ji-1,jj) ) /  ( e1v(ji,jj) * e3v_n(ji,jj,jk) )   &
106                  &              + ( zdiv(ji,jj+1) - zdiv(ji  ,jj) ) * r1_e2v(ji,jj)                     )
107            END DO
108         END DO
109         !                                             ! ===============
110      END DO                                           !   End of slab
111      !                                                ! ===============
112      CALL wrk_dealloc( jpi, jpj, zcur, zdiv ) 
113      !
114      IF( nn_timing == 1 )  CALL timing_stop('dyn_ldf_lap')
115      !
116   END SUBROUTINE dyn_ldf_lap
117
118
119   SUBROUTINE dyn_ldf_blp( kt, pub, pvb, pua, pva )
120      !!----------------------------------------------------------------------
121      !!                 ***  ROUTINE dyn_ldf_blp  ***
122      !!                   
123      !! ** Purpose :   Compute the before lateral momentum viscous trend
124      !!              and add it to the general trend of momentum equation.
125      !!
126      !! ** Method  :   The lateral viscous trends is provided by a bilaplacian
127      !!      operator applied to before field (forward in time).
128      !!      It is computed by two successive calls to dyn_ldf_lap routine
129      !!
130      !! ** Action :   pta   updated with the before rotated bilaplacian diffusion
131      !!----------------------------------------------------------------------
132      INTEGER                         , INTENT(in   ) ::   kt         ! ocean time-step index
133      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pub, pvb   ! before velocity fields
134      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pua, pva   ! momentum trend
135      !
136      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zulap, zvlap   ! laplacian at u- and v-point
137      !!----------------------------------------------------------------------
138      !
139      IF( nn_timing == 1 )  CALL timing_start('dyn_ldf_blp')
140      !
141      CALL wrk_alloc( jpi, jpj, jpk, zulap, zvlap ) 
142      !
143      IF( kt == nit000 )  THEN
144         IF(lwp) WRITE(numout,*)
145         IF(lwp) WRITE(numout,*) 'dyn_ldf_blp : bilaplacian operator momentum '
146         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
147      ENDIF
148      !
149      zulap(:,:,:) = 0._wp
150      zvlap(:,:,:) = 0._wp
151      !
152      CALL dyn_ldf_lap( kt, pub, pvb, zulap, zvlap, 1 )   ! rotated laplacian applied to ptb (output in zlap)
153      !
154      CALL lbc_lnk( zulap(:,:,:) , 'U', -1. )             ! Lateral boundary conditions
155      CALL lbc_lnk( zvlap(:,:,:) , 'V', -1. )
156      !
157      CALL dyn_ldf_lap( kt, zulap, zvlap, pua, pva, 2 )   ! rotated laplacian applied to zlap (output in pta)
158      !
159      CALL wrk_dealloc( jpi, jpj, jpk, zulap, zvlap ) 
160      !
161      IF( nn_timing == 1 )  CALL timing_stop('dyn_ldf_blp')
162      !
163   END SUBROUTINE dyn_ldf_blp
164
165   !!======================================================================
166END MODULE dynldf_lap_blp
Note: See TracBrowser for help on using the repository browser.