New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
albedo.F90 in branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/OPA_SRC/SBC/albedo.F90 @ 6316

Last change on this file since 6316 was 6316, checked in by cetlod, 8 years ago

3.6 stable : new realistic calculation of sea-ice albedo ( we keep the existing one ), see ticket #1678

  • Property svn:keywords set to Id
File size: 14.6 KB
Line 
1MODULE albedo
2   !!======================================================================
3   !!                       ***  MODULE  albedo  ***
4   !! Ocean forcing:  bulk thermohaline forcing of the ocean (or ice)
5   !!=====================================================================
6   !! History :  8.0  ! 2001-04  (LIM 1.0)
7   !!   NEMO     1.0  ! 2003-07  (C. Ethe, G. Madec)  Optimization (old name:shine)
8   !!             -   ! 2004-11  (C. Talandier)  add albedo_init
9   !!             -   ! 2001-06  (M. Vancoppenolle) LIM 3.0
10   !!             -   ! 2006-08  (G. Madec)  cleaning for surface module
11   !!            3.6  ! 2016-01  (C. Rousset) new parameterization for sea ice albedo
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   albedo_ice    : albedo for   ice (clear and overcast skies)
16   !!   albedo_oce    : albedo for ocean (clear and overcast skies)
17   !!   albedo_init   : initialisation of albedo computation
18   !!----------------------------------------------------------------------
19   USE phycst         ! physical constants
20   USE in_out_manager ! I/O manager
21   USE lib_mpp        ! MPP library
22   USE wrk_nemo       ! work arrays
23   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   albedo_ice   ! routine called sbcice_lim.F90
29   PUBLIC   albedo_oce   ! routine called by ???
30
31   INTEGER  ::   albd_init = 0      !: control flag for initialization
32   
33   !                             !!* namelist namsbc_alb
34   INTEGER  ::   nn_ice_alb
35   REAL(wp) ::   rn_albice
36
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE albedo_ice( pt_ice, ph_ice, ph_snw, pa_ice_cs, pa_ice_os )
45      !!----------------------------------------------------------------------
46      !!               ***  ROUTINE albedo_ice  ***
47      !!         
48      !! ** Purpose :   Computation of the albedo of the snow/ice system
49      !!       
50      !! ** Method  :   Two schemes are available (from namelist parameter nn_ice_alb)
51      !!                  0: the scheme is that of Shine & Henderson-Sellers (JGR 1985) for clear-skies
52      !!                  1: the scheme is "home made" (for cloudy skies) and based on Brandt et al. (J. Climate 2005)
53      !!                                                                           and Grenfell & Perovich (JGR 2004)
54      !!                Description of scheme 1:
55      !!                  1) Albedo dependency on ice thickness follows the findings from Brandt et al (2005)
56      !!                     which are an update of Allison et al. (JGR 1993) ; Brandt et al. 1999
57      !!                     0-5cm  : linear function of ice thickness
58      !!                     5-150cm: log    function of ice thickness
59      !!                     > 150cm: constant
60      !!                  2) Albedo dependency on snow thickness follows the findings from Grenfell & Perovich (2004)
61      !!                     i.e. it increases as -EXP(-snw_thick/0.02) during freezing and -EXP(-snw_thick/0.03) during melting
62      !!                  3) Albedo dependency on clouds is speculated from measurements of Grenfell and Perovich (2004)
63      !!                     i.e. cloudy-clear albedo depend on cloudy albedo following a 2d order polynomial law
64      !!                  4) The needed 4 parameters are: dry and melting snow, freezing ice and bare puddled ice
65      !!
66      !! ** Note    :   The parameterization from Shine & Henderson-Sellers presents several misconstructions:
67      !!                  1) ice albedo when ice thick. tends to 0 is different than ocean albedo
68      !!                  2) for small ice thick. covered with some snow (<3cm?), albedo is larger
69      !!                     under melting conditions than under freezing conditions
70      !!                  3) the evolution of ice albedo as a function of ice thickness shows 
71      !!                     3 sharp inflexion points (at 5cm, 100cm and 150cm) that look highly unrealistic
72      !!
73      !! References :   Shine & Henderson-Sellers 1985, JGR, 90(D1), 2243-2250.
74      !!                Brandt et al. 2005, J. Climate, vol 18
75      !!                Grenfell & Perovich 2004, JGR, vol 109
76      !!----------------------------------------------------------------------
77      REAL(wp), INTENT(in   ), DIMENSION(:,:,:) ::   pt_ice      !  ice surface temperature (Kelvin)
78      REAL(wp), INTENT(in   ), DIMENSION(:,:,:) ::   ph_ice      !  sea-ice thickness
79      REAL(wp), INTENT(in   ), DIMENSION(:,:,:) ::   ph_snw      !  snow thickness
80      REAL(wp), INTENT(  out), DIMENSION(:,:,:) ::   pa_ice_cs   !  albedo of ice under clear    sky
81      REAL(wp), INTENT(  out), DIMENSION(:,:,:) ::   pa_ice_os   !  albedo of ice under overcast sky
82      !!
83      INTEGER  ::   ji, jj, jl         ! dummy loop indices
84      INTEGER  ::   ijpl               ! number of ice categories (3rd dim of ice input arrays)
85      REAL(wp), PARAMETER ::   ralb_oce = 0.066   ! ocean or lead albedo (Pegau and Paulson, Ann. Glac. 2001)
86      REAL(wp), PARAMETER ::   c1       = 0.05    ! snow thickness (only for nn_ice_alb=0)
87      REAL(wp), PARAMETER ::   c2       = 0.10    !  "        "
88      REAL(wp), PARAMETER ::   rcloud   = 0.06    ! cloud effect on albedo (only for nn_ice_alb=0)
89      REAL(wp)            ::   ralb_im, ralb_sf, ralb_sm, ralb_if
90      REAL(wp)            ::   zswitch, z1_c1, z1_c2
91      REAL(wp)                            ::   zalb_sm, zalb_sf, zalb_st ! albedo of snow melting, freezing, total
92      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb, zalb_it             ! intermediate variable & albedo of ice (snow free)
93      !!---------------------------------------------------------------------
94
95      ijpl = SIZE( pt_ice, 3 )                     ! number of ice categories
96     
97      CALL wrk_alloc( jpi,jpj,ijpl, zalb, zalb_it )
98
99      IF( albd_init == 0 )   CALL albedo_init      ! initialization
100
101     
102      SELECT CASE ( nn_ice_alb )
103
104      !------------------------------------------
105      !  Shine and Henderson-Sellers (1985)
106      !------------------------------------------
107      CASE( 0 )
108       
109         ralb_sf = 0.80       ! dry snow
110         ralb_sm = 0.65       ! melting snow
111         ralb_if = 0.72       ! bare frozen ice
112         ralb_im = rn_albice  ! bare puddled ice
113         
114         !  Computation of ice albedo (free of snow)
115         WHERE     ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice )   ;   zalb(:,:,:) = ralb_im
116         ELSE WHERE                                              ;   zalb(:,:,:) = ralb_if
117         END  WHERE
118     
119         WHERE     ( 1.5  < ph_ice                     )  ;  zalb_it = zalb
120         ELSE WHERE( 1.0  < ph_ice .AND. ph_ice <= 1.5 )  ;  zalb_it = 0.472  + 2.0 * ( zalb - 0.472 ) * ( ph_ice - 1.0 )
121         ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.0 )  ;  zalb_it = 0.2467 + 0.7049 * ph_ice              &
122            &                                                                 - 0.8608 * ph_ice * ph_ice     &
123            &                                                                 + 0.3812 * ph_ice * ph_ice * ph_ice
124         ELSE WHERE                                       ;  zalb_it = 0.1    + 3.6    * ph_ice
125         END WHERE
126     
127         z1_c1 = 1. / c1
128         z1_c2 = 1. / c2
129         !  Computation of the snow/ice albedo
130         DO jl = 1, ijpl
131            DO jj = 1, jpj
132               DO ji = 1, jpi
133                  ! freezing snow
134                  ! no effect of underlying ice layer IF snow thickness > c1. Albedo does not depend on snow thick if > c2
135                  zswitch = MAX( 0._wp , SIGN( 1._wp , ph_snw(ji,jj,jl) - c1 ) )
136                  zalb_sf = ( 1._wp - zswitch ) * ( zalb_it(ji,jj,jl) + ph_snw(ji,jj,jl) &
137                     &                          * ( ralb_sf - zalb_it(ji,jj,jl) ) * z1_c1 )  &
138                     &     +          zswitch   * ralb_sf 
139                 
140                  ! melting snow
141                  ! no effect of underlying ice layer. Albedo does not depend on snow thick IF > c2   
142                  zswitch = MAX( 0._wp , SIGN( 1._wp , ph_snw(ji,jj,jl) - c2 ) )
143                  zalb_sm = ( 1._wp - zswitch ) * ( ralb_im + ph_snw(ji,jj,jl) &
144                     &                          * ( ralb_sm - ralb_im ) * z1_c2 )   &
145                     &     +          zswitch   *   ralb_sm 
146                 
147                  ! snow albedo
148                  zswitch = MAX( 0._wp , SIGN( 1._wp , pt_ice(ji,jj,jl) - rt0_snow ) )   
149                  zalb_st = zswitch * zalb_sm + ( 1.0 - zswitch ) * zalb_sf
150                 
151                  ! Ice/snow albedo   
152                  zswitch             = MAX( 0._wp , SIGN( 1._wp , - ph_snw(ji,jj,jl) ) )
153                  pa_ice_cs(ji,jj,jl) = ( 1._wp - zswitch ) * zalb_st + zswitch *  zalb_it(ji,jj,jl)
154               END DO
155            END DO
156         END DO
157         pa_ice_os(:,:,:) = pa_ice_cs(:,:,:) + rcloud       ! Oberhuber correction for overcast sky
158
159      !------------------------------------------
160      !  New parameterization (2016)
161      !------------------------------------------
162      CASE( 1 ) 
163
164         ralb_im = rn_albice  ! bare puddled ice
165! compilation of values from literature
166         ralb_sf = 0.85      ! dry snow
167         ralb_sm = 0.75      ! melting snow
168         ralb_if = 0.60      ! bare frozen ice
169! Perovich et al 2002 (Sheba) => the only dataset for which all types of ice/snow were retrieved
170!         ralb_sf = 0.85       ! dry snow
171!         ralb_sm = 0.72       ! melting snow
172!         ralb_if = 0.65       ! bare frozen ice
173! Brandt et al 2005 (East Antarctica)
174!         ralb_sf = 0.87      ! dry snow
175!         ralb_sm = 0.82      ! melting snow
176!         ralb_if = 0.54      ! bare frozen ice
177!
178         !  Computation of ice albedo (free of snow)
179         z1_c1 = 1. / ( LOG(1.5) - LOG(0.05) ) 
180         z1_c2 = 1. / 0.05
181         WHERE     ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice )   ;   zalb = ralb_im
182         ELSE WHERE                                              ;   zalb = ralb_if
183         END  WHERE
184         
185         WHERE     ( 1.5  < ph_ice                     )  ;  zalb_it = zalb
186         ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.5 )  ;  zalb_it = zalb     + ( 0.18 - zalb     ) * z1_c1 *  &
187            &                                                                     ( LOG(1.5) - LOG(ph_ice) )
188         ELSE WHERE                                       ;  zalb_it = ralb_oce + ( 0.18 - ralb_oce ) * z1_c2 * ph_ice
189         END WHERE
190
191         z1_c1 = 1. / 0.02
192         z1_c2 = 1. / 0.03
193         !  Computation of the snow/ice albedo
194         DO jl = 1, ijpl
195            DO jj = 1, jpj
196               DO ji = 1, jpi
197                  zalb_sf = ralb_sf - ( ralb_sf - zalb_it(ji,jj,jl)) * EXP( - ph_snw(ji,jj,jl) * z1_c1 );
198                  zalb_sm = ralb_sm - ( ralb_sm - zalb_it(ji,jj,jl)) * EXP( - ph_snw(ji,jj,jl) * z1_c2 );
199
200                   ! snow albedo
201                  zswitch = MAX( 0._wp , SIGN( 1._wp , pt_ice(ji,jj,jl) - rt0_snow ) )   
202                  zalb_st = zswitch * zalb_sm + ( 1._wp - zswitch ) * zalb_sf
203
204                  ! Ice/snow albedo   
205                  zswitch             = MAX( 0._wp , SIGN( 1._wp , - ph_snw(ji,jj,jl) ) )
206                  pa_ice_os(ji,jj,jl) = ( 1._wp - zswitch ) * zalb_st + zswitch *  zalb_it(ji,jj,jl)
207
208              END DO
209            END DO
210         END DO
211         ! Effect of the clouds (2d order polynomial)
212         pa_ice_cs = pa_ice_os - ( - 0.1010 * pa_ice_os * pa_ice_os + 0.1933 * pa_ice_os - 0.0148 ); 
213
214      END SELECT
215     
216      CALL wrk_dealloc( jpi,jpj,ijpl, zalb, zalb_it )
217      !
218   END SUBROUTINE albedo_ice
219
220
221   SUBROUTINE albedo_oce( pa_oce_os , pa_oce_cs )
222      !!----------------------------------------------------------------------
223      !!               ***  ROUTINE albedo_oce  ***
224      !!
225      !! ** Purpose :   Computation of the albedo of the ocean
226      !!----------------------------------------------------------------------
227      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pa_oce_os   !  albedo of ocean under overcast sky
228      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pa_oce_cs   !  albedo of ocean under clear sky
229      !!
230      REAL(wp) ::   rmue   = 0.40    !  cosine of local solar altitude
231      !!----------------------------------------------------------------------
232      !
233      pa_oce_cs(:,:) = 0.05 / ( 1.1 * rmue**1.4 + 0.15 )   ! Parameterization of Briegled and Ramanathan, 1982             
234      pa_oce_os(:,:) = 0.06                                ! Parameterization of Kondratyev, 1969 and Payne, 1972
235      !
236   END SUBROUTINE albedo_oce
237
238
239   SUBROUTINE albedo_init
240      !!----------------------------------------------------------------------
241      !!                 ***  ROUTINE albedo_init  ***
242      !!
243      !! ** Purpose :   initializations for the albedo parameters
244      !!
245      !! ** Method  :   Read the namelist namsbc_alb
246      !!----------------------------------------------------------------------
247      INTEGER  ::   ios                 ! Local integer output status for namelist read
248      NAMELIST/namsbc_alb/ nn_ice_alb, rn_albice 
249      !!----------------------------------------------------------------------
250      !
251      albd_init = 1                     ! indicate that the initialization has been done
252      !
253      REWIND( numnam_ref )              ! Namelist namsbc_alb in reference namelist : Albedo parameters
254      READ  ( numnam_ref, namsbc_alb, IOSTAT = ios, ERR = 901)
255901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_alb in reference namelist', lwp )
256
257      REWIND( numnam_cfg )              ! Namelist namsbc_alb in configuration namelist : Albedo parameters
258      READ  ( numnam_cfg, namsbc_alb, IOSTAT = ios, ERR = 902 )
259902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_alb in configuration namelist', lwp )
260      IF(lwm) WRITE ( numond, namsbc_alb )
261      !
262      IF(lwp) THEN                      ! Control print
263         WRITE(numout,*)
264         WRITE(numout,*) 'albedo : set albedo parameters'
265         WRITE(numout,*) '~~~~~~~'
266         WRITE(numout,*) '   Namelist namsbc_alb : albedo '
267         WRITE(numout,*) '      choose the albedo parameterization                  nn_ice_alb = ', nn_ice_alb
268         WRITE(numout,*) '      albedo of bare puddled ice                          rn_albice  = ', rn_albice
269      ENDIF
270      !
271   END SUBROUTINE albedo_init
272
273   !!======================================================================
274END MODULE albedo
Note: See TracBrowser for help on using the repository browser.