New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in branches/2015/dev_r5936_INGV1_WAVE/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2015/dev_r5936_INGV1_WAVE/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 7171

Last change on this file since 7171 was 7171, checked in by emanuelaclementi, 7 years ago

#1643 Updates and bug fix on development branch 2015/dev_r5936_INGV1_WAVE
  • Property svn:keywords set to Id
File size: 13.6 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !   2011-09  (Adani M)  Original code: Drag Coefficient
7   !!         :  3.4  !   2012-10  (Adani M)                 Stokes Drift
8   !!            3.6  !   2014-09  (Clementi E, Oddo P)New Stokes Drift Computation
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_wave      : wave data from wave model in netcdf files
13   !!----------------------------------------------------------------------
14   USE oce            !
15   USE sbc_oce       ! Surface boundary condition: ocean fields
16   USE bdy_oce        !
17   USE domvvl         !
18   !
19   USE iom            ! I/O manager library
20   USE in_out_manager ! I/O manager
21   USE lib_mpp        ! distribued memory computing library
22   USE fldread       ! read input fields
23   USE wrk_nemo       !
24   USE phycst         ! physical constants
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   sbc_wave    ! routine called in sbcmod
30   
31   INTEGER , PARAMETER ::   jpfld  = 4           ! number of files to read for stokes drift
32   INTEGER , PARAMETER ::   jp_usd = 1           ! index of stokes drift  (i-component) (m/s)    at T-point
33   INTEGER , PARAMETER ::   jp_vsd = 2           ! index of stokes drift  (j-component) (m/s)    at T-point
34   INTEGER , PARAMETER ::   jp_swh = 3           ! index of significant wave hight      (m)      at T-point
35   INTEGER , PARAMETER ::   jp_wmp = 4           ! index of mean wave period            (s)      at T-point
36
37   TYPE(FLD), ALLOCATABLE, DIMENSION(:)  :: sf_cd    ! structure of input fields (file informations, fields read) Drag Coefficient
38   TYPE(FLD), ALLOCATABLE, DIMENSION(:)  :: sf_sd    ! structure of input fields (file informations, fields read) Stokes Drift
39   TYPE(FLD), ALLOCATABLE, DIMENSION(:)  :: sf_wn    ! structure of input fields (file informations, fields read) wave number for Qiao
40   TYPE(FLD), ALLOCATABLE, DIMENSION(:)  :: sf_tauoc ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
41   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)       :: cdn_wave 
42   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)       :: swh,wmp, wnum
43   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)       :: tauoc_wave
44   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)       :: tsd2d
45   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)       :: usd2d, vsd2d
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)     :: usd3d, vsd3d, wsd3d 
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)     :: usd3dt, vsd3dt
48   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)       :: zusd2dt, zvsd2dt
49
50   !! * Substitutions
51#  include "domzgr_substitute.h90"
52#  include "vectopt_loop_substitute.h90"
53   !!----------------------------------------------------------------------
54   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
55   !! $Id$
56   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
57   !!----------------------------------------------------------------------
58CONTAINS
59
60   SUBROUTINE sbc_wave( kt )
61      !!---------------------------------------------------------------------
62      !!                     ***  ROUTINE sbc_wave  ***
63      !!
64      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
65      !!
66      !! ** Method  : - Read namelist namsbc_wave
67      !!              - Read Cd_n10 fields in netcdf files
68      !!              - Read stokes drift 2d in netcdf files
69      !!              - Read wave number in netcdf files
70      !!              - Compute 3d stokes drift using Breivik et al.,2014
71      !!                formulation
72      !! ** action 
73      !!---------------------------------------------------------------------
74      USE zdf_oce,  ONLY : ln_zdfqiao
75
76      INTEGER, INTENT( in  ) ::   kt       ! ocean time step
77      !
78      INTEGER                ::   ierror   ! return error code
79      INTEGER                ::   ifpr, jj,ji,jk 
80      INTEGER                ::   ios      ! Local integer output status for namelist read
81      !
82      CHARACTER(len=100)     ::  cn_dir                          ! Root directory for location of drag coefficient files
83      REAL(wp)                       ::  ztransp, zsp0, zk, zus, zvs
84      REAL(wp), DIMENSION(jpi,jpj)   ::  zfac 
85      REAL(wp), DIMENSION(:,:,:), POINTER :: ze3hdiv   ! 3D workspace
86      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i     ! array of namelist informations on the fields to read
87      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd,  &
88                             &   sn_swh, sn_wmp, sn_wnum, sn_tauoc      ! informations about the fields to be read
89      !!
90      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_swh, sn_wmp, sn_wnum, sn_tauoc
91      !!---------------------------------------------------------------------
92      !
93      !                                         ! -------------------- !
94      IF( kt == nit000 ) THEN                   ! First call kt=nit000 !
95         !                                      ! -------------------- !
96         REWIND( numnam_ref )              ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
97         READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
98901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
99
100         REWIND( numnam_cfg )              ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
101         READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
102902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
103         IF(lwm) WRITE ( numond, namsbc_wave )
104         !
105         IF ( ln_cdgw ) THEN
106            ALLOCATE( sf_cd(1), STAT=ierror )           !* allocate and fill sf_wave with sn_cdg
107            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave: unable to allocate sf_wave structure' )
108            !
109                                   ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
110            IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
111            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave', 'Wave module ', 'namsbc_wave' )
112            ALLOCATE( cdn_wave(jpi,jpj) )
113            cdn_wave(:,:) = 0.0
114         ENDIF
115
116         IF ( ln_tauoc ) THEN
117            ALLOCATE( sf_tauoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauoc
118            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave: unable to allocate sf_wave structure' )
119            !
120                                   ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1)   )
121            IF( sn_tauoc%ln_tint )   ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
122            CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
123            ALLOCATE( tauoc_wave(jpi,jpj) )
124            tauoc_wave(:,:) = 0.0
125        ENDIF
126
127         IF ( ln_sdw ) THEN
128            slf_i(jp_usd) = sn_usd ; slf_i(jp_vsd) = sn_vsd;
129            slf_i(jp_swh) = sn_swh ; slf_i(jp_wmp) = sn_wmp;
130            ALLOCATE( sf_sd(jpfld), STAT=ierror )           !* allocate and fill sf_sd with stokes drift
131            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave: unable to allocate sf_wave structure' )
132            !
133            DO ifpr= 1, jpfld
134               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
135               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
136            END DO
137
138            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave', 'Wave module ', 'namsbc_wave' )
139            ALLOCATE( usd2d(jpi,jpj),vsd2d(jpi,jpj) )
140            ALLOCATE( usd3d(jpi,jpj,jpk),vsd3d(jpi,jpj,jpk),wsd3d(jpi,jpj,jpk) )
141            ALLOCATE( usd3dt(jpi,jpj,jpk),vsd3dt(jpi,jpj,jpk) )
142            ALLOCATE( swh(jpi,jpj), wmp(jpi,jpj) )
143            ALLOCATE( zusd2dt(jpi,jpj), zvsd2dt(jpi,jpj) )
144            usd3d(:,:,:) = 0._wp   ;   usd2d(:,:) = 0._wp   ;   
145            vsd3d(:,:,:) = 0._wp   ;   vsd2d(:,:) = 0._wp   ; 
146            wsd3d(:,:,:) = 0._wp   ;
147            usd3dt(:,:,:) = 0._wp  ;   vsd3dt(:,:,:) = 0._wp   ;
148            swh  (:,:)   = 0._wp   ;    wmp (:,:) = 0._wp ;
149            IF ( ln_zdfqiao ) THEN     !==  Vertical mixing enhancement using Qiao,2010  ==!
150               ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
151               IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave: unable toallocate sf_wave structure' )
152                                      ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
153               IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
154               CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
155               ALLOCATE( wnum(jpi,jpj),tsd2d(jpi,jpj) )
156               wnum(:,:) = 0._wp ; tsd2d(:,:) = 0._wp
157            ENDIF
158         ENDIF
159      ENDIF
160      !
161      IF ( ln_cdgw ) THEN              !==  Neutral drag coefficient  ==!
162         CALL fld_read( kt, nn_fsbc, sf_cd )      ! read from external forcing
163         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
164      ENDIF
165
166      IF ( ln_tauoc ) THEN             !==  Wave induced stress  ==!
167         CALL fld_read( kt, nn_fsbc, sf_tauoc )      !* read wave norm stress from external forcing
168         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1)
169      ENDIF
170
171      IF ( ln_sdw )  THEN                         !==  Computation of the 3d Stokes Drift  ==!
172         !
173         CALL fld_read( kt, nn_fsbc, sf_sd )      !* read wave parameters from external forcing
174         swh(:,:)     = sf_sd(jp_swh)%fnow(:,:,1)   ! significant wave height
175         wmp(:,:)     = sf_sd(jp_wmp)%fnow(:,:,1)   ! wave mean period
176         zusd2dt(:,:) = sf_sd(jp_usd)%fnow(:,:,1)   ! 2D zonal Stokes Drift at T point
177         zvsd2dt(:,:) = sf_sd(jp_vsd)%fnow(:,:,1)   ! 2D meridional Stokes Drift at T point
178         !
179         !==  Computation of the 3d Stokes Drift according to Breivik et al.,2014
180         !(DOI: 10.1175/JPO-D-14-0020.1)==!
181         !
182         CALL wrk_alloc( jpi,jpj,jpk, ze3hdiv )
183         DO jk = 1, jpk
184            DO jj = 1, jpj
185               DO ji = 1, jpi
186               ! On T grid
187               ! Stokes transport speed estimated from Hs and Tmean
188               ztransp = 2.0_wp*rpi*swh(ji,jj)**2.0_wp/(16.0_wp*MAX(wmp(ji,jj),0.0000001_wp))
189               ! Stokes surface speed
190               zsp0 = SQRT( zusd2dt(ji,jj)**2 + zvsd2dt(ji,jj)**2)
191               ! Wavenumber scale
192               zk = ABS(zsp0)/MAX(ABS(5.97_wp*ztransp),0.0000001_wp)
193               ! Depth attenuation
194               zfac(ji,jj) = EXP(-2.0_wp*zk*fsdept(ji,jj,jk))/(1.0_wp+8.0_wp*zk*fsdept(ji,jj,jk))
195               END DO
196            END DO
197            !
198            DO jj = 1, jpj
199               DO ji = 1, jpi
200                 usd3dt(ji,jj,jk) = zfac(ji,jj) * zusd2dt (ji,jj) * tmask(ji,jj,jk)
201                 vsd3dt(ji,jj,jk) = zfac(ji,jj) * zvsd2dt (ji,jj) * tmask(ji,jj,jk)
202               END DO
203            END DO
204         END DO
205         ! Into the U and V Grid
206         DO jk = 1, jpkm1
207            DO jj = 1, jpjm1
208               DO ji = 1, jpim1
209               usd3d(ji,jj,jk) =   0.5 *  umask(ji,jj,jk)  *        &
210                               &  (usd3dt(ji,jj,jk) + usd3dt(ji+1,jj,jk))
211               vsd3d(ji,jj,jk) =  0.5 *  vmask(ji,jj,jk)  *           &
212                               &  (vsd3dt(ji,jj,jk) + vsd3dt(ji,jj+1,jk))
213               END DO
214            END DO
215         END DO
216         !
217         CALL lbc_lnk( usd3d(:,:,:), 'U', -1. )
218         CALL lbc_lnk( vsd3d(:,:,:), 'V', -1. )
219         !
220         DO jk = 1, jpkm1                       ! e3t * Horizontal divergence
221            DO jj = 2, jpjm1
222               DO ji = fs_2, fs_jpim1   ! vector opt.
223                  ze3hdiv(ji,jj,jk) = (  e2u(ji  ,jj) * fse3u_n(ji  ,jj,jk) * usd3d(ji  ,jj,jk)     &
224                     &                 - e2u(ji-1,jj) * fse3u_n(ji-1,jj,jk) * usd3d(ji-1,jj,jk)     &
225                     &                 + e1v(ji,jj  ) * fse3v_n(ji,jj  ,jk) * vsd3d(ji,jj  ,jk)     &
226                     &                 - e1v(ji,jj-1) * fse3v_n(ji,jj-1,jk) * vsd3d(ji,jj-1,jk)   ) * r1_e1e2t(ji,jj)
227               END DO 
228            END DO 
229            IF( .NOT. AGRIF_Root() ) THEN
230               IF( nbondi ==  1 .OR. nbondi == 2 )   ze3hdiv(nlci-1,   :  ,jk) = 0._wp      ! east
231               IF( nbondi == -1 .OR. nbondi == 2 )   ze3hdiv(  2   ,   :  ,jk) = 0._wp      ! west
232               IF( nbondj ==  1 .OR. nbondj == 2 )   ze3hdiv(  :   ,nlcj-1,jk) = 0._wp      ! north
233               IF( nbondj == -1 .OR. nbondj == 2 )   ze3hdiv(  :   ,  2   ,jk) = 0._wp      ! south
234            ENDIF
235         END DO
236         CALL lbc_lnk( ze3hdiv, 'T', 1. ) 
237         !
238         DO jk = jpkm1, 1, -1                   !* integrate from the bottom the e3t * hor. divergence
239            wsd3d(:,:,jk) = wsd3d(:,:,jk+1) - ze3hdiv(:,:,jk)
240         END DO
241#if defined key_bdy
242         IF( lk_bdy ) THEN
243            DO jk = 1, jpkm1
244               wsd3d(:,:,jk) = wsd3d(:,:,jk) * bdytmask(:,:)
245            END DO
246         ENDIF
247#endif
248         CALL wrk_dealloc( jpi,jpj,jpk, ze3hdiv )
249
250         IF ( ln_zdfqiao ) THEN
251            wnum(:,:) = sf_wn(1)%fnow(:,:,1)
252           
253            ! Calculate the module of the stokes drift on T grid
254            !-------------------------------------------------
255            DO jj = 1, jpj
256               DO ji = 1, jpi
257                   tsd2d(ji,jj) = SQRT( zusd2dt(ji,jj)**2 + zvsd2dt(ji,jj)**2)
258               END DO
259            END DO
260         ENDIF
261         !
262      ENDIF
263      !
264   END SUBROUTINE sbc_wave
265     
266   !!======================================================================
267END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.