1 | MODULE albedo |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE albedo *** |
---|
4 | !! Ocean forcing: bulk thermohaline forcing of the ocean (or ice) |
---|
5 | !!===================================================================== |
---|
6 | !! History : 8.0 ! 2001-04 (LIM 1.0) |
---|
7 | !! NEMO 1.0 ! 2003-07 (C. Ethe, G. Madec) Optimization (old name:shine) |
---|
8 | !! - ! 2004-11 (C. Talandier) add albedo_init |
---|
9 | !! - ! 2001-06 (M. Vancoppenolle) LIM 3.0 |
---|
10 | !! - ! 2006-08 (G. Madec) cleaning for surface module |
---|
11 | !! 3.6 ! 2016-01 (C. Rousset) new parameterization for sea ice albedo |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! albedo_ice : albedo for ice (clear and overcast skies) |
---|
16 | !! albedo_oce : albedo for ocean (clear and overcast skies) |
---|
17 | !! albedo_init : initialisation of albedo computation |
---|
18 | !!---------------------------------------------------------------------- |
---|
19 | USE phycst ! physical constants |
---|
20 | USE in_out_manager ! I/O manager |
---|
21 | USE lib_mpp ! MPP library |
---|
22 | USE wrk_nemo ! work arrays |
---|
23 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
24 | |
---|
25 | IMPLICIT NONE |
---|
26 | PRIVATE |
---|
27 | |
---|
28 | PUBLIC albedo_ice ! routine called sbcice_lim.F90 |
---|
29 | PUBLIC albedo_oce ! routine called by ??? |
---|
30 | |
---|
31 | INTEGER :: albd_init = 0 !: control flag for initialization |
---|
32 | |
---|
33 | REAL(wp) :: rmue = 0.40 ! cosine of local solar altitude |
---|
34 | REAL(wp) :: ralb_oce = 0.066 ! ocean or lead albedo (Pegau and Paulson, Ann. Glac. 2001) |
---|
35 | REAL(wp) :: c1 = 0.05 ! snow thickness (only for nn_ice_alb=0) |
---|
36 | REAL(wp) :: c2 = 0.10 ! " " |
---|
37 | REAL(wp) :: rcloud = 0.06 ! cloud effect on albedo (only-for nn_ice_alb=0) |
---|
38 | |
---|
39 | ! !!* namelist namsbc_alb |
---|
40 | INTEGER :: nn_ice_alb |
---|
41 | REAL(wp) :: rn_alb_sdry, rn_alb_smlt, rn_alb_idry, rn_alb_imlt |
---|
42 | |
---|
43 | !!---------------------------------------------------------------------- |
---|
44 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
45 | !! $Id$ |
---|
46 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
47 | !!---------------------------------------------------------------------- |
---|
48 | CONTAINS |
---|
49 | |
---|
50 | SUBROUTINE albedo_ice( pt_ice, ph_ice, ph_snw, pa_ice_cs, pa_ice_os ) |
---|
51 | !!---------------------------------------------------------------------- |
---|
52 | !! *** ROUTINE albedo_ice *** |
---|
53 | !! |
---|
54 | !! ** Purpose : Computation of the albedo of the snow/ice system |
---|
55 | !! |
---|
56 | !! ** Method : Two schemes are available (from namelist parameter nn_ice_alb) |
---|
57 | !! 0: the scheme is that of Shine & Henderson-Sellers (JGR 1985) for clear-skies |
---|
58 | !! 1: the scheme is "home made" (for cloudy skies) and based on Brandt et al. (J. Climate 2005) |
---|
59 | !! and Grenfell & Perovich (JGR 2004) |
---|
60 | !! Description of scheme 1: |
---|
61 | !! 1) Albedo dependency on ice thickness follows the findings from Brandt et al (2005) |
---|
62 | !! which are an update of Allison et al. (JGR 1993) ; Brandt et al. 1999 |
---|
63 | !! 0-5cm : linear function of ice thickness |
---|
64 | !! 5-150cm: log function of ice thickness |
---|
65 | !! > 150cm: constant |
---|
66 | !! 2) Albedo dependency on snow thickness follows the findings from Grenfell & Perovich (2004) |
---|
67 | !! i.e. it increases as -EXP(-snw_thick/0.02) during freezing and -EXP(-snw_thick/0.03) during melting |
---|
68 | !! 3) Albedo dependency on clouds is speculated from measurements of Grenfell and Perovich (2004) |
---|
69 | !! i.e. cloudy-clear albedo depend on cloudy albedo following a 2d order polynomial law |
---|
70 | !! 4) The needed 4 parameters are: dry and melting snow, freezing ice and bare puddled ice |
---|
71 | !! |
---|
72 | !! ** Note : The parameterization from Shine & Henderson-Sellers presents several misconstructions: |
---|
73 | !! 1) ice albedo when ice thick. tends to 0 is different than ocean albedo |
---|
74 | !! 2) for small ice thick. covered with some snow (<3cm?), albedo is larger |
---|
75 | !! under melting conditions than under freezing conditions |
---|
76 | !! 3) the evolution of ice albedo as a function of ice thickness shows |
---|
77 | !! 3 sharp inflexion points (at 5cm, 100cm and 150cm) that look highly unrealistic |
---|
78 | !! |
---|
79 | !! References : Shine & Henderson-Sellers 1985, JGR, 90(D1), 2243-2250. |
---|
80 | !! Brandt et al. 2005, J. Climate, vol 18 |
---|
81 | !! Grenfell & Perovich 2004, JGR, vol 109 |
---|
82 | !!---------------------------------------------------------------------- |
---|
83 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: pt_ice ! ice surface temperature (Kelvin) |
---|
84 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_ice ! sea-ice thickness |
---|
85 | REAL(wp), INTENT(in ), DIMENSION(:,:,:) :: ph_snw ! snow thickness |
---|
86 | REAL(wp), INTENT( out), DIMENSION(:,:,:) :: pa_ice_cs ! albedo of ice under clear sky |
---|
87 | REAL(wp), INTENT( out), DIMENSION(:,:,:) :: pa_ice_os ! albedo of ice under overcast sky |
---|
88 | !! |
---|
89 | INTEGER :: ji, jj, jl ! dummy loop indices |
---|
90 | INTEGER :: ijpl ! number of ice categories (3rd dim of ice input arrays) |
---|
91 | REAL(wp) :: ralb_im, ralb_sf, ralb_sm, ralb_if |
---|
92 | REAL(wp) :: zswitch, z1_c1, z1_c2 |
---|
93 | REAL(wp) :: zalb_sm, zalb_sf, zalb_st ! albedo of snow melting, freezing, total |
---|
94 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb, zalb_it ! intermediate variable & albedo of ice (snow free) |
---|
95 | !!--------------------------------------------------------------------- |
---|
96 | |
---|
97 | ijpl = SIZE( pt_ice, 3 ) ! number of ice categories |
---|
98 | |
---|
99 | CALL wrk_alloc( jpi,jpj,ijpl, zalb, zalb_it ) |
---|
100 | |
---|
101 | IF( albd_init == 0 ) CALL albedo_init ! initialization |
---|
102 | |
---|
103 | ralb_sf = rn_alb_sdry ! dry snow |
---|
104 | ralb_sm = rn_alb_smlt ! melting snow |
---|
105 | ralb_if = rn_alb_idry ! bare frozen ice |
---|
106 | ralb_im = rn_alb_imlt ! bare puddled ice |
---|
107 | |
---|
108 | SELECT CASE ( nn_ice_alb ) |
---|
109 | |
---|
110 | !------------------------------------------ |
---|
111 | ! Shine and Henderson-Sellers (1985) |
---|
112 | !------------------------------------------ |
---|
113 | CASE( 0 ) |
---|
114 | |
---|
115 | ! Computation of ice albedo (free of snow) |
---|
116 | WHERE ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice ) ; zalb(:,:,:) = ralb_im |
---|
117 | ELSE WHERE ; zalb(:,:,:) = ralb_if |
---|
118 | END WHERE |
---|
119 | |
---|
120 | WHERE ( 1.5 < ph_ice ) ; zalb_it = zalb |
---|
121 | ELSE WHERE( 1.0 < ph_ice .AND. ph_ice <= 1.5 ) ; zalb_it = 0.472 + 2.0 * ( zalb - 0.472 ) * ( ph_ice - 1.0 ) |
---|
122 | ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.0 ) ; zalb_it = 0.2467 + 0.7049 * ph_ice & |
---|
123 | & - 0.8608 * ph_ice * ph_ice & |
---|
124 | & + 0.3812 * ph_ice * ph_ice * ph_ice |
---|
125 | ELSE WHERE ; zalb_it = 0.1 + 3.6 * ph_ice |
---|
126 | END WHERE |
---|
127 | |
---|
128 | DO jl = 1, ijpl |
---|
129 | DO jj = 1, jpj |
---|
130 | DO ji = 1, jpi |
---|
131 | ! freezing snow |
---|
132 | ! no effect of underlying ice layer IF snow thickness > c1. Albedo does not depend on snow thick if > c2 |
---|
133 | ! ! freezing snow |
---|
134 | zswitch = 1._wp - MAX( 0._wp , SIGN( 1._wp , - ( ph_snw(ji,jj,jl) - c1 ) ) ) |
---|
135 | zalb_sf = ( 1._wp - zswitch ) * ( zalb_it(ji,jj,jl) & |
---|
136 | & + ph_snw(ji,jj,jl) * ( ralb_sf - zalb_it(ji,jj,jl) ) / c1 ) & |
---|
137 | & + zswitch * ralb_sf |
---|
138 | |
---|
139 | ! melting snow |
---|
140 | ! no effect of underlying ice layer. Albedo does not depend on snow thick IF > c2 |
---|
141 | zswitch = MAX( 0._wp , SIGN( 1._wp , ph_snw(ji,jj,jl) - c2 ) ) |
---|
142 | zalb_sm = ( 1._wp - zswitch ) * ( ralb_im + ph_snw(ji,jj,jl) * ( ralb_sm - ralb_im ) / c2 ) & |
---|
143 | & + zswitch * ralb_sm |
---|
144 | ! |
---|
145 | ! snow albedo |
---|
146 | zswitch = MAX( 0._wp , SIGN( 1._wp , pt_ice(ji,jj,jl) - rt0_snow ) ) |
---|
147 | zalb_st = zswitch * zalb_sm + ( 1._wp - zswitch ) * zalb_sf |
---|
148 | |
---|
149 | ! Ice/snow albedo |
---|
150 | zswitch = 1._wp - MAX( 0._wp , SIGN( 1._wp , - ph_snw(ji,jj,jl) ) ) |
---|
151 | pa_ice_cs(ji,jj,jl) = zswitch * zalb_st + ( 1._wp - zswitch ) * zalb_it(ji,jj,jl) |
---|
152 | ! |
---|
153 | END DO |
---|
154 | END DO |
---|
155 | END DO |
---|
156 | |
---|
157 | pa_ice_os(:,:,:) = pa_ice_cs(:,:,:) + rcloud ! Oberhuber correction for overcast sky |
---|
158 | |
---|
159 | !------------------------------------------ |
---|
160 | ! New parameterization (2016) |
---|
161 | !------------------------------------------ |
---|
162 | CASE( 1 ) |
---|
163 | |
---|
164 | ! compilation of values from literature |
---|
165 | ! ralb_sf = 0.85 ! dry snow |
---|
166 | ! ralb_sm = 0.75 ! melting snow |
---|
167 | ! ralb_if = 0.60 ! bare frozen ice |
---|
168 | ! Perovich et al 2002 (Sheba) => the only dataset for which all types of ice/snow were retrieved |
---|
169 | ! ralb_sf = 0.85 ! dry snow |
---|
170 | ! ralb_sm = 0.72 ! melting snow |
---|
171 | ! ralb_if = 0.65 ! bare frozen ice |
---|
172 | ! Brandt et al 2005 (East Antarctica) |
---|
173 | ! ralb_sf = 0.87 ! dry snow |
---|
174 | ! ralb_sm = 0.82 ! melting snow |
---|
175 | ! ralb_if = 0.54 ! bare frozen ice |
---|
176 | ! |
---|
177 | ! Computation of ice albedo (free of snow) |
---|
178 | z1_c1 = 1. / ( LOG(1.5) - LOG(0.05) ) |
---|
179 | z1_c2 = 1. / 0.05 |
---|
180 | WHERE ( ph_snw == 0._wp .AND. pt_ice >= rt0_ice ) ; zalb = ralb_im |
---|
181 | ELSE WHERE ; zalb = ralb_if |
---|
182 | END WHERE |
---|
183 | |
---|
184 | WHERE ( 1.5 < ph_ice ) ; zalb_it = zalb |
---|
185 | ELSE WHERE( 0.05 < ph_ice .AND. ph_ice <= 1.5 ) ; zalb_it = zalb + ( 0.18 - zalb ) * z1_c1 * & |
---|
186 | & ( LOG(1.5) - LOG(ph_ice) ) |
---|
187 | ELSE WHERE ; zalb_it = ralb_oce + ( 0.18 - ralb_oce ) * z1_c2 * ph_ice |
---|
188 | END WHERE |
---|
189 | |
---|
190 | z1_c1 = 1. / 0.02 |
---|
191 | z1_c2 = 1. / 0.03 |
---|
192 | ! Computation of the snow/ice albedo |
---|
193 | DO jl = 1, ijpl |
---|
194 | DO jj = 1, jpj |
---|
195 | DO ji = 1, jpi |
---|
196 | zalb_sf = ralb_sf - ( ralb_sf - zalb_it(ji,jj,jl)) * EXP( - ph_snw(ji,jj,jl) * z1_c1 ); |
---|
197 | zalb_sm = ralb_sm - ( ralb_sm - zalb_it(ji,jj,jl)) * EXP( - ph_snw(ji,jj,jl) * z1_c2 ); |
---|
198 | |
---|
199 | ! snow albedo |
---|
200 | zswitch = MAX( 0._wp , SIGN( 1._wp , pt_ice(ji,jj,jl) - rt0_snow ) ) |
---|
201 | zalb_st = zswitch * zalb_sm + ( 1._wp - zswitch ) * zalb_sf |
---|
202 | |
---|
203 | ! Ice/snow albedo |
---|
204 | zswitch = MAX( 0._wp , SIGN( 1._wp , - ph_snw(ji,jj,jl) ) ) |
---|
205 | pa_ice_os(ji,jj,jl) = ( 1._wp - zswitch ) * zalb_st + zswitch * zalb_it(ji,jj,jl) |
---|
206 | |
---|
207 | END DO |
---|
208 | END DO |
---|
209 | END DO |
---|
210 | ! Effect of the clouds (2d order polynomial) |
---|
211 | pa_ice_cs = pa_ice_os - ( - 0.1010 * pa_ice_os * pa_ice_os + 0.1933 * pa_ice_os - 0.0148 ); |
---|
212 | |
---|
213 | END SELECT |
---|
214 | |
---|
215 | CALL wrk_dealloc( jpi,jpj,ijpl, zalb, zalb_it ) |
---|
216 | ! |
---|
217 | END SUBROUTINE albedo_ice |
---|
218 | |
---|
219 | |
---|
220 | SUBROUTINE albedo_oce( pa_oce_os , pa_oce_cs ) |
---|
221 | !!---------------------------------------------------------------------- |
---|
222 | !! *** ROUTINE albedo_oce *** |
---|
223 | !! |
---|
224 | !! ** Purpose : Computation of the albedo of the ocean |
---|
225 | !!---------------------------------------------------------------------- |
---|
226 | REAL(wp), DIMENSION(:,:), INTENT(out) :: pa_oce_os ! albedo of ocean under overcast sky |
---|
227 | REAL(wp), DIMENSION(:,:), INTENT(out) :: pa_oce_cs ! albedo of ocean under clear sky |
---|
228 | !! |
---|
229 | REAL(wp) :: zcoef |
---|
230 | !!---------------------------------------------------------------------- |
---|
231 | ! |
---|
232 | zcoef = 0.05 / ( 1.1 * rmue**1.4 + 0.15 ) ! Parameterization of Briegled and Ramanathan, 1982 |
---|
233 | pa_oce_cs(:,:) = zcoef |
---|
234 | pa_oce_os(:,:) = 0.06 ! Parameterization of Kondratyev, 1969 and Payne, 1972 |
---|
235 | ! |
---|
236 | END SUBROUTINE albedo_oce |
---|
237 | |
---|
238 | |
---|
239 | SUBROUTINE albedo_init |
---|
240 | !!---------------------------------------------------------------------- |
---|
241 | !! *** ROUTINE albedo_init *** |
---|
242 | !! |
---|
243 | !! ** Purpose : initializations for the albedo parameters |
---|
244 | !! |
---|
245 | !! ** Method : Read the namelist namsbc_alb |
---|
246 | !!---------------------------------------------------------------------- |
---|
247 | INTEGER :: ios ! Local integer output status for namelist read |
---|
248 | NAMELIST/namsbc_alb/ nn_ice_alb, rn_alb_sdry, rn_alb_smlt, rn_alb_idry , rn_alb_imlt |
---|
249 | !!---------------------------------------------------------------------- |
---|
250 | ! |
---|
251 | albd_init = 1 ! indicate that the initialization has been done |
---|
252 | ! |
---|
253 | REWIND( numnam_ref ) ! Namelist namsbc_alb in reference namelist : Albedo parameters |
---|
254 | READ ( numnam_ref, namsbc_alb, IOSTAT = ios, ERR = 901) |
---|
255 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_alb in reference namelist', lwp ) |
---|
256 | |
---|
257 | REWIND( numnam_cfg ) ! Namelist namsbc_alb in configuration namelist : Albedo parameters |
---|
258 | READ ( numnam_cfg, namsbc_alb, IOSTAT = ios, ERR = 902 ) |
---|
259 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_alb in configuration namelist', lwp ) |
---|
260 | IF(lwm) WRITE ( numond, namsbc_alb ) |
---|
261 | ! |
---|
262 | IF(lwp) THEN ! Control print |
---|
263 | WRITE(numout,*) |
---|
264 | WRITE(numout,*) 'albedo : set albedo parameters' |
---|
265 | WRITE(numout,*) '~~~~~~~' |
---|
266 | WRITE(numout,*) ' Namelist namsbc_alb : albedo ' |
---|
267 | WRITE(numout,*) ' choose the albedo parameterization nn_ice_alb = ', nn_ice_alb |
---|
268 | WRITE(numout,*) ' albedo of dry snow rn_alb_sdry = ', rn_alb_sdry |
---|
269 | WRITE(numout,*) ' albedo of melting snow rn_alb_smlt = ', rn_alb_smlt |
---|
270 | WRITE(numout,*) ' albedo of dry ice rn_alb_idry = ', rn_alb_idry |
---|
271 | WRITE(numout,*) ' albedo of bare puddled ice rn_alb_imlt = ', rn_alb_imlt |
---|
272 | ENDIF |
---|
273 | ! |
---|
274 | END SUBROUTINE albedo_init |
---|
275 | |
---|
276 | !!====================================================================== |
---|
277 | END MODULE albedo |
---|